config/kernel.m4

   1 dnl #
   2 dnl # Default ZFS kernel configuration
   3 dnl #
   4 AC_DEFUN([ZFS_AC_CONFIG_KERNEL], [
   5         ZFS_AC_KERNEL
   6         ZFS_AC_SPL
   7         ZFS_AC_QAT
   8         ZFS_AC_TEST_MODULE
   9         ZFS_AC_KERNEL_OBJTOOL
  10         ZFS_AC_KERNEL_CONFIG
  11         ZFS_AC_KERNEL_DECLARE_EVENT_CLASS
  12         ZFS_AC_KERNEL_CURRENT_BIO_TAIL
  13         ZFS_AC_KERNEL_SUPER_USER_NS
  14         ZFS_AC_KERNEL_SUBMIT_BIO
  15         ZFS_AC_KERNEL_BDEV_BLOCK_DEVICE_OPERATIONS
  16         ZFS_AC_KERNEL_BLOCK_DEVICE_OPERATIONS_RELEASE_VOID
  17         ZFS_AC_KERNEL_TYPE_FMODE_T
  18         ZFS_AC_KERNEL_3ARG_BLKDEV_GET
  19         ZFS_AC_KERNEL_BLKDEV_GET_BY_PATH
  20         ZFS_AC_KERNEL_OPEN_BDEV_EXCLUSIVE
  21         ZFS_AC_KERNEL_LOOKUP_BDEV
  22         ZFS_AC_KERNEL_INVALIDATE_BDEV_ARGS
  23         ZFS_AC_KERNEL_BDEV_LOGICAL_BLOCK_SIZE
  24         ZFS_AC_KERNEL_BDEV_PHYSICAL_BLOCK_SIZE
  25         ZFS_AC_KERNEL_BIO_BVEC_ITER
  26         ZFS_AC_KERNEL_BIO_FAILFAST_DTD
  27         ZFS_AC_KERNEL_BIO_SET_DEV
  28         ZFS_AC_KERNEL_REQ_FAILFAST_MASK
  29         ZFS_AC_KERNEL_REQ_OP_DISCARD
  30         ZFS_AC_KERNEL_REQ_OP_SECURE_ERASE
  31         ZFS_AC_KERNEL_REQ_OP_FLUSH
  32         ZFS_AC_KERNEL_BIO_BI_OPF
  33         ZFS_AC_KERNEL_BIO_END_IO_T_ARGS
  34         ZFS_AC_KERNEL_BIO_BI_STATUS
  35         ZFS_AC_KERNEL_BIO_RW_BARRIER
  36         ZFS_AC_KERNEL_BIO_RW_DISCARD
  37         ZFS_AC_KERNEL_BLK_QUEUE_BDI
  38         ZFS_AC_KERNEL_BLK_QUEUE_FLUSH
  39         ZFS_AC_KERNEL_BLK_QUEUE_MAX_HW_SECTORS
  40         ZFS_AC_KERNEL_BLK_QUEUE_MAX_SEGMENTS
  41         ZFS_AC_KERNEL_BLK_QUEUE_HAVE_BIO_RW_UNPLUG
  42         ZFS_AC_KERNEL_BLK_QUEUE_HAVE_BLK_PLUG
  43         ZFS_AC_KERNEL_GET_DISK_RO
  44         ZFS_AC_KERNEL_GET_GENDISK
  45         ZFS_AC_KERNEL_HAVE_BIO_SET_OP_ATTRS
  46         ZFS_AC_KERNEL_GENERIC_READLINK_GLOBAL
  47         ZFS_AC_KERNEL_DISCARD_GRANULARITY
  48         ZFS_AC_KERNEL_CONST_XATTR_HANDLER
  49         ZFS_AC_KERNEL_XATTR_HANDLER_NAME
  50         ZFS_AC_KERNEL_XATTR_HANDLER_GET
  51         ZFS_AC_KERNEL_XATTR_HANDLER_SET
  52         ZFS_AC_KERNEL_XATTR_HANDLER_LIST
  53         ZFS_AC_KERNEL_INODE_OWNER_OR_CAPABLE
  54         ZFS_AC_KERNEL_POSIX_ACL_FROM_XATTR_USERNS
  55         ZFS_AC_KERNEL_POSIX_ACL_RELEASE
  56         ZFS_AC_KERNEL_SET_CACHED_ACL_USABLE
  57         ZFS_AC_KERNEL_POSIX_ACL_CHMOD
  58         ZFS_AC_KERNEL_POSIX_ACL_EQUIV_MODE_WANTS_UMODE_T
  59         ZFS_AC_KERNEL_POSIX_ACL_VALID_WITH_NS
  60         ZFS_AC_KERNEL_INODE_OPERATIONS_PERMISSION
  61         ZFS_AC_KERNEL_INODE_OPERATIONS_PERMISSION_WITH_NAMEIDATA
  62         ZFS_AC_KERNEL_INODE_OPERATIONS_CHECK_ACL
  63         ZFS_AC_KERNEL_INODE_OPERATIONS_CHECK_ACL_WITH_FLAGS
  64         ZFS_AC_KERNEL_INODE_OPERATIONS_GET_ACL
  65         ZFS_AC_KERNEL_INODE_OPERATIONS_SET_ACL
  66         ZFS_AC_KERNEL_INODE_OPERATIONS_GETATTR
  67         ZFS_AC_KERNEL_INODE_SET_FLAGS
  68         ZFS_AC_KERNEL_INODE_SET_IVERSION
  69         ZFS_AC_KERNEL_GET_ACL_HANDLE_CACHE
  70         ZFS_AC_KERNEL_SHOW_OPTIONS
  71         ZFS_AC_KERNEL_FILE_INODE
  72         ZFS_AC_KERNEL_FILE_DENTRY
  73         ZFS_AC_KERNEL_FSYNC
  74         ZFS_AC_KERNEL_EVICT_INODE
  75         ZFS_AC_KERNEL_DIRTY_INODE_WITH_FLAGS
  76         ZFS_AC_KERNEL_NR_CACHED_OBJECTS
  77         ZFS_AC_KERNEL_FREE_CACHED_OBJECTS
  78         ZFS_AC_KERNEL_FALLOCATE
  79         ZFS_AC_KERNEL_AIO_FSYNC
  80         ZFS_AC_KERNEL_MKDIR_UMODE_T
  81         ZFS_AC_KERNEL_LOOKUP_NAMEIDATA
  82         ZFS_AC_KERNEL_CREATE_NAMEIDATA
  83         ZFS_AC_KERNEL_GET_LINK
  84         ZFS_AC_KERNEL_PUT_LINK
  85         ZFS_AC_KERNEL_TMPFILE
  86         ZFS_AC_KERNEL_TRUNCATE_RANGE
  87         ZFS_AC_KERNEL_AUTOMOUNT
  88         ZFS_AC_KERNEL_ENCODE_FH_WITH_INODE
  89         ZFS_AC_KERNEL_COMMIT_METADATA
  90         ZFS_AC_KERNEL_CLEAR_INODE
  91         ZFS_AC_KERNEL_SETATTR_PREPARE
  92         ZFS_AC_KERNEL_INSERT_INODE_LOCKED
  93         ZFS_AC_KERNEL_D_MAKE_ROOT
  94         ZFS_AC_KERNEL_D_OBTAIN_ALIAS
  95         ZFS_AC_KERNEL_D_PRUNE_ALIASES
  96         ZFS_AC_KERNEL_D_SET_D_OP
  97         ZFS_AC_KERNEL_D_REVALIDATE_NAMEIDATA
  98         ZFS_AC_KERNEL_CONST_DENTRY_OPERATIONS
  99         ZFS_AC_KERNEL_TRUNCATE_SETSIZE
 100         ZFS_AC_KERNEL_6ARGS_SECURITY_INODE_INIT_SECURITY
 101         ZFS_AC_KERNEL_CALLBACK_SECURITY_INODE_INIT_SECURITY
 102         ZFS_AC_KERNEL_MOUNT_NODEV
 103         ZFS_AC_KERNEL_SHRINK
 104         ZFS_AC_KERNEL_SHRINK_CONTROL_HAS_NID
 105         ZFS_AC_KERNEL_S_INSTANCES_LIST_HEAD
 106         ZFS_AC_KERNEL_S_D_OP
 107         ZFS_AC_KERNEL_BDI
 108         ZFS_AC_KERNEL_SET_NLINK
 109         ZFS_AC_KERNEL_ELEVATOR_CHANGE
 110         ZFS_AC_KERNEL_5ARG_SGET
 111         ZFS_AC_KERNEL_LSEEK_EXECUTE
 112         ZFS_AC_KERNEL_VFS_ITERATE
 113         ZFS_AC_KERNEL_VFS_RW_ITERATE
 114         ZFS_AC_KERNEL_GENERIC_WRITE_CHECKS
 115         ZFS_AC_KERNEL_KMAP_ATOMIC_ARGS
 116         ZFS_AC_KERNEL_FOLLOW_DOWN_ONE
 117         ZFS_AC_KERNEL_MAKE_REQUEST_FN
 118         ZFS_AC_KERNEL_GENERIC_IO_ACCT_3ARG
 119         ZFS_AC_KERNEL_GENERIC_IO_ACCT_4ARG
 120         ZFS_AC_KERNEL_FPU
 121         ZFS_AC_KERNEL_KUID_HELPERS
 122         ZFS_AC_KERNEL_MODULE_PARAM_CALL_CONST
 123         ZFS_AC_KERNEL_RENAME_WANTS_FLAGS
 124         ZFS_AC_KERNEL_HAVE_GENERIC_SETXATTR
 125         ZFS_AC_KERNEL_CURRENT_TIME
 126         ZFS_AC_KERNEL_VM_NODE_STAT
 127
 128         AS_IF([test "$LINUX_OBJ" != "$LINUX"], [
 129                 KERNEL_MAKE="$KERNEL_MAKE O=$LINUX_OBJ"
 130         ])
 131
 132         AC_SUBST(KERNEL_MAKE)
 133 ])
 134
 135 dnl #
 136 dnl # Detect name used for Module.symvers file in kernel
 137 dnl #
 138 AC_DEFUN([ZFS_AC_MODULE_SYMVERS], [
 139         modpost=$LINUX/scripts/Makefile.modpost
 140         AC_MSG_CHECKING([kernel file name for module symbols])
 141         AS_IF([test "x$enable_linux_builtin" != xyes -a -f "$modpost"], [
 142                 AS_IF([grep -q Modules.symvers $modpost], [
 143                         LINUX_SYMBOLS=Modules.symvers
 144                 ], [
 145                         LINUX_SYMBOLS=Module.symvers
 146                 ])
 147
 148                 AS_IF([test ! -f "$LINUX_OBJ/$LINUX_SYMBOLS"], [
 149                         AC_MSG_ERROR([
 150         *** Please make sure the kernel devel package for your distribution
 151         *** is installed.  If you are building with a custom kernel, make sure the
 152         *** kernel is configured, built, and the '--with-linux=PATH' configure
 153         *** option refers to the location of the kernel source.])
 154                 ])
 155         ], [
 156                 LINUX_SYMBOLS=NONE
 157         ])
 158         AC_MSG_RESULT($LINUX_SYMBOLS)
 159         AC_SUBST(LINUX_SYMBOLS)
 160 ])
 161
 162 dnl #
 163 dnl # Detect the kernel to be built against
 164 dnl #
 165 AC_DEFUN([ZFS_AC_KERNEL], [
 166         AC_ARG_WITH([linux],
 167                 AS_HELP_STRING([--with-linux=PATH],
 168                 [Path to kernel source]),
 169                 [kernelsrc="$withval"])
 170
 171         AC_ARG_WITH(linux-obj,
 172                 AS_HELP_STRING([--with-linux-obj=PATH],
 173                 [Path to kernel build objects]),
 174                 [kernelbuild="$withval"])
 175
 176         AC_MSG_CHECKING([kernel source directory])
 177         AS_IF([test -z "$kernelsrc"], [
 178                 AS_IF([test -e "/lib/modules/$(uname -r)/source"], [
 179                         headersdir="/lib/modules/$(uname -r)/source"
 180                         sourcelink=$(readlink -f "$headersdir")
 181                 ], [test -e "/lib/modules/$(uname -r)/build"], [
 182                         headersdir="/lib/modules/$(uname -r)/build"
 183                         sourcelink=$(readlink -f "$headersdir")
 184                 ], [
 185                         sourcelink=$(ls -1d /usr/src/kernels/* \
 186                                      /usr/src/linux-* \
 187                                      2>/dev/null | grep -v obj | tail -1)
 188                 ])
 189
 190                 AS_IF([test -n "$sourcelink" && test -e ${sourcelink}], [
 191                         kernelsrc=`readlink -f ${sourcelink}`
 192                 ], [
 193                         kernelsrc="[Not found]"
 194                 ])
 195         ], [
 196                 AS_IF([test "$kernelsrc" = "NONE"], [
 197                         kernsrcver=NONE
 198                 ])
 199                 withlinux=yes
 200         ])
 201
 202         AC_MSG_RESULT([$kernelsrc])
 203         AS_IF([test ! -d "$kernelsrc"], [
 204                 AC_MSG_ERROR([
 205         *** Please make sure the kernel devel package for your distribution
 206         *** is installed and then try again.  If that fails, you can specify the
 207         *** location of the kernel source with the '--with-linux=PATH' option.])
 208         ])
 209
 210         AC_MSG_CHECKING([kernel build directory])
 211         AS_IF([test -z "$kernelbuild"], [
 212                 AS_IF([test x$withlinux != xyes -a -e "/lib/modules/$(uname -r)/build"], [
 213                         kernelbuild=`readlink -f /lib/modules/$(uname -r)/build`
 214                 ], [test -d ${kernelsrc}-obj/${target_cpu}/${target_cpu}], [
 215                         kernelbuild=${kernelsrc}-obj/${target_cpu}/${target_cpu}
 216                 ], [test -d ${kernelsrc}-obj/${target_cpu}/default], [
 217                         kernelbuild=${kernelsrc}-obj/${target_cpu}/default
 218                 ], [test -d `dirname ${kernelsrc}`/build-${target_cpu}], [
 219                         kernelbuild=`dirname ${kernelsrc}`/build-${target_cpu}
 220                 ], [
 221                         kernelbuild=${kernelsrc}
 222                 ])
 223         ])
 224         AC_MSG_RESULT([$kernelbuild])
 225
 226         AC_MSG_CHECKING([kernel source version])
 227         utsrelease1=$kernelbuild/include/linux/version.h
 228         utsrelease2=$kernelbuild/include/linux/utsrelease.h
 229         utsrelease3=$kernelbuild/include/generated/utsrelease.h
 230         AS_IF([test -r $utsrelease1 && fgrep -q UTS_RELEASE $utsrelease1], [
 231                 utsrelease=linux/version.h
 232         ], [test -r $utsrelease2 && fgrep -q UTS_RELEASE $utsrelease2], [
 233                 utsrelease=linux/utsrelease.h
 234         ], [test -r $utsrelease3 && fgrep -q UTS_RELEASE $utsrelease3], [
 235                 utsrelease=generated/utsrelease.h
 236         ])
 237
 238         AS_IF([test "$utsrelease"], [
 239                 kernsrcver=`(echo "#include <$utsrelease>";
 240                              echo "kernsrcver=UTS_RELEASE") |
 241                              cpp -I $kernelbuild/include |
 242                              grep "^kernsrcver=" | cut -d \" -f 2`
 243
 244                 AS_IF([test -z "$kernsrcver"], [
 245                         AC_MSG_RESULT([Not found])
 246                         AC_MSG_ERROR([*** Cannot determine kernel version.])
 247                 ])
 248         ], [
 249                 AC_MSG_RESULT([Not found])
 250                 if test "x$enable_linux_builtin" != xyes; then
 251                         AC_MSG_ERROR([*** Cannot find UTS_RELEASE definition.])
 252                 else
 253                         AC_MSG_ERROR([
 254         *** Cannot find UTS_RELEASE definition.
 255         *** Please run 'make prepare' inside the kernel source tree.])
 256                 fi
 257         ])
 258
 259         AC_MSG_RESULT([$kernsrcver])
 260
 261         LINUX=${kernelsrc}
 262         LINUX_OBJ=${kernelbuild}
 263         LINUX_VERSION=${kernsrcver}
 264
 265         AC_SUBST(LINUX)
 266         AC_SUBST(LINUX_OBJ)
 267         AC_SUBST(LINUX_VERSION)
 268
 269         ZFS_AC_MODULE_SYMVERS
 270 ])
 271
 272
 273 dnl #
 274 dnl # Detect the SPL module to be built against
 275 dnl #
 276 AC_DEFUN([ZFS_AC_SPL], [
 277         AC_ARG_WITH([spl],
 278                 AS_HELP_STRING([--with-spl=PATH],
 279                 [Path to spl source]),
 280                 AS_IF([test "$withval" = "yes"],
 281                         AC_MSG_ERROR([--with-spl=PATH requires a PATH]),
 282                         [splsrc="$withval"]))
 283
 284         AC_ARG_WITH([spl-obj],
 285                 AS_HELP_STRING([--with-spl-obj=PATH],
 286                 [Path to spl build objects]),
 287                 [splbuild="$withval"])
 288
 289         AC_ARG_WITH([spl-timeout],
 290                 AS_HELP_STRING([--with-spl-timeout=SECS],
 291                 [Wait SECS for SPL header and symver file @<:@default=0@:>@]),
 292                 [timeout="$withval"], [timeout=0])
 293
 294         dnl #
 295         dnl # The existence of spl.release.in is used to identify a valid
 296         dnl # source directory.  In order of preference:
 297         dnl #
 298         splsrc0="/var/lib/dkms/spl/${VERSION}/build"
 299         splsrc1="/usr/local/src/spl-${VERSION}/${LINUX_VERSION}"
 300         splsrc2="/usr/local/src/spl-${VERSION}"
 301         splsrc3="/usr/src/spl-${VERSION}/${LINUX_VERSION}"
 302         splsrc4="/usr/src/spl-${VERSION}"
 303         splsrc5="../spl/"
 304         splsrc6="$LINUX"
 305
 306         AC_MSG_CHECKING([spl source directory])
 307         AS_IF([test -z "${splsrc}"], [
 308                 [all_spl_sources="
 309                 ${splsrc0}
 310                 ${splsrc1}
 311                 ${splsrc2}
 312                 ${splsrc3}
 313                 ${splsrc4}
 314                 ${splsrc5}
 315                 ${splsrc6}"],
 316                 AS_IF([ test -e "${splsrc0}/spl.release.in"], [
 317                         splsrc=${splsrc0}
 318                 ], [ test -e "${splsrc1}/spl.release.in"], [
 319                         splsrc=${splsrc1}
 320                 ], [ test -e "${splsrc2}/spl.release.in"], [
 321                         splsrc=${splsrc2}
 322                 ], [ test -e "${splsrc3}/spl.release.in"], [
 323                         splsrc=$(readlink -f "${splsrc3}")
 324                 ], [ test -e "${splsrc4}/spl.release.in" ], [
 325                         splsrc=${splsrc4}
 326                 ], [ test -e "${splsrc5}/spl.release.in"], [
 327                         splsrc=$(readlink -f "${splsrc5}")
 328                 ], [ test -e "${splsrc6}/spl.release.in" ], [
 329                         splsrc=${splsrc6}
 330                 ], [
 331                         splsrc="[Not found]"
 332                 ])
 333         ], [
 334                 [all_spl_sources="$withval"],
 335                 AS_IF([test "$splsrc" = "NONE"], [
 336                         splbuild=NONE
 337                         splsrcver=NONE
 338                 ])
 339         ])
 340
 341         AC_MSG_RESULT([$splsrc])
 342         AS_IF([ test ! -e "$splsrc/spl.release.in"], [
 343                 AC_MSG_ERROR([
 344         *** Please make sure the kmod spl devel package for your distribution
 345         *** is installed then try again.  If that fails you can specify the
 346         *** location of the spl source with the '--with-spl=PATH' option.
 347         *** The spl version must match the version of ZFS you are building,
 348         *** ${VERSION}.  Failed to find spl.release.in in the following:
 349         $all_spl_sources])
 350         ])
 351
 352         dnl #
 353         dnl # The existence of the spl_config.h is used to identify a valid
 354         dnl # spl object directory.  In many cases the object and source
 355         dnl # directory are the same, however the objects may also reside
 356         dnl # is a subdirectory named after the kernel version.
 357         dnl #
 358         dnl # This file is supposed to be available after DKMS finishes
 359         dnl # building the SPL kernel module for the target kernel.  The
 360         dnl # '--with-spl-timeout' option can be passed to pause here,
 361         dnl # waiting for the file to appear from a concurrently building
 362         dnl # SPL package.
 363         dnl #
 364         AC_MSG_CHECKING([spl build directory])
 365
 366         all_spl_config_locs="${splsrc}/${LINUX_VERSION}
 367         ${splsrc}"
 368
 369         while true; do
 370                 AS_IF([test -z "$splbuild"], [
 371                         AS_IF([ test -e "${splsrc}/${LINUX_VERSION}/spl_config.h" ], [
 372                                 splbuild="${splsrc}/${LINUX_VERSION}"
 373                         ], [ test -e "${splsrc}/spl_config.h" ], [
 374                                 splbuild="${splsrc}"
 375                         ], [ find -L "${splsrc}" -name spl_config.h 2> /dev/null | grep -wq spl_config.h ], [
 376                                 splbuild=$(find -L "${splsrc}" -name spl_config.h | sed 's,/spl_config.h,,')
 377                         ], [
 378                                 splbuild="[Not found]"
 379                         ])
 380                 ])
 381                 AS_IF([test -e "$splbuild/spl_config.h" -o $timeout -le 0], [
 382                         break;
 383                 ], [
 384                         sleep 1
 385                         timeout=$((timeout-1))
 386                 ])
 387         done
 388
 389         AC_MSG_RESULT([$splbuild])
 390         AS_IF([ ! test -e "$splbuild/spl_config.h"], [
 391                 AC_MSG_ERROR([
 392         *** Please make sure the kmod spl devel <kernel> package for your
 393         *** distribution is installed then try again.  If that fails you
 394         *** can specify the location of the spl objects with the
 395         *** '--with-spl-obj=PATH' option.  Failed to find spl_config.h in
 396         *** any of the following:
 397         $all_spl_config_locs])
 398         ])
 399
 400         AC_MSG_CHECKING([spl source version])
 401         AS_IF([test -r $splbuild/spl_config.h &&
 402                 fgrep -q SPL_META_VERSION $splbuild/spl_config.h], [
 403
 404                 splsrcver=`(echo "#include <spl_config.h>";
 405                             echo "splsrcver=SPL_META_VERSION-SPL_META_RELEASE") |
 406                             cpp -I $splbuild |
 407                             grep "^splsrcver=" | tr -d \" | cut -d= -f2`
 408         ])
 409
 410         AS_IF([test -z "$splsrcver"], [
 411                 AC_MSG_RESULT([Not found])
 412                 AC_MSG_ERROR([
 413         *** Cannot determine the version of the spl source.
 414         *** Please prepare the spl source before running this script])
 415         ])
 416
 417         AC_MSG_RESULT([$splsrcver])
 418
 419         SPL=${splsrc}
 420         SPL_OBJ=${splbuild}
 421         SPL_VERSION=${splsrcver}
 422
 423         AC_SUBST(SPL)
 424         AC_SUBST(SPL_OBJ)
 425         AC_SUBST(SPL_VERSION)
 426
 427         dnl #
 428         dnl # Detect the name used for the SPL Module.symvers file.  If one
 429         dnl # does not exist this is likely because the SPL has been configured
 430         dnl # but not built.  The '--with-spl-timeout' option can be passed
 431         dnl # to pause here, waiting for the file to appear from a concurrently
 432         dnl # building SPL package.  If the file does not appear in time, a good
 433         dnl # guess is made as to what this file will be named based on what it
 434         dnl # is named in the kernel build products.  This file will first be
 435         dnl # used at link time so if the guess is wrong the build will fail
 436         dnl # then.  This unfortunately means the ZFS package does not contain a
 437         dnl # reliable mechanism to detect symbols exported by the SPL at
 438         dnl # configure time.
 439         dnl #
 440         AC_MSG_CHECKING([spl file name for module symbols])
 441         SPL_SYMBOLS=NONE
 442
 443         while true; do
 444                 AS_IF([test -r $SPL_OBJ/Module.symvers], [
 445                         SPL_SYMBOLS=Module.symvers
 446                 ], [test -r $SPL_OBJ/Modules.symvers], [
 447                         SPL_SYMBOLS=Modules.symvers
 448                 ], [test -r $SPL_OBJ/module/Module.symvers], [
 449                         SPL_SYMBOLS=Module.symvers
 450                 ], [test -r $SPL_OBJ/module/Modules.symvers], [
 451                         SPL_SYMBOLS=Modules.symvers
 452                 ])
 453
 454                 AS_IF([test $SPL_SYMBOLS != NONE -o $timeout -le 0], [
 455                         break;
 456                 ], [
 457                         sleep 1
 458                         timeout=$((timeout-1))
 459                 ])
 460         done
 461
 462         AS_IF([test "$SPL_SYMBOLS" = NONE], [
 463                 SPL_SYMBOLS=$LINUX_SYMBOLS
 464         ])
 465
 466         AC_MSG_RESULT([$SPL_SYMBOLS])
 467         AC_SUBST(SPL_SYMBOLS)
 468 ])
 469
 470 dnl #
 471 dnl # Detect the QAT module to be built against
 472 dnl # QAT provides hardware acceleration for data compression:
 473 dnl #   https://01.org/intel-quickassist-technology
 474 dnl # * Download and install QAT driver from the above link
 475 dnl # * Start QAT driver in your system:
 476 dnl #   service qat_service start
 477 dnl # * Enable QAT in ZFS, e.g.:
 478 dnl #   ./configure --with-qat=<qat-driver-path>/QAT1.6
 479 dnl #   make
 480 dnl # * Set GZIP compression in ZFS dataset:
 481 dnl #   zfs set compression = gzip <dataset>
 482 dnl # Then the data written to this ZFS pool is compressed
 483 dnl # by QAT accelerator automatically, and de-compressed by
 484 dnl # QAT when read from the pool.
 485 dnl # * Get QAT hardware statistics by:
 486 dnl #   cat /proc/icp_dh895xcc_dev/qat
 487 dnl # * To disable QAT:
 488 dnl #   insmod zfs.ko zfs_qat_disable=1
 489 dnl #
 490 AC_DEFUN([ZFS_AC_QAT], [
 491         AC_ARG_WITH([qat],
 492                 AS_HELP_STRING([--with-qat=PATH],
 493                 [Path to qat source]),
 494                 AS_IF([test "$withval" = "yes"],
 495                         AC_MSG_ERROR([--with-qat=PATH requires a PATH]),
 496                         [qatsrc="$withval"]))
 497
 498         AC_ARG_WITH([qat-obj],
 499                 AS_HELP_STRING([--with-qat-obj=PATH],
 500                 [Path to qat build objects]),
 501                 [qatbuild="$withval"])
 502
 503         AS_IF([test ! -z "${qatsrc}"], [
 504                 AC_MSG_CHECKING([qat source directory])
 505                 AC_MSG_RESULT([$qatsrc])
 506                 QAT_SRC="${qatsrc}/quickassist"
 507                 AS_IF([ test ! -e "$QAT_SRC/include/cpa.h"], [
 508                         AC_MSG_ERROR([
 509                 *** Please make sure the qat driver package is installed
 510                 *** and specify the location of the qat source with the
 511                 *** '--with-qat=PATH' option then try again. Failed to
 512                 *** find cpa.h in:
 513                 ${QAT_SRC}/include])
 514                 ])
 515         ])
 516
 517         AS_IF([test ! -z "${qatsrc}"], [
 518                 AC_MSG_CHECKING([qat build directory])
 519                 AS_IF([test -z "$qatbuild"], [
 520                         qatbuild="${qatsrc}/build"
 521                 ])
 522
 523                 AC_MSG_RESULT([$qatbuild])
 524                 QAT_OBJ=${qatbuild}
 525                 AS_IF([ ! test -e "$QAT_OBJ/icp_qa_al.ko" && ! test -e "$QAT_OBJ/qat_api.ko"], [
 526                         AC_MSG_ERROR([
 527                 *** Please make sure the qat driver is installed then try again.
 528                 *** Failed to find icp_qa_al.ko or qat_api.ko in:
 529                 $QAT_OBJ])
 530                 ])
 531
 532                 AC_SUBST(QAT_SRC)
 533                 AC_SUBST(QAT_OBJ)
 534
 535                 AC_DEFINE(HAVE_QAT, 1,
 536                 [qat is enabled and existed])
 537         ])
 538
 539         dnl #
 540         dnl # Detect the name used for the QAT Module.symvers file.
 541         dnl #
 542         AS_IF([test ! -z "${qatsrc}"], [
 543                 AC_MSG_CHECKING([qat file for module symbols])
 544                 QAT_SYMBOLS=$QAT_SRC/lookaside/access_layer/src/Module.symvers
 545
 546                 AS_IF([test -r $QAT_SYMBOLS], [
 547                         AC_MSG_RESULT([$QAT_SYMBOLS])
 548                         AC_SUBST(QAT_SYMBOLS)
 549                 ],[
 550                        AC_MSG_ERROR([
 551                         *** Please make sure the qat driver is installed then try again.
 552                         *** Failed to find Module.symvers in:
 553                         $QAT_SYMBOLS])
 554                         ])
 555                 ])
 556         ])
 557 ])
 558
 559 dnl #
 560 dnl # Basic toolchain sanity check.
 561 dnl #
 562 AC_DEFUN([ZFS_AC_TEST_MODULE], [
 563         AC_MSG_CHECKING([whether modules can be built])
 564         ZFS_LINUX_TRY_COMPILE([],[],[
 565                 AC_MSG_RESULT([yes])
 566         ],[
 567                 AC_MSG_RESULT([no])
 568                 if test "x$enable_linux_builtin" != xyes; then
 569                         AC_MSG_ERROR([*** Unable to build an empty module.])
 570                 else
 571                         AC_MSG_ERROR([
 572         *** Unable to build an empty module.
 573         *** Please run 'make scripts' inside the kernel source tree.])
 574                 fi
 575         ])
 576 ])
 577
 578 dnl #
 579 dnl # Certain kernel build options are not supported.  These must be
 580 dnl # detected at configure time and cause a build failure.  Otherwise
 581 dnl # modules may be successfully built that behave incorrectly.
 582 dnl #
 583 AC_DEFUN([ZFS_AC_KERNEL_CONFIG], [
 584         AS_IF([test "x$cross_compiling" != xyes], [
 585                 AC_RUN_IFELSE([
 586                         AC_LANG_PROGRAM([
 587                                 #include "$LINUX/include/linux/license.h"
 588                         ], [
 589                                 return !license_is_gpl_compatible("$ZFS_META_LICENSE");
 590                         ])
 591                 ], [
 592                         AC_DEFINE([ZFS_IS_GPL_COMPATIBLE], [1],
 593                             [Define to 1 if GPL-only symbols can be used])
 594                 ], [
 595                 ])
 596         ])
 597
 598         ZFS_AC_KERNEL_CONFIG_THREAD_SIZE
 599         ZFS_AC_KERNEL_CONFIG_DEBUG_LOCK_ALLOC
 600 ])
 601
 602 dnl #
 603 dnl # Check configured THREAD_SIZE
 604 dnl #
 605 dnl # The stack size will vary by architecture, but as of Linux 3.15 on x86_64
 606 dnl # the default thread stack size was increased to 16K from 8K.  Therefore,
 607 dnl # on newer kernels and some architectures stack usage optimizations can be
 608 dnl # conditionally applied to improve performance without negatively impacting
 609 dnl # stability.
 610 dnl #
 611 AC_DEFUN([ZFS_AC_KERNEL_CONFIG_THREAD_SIZE], [
 612         AC_MSG_CHECKING([whether kernel was built with 16K or larger stacks])
 613         ZFS_LINUX_TRY_COMPILE([
 614                 #include <linux/module.h>
 615         ],[
 616                 #if (THREAD_SIZE < 16384)
 617                 #error "THREAD_SIZE is less than 16K"
 618                 #endif
 619         ],[
 620                 AC_MSG_RESULT([yes])
 621                 AC_DEFINE(HAVE_LARGE_STACKS, 1, [kernel has large stacks])
 622         ],[
 623                 AC_MSG_RESULT([no])
 624         ])
 625 ])
 626
 627 dnl #
 628 dnl # Check CONFIG_DEBUG_LOCK_ALLOC
 629 dnl #
 630 dnl # This is typically only set for debug kernels because it comes with
 631 dnl # a performance penalty.  However, when it is set it maps the non-GPL
 632 dnl # symbol mutex_lock() to the GPL-only mutex_lock_nested() symbol.
 633 dnl # This will cause a failure at link time which we'd rather know about
 634 dnl # at compile time.
 635 dnl #
 636 dnl # Since we plan to pursue making mutex_lock_nested() a non-GPL symbol
 637 dnl # with the upstream community we add a check to detect this case.
 638 dnl #
 639 AC_DEFUN([ZFS_AC_KERNEL_CONFIG_DEBUG_LOCK_ALLOC], [
 640
 641         ZFS_LINUX_CONFIG([DEBUG_LOCK_ALLOC], [
 642                 AC_MSG_CHECKING([whether mutex_lock() is GPL-only])
 643                 tmp_flags="$EXTRA_KCFLAGS"
 644                 ZFS_LINUX_TRY_COMPILE([
 645                         #include <linux/module.h>
 646                         #include <linux/mutex.h>
 647
 648                         MODULE_LICENSE("$ZFS_META_LICENSE");
 649                 ],[
 650                         struct mutex lock;
 651
 652                         mutex_init(&lock);
 653                         mutex_lock(&lock);
 654                         mutex_unlock(&lock);
 655                 ],[
 656                         AC_MSG_RESULT(no)
 657                 ],[
 658                         AC_MSG_RESULT(yes)
 659                         AC_MSG_ERROR([
 660         *** Kernel built with CONFIG_DEBUG_LOCK_ALLOC which is incompatible
 661         *** with the CDDL license and will prevent the module linking stage
 662         *** from succeeding.  You must rebuild your kernel without this
 663         *** option enabled.])
 664                 ])
 665                 EXTRA_KCFLAGS="$tmp_flags"
 666         ], [])
 667 ])
 668
 669 dnl #
 670 dnl # ZFS_LINUX_CONFTEST_H
 671 dnl #
 672 AC_DEFUN([ZFS_LINUX_CONFTEST_H], [
 673 cat - <<_ACEOF >conftest.h
 674 $1
 675 _ACEOF
 676 ])
 677
 678 dnl #
 679 dnl # ZFS_LINUX_CONFTEST_C
 680 dnl #
 681 AC_DEFUN([ZFS_LINUX_CONFTEST_C], [
 682 cat confdefs.h - <<_ACEOF >conftest.c
 683 $1
 684 _ACEOF
 685 ])
 686
 687 dnl #
 688 dnl # ZFS_LANG_PROGRAM(C)([PROLOGUE], [BODY])
 689 dnl #
 690 m4_define([ZFS_LANG_PROGRAM], [
 691 $1
 692 int
 693 main (void)
 694 {
 695 dnl Do *not* indent the following line: there may be CPP directives.
 696 dnl Don't move the `;' right after for the same reason.
 697 $2
 698   ;
 699   return 0;
 700 }
 701 ])
 702
 703 dnl #
 704 dnl # ZFS_LINUX_COMPILE_IFELSE / like AC_COMPILE_IFELSE
 705 dnl #
 706 AC_DEFUN([ZFS_LINUX_COMPILE_IFELSE], [
 707         m4_ifvaln([$1], [ZFS_LINUX_CONFTEST_C([$1])])
 708         m4_ifvaln([$6], [ZFS_LINUX_CONFTEST_H([$6])], [ZFS_LINUX_CONFTEST_H([])])
 709         rm -Rf build && mkdir -p build && touch build/conftest.mod.c
 710         echo "obj-m := conftest.o" >build/Makefile
 711         modpost_flag=''
 712         test "x$enable_linux_builtin" = xyes && modpost_flag='modpost=true' # fake modpost stage
 713         AS_IF(
 714                 [AC_TRY_COMMAND(cp conftest.c conftest.h build && make [$2] -C $LINUX_OBJ EXTRA_CFLAGS="-Werror $EXTRA_KCFLAGS" $ARCH_UM M=$PWD/build $modpost_flag) >/dev/null && AC_TRY_COMMAND([$3])],
 715                 [$4],
 716                 [_AC_MSG_LOG_CONFTEST m4_ifvaln([$5],[$5])]
 717         )
 718         rm -Rf build
 719 ])
 720
 721 dnl #
 722 dnl # ZFS_LINUX_TRY_COMPILE like AC_TRY_COMPILE
 723 dnl #
 724 AC_DEFUN([ZFS_LINUX_TRY_COMPILE],
 725         [ZFS_LINUX_COMPILE_IFELSE(
 726         [AC_LANG_SOURCE([ZFS_LANG_PROGRAM([[$1]], [[$2]])])],
 727         [modules],
 728         [test -s build/conftest.o],
 729         [$3], [$4])
 730 ])
 731
 732 dnl #
 733 dnl # ZFS_LINUX_CONFIG
 734 dnl #
 735 AC_DEFUN([ZFS_LINUX_CONFIG],
 736         [AC_MSG_CHECKING([whether kernel was built with CONFIG_$1])
 737         ZFS_LINUX_TRY_COMPILE([
 738                 #include <linux/module.h>
 739         ],[
 740                 #ifndef CONFIG_$1
 741                 #error CONFIG_$1 not #defined
 742                 #endif
 743         ],[
 744                 AC_MSG_RESULT([yes])
 745                 $2
 746         ],[
 747                 AC_MSG_RESULT([no])
 748                 $3
 749         ])
 750 ])
 751
 752 dnl #
 753 dnl # ZFS_CHECK_SYMBOL_EXPORT
 754 dnl # check symbol exported or not
 755 dnl #
 756 AC_DEFUN([ZFS_CHECK_SYMBOL_EXPORT], [
 757         grep -q -E '[[[:space:]]]$1[[[:space:]]]' \
 758                 $LINUX_OBJ/$LINUX_SYMBOLS 2>/dev/null
 759         rc=$?
 760         if test $rc -ne 0; then
 761                 export=0
 762                 for file in $2; do
 763                         grep -q -E "EXPORT_SYMBOL.*($1)" \
 764                                 "$LINUX/$file" 2>/dev/null
 765                         rc=$?
 766                         if test $rc -eq 0; then
 767                                 export=1
 768                                 break;
 769                         fi
 770                 done
 771                 if test $export -eq 0; then :
 772                         $4
 773                 else :
 774                         $3
 775                 fi
 776         else :
 777                 $3
 778         fi
 779 ])
 780
 781 dnl #
 782 dnl # ZFS_LINUX_TRY_COMPILE_SYMBOL
 783 dnl # like ZFS_LINUX_TRY_COMPILE, except ZFS_CHECK_SYMBOL_EXPORT
 784 dnl # is called if not compiling for builtin
 785 dnl #
 786 AC_DEFUN([ZFS_LINUX_TRY_COMPILE_SYMBOL], [
 787         ZFS_LINUX_TRY_COMPILE([$1], [$2], [rc=0], [rc=1])
 788         if test $rc -ne 0; then :
 789                 $6
 790         else
 791                 if test "x$enable_linux_builtin" != xyes; then
 792                         ZFS_CHECK_SYMBOL_EXPORT([$3], [$4], [rc=0], [rc=1])
 793                 fi
 794                 if test $rc -ne 0; then :
 795                         $6
 796                 else :
 797                         $5
 798                 fi
 799         fi
 800 ])
 801
 802 dnl #
 803 dnl # ZFS_LINUX_TRY_COMPILE_HEADER
 804 dnl # like ZFS_LINUX_TRY_COMPILE, except the contents conftest.h are
 805 dnl # provided via the fifth parameter
 806 dnl #
 807 AC_DEFUN([ZFS_LINUX_TRY_COMPILE_HEADER],
 808         [ZFS_LINUX_COMPILE_IFELSE(
 809         [AC_LANG_SOURCE([ZFS_LANG_PROGRAM([[$1]], [[$2]])])],
 810         [modules],
 811         [test -s build/conftest.o],
 812         [$3], [$4], [$5])
 813 ])