ceph/src/jaegertracing/opentelemetry-cpp/tools/vcpkg/ports/sdl2-gfx/CMakeLists.txt

   1 cmake_minimum_required(VERSION 3.0)
   2 project(SDL2_gfx VERSION 1.0.4 LANGUAGES C)
   3
   4 set(CONFIG_NAME "sdl2-gfx")
   5
   6 find_path(SDL_INCLUDE_DIR SDL2/SDL.h)
   7 find_package(SDL2 CONFIG REQUIRED)
   8
   9 # builtin formats
  10 set(SDL_GFX_DEFINES WIN32)
  11 if(BUILD_SHARED_LIBS)
  12     list(APPEND SDL_GFX_DEFINES DLL_EXPORT)
  13 endif()
  14
  15 add_library(${PROJECT_NAME}
  16     SDL2_framerate.c
  17     SDL2_gfxPrimitives.c
  18     SDL2_imageFilter.c
  19     SDL2_rotozoom.c)
  20
  21 target_include_directories(${PROJECT_NAME} PUBLIC
  22     $<BUILD_INTERFACE:${PROJECT_SOURCE_DIR}>
  23     $<INSTALL_INTERFACE:include>
  24     $<INSTALL_INTERFACE:include/SDL2>
  25 )
  26
  27 if(WIN32)
  28     add_compile_definitions(${SDL_GFX_DEFINES})
  29 endif()
  30 target_include_directories(${PROJECT_NAME} PRIVATE ${SDL_INCLUDE_DIR}/SDL2)
  31 target_link_libraries(${PROJECT_NAME} PRIVATE SDL2::SDL2)
  32
  33 install(TARGETS ${PROJECT_NAME}
  34     EXPORT ${PROJECT_NAME}
  35     RUNTIME DESTINATION bin
  36     ARCHIVE DESTINATION lib
  37     LIBRARY DESTINATION lib)
  38
  39 install(EXPORT ${PROJECT_NAME}
  40     FILE ${CONFIG_NAME}-targets.cmake
  41     NAMESPACE SDL2::
  42     DESTINATION share/${CONFIG_NAME}/
  43 )
  44 file(WRITE ${CMAKE_CURRENT_BINARY_DIR}/${CONFIG_NAME}-config.cmake
  45 "include(CMakeFindDependencyMacro)
  46 find_dependency(SDL2 CONFIG)
  47 include(\${CMAKE_CURRENT_LIST_DIR}/${CONFIG_NAME}-targets.cmake)"
  48 )
  49 install(FILES ${CMAKE_CURRENT_BINARY_DIR}/${CONFIG_NAME}-config.cmake DESTINATION share/${CONFIG_NAME})
  50
  51 if(NOT SDL_GFX_SKIP_HEADERS)
  52     install(FILES SDL2_framerate.h SDL2_gfxPrimitives.h SDL2_imageFilter.h SDL2_rotozoom.h SDL2_gfxPrimitives_font.h DESTINATION include/SDL2)
  53 endif()