ceph/src/jaegertracing/opentelemetry-cpp/tools/vcpkg/ports/soci/portfile.cmake

   1 vcpkg_from_github(
   2     OUT_SOURCE_PATH SOURCE_PATH
   3     REPO SOCI/soci
   4     REF 334cc55d9fa7b42d7214a8533a246d637bc92899 #version 4.0.1 commit on 2020.10.19
   5     SHA512 b300b13f68347d78252812e09efffb1735072cf5019940da53366a5cdee997f4b8b03a584a87a95ba764b0a78640ad6eb4966b53f9156280cb452465607afbc7
   6     HEAD_REF master
   7     PATCHES
   8         fix-dependency-libmysql.patch
   9         export-include-dirs.patch
  10 )
  11
  12 string(COMPARE EQUAL "${VCPKG_LIBRARY_LINKAGE}" "dynamic" SOCI_DYNAMIC)
  13 string(COMPARE EQUAL "${VCPKG_LIBRARY_LINKAGE}" "static" SOCI_STATIC)
  14
  15 # Handle features
  16 set(_COMPONENT_FLAGS "")
  17 foreach(_feature IN LISTS ALL_FEATURES)
  18     # Uppercase the feature name and replace "-" with "_"
  19     string(TOUPPER "${_feature}" _FEATURE)
  20     string(REPLACE "-" "_" _FEATURE "${_FEATURE}")
  21
  22     # Turn "-DWITH_*=" ON or OFF depending on whether the feature
  23     # is in the list.
  24     if(_feature IN_LIST FEATURES)
  25         list(APPEND _COMPONENT_FLAGS "-DWITH_${_FEATURE}=ON")
  26     else()
  27         list(APPEND _COMPONENT_FLAGS "-DWITH_${_FEATURE}=OFF")
  28     endif()
  29
  30     if(_feature MATCHES "mysql")
  31         set(MYSQL_OPT -DMYSQL_INCLUDE_DIR=${CURRENT_INSTALLED_DIR}/include/mysql)
  32     endif()
  33 endforeach()
  34
  35 vcpkg_configure_cmake(
  36     SOURCE_PATH ${SOURCE_PATH}
  37     PREFER_NINJA
  38     OPTIONS
  39         -DSOCI_TESTS=OFF
  40         -DSOCI_CXX11=ON
  41         -DSOCI_LIBDIR:STRING=lib # This is to always have output in the lib folder and not lib64 for 64-bit builds
  42         -DLIBDIR:STRING=lib
  43         -DSOCI_STATIC=${SOCI_STATIC}
  44         -DSOCI_SHARED=${SOCI_DYNAMIC}
  45         ${_COMPONENT_FLAGS}
  46         ${MYSQL_OPT}
  47         -DWITH_ORACLE=OFF
  48         -DWITH_FIREBIRD=OFF
  49         -DWITH_DB2=OFF
  50 )
  51
  52 vcpkg_install_cmake()
  53 vcpkg_copy_pdbs()
  54 vcpkg_fixup_cmake_targets(CONFIG_PATH cmake)
  55 # Correct the config file name
  56 file(RENAME ${CURRENT_PACKAGES_DIR}/share/${PORT}/SOCI.cmake ${CURRENT_PACKAGES_DIR}/share/${PORT}/SOCIConfig.cmake)
  57
  58 if ("mysql" IN_LIST FEATURES)
  59     vcpkg_replace_string(${CURRENT_PACKAGES_DIR}/share/${PORT}/SOCIConfig.cmake
  60         "# Create imported target SOCI::soci_mysql"
  61         "\ninclude(CMakeFindDependencyMacro)\nfind_dependency(libmysql)\n# Create imported target SOCI::soci_mysql"
  62     )
  63 endif()
  64
  65 file(REMOVE_RECURSE ${CURRENT_PACKAGES_DIR}/debug/include ${CURRENT_PACKAGES_DIR}/debug/share)
  66
  67 # Handle copyright
  68 file(INSTALL ${SOURCE_PATH}/LICENSE_1_0.txt DESTINATION ${CURRENT_PACKAGES_DIR}/share/${PORT} RENAME copyright)