ceph/src/seastar/cmake/Findc-ares.cmake

   1 #
   2 # This file is open source software, licensed to you under the terms
   3 # of the Apache License, Version 2.0 (the "License").  See the NOTICE file
   4 # distributed with this work for additional information regarding copyright
   5 # ownership.  You may not use this file except in compliance with the License.
   6 #
   7 # You may obtain a copy of the License at
   8 #
   9 #   http://www.apache.org/licenses/LICENSE-2.0
  10 #
  11 # Unless required by applicable law or agreed to in writing,
  12 # software distributed under the License is distributed on an
  13 # "AS IS" BASIS, WITHOUT WARRANTIES OR CONDITIONS OF ANY
  14 # KIND, either express or implied.  See the License for the
  15 # specific language governing permissions and limitations
  16 # under the License.
  17 #
  18
  19 #
  20 # Copyright (C) 2018 Scylladb, Ltd.
  21 #
  22
  23 find_package (PkgConfig REQUIRED)
  24
  25 pkg_check_modules (PC_c-ares QUIET libcares)
  26
  27 find_library (c-ares_LIBRARY
  28   NAMES cares
  29   HINTS
  30     ${PC_c-ares_LIBDIR}
  31     ${PC_c-ares_LIBRARY_DIRS})
  32
  33 find_path (c-ares_INCLUDE_DIR
  34   NAMES ares_dns.h
  35   HINTS
  36     ${PC_c-ares_INCLUDEDIR}
  37     ${PC_c-ares_INCLUDE_DIRS})
  38
  39 mark_as_advanced (
  40   c-ares_LIBRARY
  41   c-ares_INCLUDE_DIR)
  42
  43 include (FindPackageHandleStandardArgs)
  44
  45 find_package_handle_standard_args (c-ares
  46   REQUIRED_VARS
  47     c-ares_LIBRARY
  48     c-ares_INCLUDE_DIR
  49   VERSION_VAR PC_c-ares_VERSION)
  50
  51 if (c-ares_FOUND)
  52   set (c-ares_LIBRARIES ${c-ares_LIBRARY})
  53   set (c-ares_INCLUDE_DIRS ${c-ares_INCLUDE_DIR})
  54   if (NOT (TARGET c-ares::cares))
  55     add_library (c-ares::cares UNKNOWN IMPORTED)
  56
  57     set_target_properties (c-ares::cares
  58       PROPERTIES
  59         IMPORTED_LOCATION ${c-ares_LIBRARY}
  60         INTERFACE_INCLUDE_DIRECTORIES ${c-ares_INCLUDE_DIRS})
  61   endif ()
  62 endif ()