ceph/src/spawn/test/dependency/googletest/googletest/CMakeLists.txt

   1 ########################################################################
   2 # Note: CMake support is community-based. The maintainers do not use CMake
   3 # internally.
   4 #
   5 # CMake build script for Google Test.
   6 #
   7 # To run the tests for Google Test itself on Linux, use 'make test' or
   8 # ctest.  You can select which tests to run using 'ctest -R regex'.
   9 # For more options, run 'ctest --help'.
  10
  11 # When other libraries are using a shared version of runtime libraries,
  12 # Google Test also has to use one.
  13 option(
  14   gtest_force_shared_crt
  15   "Use shared (DLL) run-time lib even when Google Test is built as static lib."
  16   OFF)
  17
  18 option(gtest_build_tests "Build all of gtest's own tests." OFF)
  19
  20 option(gtest_build_samples "Build gtest's sample programs." OFF)
  21
  22 option(gtest_disable_pthreads "Disable uses of pthreads in gtest." OFF)
  23
  24 option(
  25   gtest_hide_internal_symbols
  26   "Build gtest with internal symbols hidden in shared libraries."
  27   OFF)
  28
  29 # Defines pre_project_set_up_hermetic_build() and set_up_hermetic_build().
  30 include(cmake/hermetic_build.cmake OPTIONAL)
  31
  32 if (COMMAND pre_project_set_up_hermetic_build)
  33   pre_project_set_up_hermetic_build()
  34 endif()
  35
  36 ########################################################################
  37 #
  38 # Project-wide settings
  39
  40 # Name of the project.
  41 #
  42 # CMake files in this project can refer to the root source directory
  43 # as ${gtest_SOURCE_DIR} and to the root binary directory as
  44 # ${gtest_BINARY_DIR}.
  45 # Language "C" is required for find_package(Threads).
  46
  47 # Project version:
  48
  49 if (CMAKE_VERSION VERSION_LESS 3.0)
  50   project(gtest CXX C)
  51   set(PROJECT_VERSION ${GOOGLETEST_VERSION})
  52 else()
  53   cmake_policy(SET CMP0048 NEW)
  54   project(gtest VERSION ${GOOGLETEST_VERSION} LANGUAGES CXX C)
  55 endif()
  56 cmake_minimum_required(VERSION 2.6.4)
  57
  58 if (POLICY CMP0063) # Visibility
  59   cmake_policy(SET CMP0063 NEW)
  60 endif (POLICY CMP0063)
  61
  62 if (COMMAND set_up_hermetic_build)
  63   set_up_hermetic_build()
  64 endif()
  65
  66 # These commands only run if this is the main project
  67 if(CMAKE_PROJECT_NAME STREQUAL "gtest" OR CMAKE_PROJECT_NAME STREQUAL "googletest-distribution")
  68
  69   # BUILD_SHARED_LIBS is a standard CMake variable, but we declare it here to
  70   # make it prominent in the GUI.
  71   option(BUILD_SHARED_LIBS "Build shared libraries (DLLs)." OFF)
  72
  73 else()
  74
  75   mark_as_advanced(
  76     gtest_force_shared_crt
  77     gtest_build_tests
  78     gtest_build_samples
  79     gtest_disable_pthreads
  80     gtest_hide_internal_symbols)
  81
  82 endif()
  83
  84
  85 if (gtest_hide_internal_symbols)
  86   set(CMAKE_CXX_VISIBILITY_PRESET hidden)
  87   set(CMAKE_VISIBILITY_INLINES_HIDDEN 1)
  88 endif()
  89
  90 # Define helper functions and macros used by Google Test.
  91 include(cmake/internal_utils.cmake)
  92
  93 config_compiler_and_linker()  # Defined in internal_utils.cmake.
  94
  95 # Create the CMake package file descriptors.
  96 if (INSTALL_GTEST)
  97   include(CMakePackageConfigHelpers)
  98   set(cmake_package_name GTest)
  99   set(targets_export_name ${cmake_package_name}Targets CACHE INTERNAL "")
 100   set(generated_dir "${CMAKE_CURRENT_BINARY_DIR}/generated" CACHE INTERNAL "")
 101   set(cmake_files_install_dir "${CMAKE_INSTALL_LIBDIR}/cmake/${cmake_package_name}")
 102   set(version_file "${generated_dir}/${cmake_package_name}ConfigVersion.cmake")
 103   write_basic_package_version_file(${version_file} VERSION ${GOOGLETEST_VERSION} COMPATIBILITY AnyNewerVersion)
 104   install(EXPORT ${targets_export_name}
 105     NAMESPACE ${cmake_package_name}::
 106     DESTINATION ${cmake_files_install_dir})
 107   set(config_file "${generated_dir}/${cmake_package_name}Config.cmake")
 108   configure_package_config_file("${gtest_SOURCE_DIR}/cmake/Config.cmake.in"
 109     "${config_file}" INSTALL_DESTINATION ${cmake_files_install_dir})
 110   install(FILES ${version_file} ${config_file}
 111     DESTINATION ${cmake_files_install_dir})
 112 endif()
 113
 114 # Where Google Test's .h files can be found.
 115 set(gtest_build_include_dirs
 116   "${gtest_SOURCE_DIR}/include"
 117   "${gtest_SOURCE_DIR}")
 118 include_directories(${gtest_build_include_dirs})
 119
 120 ########################################################################
 121 #
 122 # Defines the gtest & gtest_main libraries.  User tests should link
 123 # with one of them.
 124
 125 # Google Test libraries.  We build them using more strict warnings than what
 126 # are used for other targets, to ensure that gtest can be compiled by a user
 127 # aggressive about warnings.
 128 cxx_library(gtest "${cxx_strict}" src/gtest-all.cc)
 129 cxx_library(gtest_main "${cxx_strict}" src/gtest_main.cc)
 130 # If the CMake version supports it, attach header directory information
 131 # to the targets for when we are part of a parent build (ie being pulled
 132 # in via add_subdirectory() rather than being a standalone build).
 133 if (DEFINED CMAKE_VERSION AND NOT "${CMAKE_VERSION}" VERSION_LESS "2.8.11")
 134   target_include_directories(gtest SYSTEM INTERFACE
 135     "$<BUILD_INTERFACE:${gtest_build_include_dirs}>"
 136     "$<INSTALL_INTERFACE:$<INSTALL_PREFIX>/${CMAKE_INSTALL_INCLUDEDIR}>")
 137   target_include_directories(gtest_main SYSTEM INTERFACE
 138     "$<BUILD_INTERFACE:${gtest_build_include_dirs}>"
 139     "$<INSTALL_INTERFACE:$<INSTALL_PREFIX>/${CMAKE_INSTALL_INCLUDEDIR}>")
 140 endif()
 141 target_link_libraries(gtest_main PUBLIC gtest)
 142
 143 ########################################################################
 144 #
 145 # Install rules
 146 install_project(gtest gtest_main)
 147
 148 ########################################################################
 149 #
 150 # Samples on how to link user tests with gtest or gtest_main.
 151 #
 152 # They are not built by default.  To build them, set the
 153 # gtest_build_samples option to ON.  You can do it by running ccmake
 154 # or specifying the -Dgtest_build_samples=ON flag when running cmake.
 155
 156 if (gtest_build_samples)
 157   cxx_executable(sample1_unittest samples gtest_main samples/sample1.cc)
 158   cxx_executable(sample2_unittest samples gtest_main samples/sample2.cc)
 159   cxx_executable(sample3_unittest samples gtest_main)
 160   cxx_executable(sample4_unittest samples gtest_main samples/sample4.cc)
 161   cxx_executable(sample5_unittest samples gtest_main samples/sample1.cc)
 162   cxx_executable(sample6_unittest samples gtest_main)
 163   cxx_executable(sample7_unittest samples gtest_main)
 164   cxx_executable(sample8_unittest samples gtest_main)
 165   cxx_executable(sample9_unittest samples gtest)
 166   cxx_executable(sample10_unittest samples gtest)
 167 endif()
 168
 169 ########################################################################
 170 #
 171 # Google Test's own tests.
 172 #
 173 # You can skip this section if you aren't interested in testing
 174 # Google Test itself.
 175 #
 176 # The tests are not built by default.  To build them, set the
 177 # gtest_build_tests option to ON.  You can do it by running ccmake
 178 # or specifying the -Dgtest_build_tests=ON flag when running cmake.
 179
 180 if (gtest_build_tests)
 181   # This must be set in the root directory for the tests to be run by
 182   # 'make test' or ctest.
 183   enable_testing()
 184
 185   if (WIN32)
 186     file(GENERATE OUTPUT "${CMAKE_CURRENT_BINARY_DIR}/$<CONFIG>/RunTest.ps1"
 187          CONTENT
 188 "$project_bin = \"${CMAKE_BINARY_DIR}/bin/$<CONFIG>\"
 189 $env:Path = \"$project_bin;$env:Path\"
 190 & $args")
 191   elseif (MINGW OR CYGWIN)
 192     file(GENERATE OUTPUT "${CMAKE_CURRENT_BINARY_DIR}/RunTest.ps1"
 193          CONTENT
 194 "$project_bin = (cygpath --windows ${CMAKE_BINARY_DIR}/bin)
 195 $env:Path = \"$project_bin;$env:Path\"
 196 & $args")
 197   endif()
 198
 199   ############################################################
 200   # C++ tests built with standard compiler flags.
 201
 202   cxx_test(googletest-death-test-test gtest_main)
 203   cxx_test(gtest_environment_test gtest)
 204   cxx_test(googletest-filepath-test gtest_main)
 205   cxx_test(googletest-listener-test gtest_main)
 206   cxx_test(gtest_main_unittest gtest_main)
 207   cxx_test(googletest-message-test gtest_main)
 208   cxx_test(gtest_no_test_unittest gtest)
 209   cxx_test(googletest-options-test gtest_main)
 210   cxx_test(googletest-param-test-test gtest
 211     test/googletest-param-test2-test.cc)
 212   cxx_test(googletest-port-test gtest_main)
 213   cxx_test(gtest_pred_impl_unittest gtest_main)
 214   cxx_test(gtest_premature_exit_test gtest
 215     test/gtest_premature_exit_test.cc)
 216   cxx_test(googletest-printers-test gtest_main)
 217   cxx_test(gtest_prod_test gtest_main
 218     test/production.cc)
 219   cxx_test(gtest_repeat_test gtest)
 220   cxx_test(gtest_sole_header_test gtest_main)
 221   cxx_test(gtest_stress_test gtest)
 222   cxx_test(googletest-test-part-test gtest_main)
 223   cxx_test(gtest_throw_on_failure_ex_test gtest)
 224   cxx_test(gtest-typed-test_test gtest_main
 225     test/gtest-typed-test2_test.cc)
 226   cxx_test(gtest_unittest gtest_main)
 227   cxx_test(gtest-unittest-api_test gtest)
 228   cxx_test(gtest_skip_in_environment_setup_test gtest_main)
 229   cxx_test(gtest_skip_test gtest_main)
 230
 231   ############################################################
 232   # C++ tests built with non-standard compiler flags.
 233
 234   # MSVC 7.1 does not support STL with exceptions disabled.
 235   if (NOT MSVC OR MSVC_VERSION GREATER 1310)
 236     cxx_library(gtest_no_exception "${cxx_no_exception}"
 237       src/gtest-all.cc)
 238     cxx_library(gtest_main_no_exception "${cxx_no_exception}"
 239       src/gtest-all.cc src/gtest_main.cc)
 240   endif()
 241   cxx_library(gtest_main_no_rtti "${cxx_no_rtti}"
 242     src/gtest-all.cc src/gtest_main.cc)
 243
 244   cxx_test_with_flags(gtest-death-test_ex_nocatch_test
 245     "${cxx_exception} -DGTEST_ENABLE_CATCH_EXCEPTIONS_=0"
 246     gtest test/googletest-death-test_ex_test.cc)
 247   cxx_test_with_flags(gtest-death-test_ex_catch_test
 248     "${cxx_exception} -DGTEST_ENABLE_CATCH_EXCEPTIONS_=1"
 249     gtest test/googletest-death-test_ex_test.cc)
 250
 251   cxx_test_with_flags(gtest_no_rtti_unittest "${cxx_no_rtti}"
 252     gtest_main_no_rtti test/gtest_unittest.cc)
 253
 254   cxx_shared_library(gtest_dll "${cxx_default}"
 255     src/gtest-all.cc src/gtest_main.cc)
 256
 257   cxx_executable_with_flags(gtest_dll_test_ "${cxx_default}"
 258     gtest_dll test/gtest_all_test.cc)
 259   set_target_properties(gtest_dll_test_
 260                         PROPERTIES
 261                         COMPILE_DEFINITIONS "GTEST_LINKED_AS_SHARED_LIBRARY=1")
 262
 263   ############################################################
 264   # Python tests.
 265
 266   cxx_executable(googletest-break-on-failure-unittest_ test gtest)
 267   py_test(googletest-break-on-failure-unittest)
 268
 269   py_test(gtest_skip_environment_check_output_test)
 270
 271   # Visual Studio .NET 2003 does not support STL with exceptions disabled.
 272   if (NOT MSVC OR MSVC_VERSION GREATER 1310)  # 1310 is Visual Studio .NET 2003
 273     cxx_executable_with_flags(
 274       googletest-catch-exceptions-no-ex-test_
 275       "${cxx_no_exception}"
 276       gtest_main_no_exception
 277       test/googletest-catch-exceptions-test_.cc)
 278   endif()
 279
 280   cxx_executable_with_flags(
 281     googletest-catch-exceptions-ex-test_
 282     "${cxx_exception}"
 283     gtest_main
 284     test/googletest-catch-exceptions-test_.cc)
 285   py_test(googletest-catch-exceptions-test)
 286
 287   cxx_executable(googletest-color-test_ test gtest)
 288   py_test(googletest-color-test)
 289
 290   cxx_executable(googletest-env-var-test_ test gtest)
 291   py_test(googletest-env-var-test)
 292
 293   cxx_executable(googletest-filter-unittest_ test gtest)
 294   py_test(googletest-filter-unittest)
 295
 296   cxx_executable(gtest_help_test_ test gtest_main)
 297   py_test(gtest_help_test)
 298
 299   cxx_executable(googletest-list-tests-unittest_ test gtest)
 300   py_test(googletest-list-tests-unittest)
 301
 302   cxx_executable(googletest-output-test_ test gtest)
 303   py_test(googletest-output-test --no_stacktrace_support)
 304
 305   cxx_executable(googletest-shuffle-test_ test gtest)
 306   py_test(googletest-shuffle-test)
 307
 308   # MSVC 7.1 does not support STL with exceptions disabled.
 309   if (NOT MSVC OR MSVC_VERSION GREATER 1310)
 310     cxx_executable(googletest-throw-on-failure-test_ test gtest_no_exception)
 311     set_target_properties(googletest-throw-on-failure-test_
 312       PROPERTIES
 313       COMPILE_FLAGS "${cxx_no_exception}")
 314     py_test(googletest-throw-on-failure-test)
 315   endif()
 316
 317   cxx_executable(googletest-uninitialized-test_ test gtest)
 318   py_test(googletest-uninitialized-test)
 319
 320   cxx_executable(gtest_xml_outfile1_test_ test gtest_main)
 321   cxx_executable(gtest_xml_outfile2_test_ test gtest_main)
 322   py_test(gtest_xml_outfiles_test)
 323   py_test(googletest-json-outfiles-test)
 324
 325   cxx_executable(gtest_xml_output_unittest_ test gtest)
 326   py_test(gtest_xml_output_unittest --no_stacktrace_support)
 327   py_test(googletest-json-output-unittest --no_stacktrace_support)
 328 endif()