config/kernel.m4

   1 dnl #
   2 dnl # Default ZFS kernel configuration
   3 dnl #
   4 AC_DEFUN([ZFS_AC_CONFIG_KERNEL], [
   5         ZFS_AC_KERNEL
   6         ZFS_AC_SPL
   7         ZFS_AC_TEST_MODULE
   8         ZFS_AC_KERNEL_CONFIG
   9         ZFS_AC_KERNEL_DECLARE_EVENT_CLASS
  10         ZFS_AC_KERNEL_CURRENT_BIO_TAIL
  11         ZFS_AC_KERNEL_BDEV_BLOCK_DEVICE_OPERATIONS
  12         ZFS_AC_KERNEL_BLOCK_DEVICE_OPERATIONS_RELEASE_VOID
  13         ZFS_AC_KERNEL_TYPE_FMODE_T
  14         ZFS_AC_KERNEL_KOBJ_NAME_LEN
  15         ZFS_AC_KERNEL_3ARG_BLKDEV_GET
  16         ZFS_AC_KERNEL_BLKDEV_GET_BY_PATH
  17         ZFS_AC_KERNEL_OPEN_BDEV_EXCLUSIVE
  18         ZFS_AC_KERNEL_LOOKUP_BDEV
  19         ZFS_AC_KERNEL_INVALIDATE_BDEV_ARGS
  20         ZFS_AC_KERNEL_BDEV_LOGICAL_BLOCK_SIZE
  21         ZFS_AC_KERNEL_BDEV_PHYSICAL_BLOCK_SIZE
  22         ZFS_AC_KERNEL_BIO_BVEC_ITER
  23         ZFS_AC_KERNEL_BIO_FAILFAST_DTD
  24         ZFS_AC_KERNEL_REQ_FAILFAST_MASK
  25         ZFS_AC_KERNEL_BIO_END_IO_T_ARGS
  26         ZFS_AC_KERNEL_BIO_RW_BARRIER
  27         ZFS_AC_KERNEL_BIO_RW_DISCARD
  28         ZFS_AC_KERNEL_BLK_QUEUE_FLUSH
  29         ZFS_AC_KERNEL_BLK_QUEUE_MAX_HW_SECTORS
  30         ZFS_AC_KERNEL_BLK_QUEUE_MAX_SEGMENTS
  31         ZFS_AC_KERNEL_GET_DISK_RO
  32         ZFS_AC_KERNEL_GET_GENDISK
  33         ZFS_AC_KERNEL_DISCARD_GRANULARITY
  34         ZFS_AC_KERNEL_CONST_XATTR_HANDLER
  35         ZFS_AC_KERNEL_XATTR_HANDLER_GET
  36         ZFS_AC_KERNEL_XATTR_HANDLER_SET
  37         ZFS_AC_KERNEL_XATTR_HANDLER_LIST
  38         ZFS_AC_KERNEL_INODE_OWNER_OR_CAPABLE
  39         ZFS_AC_KERNEL_POSIX_ACL_FROM_XATTR_USERNS
  40         ZFS_AC_KERNEL_POSIX_ACL_RELEASE
  41         ZFS_AC_KERNEL_POSIX_ACL_CHMOD
  42         ZFS_AC_KERNEL_POSIX_ACL_CACHING
  43         ZFS_AC_KERNEL_POSIX_ACL_EQUIV_MODE_WANTS_UMODE_T
  44         ZFS_AC_KERNEL_INODE_OPERATIONS_PERMISSION
  45         ZFS_AC_KERNEL_INODE_OPERATIONS_PERMISSION_WITH_NAMEIDATA
  46         ZFS_AC_KERNEL_INODE_OPERATIONS_CHECK_ACL
  47         ZFS_AC_KERNEL_INODE_OPERATIONS_CHECK_ACL_WITH_FLAGS
  48         ZFS_AC_KERNEL_INODE_OPERATIONS_GET_ACL
  49         ZFS_AC_KERNEL_CURRENT_UMASK
  50         ZFS_AC_KERNEL_SHOW_OPTIONS
  51         ZFS_AC_KERNEL_FILE_INODE
  52         ZFS_AC_KERNEL_FSYNC
  53         ZFS_AC_KERNEL_EVICT_INODE
  54         ZFS_AC_KERNEL_DIRTY_INODE_WITH_FLAGS
  55         ZFS_AC_KERNEL_NR_CACHED_OBJECTS
  56         ZFS_AC_KERNEL_FREE_CACHED_OBJECTS
  57         ZFS_AC_KERNEL_FALLOCATE
  58         ZFS_AC_KERNEL_MKDIR_UMODE_T
  59         ZFS_AC_KERNEL_LOOKUP_NAMEIDATA
  60         ZFS_AC_KERNEL_CREATE_NAMEIDATA
  61         ZFS_AC_KERNEL_FOLLOW_LINK
  62         ZFS_AC_KERNEL_PUT_LINK
  63         ZFS_AC_KERNEL_TRUNCATE_RANGE
  64         ZFS_AC_KERNEL_AUTOMOUNT
  65         ZFS_AC_KERNEL_ENCODE_FH_WITH_INODE
  66         ZFS_AC_KERNEL_COMMIT_METADATA
  67         ZFS_AC_KERNEL_CLEAR_INODE
  68         ZFS_AC_KERNEL_INSERT_INODE_LOCKED
  69         ZFS_AC_KERNEL_D_MAKE_ROOT
  70         ZFS_AC_KERNEL_D_OBTAIN_ALIAS
  71         ZFS_AC_KERNEL_D_PRUNE_ALIASES
  72         ZFS_AC_KERNEL_D_SET_D_OP
  73         ZFS_AC_KERNEL_D_REVALIDATE_NAMEIDATA
  74         ZFS_AC_KERNEL_CONST_DENTRY_OPERATIONS
  75         ZFS_AC_KERNEL_TRUNCATE_SETSIZE
  76         ZFS_AC_KERNEL_6ARGS_SECURITY_INODE_INIT_SECURITY
  77         ZFS_AC_KERNEL_CALLBACK_SECURITY_INODE_INIT_SECURITY
  78         ZFS_AC_KERNEL_MOUNT_NODEV
  79         ZFS_AC_KERNEL_SHRINK
  80         ZFS_AC_KERNEL_SHRINK_CONTROL_HAS_NID
  81         ZFS_AC_KERNEL_S_INSTANCES_LIST_HEAD
  82         ZFS_AC_KERNEL_S_D_OP
  83         ZFS_AC_KERNEL_BDI_SETUP_AND_REGISTER
  84         ZFS_AC_KERNEL_SET_NLINK
  85         ZFS_AC_KERNEL_ELEVATOR_CHANGE
  86         ZFS_AC_KERNEL_5ARG_SGET
  87         ZFS_AC_KERNEL_LSEEK_EXECUTE
  88         ZFS_AC_KERNEL_VFS_ITERATE
  89         ZFS_AC_KERNEL_VFS_RW_ITERATE
  90         ZFS_AC_KERNEL_KMAP_ATOMIC_ARGS
  91         ZFS_AC_KERNEL_FOLLOW_DOWN_ONE
  92         ZFS_AC_KERNEL_MAKE_REQUEST_FN
  93         ZFS_AC_KERNEL_GENERIC_IO_ACCT
  94
  95         AS_IF([test "$LINUX_OBJ" != "$LINUX"], [
  96                 KERNELMAKE_PARAMS="$KERNELMAKE_PARAMS O=$LINUX_OBJ"
  97         ])
  98         AC_SUBST(KERNELMAKE_PARAMS)
  99
 100
 101         dnl # -Wall -fno-strict-aliasing -Wstrict-prototypes and other
 102         dnl # compiler options are added by the kernel build system.
 103         KERNELCPPFLAGS="$KERNELCPPFLAGS $NO_UNUSED_BUT_SET_VARIABLE"
 104         KERNELCPPFLAGS="$KERNELCPPFLAGS $NO_BOOL_COMPARE"
 105         KERNELCPPFLAGS="$KERNELCPPFLAGS -DHAVE_SPL -D_KERNEL"
 106         KERNELCPPFLAGS="$KERNELCPPFLAGS -DTEXT_DOMAIN=\\\"zfs-linux-kernel\\\""
 107
 108         AC_SUBST(KERNELCPPFLAGS)
 109 ])
 110
 111 dnl #
 112 dnl # Detect name used for Module.symvers file in kernel
 113 dnl #
 114 AC_DEFUN([ZFS_AC_MODULE_SYMVERS], [
 115         modpost=$LINUX/scripts/Makefile.modpost
 116         AC_MSG_CHECKING([kernel file name for module symbols])
 117         AS_IF([test "x$enable_linux_builtin" != xyes -a -f "$modpost"], [
 118                 AS_IF([grep -q Modules.symvers $modpost], [
 119                         LINUX_SYMBOLS=Modules.symvers
 120                 ], [
 121                         LINUX_SYMBOLS=Module.symvers
 122                 ])
 123
 124                 AS_IF([test ! -f "$LINUX_OBJ/$LINUX_SYMBOLS"], [
 125                         AC_MSG_ERROR([
 126         *** Please make sure the kernel devel package for your distribution
 127         *** is installed.  If you are building with a custom kernel, make sure the
 128         *** kernel is configured, built, and the '--with-linux=PATH' configure
 129         *** option refers to the location of the kernel source.])
 130                 ])
 131         ], [
 132                 LINUX_SYMBOLS=NONE
 133         ])
 134         AC_MSG_RESULT($LINUX_SYMBOLS)
 135         AC_SUBST(LINUX_SYMBOLS)
 136 ])
 137
 138 dnl #
 139 dnl # Detect the kernel to be built against
 140 dnl #
 141 AC_DEFUN([ZFS_AC_KERNEL], [
 142         AC_ARG_WITH([linux],
 143                 AS_HELP_STRING([--with-linux=PATH],
 144                 [Path to kernel source]),
 145                 [kernelsrc="$withval"])
 146
 147         AC_ARG_WITH(linux-obj,
 148                 AS_HELP_STRING([--with-linux-obj=PATH],
 149                 [Path to kernel build objects]),
 150                 [kernelbuild="$withval"])
 151
 152         AC_MSG_CHECKING([kernel source directory])
 153         AS_IF([test -z "$kernelsrc"], [
 154                 AS_IF([test -e "/lib/modules/$(uname -r)/source"], [
 155                         headersdir="/lib/modules/$(uname -r)/source"
 156                         sourcelink=$(readlink -f "$headersdir")
 157                 ], [test -e "/lib/modules/$(uname -r)/build"], [
 158                         headersdir="/lib/modules/$(uname -r)/build"
 159                         sourcelink=$(readlink -f "$headersdir")
 160                 ], [
 161                         sourcelink=$(ls -1d /usr/src/kernels/* \
 162                                      /usr/src/linux-* \
 163                                      2>/dev/null | grep -v obj | tail -1)
 164                 ])
 165
 166                 AS_IF([test -n "$sourcelink" && test -e ${sourcelink}], [
 167                         kernelsrc=`readlink -f ${sourcelink}`
 168                 ], [
 169                         kernelsrc="[Not found]"
 170                 ])
 171         ], [
 172                 AS_IF([test "$kernelsrc" = "NONE"], [
 173                         kernsrcver=NONE
 174                 ])
 175         ])
 176
 177         AC_MSG_RESULT([$kernelsrc])
 178         AS_IF([test ! -d "$kernelsrc"], [
 179                 AC_MSG_ERROR([
 180         *** Please make sure the kernel devel package for your distribution
 181         *** is installed and then try again.  If that fails, you can specify the
 182         *** location of the kernel source with the '--with-linux=PATH' option.])
 183         ])
 184
 185         AC_MSG_CHECKING([kernel build directory])
 186         AS_IF([test -z "$kernelbuild"], [
 187                 AS_IF([test -e "/lib/modules/$(uname -r)/build"], [
 188                         kernelbuild=`readlink -f /lib/modules/$(uname -r)/build`
 189                 ], [test -d ${kernelsrc}-obj/${target_cpu}/${target_cpu}], [
 190                         kernelbuild=${kernelsrc}-obj/${target_cpu}/${target_cpu}
 191                 ], [test -d ${kernelsrc}-obj/${target_cpu}/default], [
 192                         kernelbuild=${kernelsrc}-obj/${target_cpu}/default
 193                 ], [test -d `dirname ${kernelsrc}`/build-${target_cpu}], [
 194                         kernelbuild=`dirname ${kernelsrc}`/build-${target_cpu}
 195                 ], [
 196                         kernelbuild=${kernelsrc}
 197                 ])
 198         ])
 199         AC_MSG_RESULT([$kernelbuild])
 200
 201         AC_MSG_CHECKING([kernel source version])
 202         utsrelease1=$kernelbuild/include/linux/version.h
 203         utsrelease2=$kernelbuild/include/linux/utsrelease.h
 204         utsrelease3=$kernelbuild/include/generated/utsrelease.h
 205         AS_IF([test -r $utsrelease1 && fgrep -q UTS_RELEASE $utsrelease1], [
 206                 utsrelease=linux/version.h
 207         ], [test -r $utsrelease2 && fgrep -q UTS_RELEASE $utsrelease2], [
 208                 utsrelease=linux/utsrelease.h
 209         ], [test -r $utsrelease3 && fgrep -q UTS_RELEASE $utsrelease3], [
 210                 utsrelease=generated/utsrelease.h
 211         ])
 212
 213         AS_IF([test "$utsrelease"], [
 214                 kernsrcver=`(echo "#include <$utsrelease>";
 215                              echo "kernsrcver=UTS_RELEASE") |
 216                              cpp -I $kernelbuild/include |
 217                              grep "^kernsrcver=" | cut -d \" -f 2`
 218
 219                 AS_IF([test -z "$kernsrcver"], [
 220                         AC_MSG_RESULT([Not found])
 221                         AC_MSG_ERROR([*** Cannot determine kernel version.])
 222                 ])
 223         ], [
 224                 AC_MSG_RESULT([Not found])
 225                 if test "x$enable_linux_builtin" != xyes; then
 226                         AC_MSG_ERROR([*** Cannot find UTS_RELEASE definition.])
 227                 else
 228                         AC_MSG_ERROR([
 229         *** Cannot find UTS_RELEASE definition.
 230         *** Please run 'make prepare' inside the kernel source tree.])
 231                 fi
 232         ])
 233
 234         AC_MSG_RESULT([$kernsrcver])
 235
 236         LINUX=${kernelsrc}
 237         LINUX_OBJ=${kernelbuild}
 238         LINUX_VERSION=${kernsrcver}
 239
 240         AC_SUBST(LINUX)
 241         AC_SUBST(LINUX_OBJ)
 242         AC_SUBST(LINUX_VERSION)
 243
 244         ZFS_AC_MODULE_SYMVERS
 245 ])
 246
 247
 248 dnl #
 249 dnl # Detect the SPL module to be built against
 250 dnl #
 251 AC_DEFUN([ZFS_AC_SPL], [
 252         AC_ARG_WITH([spl],
 253                 AS_HELP_STRING([--with-spl=PATH],
 254                 [Path to spl source]),
 255                 [splsrc="$withval"])
 256
 257         AC_ARG_WITH([spl-obj],
 258                 AS_HELP_STRING([--with-spl-obj=PATH],
 259                 [Path to spl build objects]),
 260                 [splbuild="$withval"])
 261
 262         AC_ARG_WITH([spl-timeout],
 263                 AS_HELP_STRING([--with-spl-timeout=SECS],
 264                 [Wait SECS for SPL header and symver file @<:@default=0@:>@]),
 265                 [timeout="$withval"], [timeout=0])
 266
 267         dnl #
 268         dnl # The existence of spl.release.in is used to identify a valid
 269         dnl # source directory.  In order of preference:
 270         dnl #
 271         splsrc0="/var/lib/dkms/spl/${VERSION}/build"
 272         splsrc1="/usr/local/src/spl-${VERSION}/${LINUX_VERSION}"
 273         splsrc2="/usr/local/src/spl-${VERSION}"
 274         splsrc3="/usr/src/spl-${VERSION}/${LINUX_VERSION}"
 275         splsrc4="/usr/src/spl-${VERSION}"
 276         splsrc5="../spl/"
 277         splsrc6="$LINUX"
 278
 279         AC_MSG_CHECKING([spl source directory])
 280         AS_IF([test -z "${splsrc}"], [
 281                 AS_IF([ test -e "${splsrc0}/spl.release.in"], [
 282                         splsrc=${splsrc0}
 283                 ], [ test -e "${splsrc1}/spl.release.in"], [
 284                         splsrc=${splsrc1}
 285                 ], [ test -e "${splsrc2}/spl.release.in"], [
 286                         splsrc=${splsrc2}
 287                 ], [ test -e "${splsrc3}/spl.release.in"], [
 288                         splsrc=$(readlink -f "${splsrc3}")
 289                 ], [ test -e "${splsrc4}/spl.release.in" ], [
 290                         splsrc=${splsrc4}
 291                 ], [ test -e "${splsrc5}/spl.release.in"], [
 292                         splsrc=$(readlink -f "${splsrc5}")
 293                 ], [ test -e "${splsrc6}/spl.release.in" ], [
 294                         splsrc=${splsrc6}
 295                 ], [
 296                         splsrc="[Not found]"
 297                 ])
 298         ], [
 299                 AS_IF([test "$splsrc" = "NONE"], [
 300                         splbuild=NONE
 301                         splsrcver=NONE
 302                 ])
 303         ])
 304
 305         AC_MSG_RESULT([$splsrc])
 306         AS_IF([ test ! -e "$splsrc/spl.release.in"], [
 307                 AC_MSG_ERROR([
 308         *** Please make sure the kmod spl devel package for your distribution
 309         *** is installed then try again.  If that fails you can specify the
 310         *** location of the spl source with the '--with-spl=PATH' option.])
 311         ])
 312
 313         dnl #
 314         dnl # The existence of the spl_config.h is used to identify a valid
 315         dnl # spl object directory.  In many cases the object and source
 316         dnl # directory are the same, however the objects may also reside
 317         dnl # is a subdirectory named after the kernel version.
 318         dnl #
 319         dnl # This file is supposed to be available after DKMS finishes
 320         dnl # building the SPL kernel module for the target kernel.  The
 321         dnl # '--with-spl-timeout' option can be passed to pause here,
 322         dnl # waiting for the file to appear from a concurrently building
 323         dnl # SPL package.
 324         dnl #
 325         AC_MSG_CHECKING([spl build directory])
 326         while true; do
 327                 AS_IF([test -z "$splbuild"], [
 328                         AS_IF([ test -e "${splsrc}/${LINUX_VERSION}/spl_config.h" ], [
 329                                 splbuild="${splsrc}/${LINUX_VERSION}"
 330                         ], [ test -e "${splsrc}/spl_config.h" ], [
 331                                 splbuild="${splsrc}"
 332                         ], [ find -L "${splsrc}" -name spl_config.h 2> /dev/null | grep -wq spl_config.h ], [
 333                                 splbuild=$(find -L "${splsrc}" -name spl_config.h | sed 's,/spl_config.h,,')
 334                         ], [
 335                                 splbuild="[Not found]"
 336                         ])
 337                 ])
 338                 AS_IF([test -e "$splbuild/spl_config.h" -o $timeout -le 0], [
 339                         break;
 340                 ], [
 341                         sleep 1
 342                         timeout=$((timeout-1))
 343                 ])
 344         done
 345
 346         AC_MSG_RESULT([$splbuild])
 347         AS_IF([ ! test -e "$splbuild/spl_config.h"], [
 348                 AC_MSG_ERROR([
 349         *** Please make sure the kmod spl devel <kernel> package for your
 350         *** distribution is installed then try again.  If that fails you
 351         *** can specify the location of the spl objects with the
 352         *** '--with-spl-obj=PATH' option.])
 353         ])
 354
 355         AC_MSG_CHECKING([spl source version])
 356         AS_IF([test -r $splbuild/spl_config.h &&
 357                 fgrep -q SPL_META_VERSION $splbuild/spl_config.h], [
 358
 359                 splsrcver=`(echo "#include <spl_config.h>";
 360                             echo "splsrcver=SPL_META_VERSION-SPL_META_RELEASE") |
 361                             cpp -I $splbuild |
 362                             grep "^splsrcver=" | tr -d \" | cut -d= -f2`
 363         ])
 364
 365         AS_IF([test -z "$splsrcver"], [
 366                 AC_MSG_RESULT([Not found])
 367                 AC_MSG_ERROR([
 368         *** Cannot determine the version of the spl source.
 369         *** Please prepare the spl source before running this script])
 370         ])
 371
 372         AC_MSG_RESULT([$splsrcver])
 373
 374         SPL=${splsrc}
 375         SPL_OBJ=${splbuild}
 376         SPL_VERSION=${splsrcver}
 377
 378         AC_SUBST(SPL)
 379         AC_SUBST(SPL_OBJ)
 380         AC_SUBST(SPL_VERSION)
 381
 382         dnl #
 383         dnl # Detect the name used for the SPL Module.symvers file.  If one
 384         dnl # does not exist this is likely because the SPL has been configured
 385         dnl # but not built.  The '--with-spl-timeout' option can be passed
 386         dnl # to pause here, waiting for the file to appear from a concurrently
 387         dnl # building SPL package.  If the file does not appear in time, a good
 388         dnl # guess is made as to what this file will be named based on what it
 389         dnl # is named in the kernel build products.  This file will first be
 390         dnl # used at link time so if the guess is wrong the build will fail
 391         dnl # then.  This unfortunately means the ZFS package does not contain a
 392         dnl # reliable mechanism to detect symbols exported by the SPL at
 393         dnl # configure time.
 394         dnl #
 395         AC_MSG_CHECKING([spl file name for module symbols])
 396         SPL_SYMBOLS=NONE
 397
 398         while true; do
 399                 AS_IF([test -r $SPL_OBJ/Module.symvers], [
 400                         SPL_SYMBOLS=Module.symvers
 401                 ], [test -r $SPL_OBJ/Modules.symvers], [
 402                         SPL_SYMBOLS=Modules.symvers
 403                 ], [test -r $SPL_OBJ/module/Module.symvers], [
 404                         SPL_SYMBOLS=Module.symvers
 405                 ], [test -r $SPL_OBJ/module/Modules.symvers], [
 406                         SPL_SYMBOLS=Modules.symvers
 407                 ])
 408
 409                 AS_IF([test $SPL_SYMBOLS != NONE -o $timeout -le 0], [
 410                         break;
 411                 ], [
 412                         sleep 1
 413                         timeout=$((timeout-1))
 414                 ])
 415         done
 416
 417         AS_IF([test "$SPL_SYMBOLS" = NONE], [
 418                 SPL_SYMBOLS=$LINUX_SYMBOLS
 419         ])
 420
 421         AC_MSG_RESULT([$SPL_SYMBOLS])
 422         AC_SUBST(SPL_SYMBOLS)
 423 ])
 424
 425 dnl #
 426 dnl # Basic toolchain sanity check.
 427 dnl #
 428 AC_DEFUN([ZFS_AC_TEST_MODULE], [
 429         AC_MSG_CHECKING([whether modules can be built])
 430         ZFS_LINUX_TRY_COMPILE([],[],[
 431                 AC_MSG_RESULT([yes])
 432         ],[
 433                 AC_MSG_RESULT([no])
 434                 if test "x$enable_linux_builtin" != xyes; then
 435                         AC_MSG_ERROR([*** Unable to build an empty module.])
 436                 else
 437                         AC_MSG_ERROR([
 438         *** Unable to build an empty module.
 439         *** Please run 'make scripts' inside the kernel source tree.])
 440                 fi
 441         ])
 442 ])
 443
 444 dnl #
 445 dnl # Certain kernel build options are not supported.  These must be
 446 dnl # detected at configure time and cause a build failure.  Otherwise
 447 dnl # modules may be successfully built that behave incorrectly.
 448 dnl #
 449 AC_DEFUN([ZFS_AC_KERNEL_CONFIG], [
 450         AS_IF([test "x$cross_compiling" != xyes], [
 451                 AC_RUN_IFELSE([
 452                         AC_LANG_PROGRAM([
 453                                 #include "$LINUX/include/linux/license.h"
 454                         ], [
 455                                 return !license_is_gpl_compatible("$ZFS_META_LICENSE");
 456                         ])
 457                 ], [
 458                         AC_DEFINE([ZFS_IS_GPL_COMPATIBLE], [1],
 459                             [Define to 1 if GPL-only symbols can be used])
 460                 ], [
 461                 ])
 462         ])
 463
 464         ZFS_AC_KERNEL_CONFIG_THREAD_SIZE
 465         ZFS_AC_KERNEL_CONFIG_DEBUG_LOCK_ALLOC
 466 ])
 467
 468 dnl #
 469 dnl # Check configured THREAD_SIZE
 470 dnl #
 471 dnl # The stack size will vary by architecture, but as of Linux 3.15 on x86_64
 472 dnl # the default thread stack size was increased to 16K from 8K.  Therefore,
 473 dnl # on newer kernels and some architectures stack usage optimizations can be
 474 dnl # conditionally applied to improve performance without negatively impacting
 475 dnl # stability.
 476 dnl #
 477 AC_DEFUN([ZFS_AC_KERNEL_CONFIG_THREAD_SIZE], [
 478         AC_MSG_CHECKING([whether kernel was built with 16K or larger stacks])
 479         ZFS_LINUX_TRY_COMPILE([
 480                 #include <linux/module.h>
 481         ],[
 482                 #if (THREAD_SIZE < 16384)
 483                 #error "THREAD_SIZE is less than 16K"
 484                 #endif
 485         ],[
 486                 AC_MSG_RESULT([yes])
 487                 AC_DEFINE(HAVE_LARGE_STACKS, 1, [kernel has large stacks])
 488         ],[
 489                 AC_MSG_RESULT([no])
 490         ])
 491 ])
 492
 493 dnl #
 494 dnl # Check CONFIG_DEBUG_LOCK_ALLOC
 495 dnl #
 496 dnl # This is typically only set for debug kernels because it comes with
 497 dnl # a performance penalty.  However, when it is set it maps the non-GPL
 498 dnl # symbol mutex_lock() to the GPL-only mutex_lock_nested() symbol.
 499 dnl # This will cause a failure at link time which we'd rather know about
 500 dnl # at compile time.
 501 dnl #
 502 dnl # Since we plan to pursue making mutex_lock_nested() a non-GPL symbol
 503 dnl # with the upstream community we add a check to detect this case.
 504 dnl #
 505 AC_DEFUN([ZFS_AC_KERNEL_CONFIG_DEBUG_LOCK_ALLOC], [
 506
 507         ZFS_LINUX_CONFIG([DEBUG_LOCK_ALLOC], [
 508                 AC_MSG_CHECKING([whether mutex_lock() is GPL-only])
 509                 tmp_flags="$EXTRA_KCFLAGS"
 510                 ZFS_LINUX_TRY_COMPILE([
 511                         #include <linux/module.h>
 512                         #include <linux/mutex.h>
 513
 514                         MODULE_LICENSE("$ZFS_META_LICENSE");
 515                 ],[
 516                         struct mutex lock;
 517
 518                         mutex_init(&lock);
 519                         mutex_lock(&lock);
 520                         mutex_unlock(&lock);
 521                 ],[
 522                         AC_MSG_RESULT(no)
 523                 ],[
 524                         AC_MSG_RESULT(yes)
 525                         AC_MSG_ERROR([
 526         *** Kernel built with CONFIG_DEBUG_LOCK_ALLOC which is incompatible
 527         *** with the CDDL license and will prevent the module linking stage
 528         *** from succeeding.  You must rebuild your kernel without this
 529         *** option enabled.])
 530                 ])
 531                 EXTRA_KCFLAGS="$tmp_flags"
 532         ], [])
 533 ])
 534
 535 dnl #
 536 dnl # ZFS_LINUX_CONFTEST_H
 537 dnl #
 538 AC_DEFUN([ZFS_LINUX_CONFTEST_H], [
 539 cat - <<_ACEOF >conftest.h
 540 $1
 541 _ACEOF
 542 ])
 543
 544 dnl #
 545 dnl # ZFS_LINUX_CONFTEST_C
 546 dnl #
 547 AC_DEFUN([ZFS_LINUX_CONFTEST_C], [
 548 cat confdefs.h - <<_ACEOF >conftest.c
 549 $1
 550 _ACEOF
 551 ])
 552
 553 dnl #
 554 dnl # ZFS_LANG_PROGRAM(C)([PROLOGUE], [BODY])
 555 dnl #
 556 m4_define([ZFS_LANG_PROGRAM], [
 557 $1
 558 int
 559 main (void)
 560 {
 561 dnl Do *not* indent the following line: there may be CPP directives.
 562 dnl Don't move the `;' right after for the same reason.
 563 $2
 564   ;
 565   return 0;
 566 }
 567 ])
 568
 569 dnl #
 570 dnl # ZFS_LINUX_COMPILE_IFELSE / like AC_COMPILE_IFELSE
 571 dnl #
 572 AC_DEFUN([ZFS_LINUX_COMPILE_IFELSE], [
 573         m4_ifvaln([$1], [ZFS_LINUX_CONFTEST_C([$1])])
 574         m4_ifvaln([$6], [ZFS_LINUX_CONFTEST_H([$6])], [ZFS_LINUX_CONFTEST_H([])])
 575         rm -Rf build && mkdir -p build && touch build/conftest.mod.c
 576         echo "obj-m := conftest.o" >build/Makefile
 577         modpost_flag=''
 578         test "x$enable_linux_builtin" = xyes && modpost_flag='modpost=true' # fake modpost stage
 579         AS_IF(
 580                 [AC_TRY_COMMAND(cp conftest.c conftest.h build && make [$2] -C $LINUX_OBJ EXTRA_CFLAGS="-Werror $EXTRA_KCFLAGS" $ARCH_UM M=$PWD/build $modpost_flag) >/dev/null && AC_TRY_COMMAND([$3])],
 581                 [$4],
 582                 [_AC_MSG_LOG_CONFTEST m4_ifvaln([$5],[$5])]
 583         )
 584         rm -Rf build
 585 ])
 586
 587 dnl #
 588 dnl # ZFS_LINUX_TRY_COMPILE like AC_TRY_COMPILE
 589 dnl #
 590 AC_DEFUN([ZFS_LINUX_TRY_COMPILE],
 591         [ZFS_LINUX_COMPILE_IFELSE(
 592         [AC_LANG_SOURCE([ZFS_LANG_PROGRAM([[$1]], [[$2]])])],
 593         [modules],
 594         [test -s build/conftest.o],
 595         [$3], [$4])
 596 ])
 597
 598 dnl #
 599 dnl # ZFS_LINUX_CONFIG
 600 dnl #
 601 AC_DEFUN([ZFS_LINUX_CONFIG],
 602         [AC_MSG_CHECKING([whether kernel was built with CONFIG_$1])
 603         ZFS_LINUX_TRY_COMPILE([
 604                 #include <linux/module.h>
 605         ],[
 606                 #ifndef CONFIG_$1
 607                 #error CONFIG_$1 not #defined
 608                 #endif
 609         ],[
 610                 AC_MSG_RESULT([yes])
 611                 $2
 612         ],[
 613                 AC_MSG_RESULT([no])
 614                 $3
 615         ])
 616 ])
 617
 618 dnl #
 619 dnl # ZFS_CHECK_SYMBOL_EXPORT
 620 dnl # check symbol exported or not
 621 dnl #
 622 AC_DEFUN([ZFS_CHECK_SYMBOL_EXPORT], [
 623         grep -q -E '[[[:space:]]]$1[[[:space:]]]' \
 624                 $LINUX_OBJ/$LINUX_SYMBOLS 2>/dev/null
 625         rc=$?
 626         if test $rc -ne 0; then
 627                 export=0
 628                 for file in $2; do
 629                         grep -q -E "EXPORT_SYMBOL.*($1)" \
 630                                 "$LINUX/$file" 2>/dev/null
 631                         rc=$?
 632                         if test $rc -eq 0; then
 633                                 export=1
 634                                 break;
 635                         fi
 636                 done
 637                 if test $export -eq 0; then :
 638                         $4
 639                 else :
 640                         $3
 641                 fi
 642         else :
 643                 $3
 644         fi
 645 ])
 646
 647 dnl #
 648 dnl # ZFS_LINUX_TRY_COMPILE_SYMBOL
 649 dnl # like ZFS_LINUX_TRY_COMPILE, except ZFS_CHECK_SYMBOL_EXPORT
 650 dnl # is called if not compiling for builtin
 651 dnl #
 652 AC_DEFUN([ZFS_LINUX_TRY_COMPILE_SYMBOL], [
 653         ZFS_LINUX_TRY_COMPILE([$1], [$2], [rc=0], [rc=1])
 654         if test $rc -ne 0; then :
 655                 $6
 656         else
 657                 if test "x$enable_linux_builtin" != xyes; then
 658                         ZFS_CHECK_SYMBOL_EXPORT([$3], [$4], [rc=0], [rc=1])
 659                 fi
 660                 if test $rc -ne 0; then :
 661                         $6
 662                 else :
 663                         $5
 664                 fi
 665         fi
 666 ])
 667
 668 dnl #
 669 dnl # ZFS_LINUX_TRY_COMPILE_HEADER
 670 dnl # like ZFS_LINUX_TRY_COMPILE, except the contents conftest.h are
 671 dnl # provided via the fifth parameter
 672 dnl #
 673 AC_DEFUN([ZFS_LINUX_TRY_COMPILE_HEADER],
 674         [ZFS_LINUX_COMPILE_IFELSE(
 675         [AC_LANG_SOURCE([ZFS_LANG_PROGRAM([[$1]], [[$2]])])],
 676         [modules],
 677         [test -s build/conftest.o],
 678         [$3], [$4], [$5])
 679 ])