]> git.proxmox.com Git - mirror_spl-debian.git/blob - config/spl-build.m4
Imported Upstream version 0.6.4.1
[mirror_spl-debian.git] / config / spl-build.m4
1 ###############################################################################
2 # Copyright (C) 2007-2010 Lawrence Livermore National Security, LLC.
3 # Copyright (C) 2007 The Regents of the University of California.
4 # Written by Brian Behlendorf <behlendorf1@llnl.gov>.
5 ###############################################################################
6 # SPL_AC_CONFIG_KERNEL: Default SPL kernel configuration.
7 ###############################################################################
8
9 AC_DEFUN([SPL_AC_CONFIG_KERNEL], [
10 SPL_AC_KERNEL
11
12 if test "${LINUX_OBJ}" != "${LINUX}"; then
13 KERNELMAKE_PARAMS="$KERNELMAKE_PARAMS O=$LINUX_OBJ"
14 fi
15 AC_SUBST(KERNELMAKE_PARAMS)
16
17 KERNELCPPFLAGS="$KERNELCPPFLAGS -Wstrict-prototypes"
18 AC_SUBST(KERNELCPPFLAGS)
19
20 SPL_AC_DEBUG
21 SPL_AC_DEBUG_KMEM
22 SPL_AC_DEBUG_KMEM_TRACKING
23 SPL_AC_TEST_MODULE
24 SPL_AC_ATOMIC_SPINLOCK
25 SPL_AC_SHRINKER_CALLBACK
26 SPL_AC_CTL_NAME
27 SPL_AC_PDE_DATA
28 SPL_AC_SET_FS_PWD_WITH_CONST
29 SPL_AC_2ARGS_VFS_UNLINK
30 SPL_AC_4ARGS_VFS_RENAME
31 SPL_AC_2ARGS_VFS_FSYNC
32 SPL_AC_INODE_TRUNCATE_RANGE
33 SPL_AC_FS_STRUCT_SPINLOCK
34 SPL_AC_KUIDGID_T
35 SPL_AC_PUT_TASK_STRUCT
36 SPL_AC_EXPORTED_RWSEM_IS_LOCKED
37 SPL_AC_KERNEL_FALLOCATE
38 SPL_AC_CONFIG_ZLIB_INFLATE
39 SPL_AC_CONFIG_ZLIB_DEFLATE
40 SPL_AC_2ARGS_ZLIB_DEFLATE_WORKSPACESIZE
41 SPL_AC_SHRINK_CONTROL_STRUCT
42 SPL_AC_RWSEM_SPINLOCK_IS_RAW
43 SPL_AC_SCHED_RT_HEADER
44 SPL_AC_2ARGS_VFS_GETATTR
45 SPL_AC_USLEEP_RANGE
46 SPL_AC_KMEM_CACHE_ALLOCFLAGS
47 SPL_AC_WAIT_ON_BIT
48 ])
49
50 AC_DEFUN([SPL_AC_MODULE_SYMVERS], [
51 modpost=$LINUX/scripts/Makefile.modpost
52 AC_MSG_CHECKING([kernel file name for module symbols])
53 if test "x$enable_linux_builtin" != xyes -a -f "$modpost"; then
54 if grep -q Modules.symvers $modpost; then
55 LINUX_SYMBOLS=Modules.symvers
56 else
57 LINUX_SYMBOLS=Module.symvers
58 fi
59
60 if ! test -f "$LINUX_OBJ/$LINUX_SYMBOLS"; then
61 AC_MSG_ERROR([
62 *** Please make sure the kernel devel package for your distribution
63 *** is installed. If you are building with a custom kernel, make sure the
64 *** kernel is configured, built, and the '--with-linux=PATH' configure
65 *** option refers to the location of the kernel source.])
66 fi
67 else
68 LINUX_SYMBOLS=NONE
69 fi
70 AC_MSG_RESULT($LINUX_SYMBOLS)
71 AC_SUBST(LINUX_SYMBOLS)
72 ])
73
74 AC_DEFUN([SPL_AC_KERNEL], [
75 AC_ARG_WITH([linux],
76 AS_HELP_STRING([--with-linux=PATH],
77 [Path to kernel source]),
78 [kernelsrc="$withval"])
79
80 AC_ARG_WITH([linux-obj],
81 AS_HELP_STRING([--with-linux-obj=PATH],
82 [Path to kernel build objects]),
83 [kernelbuild="$withval"])
84
85 AC_MSG_CHECKING([kernel source directory])
86 if test -z "$kernelsrc"; then
87 if test -e "/lib/modules/$(uname -r)/source"; then
88 headersdir="/lib/modules/$(uname -r)/source"
89 sourcelink=$(readlink -f "$headersdir")
90 elif test -e "/lib/modules/$(uname -r)/build"; then
91 headersdir="/lib/modules/$(uname -r)/build"
92 sourcelink=$(readlink -f "$headersdir")
93 else
94 sourcelink=$(ls -1d /usr/src/kernels/* \
95 /usr/src/linux-* \
96 2>/dev/null | grep -v obj | tail -1)
97 fi
98
99 if test -n "$sourcelink" && test -e ${sourcelink}; then
100 kernelsrc=`readlink -f ${sourcelink}`
101 else
102 kernelsrc="[Not found]"
103 fi
104 else
105 if test "$kernelsrc" = "NONE"; then
106 kernsrcver=NONE
107 fi
108 fi
109
110 AC_MSG_RESULT([$kernelsrc])
111 if test ! -d "$kernelsrc"; then
112 AC_MSG_ERROR([
113 *** Please make sure the kernel devel package for your distribution
114 *** is installed and then try again. If that fails, you can specify the
115 *** location of the kernel source with the '--with-linux=PATH' option.])
116 fi
117
118 AC_MSG_CHECKING([kernel build directory])
119 if test -z "$kernelbuild"; then
120 if test -e "/lib/modules/$(uname -r)/build"; then
121 kernelbuild=`readlink -f /lib/modules/$(uname -r)/build`
122 elif test -d ${kernelsrc}-obj/${target_cpu}/${target_cpu}; then
123 kernelbuild=${kernelsrc}-obj/${target_cpu}/${target_cpu}
124 elif test -d ${kernelsrc}-obj/${target_cpu}/default; then
125 kernelbuild=${kernelsrc}-obj/${target_cpu}/default
126 elif test -d `dirname ${kernelsrc}`/build-${target_cpu}; then
127 kernelbuild=`dirname ${kernelsrc}`/build-${target_cpu}
128 else
129 kernelbuild=${kernelsrc}
130 fi
131 fi
132 AC_MSG_RESULT([$kernelbuild])
133
134 AC_MSG_CHECKING([kernel source version])
135 utsrelease1=$kernelbuild/include/linux/version.h
136 utsrelease2=$kernelbuild/include/linux/utsrelease.h
137 utsrelease3=$kernelbuild/include/generated/utsrelease.h
138 if test -r $utsrelease1 && fgrep -q UTS_RELEASE $utsrelease1; then
139 utsrelease=linux/version.h
140 elif test -r $utsrelease2 && fgrep -q UTS_RELEASE $utsrelease2; then
141 utsrelease=linux/utsrelease.h
142 elif test -r $utsrelease3 && fgrep -q UTS_RELEASE $utsrelease3; then
143 utsrelease=generated/utsrelease.h
144 fi
145
146 if test "$utsrelease"; then
147 kernsrcver=`(echo "#include <$utsrelease>";
148 echo "kernsrcver=UTS_RELEASE") |
149 cpp -I $kernelbuild/include |
150 grep "^kernsrcver=" | cut -d \" -f 2`
151
152 if test -z "$kernsrcver"; then
153 AC_MSG_RESULT([Not found])
154 AC_MSG_ERROR([*** Cannot determine kernel version.])
155 fi
156 else
157 AC_MSG_RESULT([Not found])
158 if test "x$enable_linux_builtin" != xyes; then
159 AC_MSG_ERROR([*** Cannot find UTS_RELEASE definition.])
160 else
161 AC_MSG_ERROR([
162 *** Cannot find UTS_RELEASE definition.
163 *** Please run 'make prepare' inside the kernel source tree.])
164 fi
165 fi
166
167 AC_MSG_RESULT([$kernsrcver])
168
169 LINUX=${kernelsrc}
170 LINUX_OBJ=${kernelbuild}
171 LINUX_VERSION=${kernsrcver}
172
173 AC_SUBST(LINUX)
174 AC_SUBST(LINUX_OBJ)
175 AC_SUBST(LINUX_VERSION)
176
177 SPL_AC_MODULE_SYMVERS
178 ])
179
180 dnl #
181 dnl # Default SPL user configuration
182 dnl #
183 AC_DEFUN([SPL_AC_CONFIG_USER], [])
184
185 dnl #
186 dnl # Check for rpm+rpmbuild to build RPM packages. If these tools
187 dnl # are missing, it is non-fatal, but you will not be able to build
188 dnl # RPM packages and will be warned if you try too.
189 dnl #
190 dnl # By default, the generic spec file will be used because it requires
191 dnl # minimal dependencies. Distribution specific spec files can be
192 dnl # placed under the 'rpm/<distribution>' directory and enabled using
193 dnl # the --with-spec=<distribution> configure option.
194 dnl #
195 AC_DEFUN([SPL_AC_RPM], [
196 RPM=rpm
197 RPMBUILD=rpmbuild
198
199 AC_MSG_CHECKING([whether $RPM is available])
200 AS_IF([tmp=$($RPM --version 2>/dev/null)], [
201 RPM_VERSION=$(echo $tmp | $AWK '/RPM/ { print $[3] }')
202 HAVE_RPM=yes
203 AC_MSG_RESULT([$HAVE_RPM ($RPM_VERSION)])
204 ],[
205 HAVE_RPM=no
206 AC_MSG_RESULT([$HAVE_RPM])
207 ])
208
209 AC_MSG_CHECKING([whether $RPMBUILD is available])
210 AS_IF([tmp=$($RPMBUILD --version 2>/dev/null)], [
211 RPMBUILD_VERSION=$(echo $tmp | $AWK '/RPM/ { print $[3] }')
212 HAVE_RPMBUILD=yes
213 AC_MSG_RESULT([$HAVE_RPMBUILD ($RPMBUILD_VERSION)])
214 ],[
215 HAVE_RPMBUILD=no
216 AC_MSG_RESULT([$HAVE_RPMBUILD])
217 ])
218
219 RPM_DEFINE_COMMON='--define "$(DEBUG_SPL) 1" --define "$(DEBUG_KMEM) 1" --define "$(DEBUG_KMEM_TRACKING) 1"'
220 RPM_DEFINE_UTIL=
221 RPM_DEFINE_KMOD='--define "kernels $(LINUX_VERSION)"'
222 RPM_DEFINE_DKMS=
223
224 SRPM_DEFINE_COMMON='--define "build_src_rpm 1"'
225 SRPM_DEFINE_UTIL=
226 SRPM_DEFINE_KMOD=
227 SRPM_DEFINE_DKMS=
228
229 RPM_SPEC_DIR="rpm/generic"
230 AC_ARG_WITH([spec],
231 AS_HELP_STRING([--with-spec=SPEC],
232 [Spec files 'generic|redhat']),
233 [RPM_SPEC_DIR="rpm/$withval"])
234
235 AC_MSG_CHECKING([whether spec files are available])
236 AC_MSG_RESULT([yes ($RPM_SPEC_DIR/*.spec.in)])
237
238 AC_SUBST(HAVE_RPM)
239 AC_SUBST(RPM)
240 AC_SUBST(RPM_VERSION)
241
242 AC_SUBST(HAVE_RPMBUILD)
243 AC_SUBST(RPMBUILD)
244 AC_SUBST(RPMBUILD_VERSION)
245
246 AC_SUBST(RPM_SPEC_DIR)
247 AC_SUBST(RPM_DEFINE_UTIL)
248 AC_SUBST(RPM_DEFINE_KMOD)
249 AC_SUBST(RPM_DEFINE_DKMS)
250 AC_SUBST(RPM_DEFINE_COMMON)
251 AC_SUBST(SRPM_DEFINE_UTIL)
252 AC_SUBST(SRPM_DEFINE_KMOD)
253 AC_SUBST(SRPM_DEFINE_DKMS)
254 AC_SUBST(SRPM_DEFINE_COMMON)
255 ])
256
257 dnl #
258 dnl # Check for dpkg+dpkg-buildpackage to build DEB packages. If these
259 dnl # tools are missing it is non-fatal but you will not be able to build
260 dnl # DEB packages and will be warned if you try too.
261 dnl #
262 AC_DEFUN([SPL_AC_DPKG], [
263 DPKG=dpkg
264 DPKGBUILD=dpkg-buildpackage
265
266 AC_MSG_CHECKING([whether $DPKG is available])
267 AS_IF([tmp=$($DPKG --version 2>/dev/null)], [
268 DPKG_VERSION=$(echo $tmp | $AWK '/Debian/ { print $[7] }')
269 HAVE_DPKG=yes
270 AC_MSG_RESULT([$HAVE_DPKG ($DPKG_VERSION)])
271 ],[
272 HAVE_DPKG=no
273 AC_MSG_RESULT([$HAVE_DPKG])
274 ])
275
276 AC_MSG_CHECKING([whether $DPKGBUILD is available])
277 AS_IF([tmp=$($DPKGBUILD --version 2>/dev/null)], [
278 DPKGBUILD_VERSION=$(echo $tmp | \
279 $AWK '/Debian/ { print $[4] }' | cut -f-4 -d'.')
280 HAVE_DPKGBUILD=yes
281 AC_MSG_RESULT([$HAVE_DPKGBUILD ($DPKGBUILD_VERSION)])
282 ],[
283 HAVE_DPKGBUILD=no
284 AC_MSG_RESULT([$HAVE_DPKGBUILD])
285 ])
286
287 AC_SUBST(HAVE_DPKG)
288 AC_SUBST(DPKG)
289 AC_SUBST(DPKG_VERSION)
290
291 AC_SUBST(HAVE_DPKGBUILD)
292 AC_SUBST(DPKGBUILD)
293 AC_SUBST(DPKGBUILD_VERSION)
294 ])
295
296 dnl #
297 dnl # Until native packaging for various different packing systems
298 dnl # can be added the least we can do is attempt to use alien to
299 dnl # convert the RPM packages to the needed package type. This is
300 dnl # a hack but so far it has worked reasonable well.
301 dnl #
302 AC_DEFUN([SPL_AC_ALIEN], [
303 ALIEN=alien
304
305 AC_MSG_CHECKING([whether $ALIEN is available])
306 AS_IF([tmp=$($ALIEN --version 2>/dev/null)], [
307 ALIEN_VERSION=$(echo $tmp | $AWK '{ print $[3] }')
308 HAVE_ALIEN=yes
309 AC_MSG_RESULT([$HAVE_ALIEN ($ALIEN_VERSION)])
310 ],[
311 HAVE_ALIEN=no
312 AC_MSG_RESULT([$HAVE_ALIEN])
313 ])
314
315 AC_SUBST(HAVE_ALIEN)
316 AC_SUBST(ALIEN)
317 AC_SUBST(ALIEN_VERSION)
318 ])
319
320 dnl #
321 dnl # Using the VENDOR tag from config.guess set the default
322 dnl # package type for 'make pkg': (rpm | deb | tgz)
323 dnl #
324 AC_DEFUN([SPL_AC_DEFAULT_PACKAGE], [
325 AC_MSG_CHECKING([linux distribution])
326 if test -f /etc/toss-release ; then
327 VENDOR=toss ;
328 elif test -f /etc/fedora-release ; then
329 VENDOR=fedora ;
330 elif test -f /etc/redhat-release ; then
331 VENDOR=redhat ;
332 elif test -f /etc/gentoo-release ; then
333 VENDOR=gentoo ;
334 elif test -f /etc/arch-release ; then
335 VENDOR=arch ;
336 elif test -f /etc/SuSE-release ; then
337 VENDOR=sles ;
338 elif test -f /etc/slackware-version ; then
339 VENDOR=slackware ;
340 elif test -f /etc/lunar.release ; then
341 VENDOR=lunar ;
342 elif test -f /etc/lsb-release ; then
343 VENDOR=ubuntu ;
344 elif test -f /etc/debian_version ; then
345 VENDOR=debian ;
346 else
347 VENDOR= ;
348 fi
349 AC_MSG_RESULT([$VENDOR])
350 AC_SUBST(VENDOR)
351
352 AC_MSG_CHECKING([default package type])
353 case "$VENDOR" in
354 toss) DEFAULT_PACKAGE=rpm ;;
355 redhat) DEFAULT_PACKAGE=rpm ;;
356 fedora) DEFAULT_PACKAGE=rpm ;;
357 gentoo) DEFAULT_PACKAGE=tgz ;;
358 arch) DEFAULT_PACKAGE=tgz ;;
359 sles) DEFAULT_PACKAGE=rpm ;;
360 slackware) DEFAULT_PACKAGE=tgz ;;
361 lunar) DEFAULT_PACKAGE=tgz ;;
362 ubuntu) DEFAULT_PACKAGE=deb ;;
363 debian) DEFAULT_PACKAGE=deb ;;
364 *) DEFAULT_PACKAGE=rpm ;;
365 esac
366
367 AC_MSG_RESULT([$DEFAULT_PACKAGE])
368 AC_SUBST(DEFAULT_PACKAGE)
369 ])
370
371 dnl #
372 dnl # Default SPL user configuration
373 dnl #
374 AC_DEFUN([SPL_AC_PACKAGE], [
375 SPL_AC_DEFAULT_PACKAGE
376 SPL_AC_RPM
377 SPL_AC_DPKG
378 SPL_AC_ALIEN
379 ])
380
381 AC_DEFUN([SPL_AC_LICENSE], [
382 AC_MSG_CHECKING([spl author])
383 AC_MSG_RESULT([$SPL_META_AUTHOR])
384
385 AC_MSG_CHECKING([spl license])
386 AC_MSG_RESULT([$SPL_META_LICENSE])
387 ])
388
389 AC_DEFUN([SPL_AC_CONFIG], [
390 SPL_CONFIG=all
391 AC_ARG_WITH([config],
392 AS_HELP_STRING([--with-config=CONFIG],
393 [Config file 'kernel|user|all|srpm']),
394 [SPL_CONFIG="$withval"])
395 AC_ARG_ENABLE([linux-builtin],
396 [AC_HELP_STRING([--enable-linux-builtin],
397 [Configure for builtin in-tree kernel modules @<:@default=no@:>@])],
398 [],
399 [enable_linux_builtin=no])
400
401 AC_MSG_CHECKING([spl config])
402 AC_MSG_RESULT([$SPL_CONFIG]);
403 AC_SUBST(SPL_CONFIG)
404
405 case "$SPL_CONFIG" in
406 kernel) SPL_AC_CONFIG_KERNEL ;;
407 user) SPL_AC_CONFIG_USER ;;
408 all) SPL_AC_CONFIG_KERNEL
409 SPL_AC_CONFIG_USER ;;
410 srpm) ;;
411 *)
412 AC_MSG_RESULT([Error!])
413 AC_MSG_ERROR([Bad value "$SPL_CONFIG" for --with-config,
414 user kernel|user|all|srpm]) ;;
415 esac
416
417 AM_CONDITIONAL([CONFIG_USER],
418 [test "$SPL_CONFIG" = user -o "$SPL_CONFIG" = all])
419 AM_CONDITIONAL([CONFIG_KERNEL],
420 [test "$SPL_CONFIG" = kernel -o "$SPL_CONFIG" = all] &&
421 [test "x$enable_linux_builtin" != xyes ])
422 ])
423
424 dnl #
425 dnl # Enable if the SPL should be compiled with internal debugging enabled.
426 dnl # By default this support is disabled.
427 dnl #
428 AC_DEFUN([SPL_AC_DEBUG], [
429 AC_MSG_CHECKING([whether debugging is enabled])
430 AC_ARG_ENABLE([debug],
431 [AS_HELP_STRING([--enable-debug],
432 [Enable generic debug support @<:@default=no@:>@])],
433 [],
434 [enable_debug=no])
435
436 AS_IF([test "x$enable_debug" = xyes],
437 [
438 KERNELCPPFLAGS="${KERNELCPPFLAGS} -DDEBUG -Werror"
439 DEBUG_CFLAGS="-DDEBUG -Werror"
440 DEBUG_SPL="_with_debug"
441 ], [
442 KERNELCPPFLAGS="${KERNELCPPFLAGS} -DNDEBUG"
443 DEBUG_CFLAGS="-DNDEBUG"
444 DEBUG_SPL="_without_debug"
445 ])
446
447 AC_SUBST(DEBUG_CFLAGS)
448 AC_SUBST(DEBUG_SPL)
449 AC_MSG_RESULT([$enable_debug])
450 ])
451
452 dnl #
453 dnl # Enabled by default it provides a minimal level of memory tracking.
454 dnl # A total count of bytes allocated is kept for each alloc and free.
455 dnl # Then at module unload time a report to the console will be printed
456 dnl # if memory was leaked. Additionally, /proc/spl/kmem/slab will exist
457 dnl # and provide an easy way to inspect the kmem based slab.
458 dnl #
459 AC_DEFUN([SPL_AC_DEBUG_KMEM], [
460 AC_ARG_ENABLE([debug-kmem],
461 [AS_HELP_STRING([--enable-debug-kmem],
462 [Enable basic kmem accounting @<:@default=yes@:>@])],
463 [],
464 [enable_debug_kmem=yes])
465
466 AS_IF([test "x$enable_debug_kmem" = xyes],
467 [
468 KERNELCPPFLAGS="${KERNELCPPFLAGS} -DDEBUG_KMEM"
469 DEBUG_KMEM="_with_debug_kmem"
470 AC_DEFINE([DEBUG_KMEM], [1],
471 [Define to 1 to enable basic kmem accounting])
472 ], [
473 DEBUG_KMEM="_without_debug_kmem"
474 ])
475
476 AC_SUBST(DEBUG_KMEM)
477 AC_MSG_CHECKING([whether basic kmem accounting is enabled])
478 AC_MSG_RESULT([$enable_debug_kmem])
479 ])
480
481 dnl #
482 dnl # Disabled by default it provides detailed memory tracking. This
483 dnl # feature also requires --enable-debug-kmem to be set. When enabled
484 dnl # not only will total bytes be tracked but also the location of every
485 dnl # alloc and free. When the SPL module is unloaded a list of all leaked
486 dnl # addresses and where they were allocated will be dumped to the console.
487 dnl # Enabling this feature has a significant impact on performance but it
488 dnl # makes finding memory leaks pretty straight forward.
489 dnl #
490 AC_DEFUN([SPL_AC_DEBUG_KMEM_TRACKING], [
491 AC_ARG_ENABLE([debug-kmem-tracking],
492 [AS_HELP_STRING([--enable-debug-kmem-tracking],
493 [Enable detailed kmem tracking @<:@default=no@:>@])],
494 [],
495 [enable_debug_kmem_tracking=no])
496
497 AS_IF([test "x$enable_debug_kmem_tracking" = xyes],
498 [
499 KERNELCPPFLAGS="${KERNELCPPFLAGS} -DDEBUG_KMEM_TRACKING"
500 DEBUG_KMEM_TRACKING="_with_debug_kmem_tracking"
501 AC_DEFINE([DEBUG_KMEM_TRACKING], [1],
502 [Define to 1 to enable detailed kmem tracking])
503 ], [
504 DEBUG_KMEM_TRACKING="_without_debug_kmem_tracking"
505 ])
506
507 AC_SUBST(DEBUG_KMEM_TRACKING)
508 AC_MSG_CHECKING([whether detailed kmem tracking is enabled])
509 AC_MSG_RESULT([$enable_debug_kmem_tracking])
510 ])
511
512 dnl #
513 dnl # SPL_LINUX_CONFTEST
514 dnl #
515 AC_DEFUN([SPL_LINUX_CONFTEST], [
516 cat confdefs.h - <<_ACEOF >conftest.c
517 $1
518 _ACEOF
519 ])
520
521 dnl #
522 dnl # SPL_LANG_PROGRAM(C)([PROLOGUE], [BODY])
523 dnl #
524 m4_define([SPL_LANG_PROGRAM], [
525 $1
526 int
527 main (void)
528 {
529 dnl Do *not* indent the following line: there may be CPP directives.
530 dnl Don't move the `;' right after for the same reason.
531 $2
532 ;
533 return 0;
534 }
535 ])
536
537 dnl #
538 dnl # SPL_LINUX_COMPILE_IFELSE / like AC_COMPILE_IFELSE
539 dnl #
540 AC_DEFUN([SPL_LINUX_COMPILE_IFELSE], [
541 m4_ifvaln([$1], [SPL_LINUX_CONFTEST([$1])])
542 rm -Rf build && mkdir -p build && touch build/conftest.mod.c
543 echo "obj-m := conftest.o" >build/Makefile
544 modpost_flag=''
545 test "x$enable_linux_builtin" = xyes && modpost_flag='modpost=true' # fake modpost stage
546 AS_IF(
547 [AC_TRY_COMMAND(cp conftest.c build && make [$2] -C $LINUX_OBJ EXTRA_CFLAGS="-Werror-implicit-function-declaration $EXTRA_KCFLAGS" $ARCH_UM M=$PWD/build $modpost_flag) >/dev/null && AC_TRY_COMMAND([$3])],
548 [$4],
549 [_AC_MSG_LOG_CONFTEST m4_ifvaln([$5],[$5])]
550 )
551 rm -Rf build
552 ])
553
554 dnl #
555 dnl # SPL_LINUX_TRY_COMPILE like AC_TRY_COMPILE
556 dnl #
557 AC_DEFUN([SPL_LINUX_TRY_COMPILE],
558 [SPL_LINUX_COMPILE_IFELSE(
559 [AC_LANG_SOURCE([SPL_LANG_PROGRAM([[$1]], [[$2]])])],
560 [modules],
561 [test -s build/conftest.o],
562 [$3], [$4])
563 ])
564
565 dnl #
566 dnl # SPL_CHECK_SYMBOL_EXPORT
567 dnl # check symbol exported or not
568 dnl #
569 AC_DEFUN([SPL_CHECK_SYMBOL_EXPORT], [
570 grep -q -E '[[[:space:]]]$1[[[:space:]]]' \
571 $LINUX_OBJ/Module*.symvers 2>/dev/null
572 rc=$?
573 if test $rc -ne 0; then
574 export=0
575 for file in $2; do
576 grep -q -E "EXPORT_SYMBOL.*($1)" \
577 "$LINUX_OBJ/$file" 2>/dev/null
578 rc=$?
579 if test $rc -eq 0; then
580 export=1
581 break;
582 fi
583 done
584 if test $export -eq 0; then :
585 $4
586 else :
587 $3
588 fi
589 else :
590 $3
591 fi
592 ])
593
594 dnl #
595 dnl # SPL_LINUX_TRY_COMPILE_SYMBOL
596 dnl # like SPL_LINUX_TRY_COMPILE, except SPL_CHECK_SYMBOL_EXPORT
597 dnl # is called if not compiling for builtin
598 dnl #
599 AC_DEFUN([SPL_LINUX_TRY_COMPILE_SYMBOL], [
600 SPL_LINUX_TRY_COMPILE([$1], [$2], [rc=0], [rc=1])
601 if test $rc -ne 0; then :
602 $6
603 else
604 if test "x$enable_linux_builtin" != xyes; then
605 SPL_CHECK_SYMBOL_EXPORT([$3], [$4], [rc=0], [rc=1])
606 fi
607 if test $rc -ne 0; then :
608 $6
609 else :
610 $5
611 fi
612 fi
613 ])
614
615 dnl #
616 dnl # SPL_CHECK_SYMBOL_HEADER
617 dnl # check if a symbol prototype is defined in listed headers.
618 dnl #
619 AC_DEFUN([SPL_CHECK_SYMBOL_HEADER], [
620 AC_MSG_CHECKING([whether symbol $1 exists in header])
621 header=0
622 for file in $3; do
623 grep -q "$2" "$LINUX/$file" 2>/dev/null
624 rc=$?
625 if test $rc -eq 0; then
626 header=1
627 break;
628 fi
629 done
630 if test $header -eq 0; then
631 AC_MSG_RESULT([no])
632 $5
633 else
634 AC_MSG_RESULT([yes])
635 $4
636 fi
637 ])
638
639 dnl #
640 dnl # SPL_CHECK_HEADER
641 dnl # check whether header exists and define HAVE_$2_HEADER
642 dnl #
643 AC_DEFUN([SPL_CHECK_HEADER],
644 [AC_MSG_CHECKING([whether header $1 exists])
645 SPL_LINUX_TRY_COMPILE([
646 #include <$1>
647 ],[
648 return 0;
649 ],[
650 AC_DEFINE(HAVE_$2_HEADER, 1, [$1 exists])
651 AC_MSG_RESULT(yes)
652 $3
653 ],[
654 AC_MSG_RESULT(no)
655 $4
656 ])
657 ])
658
659 dnl #
660 dnl # Basic toolchain sanity check. Verify that kernel modules can
661 dnl # be built and which symbols can be used.
662 dnl #
663 AC_DEFUN([SPL_AC_TEST_MODULE],
664 [AC_MSG_CHECKING([whether modules can be built])
665 SPL_LINUX_TRY_COMPILE([],[],[
666 AC_MSG_RESULT([yes])
667 ],[
668 AC_MSG_RESULT([no])
669 if test "x$enable_linux_builtin" != xyes; then
670 AC_MSG_ERROR([*** Unable to build an empty module.])
671 else
672 AC_MSG_ERROR([
673 *** Unable to build an empty module.
674 *** Please run 'make scripts' inside the kernel source tree.])
675 fi
676 ])
677
678 AC_RUN_IFELSE([
679 AC_LANG_PROGRAM([
680 #include "$LINUX/include/linux/license.h"
681 ], [
682 return !license_is_gpl_compatible("$SPL_META_LICENSE");
683 ])
684 ], [
685 AC_DEFINE([SPL_IS_GPL_COMPATIBLE], [1],
686 [Define to 1 if GPL-only symbols can be used])
687 ], [
688 ])
689 ])
690
691 dnl #
692 dnl # Use the atomic implemenation based on global spinlocks. This
693 dnl # should only be needed by 32-bit kernels which do not provide
694 dnl # the atomic64_* API. It may be optionally enabled as a fallback
695 dnl # if problems are observed with the direct mapping to the native
696 dnl # Linux atomic operations. You may not disable atomic spinlocks
697 dnl # if you kernel does not an atomic64_* API.
698 dnl #
699 AC_DEFUN([SPL_AC_ATOMIC_SPINLOCK], [
700 AC_ARG_ENABLE([atomic-spinlocks],
701 [AS_HELP_STRING([--enable-atomic-spinlocks],
702 [Atomic types use spinlocks @<:@default=check@:>@])],
703 [],
704 [enable_atomic_spinlocks=check])
705
706 SPL_LINUX_TRY_COMPILE([
707 #include <linux/fs.h>
708 ],[
709 atomic64_t *ptr __attribute__ ((unused));
710 ],[
711 have_atomic64_t=yes
712 AC_DEFINE(HAVE_ATOMIC64_T, 1,
713 [kernel defines atomic64_t])
714 ],[
715 have_atomic64_t=no
716 ])
717
718 AS_IF([test "x$enable_atomic_spinlocks" = xcheck], [
719 AS_IF([test "x$have_atomic64_t" = xyes], [
720 enable_atomic_spinlocks=no
721 ],[
722 enable_atomic_spinlocks=yes
723 ])
724 ])
725
726 AS_IF([test "x$enable_atomic_spinlocks" = xyes], [
727 AC_DEFINE([ATOMIC_SPINLOCK], [1],
728 [Atomic types use spinlocks])
729 ],[
730 AS_IF([test "x$have_atomic64_t" = xno], [
731 AC_MSG_FAILURE(
732 [--disable-atomic-spinlocks given but required atomic64 support is unavailable])
733 ])
734 ])
735
736 AC_MSG_CHECKING([whether atomic types use spinlocks])
737 AC_MSG_RESULT([$enable_atomic_spinlocks])
738
739 AC_MSG_CHECKING([whether kernel defines atomic64_t])
740 AC_MSG_RESULT([$have_atomic64_t])
741 ])
742
743 AC_DEFUN([SPL_AC_SHRINKER_CALLBACK],[
744 tmp_flags="$EXTRA_KCFLAGS"
745 EXTRA_KCFLAGS="-Werror"
746 dnl #
747 dnl # 2.6.23 to 2.6.34 API change
748 dnl # ->shrink(int nr_to_scan, gfp_t gfp_mask)
749 dnl #
750 AC_MSG_CHECKING([whether old 2-argument shrinker exists])
751 SPL_LINUX_TRY_COMPILE([
752 #include <linux/mm.h>
753
754 int shrinker_cb(int nr_to_scan, gfp_t gfp_mask);
755 ],[
756 struct shrinker cache_shrinker = {
757 .shrink = shrinker_cb,
758 .seeks = DEFAULT_SEEKS,
759 };
760 register_shrinker(&cache_shrinker);
761 ],[
762 AC_MSG_RESULT(yes)
763 AC_DEFINE(HAVE_2ARGS_OLD_SHRINKER_CALLBACK, 1,
764 [old shrinker callback wants 2 args])
765 ],[
766 AC_MSG_RESULT(no)
767 dnl #
768 dnl # 2.6.35 - 2.6.39 API change
769 dnl # ->shrink(struct shrinker *,
770 dnl # int nr_to_scan, gfp_t gfp_mask)
771 dnl #
772 AC_MSG_CHECKING([whether old 3-argument shrinker exists])
773 SPL_LINUX_TRY_COMPILE([
774 #include <linux/mm.h>
775
776 int shrinker_cb(struct shrinker *, int nr_to_scan,
777 gfp_t gfp_mask);
778 ],[
779 struct shrinker cache_shrinker = {
780 .shrink = shrinker_cb,
781 .seeks = DEFAULT_SEEKS,
782 };
783 register_shrinker(&cache_shrinker);
784 ],[
785 AC_MSG_RESULT(yes)
786 AC_DEFINE(HAVE_3ARGS_SHRINKER_CALLBACK, 1,
787 [old shrinker callback wants 3 args])
788 ],[
789 AC_MSG_RESULT(no)
790 dnl #
791 dnl # 3.0 - 3.11 API change
792 dnl # ->shrink(struct shrinker *,
793 dnl # struct shrink_control *sc)
794 dnl #
795 AC_MSG_CHECKING(
796 [whether new 2-argument shrinker exists])
797 SPL_LINUX_TRY_COMPILE([
798 #include <linux/mm.h>
799
800 int shrinker_cb(struct shrinker *,
801 struct shrink_control *sc);
802 ],[
803 struct shrinker cache_shrinker = {
804 .shrink = shrinker_cb,
805 .seeks = DEFAULT_SEEKS,
806 };
807 register_shrinker(&cache_shrinker);
808 ],[
809 AC_MSG_RESULT(yes)
810 AC_DEFINE(HAVE_2ARGS_NEW_SHRINKER_CALLBACK, 1,
811 [new shrinker callback wants 2 args])
812 ],[
813 AC_MSG_RESULT(no)
814 dnl #
815 dnl # 3.12 API change,
816 dnl # ->shrink() is logically split in to
817 dnl # ->count_objects() and ->scan_objects()
818 dnl #
819 AC_MSG_CHECKING(
820 [whether ->count_objects callback exists])
821 SPL_LINUX_TRY_COMPILE([
822 #include <linux/mm.h>
823
824 unsigned long shrinker_cb(
825 struct shrinker *,
826 struct shrink_control *sc);
827 ],[
828 struct shrinker cache_shrinker = {
829 .count_objects = shrinker_cb,
830 .scan_objects = shrinker_cb,
831 .seeks = DEFAULT_SEEKS,
832 };
833 register_shrinker(&cache_shrinker);
834 ],[
835 AC_MSG_RESULT(yes)
836 AC_DEFINE(HAVE_SPLIT_SHRINKER_CALLBACK,
837 1, [->count_objects exists])
838 ],[
839 AC_MSG_ERROR(error)
840 ])
841 ])
842 ])
843 ])
844 EXTRA_KCFLAGS="$tmp_flags"
845 ])
846
847 dnl #
848 dnl # 2.6.33 API change,
849 dnl # Removed .ctl_name from struct ctl_table.
850 dnl #
851 AC_DEFUN([SPL_AC_CTL_NAME], [
852 AC_MSG_CHECKING([whether struct ctl_table has ctl_name])
853 SPL_LINUX_TRY_COMPILE([
854 #include <linux/sysctl.h>
855 ],[
856 struct ctl_table ctl __attribute__ ((unused));
857 ctl.ctl_name = 0;
858 ],[
859 AC_MSG_RESULT(yes)
860 AC_DEFINE(HAVE_CTL_NAME, 1, [struct ctl_table has ctl_name])
861 ],[
862 AC_MSG_RESULT(no)
863 ])
864 ])
865
866 dnl #
867 dnl # 3.10 API change,
868 dnl # PDE is replaced by PDE_DATA
869 dnl #
870 AC_DEFUN([SPL_AC_PDE_DATA], [
871 AC_MSG_CHECKING([whether PDE_DATA() is available])
872 SPL_LINUX_TRY_COMPILE_SYMBOL([
873 #include <linux/proc_fs.h>
874 ], [
875 PDE_DATA(NULL);
876 ], [PDE_DATA], [], [
877 AC_MSG_RESULT(yes)
878 AC_DEFINE(HAVE_PDE_DATA, 1, [yes])
879 ],[
880 AC_MSG_RESULT(no)
881 ])
882 ])
883
884 dnl #
885 dnl # 3.9 API change
886 dnl # set_fs_pwd takes const struct path *
887 dnl #
888 AC_DEFUN([SPL_AC_SET_FS_PWD_WITH_CONST],
889 tmp_flags="$EXTRA_KCFLAGS"
890 EXTRA_KCFLAGS="-Werror"
891 [AC_MSG_CHECKING([whether set_fs_pwd() requires const struct path *])
892 SPL_LINUX_TRY_COMPILE([
893 #include <linux/spinlock.h>
894 #include <linux/fs_struct.h>
895 #include <linux/path.h>
896 void (*const set_fs_pwd_func)
897 (struct fs_struct *, const struct path *)
898 = set_fs_pwd;
899 ],[
900 return 0;
901 ],[
902 AC_MSG_RESULT(yes)
903 AC_DEFINE(HAVE_SET_FS_PWD_WITH_CONST, 1,
904 [set_fs_pwd() needs const path *])
905 ],[
906 SPL_LINUX_TRY_COMPILE([
907 #include <linux/spinlock.h>
908 #include <linux/fs_struct.h>
909 #include <linux/path.h>
910 void (*const set_fs_pwd_func)
911 (struct fs_struct *, struct path *)
912 = set_fs_pwd;
913 ],[
914 return 0;
915 ],[
916 AC_MSG_RESULT(no)
917 ],[
918 AC_MSG_ERROR(unknown)
919 ])
920 ])
921 EXTRA_KCFLAGS="$tmp_flags"
922 ])
923
924 dnl #
925 dnl # 3.13 API change
926 dnl # vfs_unlink() updated to take a third delegated_inode argument.
927 dnl #
928 AC_DEFUN([SPL_AC_2ARGS_VFS_UNLINK],
929 [AC_MSG_CHECKING([whether vfs_unlink() wants 2 args])
930 SPL_LINUX_TRY_COMPILE([
931 #include <linux/fs.h>
932 ],[
933 vfs_unlink((struct inode *) NULL, (struct dentry *) NULL);
934 ],[
935 AC_MSG_RESULT(yes)
936 AC_DEFINE(HAVE_2ARGS_VFS_UNLINK, 1,
937 [vfs_unlink() wants 2 args])
938 ],[
939 AC_MSG_RESULT(no)
940 dnl #
941 dnl # Linux 3.13 API change
942 dnl # Added delegated inode
943 dnl #
944 AC_MSG_CHECKING([whether vfs_unlink() wants 3 args])
945 SPL_LINUX_TRY_COMPILE([
946 #include <linux/fs.h>
947 ],[
948 vfs_unlink((struct inode *) NULL,
949 (struct dentry *) NULL,
950 (struct inode **) NULL);
951 ],[
952 AC_MSG_RESULT(yes)
953 AC_DEFINE(HAVE_3ARGS_VFS_UNLINK, 1,
954 [vfs_unlink() wants 3 args])
955 ],[
956 AC_MSG_ERROR(no)
957 ])
958
959 ])
960 ])
961
962 dnl #
963 dnl # 3.13 and 3.15 API changes
964 dnl # Added delegated inode and flags argument.
965 dnl #
966 AC_DEFUN([SPL_AC_4ARGS_VFS_RENAME],
967 [AC_MSG_CHECKING([whether vfs_rename() wants 4 args])
968 SPL_LINUX_TRY_COMPILE([
969 #include <linux/fs.h>
970 ],[
971 vfs_rename((struct inode *) NULL, (struct dentry *) NULL,
972 (struct inode *) NULL, (struct dentry *) NULL);
973 ],[
974 AC_MSG_RESULT(yes)
975 AC_DEFINE(HAVE_4ARGS_VFS_RENAME, 1,
976 [vfs_rename() wants 4 args])
977 ],[
978 AC_MSG_RESULT(no)
979 dnl #
980 dnl # Linux 3.13 API change
981 dnl # Added delegated inode
982 dnl #
983 AC_MSG_CHECKING([whether vfs_rename() wants 5 args])
984 SPL_LINUX_TRY_COMPILE([
985 #include <linux/fs.h>
986 ],[
987 vfs_rename((struct inode *) NULL,
988 (struct dentry *) NULL,
989 (struct inode *) NULL,
990 (struct dentry *) NULL,
991 (struct inode **) NULL);
992 ],[
993 AC_MSG_RESULT(yes)
994 AC_DEFINE(HAVE_5ARGS_VFS_RENAME, 1,
995 [vfs_rename() wants 5 args])
996 ],[
997 AC_MSG_RESULT(no)
998 dnl #
999 dnl # Linux 3.15 API change
1000 dnl # Added flags
1001 dnl #
1002 AC_MSG_CHECKING([whether vfs_rename() wants 6 args])
1003 SPL_LINUX_TRY_COMPILE([
1004 #include <linux/fs.h>
1005 ],[
1006 vfs_rename((struct inode *) NULL,
1007 (struct dentry *) NULL,
1008 (struct inode *) NULL,
1009 (struct dentry *) NULL,
1010 (struct inode **) NULL,
1011 (unsigned int) 0);
1012 ],[
1013 AC_MSG_RESULT(yes)
1014 AC_DEFINE(HAVE_6ARGS_VFS_RENAME, 1,
1015 [vfs_rename() wants 6 args])
1016 ],[
1017 AC_MSG_ERROR(no)
1018 ])
1019 ])
1020 ])
1021 ])
1022
1023 dnl #
1024 dnl # 2.6.36 API change,
1025 dnl # The 'struct fs_struct->lock' was changed from a rwlock_t to
1026 dnl # a spinlock_t to improve the fastpath performance.
1027 dnl #
1028 AC_DEFUN([SPL_AC_FS_STRUCT_SPINLOCK], [
1029 AC_MSG_CHECKING([whether struct fs_struct uses spinlock_t])
1030 tmp_flags="$EXTRA_KCFLAGS"
1031 EXTRA_KCFLAGS="-Werror"
1032 SPL_LINUX_TRY_COMPILE([
1033 #include <linux/sched.h>
1034 #include <linux/fs_struct.h>
1035 ],[
1036 static struct fs_struct fs;
1037 spin_lock_init(&fs.lock);
1038 ],[
1039 AC_MSG_RESULT(yes)
1040 AC_DEFINE(HAVE_FS_STRUCT_SPINLOCK, 1,
1041 [struct fs_struct uses spinlock_t])
1042 ],[
1043 AC_MSG_RESULT(no)
1044 ])
1045 EXTRA_KCFLAGS="$tmp_flags"
1046 ])
1047
1048 dnl #
1049 dnl # User namespaces, use kuid_t in place of uid_t
1050 dnl # where available. Not strictly a user namespaces thing
1051 dnl # but it should prevent surprises
1052 dnl #
1053 AC_DEFUN([SPL_AC_KUIDGID_T], [
1054 AC_MSG_CHECKING([whether kuid_t/kgid_t is available])
1055 SPL_LINUX_TRY_COMPILE([
1056 #include <linux/uidgid.h>
1057 ], [
1058 kuid_t userid = KUIDT_INIT(0);
1059 kgid_t groupid = KGIDT_INIT(0);
1060 ],[
1061 SPL_LINUX_TRY_COMPILE([
1062 #include <linux/uidgid.h>
1063 ], [
1064 kuid_t userid = 0;
1065 kgid_t groupid = 0;
1066 ],[
1067 AC_MSG_RESULT(yes; optional)
1068 ],[
1069 AC_MSG_RESULT(yes; mandatory)
1070 AC_DEFINE(HAVE_KUIDGID_T, 1, [kuid_t/kgid_t in use])
1071 ])
1072 ],[
1073 AC_MSG_RESULT(no)
1074 ])
1075 ])
1076
1077 dnl #
1078 dnl # 2.6.39 API change,
1079 dnl # __put_task_struct() was exported by the mainline kernel.
1080 dnl #
1081 AC_DEFUN([SPL_AC_PUT_TASK_STRUCT],
1082 [AC_MSG_CHECKING([whether __put_task_struct() is available])
1083 SPL_LINUX_TRY_COMPILE_SYMBOL([
1084 #include <linux/sched.h>
1085 ], [
1086 __put_task_struct(NULL);
1087 ], [__put_task_struct], [], [
1088 AC_MSG_RESULT(yes)
1089 AC_DEFINE(HAVE_PUT_TASK_STRUCT, 1,
1090 [__put_task_struct() is available])
1091 ], [
1092 AC_MSG_RESULT(no)
1093 ])
1094 ])
1095
1096 dnl #
1097 dnl # 2.6.35 API change,
1098 dnl # Unused 'struct dentry *' removed from vfs_fsync() prototype.
1099 dnl #
1100 AC_DEFUN([SPL_AC_2ARGS_VFS_FSYNC], [
1101 AC_MSG_CHECKING([whether vfs_fsync() wants 2 args])
1102 SPL_LINUX_TRY_COMPILE([
1103 #include <linux/fs.h>
1104 ],[
1105 vfs_fsync(NULL, 0);
1106 ],[
1107 AC_MSG_RESULT(yes)
1108 AC_DEFINE(HAVE_2ARGS_VFS_FSYNC, 1, [vfs_fsync() wants 2 args])
1109 ],[
1110 AC_MSG_RESULT(no)
1111 ])
1112 ])
1113
1114 dnl #
1115 dnl # 3.5 API change,
1116 dnl # inode_operations.truncate_range removed
1117 dnl #
1118 AC_DEFUN([SPL_AC_INODE_TRUNCATE_RANGE], [
1119 AC_MSG_CHECKING([whether truncate_range() inode operation is available])
1120 SPL_LINUX_TRY_COMPILE([
1121 #include <linux/fs.h>
1122 ],[
1123 struct inode_operations ops;
1124 ops.truncate_range = NULL;
1125 ],[
1126 AC_MSG_RESULT(yes)
1127 AC_DEFINE(HAVE_INODE_TRUNCATE_RANGE, 1,
1128 [truncate_range() inode operation is available])
1129 ],[
1130 AC_MSG_RESULT(no)
1131 ])
1132 ])
1133
1134 dnl #
1135 dnl # Linux 2.6.38 - 3.x API
1136 dnl #
1137 AC_DEFUN([SPL_AC_KERNEL_FILE_FALLOCATE], [
1138 AC_MSG_CHECKING([whether fops->fallocate() exists])
1139 SPL_LINUX_TRY_COMPILE([
1140 #include <linux/fs.h>
1141 ],[
1142 long (*fallocate) (struct file *, int, loff_t, loff_t) = NULL;
1143 struct file_operations fops __attribute__ ((unused)) = {
1144 .fallocate = fallocate,
1145 };
1146 ],[
1147 AC_MSG_RESULT(yes)
1148 AC_DEFINE(HAVE_FILE_FALLOCATE, 1, [fops->fallocate() exists])
1149 ],[
1150 AC_MSG_RESULT(no)
1151 ])
1152 ])
1153
1154 dnl #
1155 dnl # Linux 2.6.x - 2.6.37 API
1156 dnl #
1157 AC_DEFUN([SPL_AC_KERNEL_INODE_FALLOCATE], [
1158 AC_MSG_CHECKING([whether iops->fallocate() exists])
1159 SPL_LINUX_TRY_COMPILE([
1160 #include <linux/fs.h>
1161 ],[
1162 long (*fallocate) (struct inode *, int, loff_t, loff_t) = NULL;
1163 struct inode_operations fops __attribute__ ((unused)) = {
1164 .fallocate = fallocate,
1165 };
1166 ],[
1167 AC_MSG_RESULT(yes)
1168 AC_DEFINE(HAVE_INODE_FALLOCATE, 1, [fops->fallocate() exists])
1169 ],[
1170 AC_MSG_RESULT(no)
1171 ])
1172 ])
1173
1174 dnl #
1175 dnl # PaX Linux 2.6.38 - 3.x API
1176 dnl #
1177 AC_DEFUN([SPL_AC_PAX_KERNEL_FILE_FALLOCATE], [
1178 AC_MSG_CHECKING([whether fops->fallocate() exists])
1179 SPL_LINUX_TRY_COMPILE([
1180 #include <linux/fs.h>
1181 ],[
1182 long (*fallocate) (struct file *, int, loff_t, loff_t) = NULL;
1183 struct file_operations_no_const fops __attribute__ ((unused)) = {
1184 .fallocate = fallocate,
1185 };
1186 ],[
1187 AC_MSG_RESULT(yes)
1188 AC_DEFINE(HAVE_FILE_FALLOCATE, 1, [fops->fallocate() exists])
1189 ],[
1190 AC_MSG_RESULT(no)
1191 ])
1192 ])
1193
1194 dnl #
1195 dnl # The fallocate callback was moved from the inode_operations
1196 dnl # structure to the file_operations structure.
1197 dnl #
1198 AC_DEFUN([SPL_AC_KERNEL_FALLOCATE], [
1199 SPL_AC_KERNEL_FILE_FALLOCATE
1200 SPL_AC_KERNEL_INODE_FALLOCATE
1201 SPL_AC_PAX_KERNEL_FILE_FALLOCATE
1202 ])
1203
1204 dnl #
1205 dnl # 2.6.33 API change. Also backported in RHEL5 as of 2.6.18-190.el5.
1206 dnl # Earlier versions of rwsem_is_locked() were inline and had a race
1207 dnl # condition. The fixed version is exported as a symbol. The race
1208 dnl # condition is fixed by acquiring sem->wait_lock, so we must not
1209 dnl # call that version while holding sem->wait_lock.
1210 dnl #
1211 AC_DEFUN([SPL_AC_EXPORTED_RWSEM_IS_LOCKED],
1212 [AC_MSG_CHECKING([whether rwsem_is_locked() acquires sem->wait_lock])
1213 SPL_LINUX_TRY_COMPILE_SYMBOL([
1214 #include <linux/rwsem.h>
1215 int rwsem_is_locked(struct rw_semaphore *sem) { return 0; }
1216 ], [], [rwsem_is_locked], [lib/rwsem-spinlock.c], [
1217 AC_MSG_RESULT(yes)
1218 AC_DEFINE(RWSEM_IS_LOCKED_TAKES_WAIT_LOCK, 1,
1219 [rwsem_is_locked() acquires sem->wait_lock])
1220 ], [
1221 AC_MSG_RESULT(no)
1222 ])
1223 ])
1224
1225 dnl #
1226 dnl # zlib inflate compat,
1227 dnl # Verify the kernel has CONFIG_ZLIB_INFLATE support enabled.
1228 dnl #
1229 AC_DEFUN([SPL_AC_CONFIG_ZLIB_INFLATE], [
1230 AC_MSG_CHECKING([whether CONFIG_ZLIB_INFLATE is defined])
1231 SPL_LINUX_TRY_COMPILE([
1232 #if !defined(CONFIG_ZLIB_INFLATE) && \
1233 !defined(CONFIG_ZLIB_INFLATE_MODULE)
1234 #error CONFIG_ZLIB_INFLATE not defined
1235 #endif
1236 ],[ ],[
1237 AC_MSG_RESULT([yes])
1238 ],[
1239 AC_MSG_RESULT([no])
1240 AC_MSG_ERROR([
1241 *** This kernel does not include the required zlib inflate support.
1242 *** Rebuild the kernel with CONFIG_ZLIB_INFLATE=y|m set.])
1243 ])
1244 ])
1245
1246 dnl #
1247 dnl # zlib deflate compat,
1248 dnl # Verify the kernel has CONFIG_ZLIB_DEFLATE support enabled.
1249 dnl #
1250 AC_DEFUN([SPL_AC_CONFIG_ZLIB_DEFLATE], [
1251 AC_MSG_CHECKING([whether CONFIG_ZLIB_DEFLATE is defined])
1252 SPL_LINUX_TRY_COMPILE([
1253 #if !defined(CONFIG_ZLIB_DEFLATE) && \
1254 !defined(CONFIG_ZLIB_DEFLATE_MODULE)
1255 #error CONFIG_ZLIB_DEFLATE not defined
1256 #endif
1257 ],[ ],[
1258 AC_MSG_RESULT([yes])
1259 ],[
1260 AC_MSG_RESULT([no])
1261 AC_MSG_ERROR([
1262 *** This kernel does not include the required zlib deflate support.
1263 *** Rebuild the kernel with CONFIG_ZLIB_DEFLATE=y|m set.])
1264 ])
1265 ])
1266
1267 dnl #
1268 dnl # 2.6.39 API compat,
1269 dnl # The function zlib_deflate_workspacesize() now take 2 arguments.
1270 dnl # This was done to avoid always having to allocate the maximum size
1271 dnl # workspace (268K). The caller can now specific the windowBits and
1272 dnl # memLevel compression parameters to get a smaller workspace.
1273 dnl #
1274 AC_DEFUN([SPL_AC_2ARGS_ZLIB_DEFLATE_WORKSPACESIZE],
1275 [AC_MSG_CHECKING([whether zlib_deflate_workspacesize() wants 2 args])
1276 SPL_LINUX_TRY_COMPILE([
1277 #include <linux/zlib.h>
1278 ],[
1279 return zlib_deflate_workspacesize(MAX_WBITS, MAX_MEM_LEVEL);
1280 ],[
1281 AC_MSG_RESULT(yes)
1282 AC_DEFINE(HAVE_2ARGS_ZLIB_DEFLATE_WORKSPACESIZE, 1,
1283 [zlib_deflate_workspacesize() wants 2 args])
1284 ],[
1285 AC_MSG_RESULT(no)
1286 ])
1287 ])
1288
1289 dnl #
1290 dnl # 2.6.39 API change,
1291 dnl # Shrinker adjust to use common shrink_control structure.
1292 dnl #
1293 AC_DEFUN([SPL_AC_SHRINK_CONTROL_STRUCT], [
1294 AC_MSG_CHECKING([whether struct shrink_control exists])
1295 SPL_LINUX_TRY_COMPILE([
1296 #include <linux/mm.h>
1297 ],[
1298 struct shrink_control sc __attribute__ ((unused));
1299
1300 sc.nr_to_scan = 0;
1301 sc.gfp_mask = GFP_KERNEL;
1302 ],[
1303 AC_MSG_RESULT(yes)
1304 AC_DEFINE(HAVE_SHRINK_CONTROL_STRUCT, 1,
1305 [struct shrink_control exists])
1306 ],[
1307 AC_MSG_RESULT(no)
1308 ])
1309 ])
1310
1311 dnl #
1312 dnl # 3.1 API Change
1313 dnl #
1314 dnl # The rw_semaphore.wait_lock member was changed from spinlock_t to
1315 dnl # raw_spinlock_t at commit ddb6c9b58a19edcfac93ac670b066c836ff729f1.
1316 dnl #
1317 AC_DEFUN([SPL_AC_RWSEM_SPINLOCK_IS_RAW], [
1318 AC_MSG_CHECKING([whether struct rw_semaphore member wait_lock is raw])
1319 tmp_flags="$EXTRA_KCFLAGS"
1320 EXTRA_KCFLAGS="-Werror"
1321 SPL_LINUX_TRY_COMPILE([
1322 #include <linux/rwsem.h>
1323 ],[
1324 struct rw_semaphore dummy_semaphore __attribute__ ((unused));
1325 raw_spinlock_t dummy_lock __attribute__ ((unused));
1326 dummy_semaphore.wait_lock = dummy_lock;
1327 ],[
1328 AC_MSG_RESULT(yes)
1329 AC_DEFINE(RWSEM_SPINLOCK_IS_RAW, 1,
1330 [struct rw_semaphore member wait_lock is raw_spinlock_t])
1331 ],[
1332 AC_MSG_RESULT(no)
1333 ])
1334 EXTRA_KCFLAGS="$tmp_flags"
1335 ])
1336
1337 dnl #
1338 dnl # 3.9 API change,
1339 dnl # Moved things from linux/sched.h to linux/sched/rt.h
1340 dnl #
1341 AC_DEFUN([SPL_AC_SCHED_RT_HEADER],
1342 [AC_MSG_CHECKING([whether header linux/sched/rt.h exists])
1343 SPL_LINUX_TRY_COMPILE([
1344 #include <linux/sched.h>
1345 #include <linux/sched/rt.h>
1346 ],[
1347 return 0;
1348 ],[
1349 AC_DEFINE(HAVE_SCHED_RT_HEADER, 1, [linux/sched/rt.h exists])
1350 AC_MSG_RESULT(yes)
1351 ],[
1352 AC_MSG_RESULT(no)
1353 ])
1354 ])
1355
1356 dnl #
1357 dnl # 3.9 API change,
1358 dnl # vfs_getattr() uses 2 args
1359 dnl # It takes struct path * instead of struct vfsmount * and struct dentry *
1360 dnl #
1361 AC_DEFUN([SPL_AC_2ARGS_VFS_GETATTR], [
1362 AC_MSG_CHECKING([whether vfs_getattr() wants])
1363 SPL_LINUX_TRY_COMPILE([
1364 #include <linux/fs.h>
1365 ],[
1366 vfs_getattr((struct path *) NULL,
1367 (struct kstat *)NULL);
1368 ],[
1369 AC_MSG_RESULT(2 args)
1370 AC_DEFINE(HAVE_2ARGS_VFS_GETATTR, 1,
1371 [vfs_getattr wants 2 args])
1372 ],[
1373 SPL_LINUX_TRY_COMPILE([
1374 #include <linux/fs.h>
1375 ],[
1376 vfs_getattr((struct vfsmount *)NULL,
1377 (struct dentry *)NULL,
1378 (struct kstat *)NULL);
1379 ],[
1380 AC_MSG_RESULT(3 args)
1381 ],[
1382 AC_MSG_ERROR(unknown)
1383 ])
1384 ])
1385 ])
1386
1387 dnl #
1388 dnl # 2.6.36 API compatibility.
1389 dnl # Added usleep_range timer.
1390 dnl # usleep_range is a finer precision implementation of msleep
1391 dnl # designed to be a drop-in replacement for udelay where a precise
1392 dnl # sleep / busy-wait is unnecessary.
1393 dnl #
1394 AC_DEFUN([SPL_AC_USLEEP_RANGE], [
1395 AC_MSG_CHECKING([whether usleep_range() is available])
1396 SPL_LINUX_TRY_COMPILE([
1397 #include <linux/delay.h>
1398 ],[
1399 usleep_range(0, 0);
1400 ],[
1401 AC_MSG_RESULT(yes)
1402 AC_DEFINE(HAVE_USLEEP_RANGE, 1,
1403 [usleep_range is available])
1404 ],[
1405 AC_MSG_RESULT(no)
1406 ])
1407 ])
1408
1409 dnl #
1410 dnl # 2.6.35 API change,
1411 dnl # The cachep->gfpflags member was renamed cachep->allocflags. These are
1412 dnl # private allocation flags which are applied when allocating a new slab
1413 dnl # in kmem_getpages(). Unfortunately there is no public API for setting
1414 dnl # non-default flags.
1415 dnl #
1416 AC_DEFUN([SPL_AC_KMEM_CACHE_ALLOCFLAGS], [
1417 AC_MSG_CHECKING([whether struct kmem_cache has allocflags])
1418 SPL_LINUX_TRY_COMPILE([
1419 #include <linux/slab.h>
1420 ],[
1421 struct kmem_cache cachep __attribute__ ((unused));
1422 cachep.allocflags = GFP_KERNEL;
1423 ],[
1424 AC_MSG_RESULT(yes)
1425 AC_DEFINE(HAVE_KMEM_CACHE_ALLOCFLAGS, 1,
1426 [struct kmem_cache has allocflags])
1427 ],[
1428 AC_MSG_RESULT(no)
1429
1430 AC_MSG_CHECKING([whether struct kmem_cache has gfpflags])
1431 SPL_LINUX_TRY_COMPILE([
1432 #include <linux/slab.h>
1433 ],[
1434 struct kmem_cache cachep __attribute__ ((unused));
1435 cachep.gfpflags = GFP_KERNEL;
1436 ],[
1437 AC_MSG_RESULT(yes)
1438 AC_DEFINE(HAVE_KMEM_CACHE_GFPFLAGS, 1,
1439 [struct kmem_cache has gfpflags])
1440 ],[
1441 AC_MSG_RESULT(no)
1442 ])
1443 ])
1444 ])
1445
1446 dnl #
1447 dnl # 3.17 API change,
1448 dnl # wait_on_bit() no longer requires an action argument. The former
1449 dnl # "wait_on_bit" interface required an 'action' function to be provided
1450 dnl # which does the actual waiting. There were over 20 such functions in the
1451 dnl # kernel, many of them identical, though most cases can be satisfied by one
1452 dnl # of just two functions: one which uses io_schedule() and one which just
1453 dnl # uses schedule(). This API change was made to consolidate all of those
1454 dnl # redundant wait functions.
1455 dnl #
1456 AC_DEFUN([SPL_AC_WAIT_ON_BIT], [
1457 AC_MSG_CHECKING([whether wait_on_bit() takes an action])
1458 SPL_LINUX_TRY_COMPILE([
1459 #include <linux/wait.h>
1460 ],[
1461 int (*action)(void *) = NULL;
1462 wait_on_bit(NULL, 0, action, 0);
1463 ],[
1464 AC_MSG_RESULT(yes)
1465 AC_DEFINE(HAVE_WAIT_ON_BIT_ACTION, 1, [yes])
1466 ],[
1467 AC_MSG_RESULT(no)
1468 ])
1469 ])