ceph/src/jaegertracing/opentelemetry-cpp/tools/vcpkg/ports/mozjpeg/portfile.cmake

   1 if(EXISTS "${CURRENT_INSTALLED_DIR}/share/libjpeg-turbo/copyright")
   2     message(FATAL_ERROR "Can't build ${PORT} if libjpeg-turbo is installed. Please remove libjpeg-turbo:${TARGET_TRIPLET}, and try to install ${PORT}:${TARGET_TRIPLET} again.")
   3 endif()
   4
   5 vcpkg_from_github(
   6     OUT_SOURCE_PATH SOURCE_PATH
   7     REPO mozilla/mozjpeg
   8     REF 6d95c51adf0c314017f541b6cb07e13cc1bce754
   9     SHA512 a21c8b3a561b387933a27befaa1d05a8c63b0e203d72d73071a4c9b57c6b7d57b44836f211c4dcb80eee4b01876f0a0fb4c91a60c3ae867e906e5e4e27165627
  10     HEAD_REF master
  11     PATCHES
  12         fix-install-error.patch
  13 )
  14
  15 vcpkg_find_acquire_program(NASM)
  16 get_filename_component(NASM_EXE_PATH ${NASM} DIRECTORY)
  17 vcpkg_add_to_path(${NASM_EXE_PATH})
  18
  19 string(COMPARE EQUAL "${VCPKG_LIBRARY_LINKAGE}" "dynamic" ENABLE_SHARED)
  20 string(COMPARE EQUAL "${VCPKG_LIBRARY_LINKAGE}" "static" ENABLE_STATIC)
  21 string(COMPARE EQUAL "${VCPKG_CRT_LINKAGE}" "dynamic" WITH_CRT_DLL)
  22
  23 vcpkg_configure_cmake(
  24     SOURCE_PATH ${SOURCE_PATH}
  25     PREFER_NINJA
  26     OPTIONS
  27         -DENABLE_SHARED=${ENABLE_SHARED}
  28         -DENABLE_STATIC=${ENABLE_STATIC}
  29         -DWITH_CRT_DLL=${WITH_CRT_DLL}
  30 )
  31
  32 vcpkg_install_cmake()
  33
  34 # Rename libraries for static builds
  35 if(VCPKG_LIBRARY_LINKAGE STREQUAL static)
  36     if(EXISTS "${CURRENT_PACKAGES_DIR}/lib/jpeg-static.lib")
  37         file(RENAME "${CURRENT_PACKAGES_DIR}/lib/jpeg-static.lib" "${CURRENT_PACKAGES_DIR}/lib/jpeg.lib")
  38         file(RENAME "${CURRENT_PACKAGES_DIR}/lib/turbojpeg-static.lib" "${CURRENT_PACKAGES_DIR}/lib/turbojpeg.lib")
  39     endif()
  40     if(EXISTS "${CURRENT_PACKAGES_DIR}/debug/lib/jpeg-static.lib")
  41         file(RENAME "${CURRENT_PACKAGES_DIR}/debug/lib/jpeg-static.lib" "${CURRENT_PACKAGES_DIR}/debug/lib/jpeg.lib")
  42         file(RENAME "${CURRENT_PACKAGES_DIR}/debug/lib/turbojpeg-static.lib" "${CURRENT_PACKAGES_DIR}/debug/lib/turbojpeg.lib")
  43     endif()
  44 endif()
  45
  46 # Remove extra debug files
  47 file(REMOVE_RECURSE ${CURRENT_PACKAGES_DIR}/debug/include)
  48 file(REMOVE_RECURSE ${CURRENT_PACKAGES_DIR}/debug/share)
  49
  50 vcpkg_copy_tools(TOOL_NAMES cjpeg djpeg jpegtran AUTO_CLEAN)
  51 vcpkg_fixup_pkgconfig()
  52
  53 # Remove empty folders after static build
  54 if (VCPKG_LIBRARY_LINKAGE STREQUAL static)
  55     file(REMOVE_RECURSE ${CURRENT_PACKAGES_DIR}/bin)
  56     file(REMOVE_RECURSE ${CURRENT_PACKAGES_DIR}/debug/bin)
  57 endif()
  58
  59 # Handle copyright
  60 file(INSTALL ${SOURCE_PATH}/LICENSE.md DESTINATION ${CURRENT_PACKAGES_DIR}/share/${PORT} RENAME copyright)
  61 vcpkg_copy_pdbs()