ceph/src/jaegertracing/opentelemetry-cpp/tools/vcpkg/ports/libevent/portfile.cmake

   1 vcpkg_fail_port_install(ON_TARGET "uwp")
   2
   3 vcpkg_from_github(
   4     OUT_SOURCE_PATH SOURCE_PATH
   5     REPO libevent/libevent
   6     REF release-2.1.12-stable
   7     SHA512 5d6c6f0072f69a68b190772d4c973ce8f33961912032cdc104ad0854c0950f9d7e28bc274ca9df23897937f0cd8e45d1f214543d80ec271c5a6678814a7f195e
   8     PATCHES
   9         fix-file_path.patch
  10         fix-LibeventConfig_cmake_in_path.patch
  11 )
  12
  13 vcpkg_check_features(OUT_FEATURE_OPTIONS FEATURE_OPTIONS
  14     INVERTED_FEATURES
  15     openssl EVENT__DISABLE_OPENSSL
  16     thread  EVENT__DISABLE_THREAD_SUPPORT
  17 )
  18
  19 if (VCPKG_LIBRARY_LINKAGE STREQUAL "dynamic")
  20     set(LIBEVENT_LIB_TYPE SHARED)
  21 else()
  22     set(LIBEVENT_LIB_TYPE STATIC)
  23 endif()
  24
  25 if(VCPKG_CRT_LINKAGE STREQUAL "static")
  26     set(LIBEVENT_STATIC_RUNTIME ON)
  27 else()
  28     set(LIBEVENT_STATIC_RUNTIME OFF)
  29 endif()
  30
  31 vcpkg_configure_cmake(
  32     SOURCE_PATH ${SOURCE_PATH}
  33     PREFER_NINJA
  34     OPTIONS ${FEATURE_OPTIONS}
  35         -DEVENT__LIBRARY_TYPE=${LIBEVENT_LIB_TYPE}
  36         -DEVENT__MSVC_STATIC_RUNTIME=${LIBEVENT_STATIC_RUNTIME}
  37         -DEVENT__DISABLE_BENCHMARK=ON
  38         -DEVENT__DISABLE_TESTS=ON
  39         -DEVENT__DISABLE_REGRESS=ON
  40         -DEVENT__DISABLE_SAMPLES=ON
  41 )
  42
  43 vcpkg_install_cmake()
  44
  45 vcpkg_fixup_cmake_targets(CONFIG_PATH lib/cmake TARGET_PATH share)
  46
  47 file(MAKE_DIRECTORY ${CURRENT_PACKAGES_DIR}/tools/libevent/)
  48 file(RENAME ${CURRENT_PACKAGES_DIR}/bin/event_rpcgen.py ${CURRENT_PACKAGES_DIR}/tools/libevent/event_rpcgen.py)
  49
  50 file(REMOVE_RECURSE ${CURRENT_PACKAGES_DIR}/debug/include)
  51 file(REMOVE_RECURSE ${CURRENT_PACKAGES_DIR}/debug/share)
  52 if(VCPKG_LIBRARY_LINKAGE STREQUAL static)
  53     file(REMOVE_RECURSE ${CURRENT_PACKAGES_DIR}/bin ${CURRENT_PACKAGES_DIR}/debug/bin)
  54 endif()
  55
  56 set(_target_suffix)
  57 if(VCPKG_LIBRARY_LINKAGE STREQUAL static)
  58     set(_target_suffix static)
  59 else()
  60     set(_target_suffix shared)
  61 endif()
  62 vcpkg_replace_string(${CURRENT_PACKAGES_DIR}/share/libevent/LibeventTargets-${_target_suffix}.cmake
  63     "${CURRENT_PACKAGES_DIR}"
  64     "${CURRENT_INSTALLED_DIR}"
  65 )
  66
  67 vcpkg_copy_pdbs()
  68
  69 #Handle copyright
  70 file(INSTALL ${SOURCE_PATH}/LICENSE DESTINATION ${CURRENT_PACKAGES_DIR}/share/${PORT} RENAME copyright)