ceph/src/pybind/CMakeLists.txt

   1 include(Distutils)
   2
   3 set(CYTHON_MODULE_DIR ${CMAKE_LIBRARY_OUTPUT_DIRECTORY}/cython_modules)
   4
   5 find_package(Cython REQUIRED)
   6
   7 add_subdirectory(rados)
   8 add_custom_target(cython_modules ALL
   9   DEPENDS cython_rados)
  10
  11 if(WITH_RBD)
  12   add_subdirectory(rbd)
  13   add_dependencies(cython_modules cython_rbd)
  14 endif()
  15 if(WITH_CEPHFS)
  16   add_subdirectory(cephfs)
  17   add_dependencies(cython_modules cython_cephfs)
  18 endif()
  19 if(WITH_RADOSGW)
  20   add_subdirectory(rgw)
  21   add_dependencies(cython_modules cython_rgw)
  22 endif()
  23
  24 # if CMAKE_INSTALL_PREFIX is an empty string, must replace
  25 # it with "/" to make PYTHON_INSTALL_TEMPLATE an absolute path to be
  26 # consistent with all other installation paths.
  27 if(CMAKE_INSTALL_PREFIX)
  28   set(PYTHON_INSTALL_TEMPLATE "${CMAKE_INSTALL_PREFIX}")
  29 else(CMAKE_INSTALL_PREFIX)
  30   set(PYTHON_INSTALL_TEMPLATE "/")
  31 endif(CMAKE_INSTALL_PREFIX)
  32
  33 execute_process(
  34   COMMAND
  35   ${Python3_EXECUTABLE} -c "from distutils import sysconfig; print(sysconfig.get_python_lib(prefix='${PYTHON_INSTALL_TEMPLATE}'))"
  36   OUTPUT_VARIABLE "PYTHON3_INSTDIR"
  37   OUTPUT_STRIP_TRAILING_WHITESPACE)
  38
  39 install(FILES
  40   ${CMAKE_CURRENT_SOURCE_DIR}/ceph_argparse.py
  41   ${CMAKE_CURRENT_SOURCE_DIR}/ceph_daemon.py
  42   ${CMAKE_CURRENT_SOURCE_DIR}/ceph_volume_client.py
  43   DESTINATION ${PYTHON3_INSTDIR})
  44
  45 if(WITH_MGR)
  46   execute_process(
  47     COMMAND ${Python3_EXECUTABLE} -c "import ssl; print('.'.join(map(str,ssl.OPENSSL_VERSION_INFO[0:3])))"
  48     RESULT_VARIABLE PYSSL_RESULT
  49     OUTPUT_VARIABLE PYSSL_VER
  50     ERROR_QUIET)
  51   if (NOT ${PYSSL_RESULT})
  52     # the ideal way to get the soversion is to parse the suffix of file name of
  53     # `/lib/x86_64-linux-gnu/libssl.so.1.0.0`, but since we're lazy, and will just
  54     # trust the version number here.
  55     macro(get_openssl_soversion version prefix)
  56       string(REPLACE "." ";" ssl_version_list ${version})
  57       list(GET ssl_version_list 0 ssl_version_major)
  58       list(GET ssl_version_list 1 ssl_version_minor)
  59       set(${prefix}_SOVERSION ${ssl_version_major}.${ssl_version_minor})
  60       unset(ssl_version_list)
  61       unset(ssl_version_major)
  62       unset(ssl_version_minor)
  63     endmacro()
  64     get_openssl_soversion(${OPENSSL_VERSION} OPENSSL)
  65     get_openssl_soversion(${PYSSL_VER} PYSSL)
  66     if(NOT (OPENSSL_SOVERSION VERSION_EQUAL PYSSL_SOVERSION))
  67       message(FATAL_ERROR "Python and Ceph link to different OpenSSL versions: ${PYSSL_VER} vs ${OPENSSL_VERSION}")
  68     endif()
  69   else()
  70     message(WARNING "could not determine ssl version of python crypto lib")
  71   endif()
  72   add_subdirectory(mgr)
  73 endif(WITH_MGR)