ceph/src/jaegertracing/opentelemetry-cpp/tools/vcpkg/ports/vcpkg-gfortran/portfile.cmake

   1 vcpkg_fail_port_install(ON_ARCH "arm" ON_TARGET "linux" "osx")
   2 include(vcpkg_find_fortran)
   3 vcpkg_find_fortran(FORTRAN_CMAKE)
   4 if(VCPKG_USE_INTERNAL_Fortran)
   5     set(VCPKG_CRT_LINKAGE dynamic) # Will always be dynamic no way to overwrite internal CRT linkage here
   6     vcpkg_check_linkage(ONLY_DYNAMIC_LIBRARY)
   7     if(DEFINED ENV{PROCESSOR_ARCHITEW6432})
   8         set(HOST_ARCH $ENV{PROCESSOR_ARCHITEW6432})
   9     else()
  10         set(HOST_ARCH $ENV{PROCESSOR_ARCHITECTURE})
  11     endif()
  12
  13     if(HOST_ARCH MATCHES "(amd|AMD)64")
  14         set(MINGW_W w64)
  15         set(MSYS_HOST x86_64)
  16     elseif(HOST_ARCH MATCHES "(x|X)86")
  17         set(MINGW_W w32)
  18         set(MSYS_HOST i686)
  19     else()
  20         message(FATAL_ERROR "Unsupported host architecture ${HOST_ARCH}!" )
  21     endif()
  22
  23     if(VCPKG_TARGET_ARCHITECTURE MATCHES "(x|X)64")
  24         set(MSYS_TARGET x86_64)
  25         set(MINGW_W_TARGET 64)
  26         set(GCC_LIB_SUFFIX s_seh-1)
  27     elseif(VCPKG_TARGET_ARCHITECTURE MATCHES "(x|X)86")
  28         set(MSYS_TARGET i686)
  29         set(MINGW_W_TARGET 32)
  30         set(GCC_LIB_SUFFIX s_dw2-1)
  31     else()
  32         message(FATAL_ERROR "Unsupported target architecture ${VCPKG_TARGET_ARCHITECTURE}!" )
  33     endif()
  34
  35     set(MINGW_BIN "${vcpkg_find_fortran_MSYS_ROOT}/mingw${MINGW_W_TARGET}/bin/")
  36     set(MINGW_Fortran_DLLS
  37         "${MINGW_BIN}/libgfortran-5.dll"
  38         "${MINGW_BIN}/libquadmath-0.dll"
  39         "${MINGW_BIN}/libwinpthread-1.dll"
  40         "${MINGW_BIN}/libgcc_${GCC_LIB_SUFFIX}.dll"
  41     )
  42     file(MAKE_DIRECTORY ${CURRENT_PACKAGES_DIR}/bin ${CURRENT_PACKAGES_DIR}/debug/bin)
  43     file(COPY ${MINGW_Fortran_DLLS} DESTINATION "${CURRENT_PACKAGES_DIR}/bin")
  44     file(COPY ${MINGW_Fortran_DLLS} DESTINATION "${CURRENT_PACKAGES_DIR}/debug/bin")
  45     file(COPY "${vcpkg_find_fortran_MSYS_ROOT}/mingw${MINGW_W_TARGET}/share/licenses" DESTINATION "${CURRENT_PACKAGES_DIR}/share/${PORT}")
  46     file(INSTALL "${vcpkg_find_fortran_MSYS_ROOT}/mingw${MINGW_W_TARGET}/share/licenses/crt/COPYING.MinGW-w64-runtime.txt" DESTINATION "${CURRENT_PACKAGES_DIR}/share/${PORT}" RENAME copyright)
  47     set(VCPKG_POLICY_SKIP_DUMPBIN_CHECKS enabled) # due to outdated msvcrt
  48     set(VCPKG_POLICY_DLLS_WITHOUT_LIBS enabled)
  49     set(VCPKG_POLICY_EMPTY_INCLUDE_FOLDER enabled)
  50 else()
  51     set(VCPKG_POLICY_EMPTY_PACKAGE enabled)
  52 endif()