ceph/src/jaegertracing/opentelemetry-cpp/tools/vcpkg/ports/readosm/portfile.cmake

   1 set(READOSM_VERSION_STR "1.1.0a")
   2 vcpkg_download_distfile(ARCHIVE
   3     URLS "http://www.gaia-gis.it/gaia-sins/readosm-sources/readosm-${READOSM_VERSION_STR}.tar.gz"
   4     FILENAME "readosm-${READOSM_VERSION_STR}.tar.gz"
   5     SHA512 ec8516cdd0b02027cef8674926653f8bc76e2082c778b02fb2ebcfa6d01e21757aaa4fd5d5104059e2f5ba97190183e60184f381bfd592a635805aa35cd7a682
   6 )
   7
   8 if (VCPKG_TARGET_IS_WINDOWS)
   9   vcpkg_extract_source_archive_ex(
  10       OUT_SOURCE_PATH SOURCE_PATH
  11       ARCHIVE ${ARCHIVE}
  12       PATCHES
  13         fix-makefiles.patch
  14   )
  15
  16   if(VCPKG_CRT_LINKAGE STREQUAL dynamic)
  17     set(CL_FLAGS_DBG "/MDd /Zi")
  18     set(CL_FLAGS_REL "/MD /Ox")
  19     set(EXPAT_LIBS_REL "${CURRENT_INSTALLED_DIR}/lib/libexpat.lib")
  20     set(EXPAT_LIBS_DBG "${CURRENT_INSTALLED_DIR}/debug/lib/libexpatd.lib")
  21   else()
  22     set(CL_FLAGS_DBG "/MTd /Zi")
  23     set(CL_FLAGS_REL "/MT /Ox")
  24     set(EXPAT_LIBS_REL "${CURRENT_INSTALLED_DIR}/lib/libexpatMD.lib")
  25     set(EXPAT_LIBS_DBG "${CURRENT_INSTALLED_DIR}/debug/lib/libexpatdMD.lib")
  26   endif()
  27
  28   if(VCPKG_TARGET_IS_UWP)
  29     set(UWP_LIBS windowsapp.lib)
  30     set(UWP_LINK_FLAGS /APPCONTAINER)
  31   endif()
  32
  33   set(LIBS_ALL_DBG
  34     "${CURRENT_INSTALLED_DIR}/debug/lib/zlibd.lib \
  35     ${UWP_LIBS} \
  36     ${EXPAT_LIBS_DBG}"
  37   )
  38   set(LIBS_ALL_REL
  39     "${CURRENT_INSTALLED_DIR}/lib/zlib.lib \
  40     ${UWP_LIBS} \
  41     ${EXPAT_LIBS_REL}"
  42   )
  43
  44   string(REPLACE "/" "\\\\" INST_DIR ${CURRENT_PACKAGES_DIR})
  45   list(APPEND OPTIONS_RELEASE
  46     "LINK_FLAGS=${UWP_LINK_FLAGS}" "INST_DIR=${INST_DIR}" "CL_FLAGS=${CL_FLAGS_REL}" "LIBS_ALL=${LIBS_ALL_REL}"
  47   )
  48   list(APPEND OPTIONS_DEBUG
  49     "LINK_FLAGS=${UWP_LINK_FLAGS} /debug" "INST_DIR=${INST_DIR}\\debug" "CL_FLAGS=${CL_FLAGS_DBG}" "LIBS_ALL=${LIBS_ALL_DBG}"
  50    )
  51
  52   vcpkg_install_nmake(
  53     SOURCE_PATH ${SOURCE_PATH}
  54     OPTIONS_RELEASE
  55       ${OPTIONS_RELEASE}
  56     OPTIONS_DEBUG
  57       ${OPTIONS_DEBUG}
  58   )
  59
  60   if (VCPKG_LIBRARY_LINKAGE STREQUAL static)
  61     file(REMOVE_RECURSE ${CURRENT_PACKAGES_DIR}/bin ${CURRENT_PACKAGES_DIR}/debug/bin)
  62     file(REMOVE ${CURRENT_PACKAGES_DIR}/lib/readosm_i.lib)
  63     file(REMOVE ${CURRENT_PACKAGES_DIR}/debug/lib/readosm_i.lib)
  64   else()
  65     file(REMOVE ${CURRENT_PACKAGES_DIR}/lib/readosm.lib)
  66     file(REMOVE ${CURRENT_PACKAGES_DIR}/debug/lib/readosm.lib)
  67     file(RENAME ${CURRENT_PACKAGES_DIR}/lib/readosm_i.lib ${CURRENT_PACKAGES_DIR}/lib/readosm.lib)
  68     file(RENAME ${CURRENT_PACKAGES_DIR}/debug/lib/readosm_i.lib ${CURRENT_PACKAGES_DIR}/debug/lib/readosm.lib)
  69   endif()
  70   file(REMOVE_RECURSE ${CURRENT_PACKAGES_DIR}/debug/include)
  71 elseif (VCPKG_TARGET_IS_LINUX OR VCPKG_TARGET_IS_OSX) # Build in UNIX
  72   vcpkg_extract_source_archive_ex(
  73     ARCHIVE ${ARCHIVE}
  74     OUT_SOURCE_PATH SOURCE_PATH
  75   )
  76
  77   vcpkg_configure_make(
  78     SOURCE_PATH ${SOURCE_PATH}
  79     AUTOCONFIG
  80     OPTIONS
  81       "LIBS=-lpthread -ldl -lstdc++ -lm"
  82   )
  83
  84   vcpkg_install_make()
  85   vcpkg_fixup_pkgconfig(SYSTEM_LIBRARIES m)
  86 endif()
  87
  88 # Handle copyright
  89 file(INSTALL ${SOURCE_PATH}/COPYING DESTINATION ${CURRENT_PACKAGES_DIR}/share/${PORT} RENAME copyright)