ceph/src/jaegertracing/opentelemetry-cpp/tools/vcpkg/ports/wxwidgets/portfile.cmake

   1 vcpkg_fail_port_install(ON_TARGET "uwp")
   2
   3 vcpkg_from_github(
   4     OUT_SOURCE_PATH SOURCE_PATH
   5     REPO wxWidgets/wxWidgets
   6     REF v3.1.4
   7     SHA512 108e35220de10afbfc58762498ada9ece0b3166f56a6d11e11836d51bfbaed1de3033c32ed4109992da901fecddcf84ce8a1ba47303f728c159c638dac77d148
   8     HEAD_REF master
   9     PATCHES
  10         disable-platform-lib-dir.patch
  11         fix-stl-build-vs2019-16.6.patch
  12 )
  13
  14 set(OPTIONS)
  15 if(VCPKG_TARGET_IS_OSX)
  16     set(OPTIONS -DCOTIRE_MINIMUM_NUMBER_OF_TARGET_SOURCES=9999)
  17 endif()
  18
  19 if(VCPKG_TARGET_ARCHITECTURE STREQUAL arm64 OR VCPKG_TARGET_ARCHITECTURE STREQUAL arm)
  20     set(OPTIONS
  21         -DwxUSE_OPENGL=OFF
  22         -DwxUSE_STACKWALKER=OFF
  23     )
  24 endif()
  25
  26 vcpkg_configure_cmake(
  27     SOURCE_PATH ${SOURCE_PATH}
  28     PREFER_NINJA
  29     OPTIONS
  30         -DwxUSE_REGEX=builtin
  31         -DwxUSE_ZLIB=sys
  32         -DwxUSE_EXPAT=sys
  33         -DwxUSE_LIBJPEG=sys
  34         -DwxUSE_LIBPNG=sys
  35         -DwxUSE_LIBTIFF=sys
  36         -DwxUSE_STL=ON
  37         -DwxBUILD_DISABLE_PLATFORM_LIB_DIR=ON
  38         ${OPTIONS}
  39 )
  40
  41 vcpkg_install_cmake()
  42
  43 file(GLOB DLLS "${CURRENT_PACKAGES_DIR}/lib/*.dll")
  44 if(DLLS)
  45     file(MAKE_DIRECTORY ${CURRENT_PACKAGES_DIR}/bin)
  46     foreach(DLL ${DLLS})
  47         get_filename_component(N "${DLL}" NAME)
  48         file(RENAME ${DLL} ${CURRENT_PACKAGES_DIR}/bin/${N})
  49     endforeach()
  50 endif()
  51 file(GLOB DLLS "${CURRENT_PACKAGES_DIR}/debug/lib/*.dll")
  52 if(DLLS)
  53     file(MAKE_DIRECTORY ${CURRENT_PACKAGES_DIR}/debug/bin)
  54     foreach(DLL ${DLLS})
  55         get_filename_component(N "${DLL}" NAME)
  56         file(RENAME ${DLL} ${CURRENT_PACKAGES_DIR}/debug/bin/${N})
  57     endforeach()
  58 endif()
  59
  60 if(VCPKG_TARGET_IS_WINDOWS)
  61     vcpkg_copy_tools(TOOL_NAMES wxrc AUTO_CLEAN)
  62 else()
  63     vcpkg_copy_tools(TOOL_NAMES wxrc wx-config wxrc-3.1 AUTO_CLEAN)
  64 endif()
  65
  66 # do the copy pdbs now after the dlls got moved to the expected /bin folder above
  67 vcpkg_copy_pdbs()
  68
  69 file(REMOVE_RECURSE ${CURRENT_PACKAGES_DIR}/include/msvc)
  70 file(REMOVE_RECURSE ${CURRENT_PACKAGES_DIR}/debug/include)
  71 file(GLOB_RECURSE INCLUDES ${CURRENT_PACKAGES_DIR}/include/*.h)
  72 if(EXISTS ${CURRENT_PACKAGES_DIR}/lib/mswu/wx/setup.h)
  73     list(APPEND INCLUDES ${CURRENT_PACKAGES_DIR}/lib/mswu/wx/setup.h)
  74 endif()
  75 if(EXISTS ${CURRENT_PACKAGES_DIR}/debug/lib/mswud/wx/setup.h)
  76     list(APPEND INCLUDES ${CURRENT_PACKAGES_DIR}/debug/lib/mswud/wx/setup.h)
  77 endif()
  78 foreach(INC IN LISTS INCLUDES)
  79     file(READ "${INC}" _contents)
  80     if(VCPKG_LIBRARY_LINKAGE STREQUAL "static")
  81         string(REPLACE "defined(WXUSINGDLL)" "0" _contents "${_contents}")
  82     else()
  83         string(REPLACE "defined(WXUSINGDLL)" "1" _contents "${_contents}")
  84     endif()
  85     # Remove install prefix from setup.h to ensure package is relocatable
  86     string(REGEX REPLACE "\n#define wxINSTALL_PREFIX [^\n]*" "\n#define wxINSTALL_PREFIX \"\"" _contents "${_contents}")
  87     file(WRITE "${INC}" "${_contents}")
  88 endforeach()
  89
  90 if(NOT EXISTS ${CURRENT_PACKAGES_DIR}/include/wx/setup.h)
  91     file(GLOB_RECURSE WX_SETUP_H_FILES_DBG ${CURRENT_PACKAGES_DIR}/debug/lib/*.h)
  92     file(GLOB_RECURSE WX_SETUP_H_FILES_REL ${CURRENT_PACKAGES_DIR}/lib/*.h)
  93
  94     string(REPLACE "${CURRENT_PACKAGES_DIR}/debug/lib/" "" WX_SETUP_H_FILES_DBG "${WX_SETUP_H_FILES_DBG}")
  95     string(REPLACE "/setup.h" "" WX_SETUP_H_DBG_RELATIVE "${WX_SETUP_H_FILES_DBG}")
  96
  97     string(REPLACE "${CURRENT_PACKAGES_DIR}/lib/" "" WX_SETUP_H_FILES_REL "${WX_SETUP_H_FILES_REL}")
  98     string(REPLACE "/setup.h" "" WX_SETUP_H_REL_RELATIVE "${WX_SETUP_H_FILES_REL}")
  99
 100     configure_file(${CMAKE_CURRENT_LIST_DIR}/setup.h.in ${CURRENT_PACKAGES_DIR}/include/wx/setup.h @ONLY)
 101 endif()
 102 file(COPY ${CMAKE_CURRENT_LIST_DIR}/vcpkg-cmake-wrapper.cmake DESTINATION ${CURRENT_PACKAGES_DIR}/share/wxwidgets)
 103 configure_file(${CMAKE_CURRENT_LIST_DIR}/usage ${CURRENT_PACKAGES_DIR}/share/wxwidgets/usage COPYONLY)
 104 file(INSTALL ${SOURCE_PATH}/docs/licence.txt DESTINATION ${CURRENT_PACKAGES_DIR}/share/${PORT} RENAME copyright)