ceph/src/spdk/dpdk/drivers/net/enic/meson.build

   1 # SPDX-License-Identifier: BSD-3-Clause
   2 # Copyright(c) 2018 Cisco Systems, Inc.
   3
   4 sources = files(
   5         'base/vnic_cq.c',
   6         'base/vnic_dev.c',
   7         'base/vnic_intr.c',
   8         'base/vnic_rq.c',
   9         'base/vnic_wq.c',
  10         'enic_clsf.c',
  11         'enic_ethdev.c',
  12         'enic_flow.c',
  13         'enic_main.c',
  14         'enic_res.c',
  15         'enic_rxtx.c',
  16         )
  17 deps += ['hash']
  18 includes += include_directories('base')
  19
  20 # The current implementation assumes 64-bit pointers
  21 if dpdk_conf.has('RTE_MACHINE_CPUFLAG_AVX2') and dpdk_conf.get('RTE_ARCH_64')
  22         sources += files('enic_rxtx_vec_avx2.c')
  23 # Build the avx2 handler if the compiler supports it, even though 'machine'
  24 # does not. This is to support users who build for the min supported machine
  25 # and need to run the binary on newer CPUs too.
  26 # This part is from i40e meson.build
  27 elif cc.has_argument('-mavx2') and dpdk_conf.get('RTE_ARCH_64')
  28         enic_avx2_lib = static_library('enic_avx2_lib',
  29                         'enic_rxtx_vec_avx2.c',
  30                         dependencies: [static_rte_ethdev, static_rte_bus_pci],
  31                         include_directories: includes,
  32                         c_args: [cflags, '-mavx2'])
  33         objs += enic_avx2_lib.extract_objects('enic_rxtx_vec_avx2.c')
  34 endif