ceph/src/seastar/cmake/FindSourceLocation.cmake

   1 #
   2 # This file is open source software, licensed to you under the terms
   3 # of the Apache License, Version 2.0 (the "License").  See the NOTICE file
   4 # distributed with this work for additional information regarding copyright
   5 # ownership.  You may not use this file except in compliance with the License.
   6 #
   7 # You may obtain a copy of the License at
   8 #
   9 #   http://www.apache.org/licenses/LICENSE-2.0
  10 #
  11 # Unless required by applicable law or agreed to in writing,
  12 # software distributed under the License is distributed on an
  13 # "AS IS" BASIS, WITHOUT WARRANTIES OR CONDITIONS OF ANY
  14 # KIND, either express or implied.  See the License for the
  15 # specific language governing permissions and limitations
  16 # under the License.
  17 #
  18
  19 #
  20 # Copyright (C) 2022 Kefu Chai ( tchaikov@gmail.com )
  21 #
  22
  23 include (CheckCXXSourceCompiles)
  24 include (CheckCXXSourceRuns)
  25 include (CMakePushCheckState)
  26
  27 cmake_push_check_state ()
  28 file (READ ${CMAKE_CURRENT_LIST_DIR}/code_tests/Source_location_test.cc _source_location_test_code)
  29 set(CMAKE_REQUIRED_FLAGS "${CMAKE_CXX${CMAKE_CXX_STANDARD}_STANDARD_COMPILE_OPTION}")
  30 check_cxx_source_compiles ("${_source_location_test_code}" CxxSourceLocation_SUPPORTED)
  31
  32 file (READ ${CMAKE_CURRENT_LIST_DIR}/code_tests/Source_location_default_argument.cc _source_location_test_code)
  33 set(CMAKE_REQUIRED_FLAGS "${CMAKE_CXX${CMAKE_CXX_STANDARD}_STANDARD_COMPILE_OPTION}")
  34 # see also https://cplusplus.github.io/CWG/issues/2631.html
  35 check_cxx_source_runs ("${_source_location_test_code}" CxxSourceLocation_IMPLEMENTS_CWG2631)
  36 cmake_pop_check_state ()
  37
  38 if (NOT (TARGET SourceLocation::source_location))
  39   add_library (SourceLocation::source_location INTERFACE IMPORTED)
  40   if  ((NOT CxxSourceLocation_SUPPORTED) OR
  41        (NOT CxxSourceLocation_IMPLEMENTS_CWG2631))
  42     set_target_properties (SourceLocation::source_location
  43       PROPERTIES
  44         INTERFACE_COMPILE_DEFINITIONS SEASTAR_BROKEN_SOURCE_LOCATION)
  45   endif ()
  46 endif ()