ceph/src/jaegertracing/thrift/lib/java/gradle/generateTestThrift.gradle

   1 /*
   2  * Licensed to the Apache Software Foundation (ASF) under one
   3  * or more contributor license agreements. See the NOTICE file
   4  * distributed with this work for additional information
   5  * regarding copyright ownership. The ASF licenses this file
   6  * to you under the Apache License, Version 2.0 (the
   7  * "License"); you may not use this file except in compliance
   8  * with the License. You may obtain a copy of the License at
   9  *
  10  *   http://www.apache.org/licenses/LICENSE-2.0
  11  *
  12  * Unless required by applicable law or agreed to in writing,
  13  * software distributed under the License is distributed on an
  14  * "AS IS" BASIS, WITHOUT WARRANTIES OR CONDITIONS OF ANY
  15  * KIND, either express or implied. See the License for the
  16  * specific language governing permissions and limitations
  17  * under the License.
  18  */
  19
  20 // Following Gradle best practices to keep build logic organized
  21
  22 // Generated code locations for Unit tests
  23 ext.genSrc = file("$buildDir/gen-java")
  24 ext.genBeanSrc = file("$buildDir/gen-javabean")
  25 ext.genReuseSrc = file("$buildDir/gen-javareuse")
  26 ext.genFullCamelSrc = file("$buildDir/gen-fullcamel")
  27 ext.genUnsafeSrc = file("$buildDir/gen-unsafe")
  28
  29 // Add the generated code directories to the test source set
  30 sourceSets {
  31     test.java.srcDirs genSrc, genBeanSrc, genReuseSrc, genFullCamelSrc, genUnsafeSrc
  32 }
  33
  34 // ----------------------------------------------------------------------------
  35 // Code generation for Unit Testing
  36
  37 // A callable closure to make this easier
  38 ext.thriftCompile = { Task task, String thriftFileName, String generator = 'java', File outputDir = genSrc ->
  39     def thriftFile = file("$thriftRoot/test/$thriftFileName")
  40     assert thriftFile.exists()
  41
  42     task.inputs.file thriftFile
  43     task.outputs.dir outputDir
  44
  45     task.doLast {
  46         outputDir.mkdirs()
  47         def result = exec {
  48             executable file(thriftCompiler)
  49             args '--gen', generator
  50             args '-out', outputDir
  51             args thriftFile
  52             standardOutput = task.outputBuffer
  53             errorOutput = task.outputBuffer
  54             ignoreExitValue = true
  55         }
  56         if (result.exitValue != 0) {
  57             // Only show the Thrift compiler output on failures, cuts down on noise!
  58             println task.outputBuffer.toString()
  59             result.rethrowFailure()
  60         }
  61     }
  62 }
  63
  64 task generate(group: 'Build') {
  65     description = 'Generate all unit test Thrift sources'
  66     compileTestJava.dependsOn it
  67 }
  68
  69 task generateJava(group: 'Build') {
  70     description = 'Generate the thrift gen-java source'
  71     generate.dependsOn it
  72
  73     ext.outputBuffer = new ByteArrayOutputStream()
  74
  75     thriftCompile(it, 'ThriftTest.thrift')
  76     thriftCompile(it, 'JavaTypes.thrift')
  77     thriftCompile(it, 'DebugProtoTest.thrift')
  78     thriftCompile(it, 'DoubleConstantsTest.thrift')
  79     thriftCompile(it, 'OptionalRequiredTest.thrift')
  80     thriftCompile(it, 'ManyOptionals.thrift')
  81     thriftCompile(it, 'JavaDeepCopyTest.thrift')
  82     thriftCompile(it, 'EnumContainersTest.thrift')
  83     thriftCompile(it, 'JavaBinaryDefault.thrift')
  84 }
  85
  86 task generateBeanJava(group: 'Build') {
  87     description = 'Generate the thrift gen-javabean source'
  88     generate.dependsOn it
  89
  90     ext.outputBuffer = new ByteArrayOutputStream()
  91
  92     thriftCompile(it, 'JavaBeansTest.thrift', 'java:beans,nocamel', genBeanSrc)
  93 }
  94
  95 task generateReuseJava(group: 'Build') {
  96     description = 'Generate the thrift gen-javareuse source'
  97     generate.dependsOn it
  98
  99     ext.outputBuffer = new ByteArrayOutputStream()
 100
 101     thriftCompile(it, 'FullCamelTest.thrift', 'java:fullcamel', genFullCamelSrc)
 102 }
 103
 104 task generateFullCamelJava(group: 'Build') {
 105     description = 'Generate the thrift gen-fullcamel source'
 106     generate.dependsOn it
 107
 108     ext.outputBuffer = new ByteArrayOutputStream()
 109
 110     thriftCompile(it, 'ReuseObjects.thrift', 'java:reuse-objects', genReuseSrc)
 111 }
 112
 113 task generateUnsafeBinariesJava(group: 'Build') {
 114     description = 'Generate the thrift gen-unsafebinaries source'
 115     generate.dependsOn it
 116
 117     ext.outputBuffer = new ByteArrayOutputStream()
 118
 119     thriftCompile(it, 'UnsafeTypes.thrift', 'java:unsafe_binaries', genUnsafeSrc)
 120 }