config/kernel.m4

   1 dnl #
   2 dnl # Default ZFS kernel configuration
   3 dnl #
   4 AC_DEFUN([ZFS_AC_CONFIG_KERNEL], [
   5         ZFS_AC_KERNEL
   6         ZFS_AC_SPL
   7         ZFS_AC_TEST_MODULE
   8         ZFS_AC_KERNEL_CONFIG
   9         ZFS_AC_KERNEL_DECLARE_EVENT_CLASS
  10         ZFS_AC_KERNEL_CURRENT_BIO_TAIL
  11         ZFS_AC_KERNEL_BDEV_BLOCK_DEVICE_OPERATIONS
  12         ZFS_AC_KERNEL_BLOCK_DEVICE_OPERATIONS_RELEASE_VOID
  13         ZFS_AC_KERNEL_TYPE_FMODE_T
  14         ZFS_AC_KERNEL_3ARG_BLKDEV_GET
  15         ZFS_AC_KERNEL_BLKDEV_GET_BY_PATH
  16         ZFS_AC_KERNEL_OPEN_BDEV_EXCLUSIVE
  17         ZFS_AC_KERNEL_LOOKUP_BDEV
  18         ZFS_AC_KERNEL_INVALIDATE_BDEV_ARGS
  19         ZFS_AC_KERNEL_BDEV_LOGICAL_BLOCK_SIZE
  20         ZFS_AC_KERNEL_BDEV_PHYSICAL_BLOCK_SIZE
  21         ZFS_AC_KERNEL_BIO_BVEC_ITER
  22         ZFS_AC_KERNEL_BIO_FAILFAST_DTD
  23         ZFS_AC_KERNEL_REQ_FAILFAST_MASK
  24         ZFS_AC_KERNEL_BIO_END_IO_T_ARGS
  25         ZFS_AC_KERNEL_BIO_RW_BARRIER
  26         ZFS_AC_KERNEL_BIO_RW_DISCARD
  27         ZFS_AC_KERNEL_BLK_QUEUE_FLUSH
  28         ZFS_AC_KERNEL_BLK_QUEUE_MAX_HW_SECTORS
  29         ZFS_AC_KERNEL_BLK_QUEUE_MAX_SEGMENTS
  30         ZFS_AC_KERNEL_GET_DISK_RO
  31         ZFS_AC_KERNEL_GET_GENDISK
  32         ZFS_AC_KERNEL_DISCARD_GRANULARITY
  33         ZFS_AC_KERNEL_CONST_XATTR_HANDLER
  34         ZFS_AC_KERNEL_XATTR_HANDLER_NAME
  35         ZFS_AC_KERNEL_XATTR_HANDLER_GET
  36         ZFS_AC_KERNEL_XATTR_HANDLER_SET
  37         ZFS_AC_KERNEL_XATTR_HANDLER_LIST
  38         ZFS_AC_KERNEL_INODE_OWNER_OR_CAPABLE
  39         ZFS_AC_KERNEL_POSIX_ACL_FROM_XATTR_USERNS
  40         ZFS_AC_KERNEL_POSIX_ACL_RELEASE
  41         ZFS_AC_KERNEL_POSIX_ACL_CHMOD
  42         ZFS_AC_KERNEL_POSIX_ACL_CACHING
  43         ZFS_AC_KERNEL_POSIX_ACL_EQUIV_MODE_WANTS_UMODE_T
  44         ZFS_AC_KERNEL_INODE_OPERATIONS_PERMISSION
  45         ZFS_AC_KERNEL_INODE_OPERATIONS_PERMISSION_WITH_NAMEIDATA
  46         ZFS_AC_KERNEL_INODE_OPERATIONS_CHECK_ACL
  47         ZFS_AC_KERNEL_INODE_OPERATIONS_CHECK_ACL_WITH_FLAGS
  48         ZFS_AC_KERNEL_INODE_OPERATIONS_GET_ACL
  49         ZFS_AC_KERNEL_CURRENT_UMASK
  50         ZFS_AC_KERNEL_SHOW_OPTIONS
  51         ZFS_AC_KERNEL_FILE_INODE
  52         ZFS_AC_KERNEL_FSYNC
  53         ZFS_AC_KERNEL_EVICT_INODE
  54         ZFS_AC_KERNEL_DIRTY_INODE_WITH_FLAGS
  55         ZFS_AC_KERNEL_NR_CACHED_OBJECTS
  56         ZFS_AC_KERNEL_FREE_CACHED_OBJECTS
  57         ZFS_AC_KERNEL_FALLOCATE
  58         ZFS_AC_KERNEL_MKDIR_UMODE_T
  59         ZFS_AC_KERNEL_LOOKUP_NAMEIDATA
  60         ZFS_AC_KERNEL_CREATE_NAMEIDATA
  61         ZFS_AC_KERNEL_GET_LINK
  62         ZFS_AC_KERNEL_PUT_LINK
  63         ZFS_AC_KERNEL_TRUNCATE_RANGE
  64         ZFS_AC_KERNEL_AUTOMOUNT
  65         ZFS_AC_KERNEL_ENCODE_FH_WITH_INODE
  66         ZFS_AC_KERNEL_COMMIT_METADATA
  67         ZFS_AC_KERNEL_CLEAR_INODE
  68         ZFS_AC_KERNEL_INSERT_INODE_LOCKED
  69         ZFS_AC_KERNEL_D_MAKE_ROOT
  70         ZFS_AC_KERNEL_D_OBTAIN_ALIAS
  71         ZFS_AC_KERNEL_D_PRUNE_ALIASES
  72         ZFS_AC_KERNEL_D_SET_D_OP
  73         ZFS_AC_KERNEL_D_REVALIDATE_NAMEIDATA
  74         ZFS_AC_KERNEL_CONST_DENTRY_OPERATIONS
  75         ZFS_AC_KERNEL_TRUNCATE_SETSIZE
  76         ZFS_AC_KERNEL_6ARGS_SECURITY_INODE_INIT_SECURITY
  77         ZFS_AC_KERNEL_CALLBACK_SECURITY_INODE_INIT_SECURITY
  78         ZFS_AC_KERNEL_MOUNT_NODEV
  79         ZFS_AC_KERNEL_SHRINK
  80         ZFS_AC_KERNEL_SHRINK_CONTROL_HAS_NID
  81         ZFS_AC_KERNEL_S_INSTANCES_LIST_HEAD
  82         ZFS_AC_KERNEL_S_D_OP
  83         ZFS_AC_KERNEL_BDI_SETUP_AND_REGISTER
  84         ZFS_AC_KERNEL_SET_NLINK
  85         ZFS_AC_KERNEL_ELEVATOR_CHANGE
  86         ZFS_AC_KERNEL_5ARG_SGET
  87         ZFS_AC_KERNEL_LSEEK_EXECUTE
  88         ZFS_AC_KERNEL_VFS_ITERATE
  89         ZFS_AC_KERNEL_VFS_RW_ITERATE
  90         ZFS_AC_KERNEL_KMAP_ATOMIC_ARGS
  91         ZFS_AC_KERNEL_FOLLOW_DOWN_ONE
  92         ZFS_AC_KERNEL_MAKE_REQUEST_FN
  93         ZFS_AC_KERNEL_GENERIC_IO_ACCT
  94         ZFS_AC_KERNEL_FPU
  95         ZFS_AC_KERNEL_KUID_HELPERS
  96
  97         AS_IF([test "$LINUX_OBJ" != "$LINUX"], [
  98                 KERNELMAKE_PARAMS="$KERNELMAKE_PARAMS O=$LINUX_OBJ"
  99         ])
 100         AC_SUBST(KERNELMAKE_PARAMS)
 101
 102
 103         dnl # -Wall -fno-strict-aliasing -Wstrict-prototypes and other
 104         dnl # compiler options are added by the kernel build system.
 105         KERNELCPPFLAGS="$KERNELCPPFLAGS $NO_UNUSED_BUT_SET_VARIABLE"
 106         KERNELCPPFLAGS="$KERNELCPPFLAGS $NO_BOOL_COMPARE"
 107         KERNELCPPFLAGS="$KERNELCPPFLAGS -DHAVE_SPL -D_KERNEL"
 108         KERNELCPPFLAGS="$KERNELCPPFLAGS -DTEXT_DOMAIN=\\\"zfs-linux-kernel\\\""
 109
 110         AC_SUBST(KERNELCPPFLAGS)
 111 ])
 112
 113 dnl #
 114 dnl # Detect name used for Module.symvers file in kernel
 115 dnl #
 116 AC_DEFUN([ZFS_AC_MODULE_SYMVERS], [
 117         modpost=$LINUX/scripts/Makefile.modpost
 118         AC_MSG_CHECKING([kernel file name for module symbols])
 119         AS_IF([test "x$enable_linux_builtin" != xyes -a -f "$modpost"], [
 120                 AS_IF([grep -q Modules.symvers $modpost], [
 121                         LINUX_SYMBOLS=Modules.symvers
 122                 ], [
 123                         LINUX_SYMBOLS=Module.symvers
 124                 ])
 125
 126                 AS_IF([test ! -f "$LINUX_OBJ/$LINUX_SYMBOLS"], [
 127                         AC_MSG_ERROR([
 128         *** Please make sure the kernel devel package for your distribution
 129         *** is installed.  If you are building with a custom kernel, make sure the
 130         *** kernel is configured, built, and the '--with-linux=PATH' configure
 131         *** option refers to the location of the kernel source.])
 132                 ])
 133         ], [
 134                 LINUX_SYMBOLS=NONE
 135         ])
 136         AC_MSG_RESULT($LINUX_SYMBOLS)
 137         AC_SUBST(LINUX_SYMBOLS)
 138 ])
 139
 140 dnl #
 141 dnl # Detect the kernel to be built against
 142 dnl #
 143 AC_DEFUN([ZFS_AC_KERNEL], [
 144         AC_ARG_WITH([linux],
 145                 AS_HELP_STRING([--with-linux=PATH],
 146                 [Path to kernel source]),
 147                 [kernelsrc="$withval"])
 148
 149         AC_ARG_WITH(linux-obj,
 150                 AS_HELP_STRING([--with-linux-obj=PATH],
 151                 [Path to kernel build objects]),
 152                 [kernelbuild="$withval"])
 153
 154         AC_MSG_CHECKING([kernel source directory])
 155         AS_IF([test -z "$kernelsrc"], [
 156                 AS_IF([test -e "/lib/modules/$(uname -r)/source"], [
 157                         headersdir="/lib/modules/$(uname -r)/source"
 158                         sourcelink=$(readlink -f "$headersdir")
 159                 ], [test -e "/lib/modules/$(uname -r)/build"], [
 160                         headersdir="/lib/modules/$(uname -r)/build"
 161                         sourcelink=$(readlink -f "$headersdir")
 162                 ], [
 163                         sourcelink=$(ls -1d /usr/src/kernels/* \
 164                                      /usr/src/linux-* \
 165                                      2>/dev/null | grep -v obj | tail -1)
 166                 ])
 167
 168                 AS_IF([test -n "$sourcelink" && test -e ${sourcelink}], [
 169                         kernelsrc=`readlink -f ${sourcelink}`
 170                 ], [
 171                         kernelsrc="[Not found]"
 172                 ])
 173         ], [
 174                 AS_IF([test "$kernelsrc" = "NONE"], [
 175                         kernsrcver=NONE
 176                 ])
 177         ])
 178
 179         AC_MSG_RESULT([$kernelsrc])
 180         AS_IF([test ! -d "$kernelsrc"], [
 181                 AC_MSG_ERROR([
 182         *** Please make sure the kernel devel package for your distribution
 183         *** is installed and then try again.  If that fails, you can specify the
 184         *** location of the kernel source with the '--with-linux=PATH' option.])
 185         ])
 186
 187         AC_MSG_CHECKING([kernel build directory])
 188         AS_IF([test -z "$kernelbuild"], [
 189                 AS_IF([test -e "/lib/modules/$(uname -r)/build"], [
 190                         kernelbuild=`readlink -f /lib/modules/$(uname -r)/build`
 191                 ], [test -d ${kernelsrc}-obj/${target_cpu}/${target_cpu}], [
 192                         kernelbuild=${kernelsrc}-obj/${target_cpu}/${target_cpu}
 193                 ], [test -d ${kernelsrc}-obj/${target_cpu}/default], [
 194                         kernelbuild=${kernelsrc}-obj/${target_cpu}/default
 195                 ], [test -d `dirname ${kernelsrc}`/build-${target_cpu}], [
 196                         kernelbuild=`dirname ${kernelsrc}`/build-${target_cpu}
 197                 ], [
 198                         kernelbuild=${kernelsrc}
 199                 ])
 200         ])
 201         AC_MSG_RESULT([$kernelbuild])
 202
 203         AC_MSG_CHECKING([kernel source version])
 204         utsrelease1=$kernelbuild/include/linux/version.h
 205         utsrelease2=$kernelbuild/include/linux/utsrelease.h
 206         utsrelease3=$kernelbuild/include/generated/utsrelease.h
 207         AS_IF([test -r $utsrelease1 && fgrep -q UTS_RELEASE $utsrelease1], [
 208                 utsrelease=linux/version.h
 209         ], [test -r $utsrelease2 && fgrep -q UTS_RELEASE $utsrelease2], [
 210                 utsrelease=linux/utsrelease.h
 211         ], [test -r $utsrelease3 && fgrep -q UTS_RELEASE $utsrelease3], [
 212                 utsrelease=generated/utsrelease.h
 213         ])
 214
 215         AS_IF([test "$utsrelease"], [
 216                 kernsrcver=`(echo "#include <$utsrelease>";
 217                              echo "kernsrcver=UTS_RELEASE") |
 218                              cpp -I $kernelbuild/include |
 219                              grep "^kernsrcver=" | cut -d \" -f 2`
 220
 221                 AS_IF([test -z "$kernsrcver"], [
 222                         AC_MSG_RESULT([Not found])
 223                         AC_MSG_ERROR([*** Cannot determine kernel version.])
 224                 ])
 225         ], [
 226                 AC_MSG_RESULT([Not found])
 227                 if test "x$enable_linux_builtin" != xyes; then
 228                         AC_MSG_ERROR([*** Cannot find UTS_RELEASE definition.])
 229                 else
 230                         AC_MSG_ERROR([
 231         *** Cannot find UTS_RELEASE definition.
 232         *** Please run 'make prepare' inside the kernel source tree.])
 233                 fi
 234         ])
 235
 236         AC_MSG_RESULT([$kernsrcver])
 237
 238         LINUX=${kernelsrc}
 239         LINUX_OBJ=${kernelbuild}
 240         LINUX_VERSION=${kernsrcver}
 241
 242         AC_SUBST(LINUX)
 243         AC_SUBST(LINUX_OBJ)
 244         AC_SUBST(LINUX_VERSION)
 245
 246         ZFS_AC_MODULE_SYMVERS
 247 ])
 248
 249
 250 dnl #
 251 dnl # Detect the SPL module to be built against
 252 dnl #
 253 AC_DEFUN([ZFS_AC_SPL], [
 254         AC_ARG_WITH([spl],
 255                 AS_HELP_STRING([--with-spl=PATH],
 256                 [Path to spl source]),
 257                 AS_IF([test "$withval" = "yes"],
 258                         AC_MSG_ERROR([--with-spl=PATH requires a PATH]),
 259                         [splsrc="$withval"]))
 260
 261         AC_ARG_WITH([spl-obj],
 262                 AS_HELP_STRING([--with-spl-obj=PATH],
 263                 [Path to spl build objects]),
 264                 [splbuild="$withval"])
 265
 266         AC_ARG_WITH([spl-timeout],
 267                 AS_HELP_STRING([--with-spl-timeout=SECS],
 268                 [Wait SECS for SPL header and symver file @<:@default=0@:>@]),
 269                 [timeout="$withval"], [timeout=0])
 270
 271         dnl #
 272         dnl # The existence of spl.release.in is used to identify a valid
 273         dnl # source directory.  In order of preference:
 274         dnl #
 275         splsrc0="/var/lib/dkms/spl/${VERSION}/build"
 276         splsrc1="/usr/local/src/spl-${VERSION}/${LINUX_VERSION}"
 277         splsrc2="/usr/local/src/spl-${VERSION}"
 278         splsrc3="/usr/src/spl-${VERSION}/${LINUX_VERSION}"
 279         splsrc4="/usr/src/spl-${VERSION}"
 280         splsrc5="../spl/"
 281         splsrc6="$LINUX"
 282
 283         AC_MSG_CHECKING([spl source directory])
 284         AS_IF([test -z "${splsrc}"], [
 285                 [all_spl_sources="
 286                 ${splsrc0}
 287                 ${splsrc1}
 288                 ${splsrc2}
 289                 ${splsrc3}
 290                 ${splsrc4}
 291                 ${splsrc5}
 292                 ${splsrc6}"],
 293                 AS_IF([ test -e "${splsrc0}/spl.release.in"], [
 294                         splsrc=${splsrc0}
 295                 ], [ test -e "${splsrc1}/spl.release.in"], [
 296                         splsrc=${splsrc1}
 297                 ], [ test -e "${splsrc2}/spl.release.in"], [
 298                         splsrc=${splsrc2}
 299                 ], [ test -e "${splsrc3}/spl.release.in"], [
 300                         splsrc=$(readlink -f "${splsrc3}")
 301                 ], [ test -e "${splsrc4}/spl.release.in" ], [
 302                         splsrc=${splsrc4}
 303                 ], [ test -e "${splsrc5}/spl.release.in"], [
 304                         splsrc=$(readlink -f "${splsrc5}")
 305                 ], [ test -e "${splsrc6}/spl.release.in" ], [
 306                         splsrc=${splsrc6}
 307                 ], [
 308                         splsrc="[Not found]"
 309                 ])
 310         ], [
 311                 [all_spl_sources="$withval"],
 312                 AS_IF([test "$splsrc" = "NONE"], [
 313                         splbuild=NONE
 314                         splsrcver=NONE
 315                 ])
 316         ])
 317
 318         AC_MSG_RESULT([$splsrc])
 319         AS_IF([ test ! -e "$splsrc/spl.release.in"], [
 320                 AC_MSG_ERROR([
 321         *** Please make sure the kmod spl devel package for your distribution
 322         *** is installed then try again.  If that fails you can specify the
 323         *** location of the spl source with the '--with-spl=PATH' option.
 324         *** The spl version must match the version of ZFS you are building,
 325         *** ${VERSION}.  Failed to find spl.release.in in the following:
 326         $all_spl_sources])
 327         ])
 328
 329         dnl #
 330         dnl # The existence of the spl_config.h is used to identify a valid
 331         dnl # spl object directory.  In many cases the object and source
 332         dnl # directory are the same, however the objects may also reside
 333         dnl # is a subdirectory named after the kernel version.
 334         dnl #
 335         dnl # This file is supposed to be available after DKMS finishes
 336         dnl # building the SPL kernel module for the target kernel.  The
 337         dnl # '--with-spl-timeout' option can be passed to pause here,
 338         dnl # waiting for the file to appear from a concurrently building
 339         dnl # SPL package.
 340         dnl #
 341         AC_MSG_CHECKING([spl build directory])
 342
 343         all_spl_config_locs="${splsrc}/${LINUX_VERSION}
 344         ${splsrc}"
 345
 346         while true; do
 347                 AS_IF([test -z "$splbuild"], [
 348                         AS_IF([ test -e "${splsrc}/${LINUX_VERSION}/spl_config.h" ], [
 349                                 splbuild="${splsrc}/${LINUX_VERSION}"
 350                         ], [ test -e "${splsrc}/spl_config.h" ], [
 351                                 splbuild="${splsrc}"
 352                         ], [ find -L "${splsrc}" -name spl_config.h 2> /dev/null | grep -wq spl_config.h ], [
 353                                 splbuild=$(find -L "${splsrc}" -name spl_config.h | sed 's,/spl_config.h,,')
 354                         ], [
 355                                 splbuild="[Not found]"
 356                         ])
 357                 ])
 358                 AS_IF([test -e "$splbuild/spl_config.h" -o $timeout -le 0], [
 359                         break;
 360                 ], [
 361                         sleep 1
 362                         timeout=$((timeout-1))
 363                 ])
 364         done
 365
 366         AC_MSG_RESULT([$splbuild])
 367         AS_IF([ ! test -e "$splbuild/spl_config.h"], [
 368                 AC_MSG_ERROR([
 369         *** Please make sure the kmod spl devel <kernel> package for your
 370         *** distribution is installed then try again.  If that fails you
 371         *** can specify the location of the spl objects with the
 372         *** '--with-spl-obj=PATH' option.  Failed to find spl_config.h in
 373         *** any of the following:
 374         $all_spl_config_locs])
 375         ])
 376
 377         AC_MSG_CHECKING([spl source version])
 378         AS_IF([test -r $splbuild/spl_config.h &&
 379                 fgrep -q SPL_META_VERSION $splbuild/spl_config.h], [
 380
 381                 splsrcver=`(echo "#include <spl_config.h>";
 382                             echo "splsrcver=SPL_META_VERSION-SPL_META_RELEASE") |
 383                             cpp -I $splbuild |
 384                             grep "^splsrcver=" | tr -d \" | cut -d= -f2`
 385         ])
 386
 387         AS_IF([test -z "$splsrcver"], [
 388                 AC_MSG_RESULT([Not found])
 389                 AC_MSG_ERROR([
 390         *** Cannot determine the version of the spl source.
 391         *** Please prepare the spl source before running this script])
 392         ])
 393
 394         AC_MSG_RESULT([$splsrcver])
 395
 396         SPL=${splsrc}
 397         SPL_OBJ=${splbuild}
 398         SPL_VERSION=${splsrcver}
 399
 400         AC_SUBST(SPL)
 401         AC_SUBST(SPL_OBJ)
 402         AC_SUBST(SPL_VERSION)
 403
 404         dnl #
 405         dnl # Detect the name used for the SPL Module.symvers file.  If one
 406         dnl # does not exist this is likely because the SPL has been configured
 407         dnl # but not built.  The '--with-spl-timeout' option can be passed
 408         dnl # to pause here, waiting for the file to appear from a concurrently
 409         dnl # building SPL package.  If the file does not appear in time, a good
 410         dnl # guess is made as to what this file will be named based on what it
 411         dnl # is named in the kernel build products.  This file will first be
 412         dnl # used at link time so if the guess is wrong the build will fail
 413         dnl # then.  This unfortunately means the ZFS package does not contain a
 414         dnl # reliable mechanism to detect symbols exported by the SPL at
 415         dnl # configure time.
 416         dnl #
 417         AC_MSG_CHECKING([spl file name for module symbols])
 418         SPL_SYMBOLS=NONE
 419
 420         while true; do
 421                 AS_IF([test -r $SPL_OBJ/Module.symvers], [
 422                         SPL_SYMBOLS=Module.symvers
 423                 ], [test -r $SPL_OBJ/Modules.symvers], [
 424                         SPL_SYMBOLS=Modules.symvers
 425                 ], [test -r $SPL_OBJ/module/Module.symvers], [
 426                         SPL_SYMBOLS=Module.symvers
 427                 ], [test -r $SPL_OBJ/module/Modules.symvers], [
 428                         SPL_SYMBOLS=Modules.symvers
 429                 ])
 430
 431                 AS_IF([test $SPL_SYMBOLS != NONE -o $timeout -le 0], [
 432                         break;
 433                 ], [
 434                         sleep 1
 435                         timeout=$((timeout-1))
 436                 ])
 437         done
 438
 439         AS_IF([test "$SPL_SYMBOLS" = NONE], [
 440                 SPL_SYMBOLS=$LINUX_SYMBOLS
 441         ])
 442
 443         AC_MSG_RESULT([$SPL_SYMBOLS])
 444         AC_SUBST(SPL_SYMBOLS)
 445 ])
 446
 447 dnl #
 448 dnl # Basic toolchain sanity check.
 449 dnl #
 450 AC_DEFUN([ZFS_AC_TEST_MODULE], [
 451         AC_MSG_CHECKING([whether modules can be built])
 452         ZFS_LINUX_TRY_COMPILE([],[],[
 453                 AC_MSG_RESULT([yes])
 454         ],[
 455                 AC_MSG_RESULT([no])
 456                 if test "x$enable_linux_builtin" != xyes; then
 457                         AC_MSG_ERROR([*** Unable to build an empty module.])
 458                 else
 459                         AC_MSG_ERROR([
 460         *** Unable to build an empty module.
 461         *** Please run 'make scripts' inside the kernel source tree.])
 462                 fi
 463         ])
 464 ])
 465
 466 dnl #
 467 dnl # Certain kernel build options are not supported.  These must be
 468 dnl # detected at configure time and cause a build failure.  Otherwise
 469 dnl # modules may be successfully built that behave incorrectly.
 470 dnl #
 471 AC_DEFUN([ZFS_AC_KERNEL_CONFIG], [
 472         AS_IF([test "x$cross_compiling" != xyes], [
 473                 AC_RUN_IFELSE([
 474                         AC_LANG_PROGRAM([
 475                                 #include "$LINUX/include/linux/license.h"
 476                         ], [
 477                                 return !license_is_gpl_compatible("$ZFS_META_LICENSE");
 478                         ])
 479                 ], [
 480                         AC_DEFINE([ZFS_IS_GPL_COMPATIBLE], [1],
 481                             [Define to 1 if GPL-only symbols can be used])
 482                 ], [
 483                 ])
 484         ])
 485
 486         ZFS_AC_KERNEL_CONFIG_THREAD_SIZE
 487         ZFS_AC_KERNEL_CONFIG_DEBUG_LOCK_ALLOC
 488 ])
 489
 490 dnl #
 491 dnl # Check configured THREAD_SIZE
 492 dnl #
 493 dnl # The stack size will vary by architecture, but as of Linux 3.15 on x86_64
 494 dnl # the default thread stack size was increased to 16K from 8K.  Therefore,
 495 dnl # on newer kernels and some architectures stack usage optimizations can be
 496 dnl # conditionally applied to improve performance without negatively impacting
 497 dnl # stability.
 498 dnl #
 499 AC_DEFUN([ZFS_AC_KERNEL_CONFIG_THREAD_SIZE], [
 500         AC_MSG_CHECKING([whether kernel was built with 16K or larger stacks])
 501         ZFS_LINUX_TRY_COMPILE([
 502                 #include <linux/module.h>
 503         ],[
 504                 #if (THREAD_SIZE < 16384)
 505                 #error "THREAD_SIZE is less than 16K"
 506                 #endif
 507         ],[
 508                 AC_MSG_RESULT([yes])
 509                 AC_DEFINE(HAVE_LARGE_STACKS, 1, [kernel has large stacks])
 510         ],[
 511                 AC_MSG_RESULT([no])
 512         ])
 513 ])
 514
 515 dnl #
 516 dnl # Check CONFIG_DEBUG_LOCK_ALLOC
 517 dnl #
 518 dnl # This is typically only set for debug kernels because it comes with
 519 dnl # a performance penalty.  However, when it is set it maps the non-GPL
 520 dnl # symbol mutex_lock() to the GPL-only mutex_lock_nested() symbol.
 521 dnl # This will cause a failure at link time which we'd rather know about
 522 dnl # at compile time.
 523 dnl #
 524 dnl # Since we plan to pursue making mutex_lock_nested() a non-GPL symbol
 525 dnl # with the upstream community we add a check to detect this case.
 526 dnl #
 527 AC_DEFUN([ZFS_AC_KERNEL_CONFIG_DEBUG_LOCK_ALLOC], [
 528
 529         ZFS_LINUX_CONFIG([DEBUG_LOCK_ALLOC], [
 530                 AC_MSG_CHECKING([whether mutex_lock() is GPL-only])
 531                 tmp_flags="$EXTRA_KCFLAGS"
 532                 ZFS_LINUX_TRY_COMPILE([
 533                         #include <linux/module.h>
 534                         #include <linux/mutex.h>
 535
 536                         MODULE_LICENSE("$ZFS_META_LICENSE");
 537                 ],[
 538                         struct mutex lock;
 539
 540                         mutex_init(&lock);
 541                         mutex_lock(&lock);
 542                         mutex_unlock(&lock);
 543                 ],[
 544                         AC_MSG_RESULT(no)
 545                 ],[
 546                         AC_MSG_RESULT(yes)
 547                         AC_MSG_ERROR([
 548         *** Kernel built with CONFIG_DEBUG_LOCK_ALLOC which is incompatible
 549         *** with the CDDL license and will prevent the module linking stage
 550         *** from succeeding.  You must rebuild your kernel without this
 551         *** option enabled.])
 552                 ])
 553                 EXTRA_KCFLAGS="$tmp_flags"
 554         ], [])
 555 ])
 556
 557 dnl #
 558 dnl # ZFS_LINUX_CONFTEST_H
 559 dnl #
 560 AC_DEFUN([ZFS_LINUX_CONFTEST_H], [
 561 cat - <<_ACEOF >conftest.h
 562 $1
 563 _ACEOF
 564 ])
 565
 566 dnl #
 567 dnl # ZFS_LINUX_CONFTEST_C
 568 dnl #
 569 AC_DEFUN([ZFS_LINUX_CONFTEST_C], [
 570 cat confdefs.h - <<_ACEOF >conftest.c
 571 $1
 572 _ACEOF
 573 ])
 574
 575 dnl #
 576 dnl # ZFS_LANG_PROGRAM(C)([PROLOGUE], [BODY])
 577 dnl #
 578 m4_define([ZFS_LANG_PROGRAM], [
 579 $1
 580 int
 581 main (void)
 582 {
 583 dnl Do *not* indent the following line: there may be CPP directives.
 584 dnl Don't move the `;' right after for the same reason.
 585 $2
 586   ;
 587   return 0;
 588 }
 589 ])
 590
 591 dnl #
 592 dnl # ZFS_LINUX_COMPILE_IFELSE / like AC_COMPILE_IFELSE
 593 dnl #
 594 AC_DEFUN([ZFS_LINUX_COMPILE_IFELSE], [
 595         m4_ifvaln([$1], [ZFS_LINUX_CONFTEST_C([$1])])
 596         m4_ifvaln([$6], [ZFS_LINUX_CONFTEST_H([$6])], [ZFS_LINUX_CONFTEST_H([])])
 597         rm -Rf build && mkdir -p build && touch build/conftest.mod.c
 598         echo "obj-m := conftest.o" >build/Makefile
 599         modpost_flag=''
 600         test "x$enable_linux_builtin" = xyes && modpost_flag='modpost=true' # fake modpost stage
 601         AS_IF(
 602                 [AC_TRY_COMMAND(cp conftest.c conftest.h build && make [$2] -C $LINUX_OBJ EXTRA_CFLAGS="-Werror $EXTRA_KCFLAGS" $ARCH_UM M=$PWD/build $modpost_flag) >/dev/null && AC_TRY_COMMAND([$3])],
 603                 [$4],
 604                 [_AC_MSG_LOG_CONFTEST m4_ifvaln([$5],[$5])]
 605         )
 606         rm -Rf build
 607 ])
 608
 609 dnl #
 610 dnl # ZFS_LINUX_TRY_COMPILE like AC_TRY_COMPILE
 611 dnl #
 612 AC_DEFUN([ZFS_LINUX_TRY_COMPILE],
 613         [ZFS_LINUX_COMPILE_IFELSE(
 614         [AC_LANG_SOURCE([ZFS_LANG_PROGRAM([[$1]], [[$2]])])],
 615         [modules],
 616         [test -s build/conftest.o],
 617         [$3], [$4])
 618 ])
 619
 620 dnl #
 621 dnl # ZFS_LINUX_CONFIG
 622 dnl #
 623 AC_DEFUN([ZFS_LINUX_CONFIG],
 624         [AC_MSG_CHECKING([whether kernel was built with CONFIG_$1])
 625         ZFS_LINUX_TRY_COMPILE([
 626                 #include <linux/module.h>
 627         ],[
 628                 #ifndef CONFIG_$1
 629                 #error CONFIG_$1 not #defined
 630                 #endif
 631         ],[
 632                 AC_MSG_RESULT([yes])
 633                 $2
 634         ],[
 635                 AC_MSG_RESULT([no])
 636                 $3
 637         ])
 638 ])
 639
 640 dnl #
 641 dnl # ZFS_CHECK_SYMBOL_EXPORT
 642 dnl # check symbol exported or not
 643 dnl #
 644 AC_DEFUN([ZFS_CHECK_SYMBOL_EXPORT], [
 645         grep -q -E '[[[:space:]]]$1[[[:space:]]]' \
 646                 $LINUX_OBJ/$LINUX_SYMBOLS 2>/dev/null
 647         rc=$?
 648         if test $rc -ne 0; then
 649                 export=0
 650                 for file in $2; do
 651                         grep -q -E "EXPORT_SYMBOL.*($1)" \
 652                                 "$LINUX/$file" 2>/dev/null
 653                         rc=$?
 654                         if test $rc -eq 0; then
 655                                 export=1
 656                                 break;
 657                         fi
 658                 done
 659                 if test $export -eq 0; then :
 660                         $4
 661                 else :
 662                         $3
 663                 fi
 664         else :
 665                 $3
 666         fi
 667 ])
 668
 669 dnl #
 670 dnl # ZFS_LINUX_TRY_COMPILE_SYMBOL
 671 dnl # like ZFS_LINUX_TRY_COMPILE, except ZFS_CHECK_SYMBOL_EXPORT
 672 dnl # is called if not compiling for builtin
 673 dnl #
 674 AC_DEFUN([ZFS_LINUX_TRY_COMPILE_SYMBOL], [
 675         ZFS_LINUX_TRY_COMPILE([$1], [$2], [rc=0], [rc=1])
 676         if test $rc -ne 0; then :
 677                 $6
 678         else
 679                 if test "x$enable_linux_builtin" != xyes; then
 680                         ZFS_CHECK_SYMBOL_EXPORT([$3], [$4], [rc=0], [rc=1])
 681                 fi
 682                 if test $rc -ne 0; then :
 683                         $6
 684                 else :
 685                         $5
 686                 fi
 687         fi
 688 ])
 689
 690 dnl #
 691 dnl # ZFS_LINUX_TRY_COMPILE_HEADER
 692 dnl # like ZFS_LINUX_TRY_COMPILE, except the contents conftest.h are
 693 dnl # provided via the fifth parameter
 694 dnl #
 695 AC_DEFUN([ZFS_LINUX_TRY_COMPILE_HEADER],
 696         [ZFS_LINUX_COMPILE_IFELSE(
 697         [AC_LANG_SOURCE([ZFS_LANG_PROGRAM([[$1]], [[$2]])])],
 698         [modules],
 699         [test -s build/conftest.o],
 700         [$3], [$4], [$5])
 701 ])