ceph/src/jaegertracing/opentelemetry-cpp/tools/vcpkg/ports/libodb/CMakeLists.txt

   1 cmake_minimum_required(VERSION 3.0)
   2 project(libodb VERSION 2.4.0 LANGUAGES CXX)
   3 set(LIBODB_INSTALL_HEADERS ON CACHE BOOL "Install the header files (a debug install)")
   4 configure_file(config.unix.h.in
   5     ${CMAKE_CURRENT_SOURCE_DIR}/odb/details/config.h COPYONLY)
   6
   7 file(GLOB_RECURSE libodb_src LIST_DIRECTORIES False
   8     RELATIVE ${CMAKE_CURRENT_SOURCE_DIR}
   9     *.cxx)
  10 if (WIN32)
  11   list(FILTER libodb_src EXCLUDE REGEX /posix/.*)
  12 elseif (UNIX)
  13   list(FILTER libodb_src EXCLUDE REGEX /win32/.*)
  14 endif()
  15
  16 add_library(libodb ${libodb_src})
  17 target_include_directories(libodb
  18     PUBLIC
  19         $<INSTALL_INTERFACE:include>
  20         $<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}>
  21
  22 )
  23 if(BUILD_SHARED_LIBS)
  24     target_compile_definitions(libodb PRIVATE
  25         -DLIBODB_DYNAMIC_LIB)
  26 else()
  27     target_compile_definitions(libodb PRIVATE
  28         -DLIBODB_STATIC_LIB)
  29 endif()
  30 install(TARGETS libodb EXPORT odb_libodbConfig
  31     COMPONENT libodb
  32     ARCHIVE DESTINATION lib
  33     LIBRARY DESTINATION lib
  34     RUNTIME DESTINATION bin
  35 )
  36 if(LIBODB_INSTALL_HEADERS)
  37 install(DIRECTORY odb DESTINATION include/
  38         COMPONENT libodb
  39         FILES_MATCHING
  40         PATTERN "*.h"
  41         PATTERN "*.hxx"
  42         PATTERN "*.ixx"
  43         PATTERN "*.txx"
  44 )
  45 endif()
  46 install(EXPORT odb_libodbConfig NAMESPACE odb:: COMPONENT libodb DESTINATION share/odb)
  47 export(TARGETS libodb NAMESPACE odb:: FILE odb_libodbConfig.cmake)