ceph/src/jaegertracing/opentelemetry-cpp/tools/vcpkg/ports/portmidi/portfile.cmake

   1 vcpkg_fail_port_install(ON_TARGET "linux" "osx" "uwp" ON_ARCH "arm")
   2
   3 vcpkg_from_sourceforge(
   4     OUT_SOURCE_PATH SOURCE_PATH
   5     REPO portmedia
   6     FILENAME "portmedia-code-r234.zip"
   7     SHA512 cbc332d89bc465450b38245a83cc300dfd2e1e6de7c62284edf754ff4d8a9aa3dc49a395dcee535ed9688befb019186fa87fd6d8a3698898c2acbf3e6b7a0794
   8 )
   9
  10 # Alter path to main portmidi root
  11 set(SOURCE_PATH "${SOURCE_PATH}/portmidi/trunk")
  12
  13 # Mark portmidi-static as static, disable pmjni library depending on the Java SDK
  14
  15 file(READ "${SOURCE_PATH}/pm_common/CMakeLists.txt" PM_CMAKE)
  16 string(REPLACE "add_library(portmidi-static \${LIBSRC})" "add_library(portmidi-static STATIC \${LIBSRC})" PM_CMAKE "${PM_CMAKE}")
  17 string(REPLACE "add_library(pmjni SHARED \${JNISRC})" "# Removed pmjni" PM_CMAKE "${PM_CMAKE}")
  18 string(REPLACE "target_link_libraries(pmjni \${JNI_EXTRA_LIBS})" "# Removed pmjni" PM_CMAKE "${PM_CMAKE}")
  19 string(REPLACE "set_target_properties(pmjni PROPERTIES EXECUTABLE_EXTENSION \"jnilib\")" "# Removed pmjni" PM_CMAKE "${PM_CMAKE}")
  20 file(WRITE "${SOURCE_PATH}/pm_common/CMakeLists.txt" "${PM_CMAKE}")
  21
  22 # Run cmake configure step
  23 vcpkg_configure_cmake(
  24     SOURCE_PATH ${SOURCE_PATH}
  25     OPTIONS
  26         -DJAVA_INCLUDE_PATH=
  27         -DJAVA_INCLUDE_PATH2=
  28         -DJAVA_JVM_LIBRARY=
  29 )
  30
  31 # Run cmake build step, nothing is installed on Windows
  32 vcpkg_build_cmake()
  33
  34 file(INSTALL ${SOURCE_PATH}/pm_common/portmidi.h DESTINATION ${CURRENT_PACKAGES_DIR}/include)
  35 file(INSTALL ${SOURCE_PATH}/porttime/porttime.h DESTINATION ${CURRENT_PACKAGES_DIR}/include)
  36
  37 if(VCPKG_LIBRARY_LINKAGE STREQUAL "static")
  38     file(INSTALL ${CURRENT_BUILDTREES_DIR}/${TARGET_TRIPLET}-rel/Release/portmidi_s.lib DESTINATION ${CURRENT_PACKAGES_DIR}/lib)
  39     file(INSTALL ${CURRENT_BUILDTREES_DIR}/${TARGET_TRIPLET}-dbg/Debug/portmidi_s.lib DESTINATION ${CURRENT_PACKAGES_DIR}/debug/lib)
  40 else()
  41     file(INSTALL ${CURRENT_BUILDTREES_DIR}/${TARGET_TRIPLET}-rel/Release/portmidi.dll DESTINATION ${CURRENT_PACKAGES_DIR}/bin)
  42     file(INSTALL ${CURRENT_BUILDTREES_DIR}/${TARGET_TRIPLET}-rel/Release/portmidi.lib DESTINATION ${CURRENT_PACKAGES_DIR}/lib)
  43     file(INSTALL ${CURRENT_BUILDTREES_DIR}/${TARGET_TRIPLET}-dbg/Debug/portmidi.dll DESTINATION ${CURRENT_PACKAGES_DIR}/debug/bin)
  44     file(INSTALL ${CURRENT_BUILDTREES_DIR}/${TARGET_TRIPLET}-dbg/Debug/portmidi.lib DESTINATION ${CURRENT_PACKAGES_DIR}/debug/lib)
  45 endif()
  46
  47 file(INSTALL ${SOURCE_PATH}/license.txt DESTINATION ${CURRENT_PACKAGES_DIR}/share/portmidi RENAME copyright)