ceph/src/jaegertracing/opentelemetry-cpp/tools/vcpkg/ports/pdal/portfile.cmake

   1 set(PDAL_VERSION_STR "1.7.1")
   2
   3 vcpkg_download_distfile(ARCHIVE
   4     URLS "http://download.osgeo.org/pdal/PDAL-${PDAL_VERSION_STR}-src.tar.gz"
   5     FILENAME "PDAL-${PDAL_VERSION_STR}-src.tar.gz"
   6     SHA512 e3e63bb05930c1a28c4f46c7edfaa8e9ea20484f1888d845b660a29a76f1dd1daea3db30a98607be0c2eeb86930ec8bfd0965d5d7d84b07a4fe4cb4512da9b09
   7 )
   8
   9 vcpkg_extract_source_archive_ex(
  10     ARCHIVE ${ARCHIVE}
  11     OUT_SOURCE_PATH SOURCE_PATH
  12     PATCHES
  13         0001-win32_compiler_options.cmake.patch
  14         0002-no-source-dir-writes.patch
  15         0003-fix-copy-vendor.patch
  16         fix-dependency.patch
  17         libpq.patch
  18         fix-CPL_DLL.patch
  19         0004-fix-const-overloaded.patch
  20         geotiff.patch
  21 )
  22
  23 file(REMOVE "${SOURCE_PATH}/pdal/gitsha.cpp")
  24
  25 # Deploy custom CMake modules to enforce expected dependencies look-up
  26 foreach(_module IN ITEMS FindGDAL FindGEOS FindGeoTIFF FindCurl)  # Outdated; Supplied by CMake
  27     file(REMOVE "${SOURCE_PATH}/cmake/modules/${_module}.cmake")
  28 endforeach()
  29 foreach(_module IN ITEMS FindGEOS)  # Overwritten Modules.
  30     file(REMOVE "${SOURCE_PATH}/cmake/modules/${_module}.cmake")
  31     file(COPY ${CMAKE_CURRENT_LIST_DIR}/${_module}.cmake
  32         DESTINATION ${SOURCE_PATH}/cmake/modules/
  33     )
  34 endforeach()
  35
  36 string(COMPARE EQUAL "${VCPKG_LIBRARY_LINKAGE}" "static" VCPKG_BUILD_STATIC_LIBS)
  37
  38 vcpkg_configure_cmake(
  39     SOURCE_PATH ${SOURCE_PATH}
  40     PREFER_NINJA
  41     OPTIONS
  42         -DPDAL_BUILD_STATIC:BOOL=${VCPKG_BUILD_STATIC_LIBS}
  43         -DWITH_TESTS:BOOL=OFF
  44         -DWITH_COMPLETION:BOOL=OFF
  45 )
  46
  47 vcpkg_install_cmake(ADD_BIN_TO_PATH)
  48 vcpkg_fixup_cmake_targets(CONFIG_PATH lib/pdal/cmake)
  49 vcpkg_copy_pdbs()
  50
  51 # Install PDAL executable
  52 file(GLOB _pdal_apps ${CURRENT_PACKAGES_DIR}/bin/*.exe)
  53 file(COPY ${_pdal_apps} DESTINATION ${CURRENT_PACKAGES_DIR}/tools/pdal)
  54 file(REMOVE ${_pdal_apps})
  55 vcpkg_copy_tool_dependencies(${CURRENT_PACKAGES_DIR}/tools/${PORT})
  56
  57 # Post-install clean-up
  58 file(REMOVE_RECURSE
  59     ${CURRENT_PACKAGES_DIR}/lib/pdal
  60     ${CURRENT_PACKAGES_DIR}/debug/lib/pdal
  61     ${CURRENT_PACKAGES_DIR}/debug/include
  62     ${CURRENT_PACKAGES_DIR}/debug/share
  63 )
  64
  65 if(VCPKG_LIBRARY_LINKAGE STREQUAL static)
  66     file(REMOVE_RECURSE ${CURRENT_PACKAGES_DIR}/debug/bin ${CURRENT_PACKAGES_DIR}/bin)
  67 else()
  68     file(GLOB _pdal_bats ${CURRENT_PACKAGES_DIR}/bin/*.bat)
  69     file(REMOVE ${_pdal_bats})
  70     file(GLOB _pdal_bats ${CURRENT_PACKAGES_DIR}/debug/bin/*.bat)
  71     file(REMOVE ${_pdal_bats})
  72     file(GLOB _pdal_apps ${CURRENT_PACKAGES_DIR}/debug/bin/*.exe)
  73     file(REMOVE ${_pdal_apps})
  74 endif()
  75
  76 file(INSTALL ${SOURCE_PATH}/LICENSE.txt DESTINATION ${CURRENT_PACKAGES_DIR}/share/${PORT} RENAME copyright)