ceph/src/jaegertracing/thrift/test/haxe/make_all.bat

   1 @echo off
   2 rem /*
   3 rem  * Licensed to the Apache Software Foundation (ASF) under one
   4 rem  * or more contributor license agreements. See the NOTICE file
   5 rem  * distributed with this work for additional information
   6 rem  * regarding copyright ownership. The ASF licenses this file
   7 rem  * to you under the Apache License, Version 2.0 (the
   8 rem  * "License"); you may not use this file except in compliance
   9 rem  * with the License. You may obtain a copy of the License at
  10 rem  *
  11 rem  *   http://www.apache.org/licenses/LICENSE-2.0
  12 rem  *
  13 rem  * Unless required by applicable law or agreed to in writing,
  14 rem  * software distributed under the License is distributed on an
  15 rem  * "AS IS" BASIS, WITHOUT WARRANTIES OR CONDITIONS OF ANY
  16 rem  * KIND, either express or implied. See the License for the
  17 rem  * specific language governing permissions and limitations
  18 rem  * under the License.
  19 rem  */
  20
  21 setlocal
  22 if "%HOMEDRIVE%"=="" goto MISSINGVARS
  23 if "%HOMEPATH%"=="" goto MISSINGVARS
  24 if "%HAXEPATH%"=="" goto NOTINSTALLED
  25
  26 set path=%HAXEPATH%;%HAXEPATH%\..\neko;%path%
  27
  28 rem # invoke Thrift comnpiler
  29 thrift -r -gen haxe   ..\ThriftTest.thrift
  30 if errorlevel 1 goto STOP
  31
  32 rem # invoke Haxe compiler for all targets
  33 for %%a in (*.hxml) do (
  34         rem * filter Python, as it is not supported by Haxe 3.1.3 (but will be in 3.1.4)
  35         if not "%%a"=="python.hxml" (
  36                 echo --------------------------
  37                 echo Building %%a ...
  38                 echo --------------------------
  39                 haxe  --cwd .  %%a
  40         )
  41 )
  42
  43
  44 echo.
  45 echo done.
  46 pause
  47 goto eof
  48
  49 :NOTINSTALLED
  50 echo FATAL: Either Haxe is not installed, or the HAXEPATH variable is not set.
  51 pause
  52 goto eof
  53
  54 :MISSINGVARS
  55 echo FATAL: Unable to locate home folder.
  56 echo.
  57 echo Both HOMEDRIVE and HOMEPATH need to be set to point to your Home folder.
  58 echo The current values are:
  59 echo HOMEDRIVE=%HOMEDRIVE%
  60 echo HOMEPATH=%HOMEPATH%
  61 pause
  62 goto eof
  63
  64 :STOP
  65 pause
  66 goto eof
  67
  68 :eof