ceph/src/jaegertracing/opentelemetry-cpp/tools/vcpkg/ports/pcl/portfile.cmake

   1 vcpkg_from_github(
   2     OUT_SOURCE_PATH SOURCE_PATH
   3     REPO PointCloudLibrary/pcl
   4     REF d98313133b014553ab1b1b5b112f9aade837d55c # pcl-1.11.1
   5     SHA512 4d60f34d4fbf0a4b4caf9cc4391af471ebd260b3bbac106d45e5ff38448894ea4dc82d5320c2e395c537a4414eb13c6a6a0eb6c13e4e1cc1d831d4bf24067966
   6     HEAD_REF master
   7     PATCHES
   8         pcl_utils.patch
   9         pcl_config.patch
  10         use_flann_targets.patch
  11         boost-1.70.patch
  12         fix-link-libpng.patch
  13         remove-broken-targets.patch
  14         fix-check-sse.patch
  15         realsense2.patch
  16         add-gcc-version-check.patch
  17         fix-find-qhull.patch
  18 )
  19
  20 file(REMOVE ${SOURCE_PATH}/cmake/Modules/FindFLANN.cmake)
  21 file(REMOVE ${SOURCE_PATH}/cmake/Modules/FindQhull.cmake)
  22
  23 string(COMPARE EQUAL "${VCPKG_LIBRARY_LINKAGE}" "dynamic" PCL_SHARED_LIBS)
  24
  25 if ("cuda" IN_LIST FEATURES AND VCPKG_TARGET_ARCHITECTURE STREQUAL x86)
  26     message(FATAL_ERROR "Feature cuda only supports 64-bit compilation.")
  27 endif()
  28
  29 if ("tools" IN_LIST FEATURES AND VCPKG_LIBRARY_LINKAGE STREQUAL static)
  30     message(FATAL_ERROR "Feature tools only supports dynamic build")
  31 endif()
  32
  33 vcpkg_check_features(OUT_FEATURE_OPTIONS FEATURE_OPTIONS
  34     FEATURES
  35         openni2 WITH_OPENNI2
  36         qt      WITH_QT
  37         pcap    WITH_PCAP
  38         cuda    WITH_CUDA
  39         cuda    BUILD_CUDA
  40         cuda    BUILD_GPU
  41         tools   BUILD_tools
  42         opengl  WITH_OPENGL
  43         vtk     WITH_VTK
  44 )
  45
  46 vcpkg_configure_cmake(
  47     SOURCE_PATH ${SOURCE_PATH}
  48     PREFER_NINJA
  49     OPTIONS
  50         # BUILD
  51         -DBUILD_surface_on_nurbs=ON
  52         # PCL
  53         -DPCL_BUILD_WITH_BOOST_DYNAMIC_LINKING_WIN32=${PCL_SHARED_LIBS}
  54         -DPCL_BUILD_WITH_FLANN_DYNAMIC_LINKING_WIN32=${PCL_SHARED_LIBS}
  55         -DPCL_BUILD_WITH_QHULL_DYNAMIC_LINKING_WIN32=${PCL_SHARED_LIBS}
  56         -DPCL_SHARED_LIBS=${PCL_SHARED_LIBS}
  57         # WITH
  58         -DWITH_LIBUSB=OFF
  59         -DWITH_PNG=ON
  60         -DWITH_QHULL=ON
  61         # FEATURES
  62         ${FEATURE_OPTIONS}
  63 )
  64
  65 vcpkg_install_cmake()
  66 vcpkg_fixup_cmake_targets()
  67 vcpkg_copy_pdbs()
  68
  69 file(REMOVE_RECURSE ${CURRENT_PACKAGES_DIR}/debug/include)
  70 file(REMOVE_RECURSE ${CURRENT_PACKAGES_DIR}/debug/share)
  71
  72 if("tools" IN_LIST FEATURES)
  73     file(GLOB EXEFILES_RELEASE ${CURRENT_PACKAGES_DIR}/bin/*.exe)
  74     file(GLOB EXEFILES_DEBUG ${CURRENT_PACKAGES_DIR}/debug/bin/*.exe)
  75     file(COPY ${EXEFILES_RELEASE} DESTINATION ${CURRENT_PACKAGES_DIR}/tools/pcl)
  76     file(REMOVE ${EXEFILES_RELEASE} ${EXEFILES_DEBUG})
  77     vcpkg_copy_tool_dependencies(${CURRENT_PACKAGES_DIR}/tools/pcl)
  78 endif()
  79
  80 file(INSTALL ${SOURCE_PATH}/LICENSE.txt DESTINATION ${CURRENT_PACKAGES_DIR}/share/${PORT} RENAME copyright)