config/spl-build.m4

   1 ###############################################################################
   2 # Copyright (C) 2007-2010 Lawrence Livermore National Security, LLC.
   3 # Copyright (C) 2007 The Regents of the University of California.
   4 # Written by Brian Behlendorf <behlendorf1@llnl.gov>.
   5 ###############################################################################
   6 # SPL_AC_CONFIG_KERNEL: Default SPL kernel configuration.
   7 ###############################################################################
   8
   9 AC_DEFUN([SPL_AC_CONFIG_KERNEL], [
  10         SPL_AC_KERNEL
  11
  12         if test "${LINUX_OBJ}" != "${LINUX}"; then
  13                 KERNELMAKE_PARAMS="$KERNELMAKE_PARAMS O=$LINUX_OBJ"
  14         fi
  15         AC_SUBST(KERNELMAKE_PARAMS)
  16
  17         KERNELCPPFLAGS="$KERNELCPPFLAGS -Wstrict-prototypes"
  18         AC_SUBST(KERNELCPPFLAGS)
  19
  20         SPL_AC_DEBUG
  21         SPL_AC_DEBUG_LOG
  22         SPL_AC_DEBUG_KMEM
  23         SPL_AC_DEBUG_KMEM_TRACKING
  24         SPL_AC_TEST_MODULE
  25         SPL_AC_ATOMIC_SPINLOCK
  26         SPL_AC_TYPE_ATOMIC64_CMPXCHG
  27         SPL_AC_TYPE_ATOMIC64_XCHG
  28         SPL_AC_TYPE_UINTPTR_T
  29         SPL_AC_3ARGS_INIT_WORK
  30         SPL_AC_2ARGS_REGISTER_SYSCTL
  31         SPL_AC_SET_SHRINKER
  32         SPL_AC_3ARGS_SHRINKER_CALLBACK
  33         SPL_AC_PATH_IN_NAMEIDATA
  34         SPL_AC_TASK_CURR
  35         SPL_AC_CTL_UNNUMBERED
  36         SPL_AC_CTL_NAME
  37         SPL_AC_FLS64
  38         SPL_AC_DEVICE_CREATE
  39         SPL_AC_5ARGS_DEVICE_CREATE
  40         SPL_AC_CLASS_DEVICE_CREATE
  41         SPL_AC_SET_NORMALIZED_TIMESPEC_EXPORT
  42         SPL_AC_SET_NORMALIZED_TIMESPEC_INLINE
  43         SPL_AC_TIMESPEC_SUB
  44         SPL_AC_INIT_UTSNAME
  45         SPL_AC_UACCESS_HEADER
  46         SPL_AC_KMALLOC_NODE
  47         SPL_AC_MONOTONIC_CLOCK
  48         SPL_AC_INODE_I_MUTEX
  49         SPL_AC_MUTEX_OWNER
  50         SPL_AC_MUTEX_OWNER_TASK_STRUCT
  51         SPL_AC_MUTEX_LOCK_NESTED
  52         SPL_AC_3ARGS_ON_EACH_CPU
  53         SPL_AC_KALLSYMS_LOOKUP_NAME
  54         SPL_AC_GET_VMALLOC_INFO
  55         SPL_AC_PGDAT_HELPERS
  56         SPL_AC_FIRST_ONLINE_PGDAT
  57         SPL_AC_NEXT_ONLINE_PGDAT
  58         SPL_AC_NEXT_ZONE
  59         SPL_AC_PGDAT_LIST
  60         SPL_AC_GLOBAL_PAGE_STATE
  61         SPL_AC_ZONE_STAT_ITEM_FREE
  62         SPL_AC_ZONE_STAT_ITEM_INACTIVE
  63         SPL_AC_ZONE_STAT_ITEM_ACTIVE
  64         SPL_AC_GET_ZONE_COUNTS
  65         SPL_AC_USER_PATH_DIR
  66         SPL_AC_SET_FS_PWD
  67         SPL_AC_2ARGS_SET_FS_PWD
  68         SPL_AC_2ARGS_VFS_UNLINK
  69         SPL_AC_4ARGS_VFS_RENAME
  70         SPL_AC_VFS_FSYNC
  71         SPL_AC_2ARGS_VFS_FSYNC
  72         SPL_AC_INODE_TRUNCATE_RANGE
  73         SPL_AC_FS_STRUCT_SPINLOCK
  74         SPL_AC_CRED_STRUCT
  75         SPL_AC_GROUPS_SEARCH
  76         SPL_AC_PUT_TASK_STRUCT
  77         SPL_AC_5ARGS_PROC_HANDLER
  78         SPL_AC_KVASPRINTF
  79         SPL_AC_EXPORTED_RWSEM_IS_LOCKED
  80         SPL_AC_KERNEL_INVALIDATE_INODES
  81         SPL_AC_KERNEL_2ARGS_INVALIDATE_INODES
  82         SPL_AC_SHRINK_DCACHE_MEMORY
  83         SPL_AC_SHRINK_ICACHE_MEMORY
  84         SPL_AC_KERN_PATH_PARENT_HEADER
  85         SPL_AC_KERN_PATH_PARENT_SYMBOL
  86         SPL_AC_KERN_PATH_LOCKED
  87         SPL_AC_2ARGS_ZLIB_DEFLATE_WORKSPACESIZE
  88         SPL_AC_SHRINK_CONTROL_STRUCT
  89         SPL_AC_RWSEM_SPINLOCK_IS_RAW
  90 ])
  91
  92 AC_DEFUN([SPL_AC_MODULE_SYMVERS], [
  93         modpost=$LINUX/scripts/Makefile.modpost
  94         AC_MSG_CHECKING([kernel file name for module symbols])
  95         if test "x$enable_linux_builtin" != xyes -a -f "$modpost"; then
  96                 if grep -q Modules.symvers $modpost; then
  97                         LINUX_SYMBOLS=Modules.symvers
  98                 else
  99                         LINUX_SYMBOLS=Module.symvers
 100                 fi
 101
 102                 if ! test -f "$LINUX_OBJ/$LINUX_SYMBOLS"; then
 103                         AC_MSG_ERROR([
 104         *** Please make sure the kernel devel package for your distribution
 105         *** is installed.  If your building with a custom kernel make sure the
 106         *** kernel is configured, built, and the '--with-linux=PATH' configure
 107         *** option refers to the location of the kernel source.])
 108                 fi
 109         else
 110                 LINUX_SYMBOLS=NONE
 111         fi
 112         AC_MSG_RESULT($LINUX_SYMBOLS)
 113         AC_SUBST(LINUX_SYMBOLS)
 114 ])
 115
 116 AC_DEFUN([SPL_AC_KERNEL], [
 117         AC_ARG_WITH([linux],
 118                 AS_HELP_STRING([--with-linux=PATH],
 119                 [Path to kernel source]),
 120                 [kernelsrc="$withval"])
 121
 122         AC_ARG_WITH([linux-obj],
 123                 AS_HELP_STRING([--with-linux-obj=PATH],
 124                 [Path to kernel build objects]),
 125                 [kernelbuild="$withval"])
 126
 127         AC_MSG_CHECKING([kernel source directory])
 128         if test -z "$kernelsrc"; then
 129                 if test -e "/lib/modules/$(uname -r)/source"; then
 130                         headersdir="/lib/modules/$(uname -r)/source"
 131                         sourcelink=$(readlink -f "$headersdir")
 132                 elif test -e "/lib/modules/$(uname -r)/build"; then
 133                         headersdir="/lib/modules/$(uname -r)/build"
 134                         sourcelink=$(readlink -f "$headersdir")
 135                 else
 136                         sourcelink=$(ls -1d /usr/src/kernels/* \
 137                                      /usr/src/linux-* \
 138                                      2>/dev/null | grep -v obj | tail -1)
 139                 fi
 140
 141                 if test -n "$sourcelink" && test -e ${sourcelink}; then
 142                         kernelsrc=`readlink -f ${sourcelink}`
 143                 else
 144                         AC_MSG_RESULT([Not found])
 145                         AC_MSG_ERROR([
 146         *** Please make sure the kernel devel package for your distribution
 147         *** is installed then try again.  If that fails you can specify the
 148         *** location of the kernel source with the '--with-linux=PATH' option.])
 149                 fi
 150         else
 151                 if test "$kernelsrc" = "NONE"; then
 152                         kernsrcver=NONE
 153                 fi
 154         fi
 155
 156         AC_MSG_RESULT([$kernelsrc])
 157         AC_MSG_CHECKING([kernel build directory])
 158         if test -z "$kernelbuild"; then
 159                 if test -e "/lib/modules/$(uname -r)/build"; then
 160                         kernelbuild=`readlink -f /lib/modules/$(uname -r)/build`
 161                 elif test -d ${kernelsrc}-obj/${target_cpu}/${target_cpu}; then
 162                         kernelbuild=${kernelsrc}-obj/${target_cpu}/${target_cpu}
 163                 elif test -d ${kernelsrc}-obj/${target_cpu}/default; then
 164                         kernelbuild=${kernelsrc}-obj/${target_cpu}/default
 165                 elif test -d `dirname ${kernelsrc}`/build-${target_cpu}; then
 166                         kernelbuild=`dirname ${kernelsrc}`/build-${target_cpu}
 167                 else
 168                         kernelbuild=${kernelsrc}
 169                 fi
 170         fi
 171         AC_MSG_RESULT([$kernelbuild])
 172
 173         AC_MSG_CHECKING([kernel source version])
 174         utsrelease1=$kernelbuild/include/linux/version.h
 175         utsrelease2=$kernelbuild/include/linux/utsrelease.h
 176         utsrelease3=$kernelbuild/include/generated/utsrelease.h
 177         if test -r $utsrelease1 && fgrep -q UTS_RELEASE $utsrelease1; then
 178                 utsrelease=linux/version.h
 179         elif test -r $utsrelease2 && fgrep -q UTS_RELEASE $utsrelease2; then
 180                 utsrelease=linux/utsrelease.h
 181         elif test -r $utsrelease3 && fgrep -q UTS_RELEASE $utsrelease3; then
 182                 utsrelease=generated/utsrelease.h
 183         fi
 184
 185         if test "$utsrelease"; then
 186                 kernsrcver=`(echo "#include <$utsrelease>";
 187                              echo "kernsrcver=UTS_RELEASE") |
 188                              cpp -I $kernelbuild/include |
 189                              grep "^kernsrcver=" | cut -d \" -f 2`
 190
 191                 if test -z "$kernsrcver"; then
 192                         AC_MSG_RESULT([Not found])
 193                         AC_MSG_ERROR([*** Cannot determine kernel version.])
 194                 fi
 195         else
 196                 AC_MSG_RESULT([Not found])
 197                 if test "x$enable_linux_builtin" != xyes; then
 198                         AC_MSG_ERROR([*** Cannot find UTS_RELEASE definition.])
 199                 else
 200                         AC_MSG_ERROR([
 201         *** Cannot find UTS_RELEASE definition.
 202         *** Please run 'make prepare' inside the kernel source tree.])
 203                 fi
 204         fi
 205
 206         AC_MSG_RESULT([$kernsrcver])
 207
 208         LINUX=${kernelsrc}
 209         LINUX_OBJ=${kernelbuild}
 210         LINUX_VERSION=${kernsrcver}
 211
 212         AC_SUBST(LINUX)
 213         AC_SUBST(LINUX_OBJ)
 214         AC_SUBST(LINUX_VERSION)
 215
 216         SPL_AC_MODULE_SYMVERS
 217 ])
 218
 219 dnl #
 220 dnl # Default SPL user configuration
 221 dnl #
 222 AC_DEFUN([SPL_AC_CONFIG_USER], [])
 223
 224 dnl #
 225 dnl # Check for rpm+rpmbuild to build RPM packages.  If these tools
 226 dnl # are missing it is non-fatal but you will not be able to build
 227 dnl # RPM packages and will be warned if you try too.
 228 dnl #
 229 AC_DEFUN([SPL_AC_RPM], [
 230         RPM=rpm
 231         RPMBUILD=rpmbuild
 232
 233         AC_MSG_CHECKING([whether $RPM is available])
 234         AS_IF([tmp=$($RPM --version 2>/dev/null)], [
 235                 RPM_VERSION=$(echo $tmp | $AWK '/RPM/ { print $[3] }')
 236                 HAVE_RPM=yes
 237                 AC_MSG_RESULT([$HAVE_RPM ($RPM_VERSION)])
 238         ],[
 239                 HAVE_RPM=no
 240                 AC_MSG_RESULT([$HAVE_RPM])
 241         ])
 242
 243         AC_MSG_CHECKING([whether $RPMBUILD is available])
 244         AS_IF([tmp=$($RPMBUILD --version 2>/dev/null)], [
 245                 RPMBUILD_VERSION=$(echo $tmp | $AWK '/RPM/ { print $[3] }')
 246                 HAVE_RPMBUILD=yes
 247                 AC_MSG_RESULT([$HAVE_RPMBUILD ($RPMBUILD_VERSION)])
 248         ],[
 249                 HAVE_RPMBUILD=no
 250                 AC_MSG_RESULT([$HAVE_RPMBUILD])
 251         ])
 252
 253         AC_SUBST(HAVE_RPM)
 254         AC_SUBST(RPM)
 255         AC_SUBST(RPM_VERSION)
 256
 257         AC_SUBST(HAVE_RPMBUILD)
 258         AC_SUBST(RPMBUILD)
 259         AC_SUBST(RPMBUILD_VERSION)
 260 ])
 261
 262 dnl #
 263 dnl # Check for dpkg+dpkg-buildpackage to build DEB packages.  If these
 264 dnl # tools are missing it is non-fatal but you will not be able to build
 265 dnl # DEB packages and will be warned if you try too.
 266 dnl #
 267 AC_DEFUN([SPL_AC_DPKG], [
 268         DPKG=dpkg
 269         DPKGBUILD=dpkg-buildpackage
 270
 271         AC_MSG_CHECKING([whether $DPKG is available])
 272         AS_IF([tmp=$($DPKG --version 2>/dev/null)], [
 273                 DPKG_VERSION=$(echo $tmp | $AWK '/Debian/ { print $[7] }')
 274                 HAVE_DPKG=yes
 275                 AC_MSG_RESULT([$HAVE_DPKG ($DPKG_VERSION)])
 276         ],[
 277                 HAVE_DPKG=no
 278                 AC_MSG_RESULT([$HAVE_DPKG])
 279         ])
 280
 281         AC_MSG_CHECKING([whether $DPKGBUILD is available])
 282         AS_IF([tmp=$($DPKGBUILD --version 2>/dev/null)], [
 283                 DPKGBUILD_VERSION=$(echo $tmp | \
 284                     $AWK '/Debian/ { print $[4] }' | cut -f-4 -d'.')
 285                 HAVE_DPKGBUILD=yes
 286                 AC_MSG_RESULT([$HAVE_DPKGBUILD ($DPKGBUILD_VERSION)])
 287         ],[
 288                 HAVE_DPKGBUILD=no
 289                 AC_MSG_RESULT([$HAVE_DPKGBUILD])
 290         ])
 291
 292         AC_SUBST(HAVE_DPKG)
 293         AC_SUBST(DPKG)
 294         AC_SUBST(DPKG_VERSION)
 295
 296         AC_SUBST(HAVE_DPKGBUILD)
 297         AC_SUBST(DPKGBUILD)
 298         AC_SUBST(DPKGBUILD_VERSION)
 299 ])
 300
 301 dnl #
 302 dnl # Check for pacman+makepkg to build Arch Linux packages.  If these
 303 dnl # tools are missing it is non-fatal but you will not be able to
 304 dnl # build Arch Linux packages and will be warned if you try too.
 305 dnl #
 306 AC_DEFUN([SPL_AC_PACMAN], [
 307         PACMAN=pacman
 308         MAKEPKG=makepkg
 309
 310         AC_MSG_CHECKING([whether $PACMAN is available])
 311         tmp=$($PACMAN --version 2>/dev/null)
 312         AS_IF([test -n "$tmp"], [
 313                 PACMAN_VERSION=$(echo $tmp |
 314                                  $AWK '/Pacman/ { print $[3] }' |
 315                                  $SED 's/^v//')
 316                 HAVE_PACMAN=yes
 317                 AC_MSG_RESULT([$HAVE_PACMAN ($PACMAN_VERSION)])
 318         ],[
 319                 HAVE_PACMAN=no
 320                 AC_MSG_RESULT([$HAVE_PACMAN])
 321         ])
 322
 323         AC_MSG_CHECKING([whether $MAKEPKG is available])
 324         tmp=$($MAKEPKG --version 2>/dev/null)
 325         AS_IF([test -n "$tmp"], [
 326                 MAKEPKG_VERSION=$(echo $tmp | $AWK '/makepkg/ { print $[3] }')
 327                 HAVE_MAKEPKG=yes
 328                 AC_MSG_RESULT([$HAVE_MAKEPKG ($MAKEPKG_VERSION)])
 329         ],[
 330                 HAVE_MAKEPKG=no
 331                 AC_MSG_RESULT([$HAVE_MAKEPKG])
 332         ])
 333
 334         AC_SUBST(HAVE_PACMAN)
 335         AC_SUBST(PACMAN)
 336         AC_SUBST(PACMAN_VERSION)
 337
 338         AC_SUBST(HAVE_MAKEPKG)
 339         AC_SUBST(MAKEPKG)
 340         AC_SUBST(MAKEPKG_VERSION)
 341 ])
 342
 343 dnl #
 344 dnl # Until native packaging for various different packing systems
 345 dnl # can be added the least we can do is attempt to use alien to
 346 dnl # convert the RPM packages to the needed package type.  This is
 347 dnl # a hack but so far it has worked reasonable well.
 348 dnl #
 349 AC_DEFUN([SPL_AC_ALIEN], [
 350         ALIEN=alien
 351
 352         AC_MSG_CHECKING([whether $ALIEN is available])
 353         AS_IF([tmp=$($ALIEN --version 2>/dev/null)], [
 354                 ALIEN_VERSION=$(echo $tmp | $AWK '{ print $[3] }')
 355                 HAVE_ALIEN=yes
 356                 AC_MSG_RESULT([$HAVE_ALIEN ($ALIEN_VERSION)])
 357         ],[
 358                 HAVE_ALIEN=no
 359                 AC_MSG_RESULT([$HAVE_ALIEN])
 360         ])
 361
 362         AC_SUBST(HAVE_ALIEN)
 363         AC_SUBST(ALIEN)
 364         AC_SUBST(ALIEN_VERSION)
 365 ])
 366
 367 dnl #
 368 dnl # Using the VENDOR tag from config.guess set the default
 369 dnl # package type for 'make pkg': (rpm | deb | tgz)
 370 dnl #
 371 AC_DEFUN([SPL_AC_DEFAULT_PACKAGE], [
 372         AC_MSG_CHECKING([linux distribution])
 373         if test -f /etc/toss-release ; then
 374                 VENDOR=toss ;
 375         elif test -f /etc/fedora-release ; then
 376                 VENDOR=fedora ;
 377         elif test -f /etc/redhat-release ; then
 378                 VENDOR=redhat ;
 379         elif test -f /etc/gentoo-release ; then
 380                 VENDOR=gentoo ;
 381         elif test -f /etc/arch-release ; then
 382                 VENDOR=arch ;
 383         elif test -f /etc/SuSE-release ; then
 384                 VENDOR=sles ;
 385         elif test -f /etc/slackware-version ; then
 386                 VENDOR=slackware ;
 387         elif test -f /etc/lunar.release ; then
 388                 VENDOR=lunar ;
 389         elif test -f /etc/lsb-release ; then
 390                 VENDOR=ubuntu ;
 391         elif test -f /etc/debian_version ; then
 392                 VENDOR=debian ;
 393         else
 394                 VENDOR= ;
 395         fi
 396         AC_MSG_RESULT([$VENDOR])
 397         AC_SUBST(VENDOR)
 398
 399         AC_MSG_CHECKING([default package type])
 400         case "$VENDOR" in
 401                 toss)       DEFAULT_PACKAGE=rpm  ;;
 402                 redhat)     DEFAULT_PACKAGE=rpm  ;;
 403                 fedora)     DEFAULT_PACKAGE=rpm  ;;
 404                 gentoo)     DEFAULT_PACKAGE=tgz  ;;
 405                 arch)       DEFAULT_PACKAGE=arch ;;
 406                 sles)       DEFAULT_PACKAGE=rpm  ;;
 407                 slackware)  DEFAULT_PACKAGE=tgz  ;;
 408                 lunar)      DEFAULT_PACKAGE=tgz  ;;
 409                 ubuntu)     DEFAULT_PACKAGE=deb  ;;
 410                 debian)     DEFAULT_PACKAGE=deb  ;;
 411                 *)          DEFAULT_PACKAGE=rpm  ;;
 412         esac
 413
 414         AC_MSG_RESULT([$DEFAULT_PACKAGE])
 415         AC_SUBST(DEFAULT_PACKAGE)
 416 ])
 417
 418 dnl #
 419 dnl # Default SPL user configuration
 420 dnl #
 421 AC_DEFUN([SPL_AC_PACKAGE], [
 422         SPL_AC_DEFAULT_PACKAGE
 423         SPL_AC_RPM
 424         SPL_AC_DPKG
 425         SPL_AC_ALIEN
 426
 427         AS_IF([test "$VENDOR" = "arch"], [SPL_AC_PACMAN])
 428 ])
 429
 430 AC_DEFUN([SPL_AC_LICENSE], [
 431         AC_MSG_CHECKING([spl license])
 432         LICENSE=GPL
 433         AC_MSG_RESULT([$LICENSE])
 434         KERNELCPPFLAGS="${KERNELCPPFLAGS} -DHAVE_GPL_ONLY_SYMBOLS"
 435         AC_SUBST(LICENSE)
 436 ])
 437
 438 AC_DEFUN([SPL_AC_CONFIG], [
 439         SPL_CONFIG=all
 440         AC_ARG_WITH([config],
 441                 AS_HELP_STRING([--with-config=CONFIG],
 442                 [Config file 'kernel|user|all|srpm']),
 443                 [SPL_CONFIG="$withval"])
 444         AC_ARG_ENABLE([linux-builtin],
 445                 [AC_HELP_STRING([--enable-linux-builtin],
 446                 [Configure for builtin in-tree kernel modules @<:@default=no@:>@])],
 447                 [],
 448                 [enable_linux_builtin=no])
 449
 450         AC_MSG_CHECKING([spl config])
 451         AC_MSG_RESULT([$SPL_CONFIG]);
 452         AC_SUBST(SPL_CONFIG)
 453
 454         case "$SPL_CONFIG" in
 455                 kernel) SPL_AC_CONFIG_KERNEL ;;
 456                 user)   SPL_AC_CONFIG_USER   ;;
 457                 all)    SPL_AC_CONFIG_KERNEL
 458                         SPL_AC_CONFIG_USER   ;;
 459                 srpm)                        ;;
 460                 *)
 461                 AC_MSG_RESULT([Error!])
 462                 AC_MSG_ERROR([Bad value "$SPL_CONFIG" for --with-config,
 463                              user kernel|user|all|srpm]) ;;
 464         esac
 465
 466         AM_CONDITIONAL([CONFIG_USER],
 467                        [test "$SPL_CONFIG" = user -o "$SPL_CONFIG" = all])
 468         AM_CONDITIONAL([CONFIG_KERNEL],
 469                        [test "$SPL_CONFIG" = kernel -o "$SPL_CONFIG" = all] &&
 470                        [test "x$enable_linux_builtin" != xyes ])
 471 ])
 472
 473 dnl #
 474 dnl # Enable if the SPL should be compiled with internal debugging enabled.
 475 dnl # By default this support is disabled.
 476 dnl #
 477 AC_DEFUN([SPL_AC_DEBUG], [
 478         AC_MSG_CHECKING([whether debugging is enabled])
 479         AC_ARG_ENABLE([debug],
 480                 [AS_HELP_STRING([--enable-debug],
 481                 [Enable generic debug support @<:@default=no@:>@])],
 482                 [],
 483                 [enable_debug=no])
 484
 485         AS_IF([test "x$enable_debug" = xyes],
 486         [
 487                 KERNELCPPFLAGS="${KERNELCPPFLAGS} -DDEBUG -Werror"
 488                 DEBUG_CFLAGS="-DDEBUG -Werror"
 489                 DEBUG_SPL="_with_debug"
 490         ], [
 491                 KERNELCPPFLAGS="${KERNELCPPFLAGS} -DNDEBUG"
 492                 DEBUG_CFLAGS="-DNDEBUG"
 493                 DEBUG_SPL="_without_debug"
 494         ])
 495
 496         AC_SUBST(DEBUG_CFLAGS)
 497         AC_SUBST(DEBUG_SPL)
 498         AC_MSG_RESULT([$enable_debug])
 499 ])
 500
 501 dnl #
 502 dnl # Enabled by default it provides a basic debug log infrastructure.
 503 dnl # Each subsystem registers itself with a name and logs messages
 504 dnl # using predefined types.  If the debug mask it set to allow the
 505 dnl # message type it will be written to the internal log.  The log
 506 dnl # can be dumped to a file by echoing 1 to the 'dump' proc entry,
 507 dnl # after dumping the log it must be decoded using the spl utility.
 508 dnl #
 509 dnl # echo 1 >/proc/sys/kernel/spl/debug/dump
 510 dnl # spl /tmp/spl-log.xxx.yyy /tmp/spl-log.xxx.yyy.txt
 511 dnl #
 512 AC_DEFUN([SPL_AC_DEBUG_LOG], [
 513         AC_ARG_ENABLE([debug-log],
 514                 [AS_HELP_STRING([--enable-debug-log],
 515                 [Enable basic debug logging @<:@default=yes@:>@])],
 516                 [],
 517                 [enable_debug_log=yes])
 518
 519         AS_IF([test "x$enable_debug_log" = xyes],
 520         [
 521                 KERNELCPPFLAGS="${KERNELCPPFLAGS} -DDEBUG_LOG"
 522                 DEBUG_LOG="_with_debug_log"
 523                 AC_DEFINE([DEBUG_LOG], [1],
 524                 [Define to 1 to enable basic debug logging])
 525         ], [
 526                 DEBUG_LOG="_without_debug_log"
 527         ])
 528
 529         AC_SUBST(DEBUG_LOG)
 530         AC_MSG_CHECKING([whether basic debug logging is enabled])
 531         AC_MSG_RESULT([$enable_debug_log])
 532 ])
 533
 534 dnl #
 535 dnl # Enabled by default it provides a minimal level of memory tracking.
 536 dnl # A total count of bytes allocated is kept for each alloc and free.
 537 dnl # Then at module unload time a report to the console will be printed
 538 dnl # if memory was leaked.  Additionally, /proc/spl/kmem/slab will exist
 539 dnl # and provide an easy way to inspect the kmem based slab.
 540 dnl #
 541 AC_DEFUN([SPL_AC_DEBUG_KMEM], [
 542         AC_ARG_ENABLE([debug-kmem],
 543                 [AS_HELP_STRING([--enable-debug-kmem],
 544                 [Enable basic kmem accounting @<:@default=yes@:>@])],
 545                 [],
 546                 [enable_debug_kmem=yes])
 547
 548         AS_IF([test "x$enable_debug_kmem" = xyes],
 549         [
 550                 KERNELCPPFLAGS="${KERNELCPPFLAGS} -DDEBUG_KMEM"
 551                 DEBUG_KMEM="_with_debug_kmem"
 552                 AC_DEFINE([DEBUG_KMEM], [1],
 553                 [Define to 1 to enable basic kmem accounting])
 554         ], [
 555                 DEBUG_KMEM="_without_debug_kmem"
 556         ])
 557
 558         AC_SUBST(DEBUG_KMEM)
 559         AC_MSG_CHECKING([whether basic kmem accounting is enabled])
 560         AC_MSG_RESULT([$enable_debug_kmem])
 561 ])
 562
 563 dnl #
 564 dnl # Disabled by default it provides detailed memory tracking.  This
 565 dnl # feature also requires --enable-debug-kmem to be set.  When enabled
 566 dnl # not only will total bytes be tracked but also the location of every
 567 dnl # alloc and free.  When the SPL module is unloaded a list of all leaked
 568 dnl # addresses and where they were allocated will be dumped to the console.
 569 dnl # Enabling this feature has a significant impact on performance but it
 570 dnl # makes finding memory leaks pretty straight forward.
 571 dnl #
 572 AC_DEFUN([SPL_AC_DEBUG_KMEM_TRACKING], [
 573         AC_ARG_ENABLE([debug-kmem-tracking],
 574                 [AS_HELP_STRING([--enable-debug-kmem-tracking],
 575                 [Enable detailed kmem tracking  @<:@default=no@:>@])],
 576                 [],
 577                 [enable_debug_kmem_tracking=no])
 578
 579         AS_IF([test "x$enable_debug_kmem_tracking" = xyes],
 580         [
 581                 KERNELCPPFLAGS="${KERNELCPPFLAGS} -DDEBUG_KMEM_TRACKING"
 582                 DEBUG_KMEM_TRACKING="_with_debug_kmem_tracking"
 583                 AC_DEFINE([DEBUG_KMEM_TRACKING], [1],
 584                 [Define to 1 to enable detailed kmem tracking])
 585         ], [
 586                 DEBUG_KMEM_TRACKING="_without_debug_kmem_tracking"
 587         ])
 588
 589         AC_SUBST(DEBUG_KMEM_TRACKING)
 590         AC_MSG_CHECKING([whether detailed kmem tracking is enabled])
 591         AC_MSG_RESULT([$enable_debug_kmem_tracking])
 592 ])
 593
 594 dnl #
 595 dnl # SPL_LINUX_CONFTEST
 596 dnl #
 597 AC_DEFUN([SPL_LINUX_CONFTEST], [
 598 cat confdefs.h - <<_ACEOF >conftest.c
 599 $1
 600 _ACEOF
 601 ])
 602
 603 dnl #
 604 dnl # SPL_LANG_PROGRAM(C)([PROLOGUE], [BODY])
 605 dnl #
 606 m4_define([SPL_LANG_PROGRAM], [
 607 $1
 608 int
 609 main (void)
 610 {
 611 dnl Do *not* indent the following line: there may be CPP directives.
 612 dnl Don't move the `;' right after for the same reason.
 613 $2
 614   ;
 615   return 0;
 616 }
 617 ])
 618
 619 dnl #
 620 dnl # SPL_LINUX_COMPILE_IFELSE / like AC_COMPILE_IFELSE
 621 dnl #
 622 AC_DEFUN([SPL_LINUX_COMPILE_IFELSE], [
 623         m4_ifvaln([$1], [SPL_LINUX_CONFTEST([$1])])
 624         rm -Rf build && mkdir -p build && touch build/conftest.mod.c
 625         echo "obj-m := conftest.o" >build/Makefile
 626         modpost_flag=''
 627         test "x$enable_linux_builtin" = xyes && modpost_flag='modpost=true' # fake modpost stage
 628         AS_IF(
 629                 [AC_TRY_COMMAND(cp conftest.c build && make [$2] -C $LINUX_OBJ EXTRA_CFLAGS="-Werror-implicit-function-declaration $EXTRA_KCFLAGS" $ARCH_UM M=$PWD/build $modpost_flag) >/dev/null && AC_TRY_COMMAND([$3])],
 630                 [$4],
 631                 [_AC_MSG_LOG_CONFTEST m4_ifvaln([$5],[$5])]
 632         )
 633         rm -Rf build
 634 ])
 635
 636 dnl #
 637 dnl # SPL_LINUX_TRY_COMPILE like AC_TRY_COMPILE
 638 dnl #
 639 AC_DEFUN([SPL_LINUX_TRY_COMPILE],
 640         [SPL_LINUX_COMPILE_IFELSE(
 641         [AC_LANG_SOURCE([SPL_LANG_PROGRAM([[$1]], [[$2]])])],
 642         [modules],
 643         [test -s build/conftest.o],
 644         [$3], [$4])
 645 ])
 646
 647 dnl #
 648 dnl # SPL_CHECK_SYMBOL_EXPORT
 649 dnl # check symbol exported or not
 650 dnl #
 651 AC_DEFUN([SPL_CHECK_SYMBOL_EXPORT], [
 652         grep -q -E '[[[:space:]]]$1[[[:space:]]]' \
 653                 $LINUX_OBJ/Module*.symvers 2>/dev/null
 654         rc=$?
 655         if test $rc -ne 0; then
 656                 export=0
 657                 for file in $2; do
 658                         grep -q -E "EXPORT_SYMBOL.*($1)" \
 659                                 "$LINUX_OBJ/$file" 2>/dev/null
 660                         rc=$?
 661                         if test $rc -eq 0; then
 662                                 export=1
 663                                 break;
 664                         fi
 665                 done
 666                 if test $export -eq 0; then :
 667                         $4
 668                 else :
 669                         $3
 670                 fi
 671         else :
 672                 $3
 673         fi
 674 ])
 675
 676 dnl #
 677 dnl # SPL_LINUX_TRY_COMPILE_SYMBOL
 678 dnl # like SPL_LINUX_TRY_COMPILE, except SPL_CHECK_SYMBOL_EXPORT
 679 dnl # is called if not compiling for builtin
 680 dnl #
 681 AC_DEFUN([SPL_LINUX_TRY_COMPILE_SYMBOL], [
 682         SPL_LINUX_TRY_COMPILE([$1], [$2], [rc=0], [rc=1])
 683         if test $rc -ne 0; then :
 684                 $6
 685         else
 686                 if test "x$enable_linux_builtin" != xyes; then
 687                         SPL_CHECK_SYMBOL_EXPORT([$3], [$4], [rc=0], [rc=1])
 688                 fi
 689                 if test $rc -ne 0; then :
 690                         $6
 691                 else :
 692                         $5
 693                 fi
 694         fi
 695 ])
 696
 697 dnl #
 698 dnl # SPL_CHECK_SYMBOL_HEADER
 699 dnl # check if a symbol prototype is defined in listed headers.
 700 dnl #
 701 AC_DEFUN([SPL_CHECK_SYMBOL_HEADER], [
 702         AC_MSG_CHECKING([whether symbol $1 exists in header])
 703         header=0
 704         for file in $3; do
 705                 grep -q "$2" "$LINUX/$file" 2>/dev/null
 706                 rc=$?
 707                 if test $rc -eq 0; then
 708                         header=1
 709                         break;
 710                 fi
 711         done
 712         if test $header -eq 0; then
 713                 AC_MSG_RESULT([no])
 714                 $5
 715         else
 716                 AC_MSG_RESULT([yes])
 717                 $4
 718         fi
 719 ])
 720
 721 dnl #
 722 dnl # SPL_CHECK_HEADER
 723 dnl # check whether header exists and define HAVE_$2_HEADER
 724 dnl #
 725 AC_DEFUN([SPL_CHECK_HEADER],
 726         [AC_MSG_CHECKING([whether header $1 exists])
 727         SPL_LINUX_TRY_COMPILE([
 728                 #include <$1>
 729         ],[
 730                 return 0;
 731         ],[
 732                 AC_DEFINE(HAVE_$2_HEADER, 1, [$1 exists])
 733                 AC_MSG_RESULT(yes)
 734                 $3
 735         ],[
 736                 AC_MSG_RESULT(no)
 737                 $4
 738         ])
 739 ])
 740
 741 dnl #
 742 dnl # Basic toolchain sanity check.
 743 dnl #
 744 AC_DEFUN([SPL_AC_TEST_MODULE],
 745         [AC_MSG_CHECKING([whether modules can be built])
 746         SPL_LINUX_TRY_COMPILE([],[],[
 747                 AC_MSG_RESULT([yes])
 748         ],[
 749                 AC_MSG_RESULT([no])
 750                 if test "x$enable_linux_builtin" != xyes; then
 751                         AC_MSG_ERROR([*** Unable to build an empty module.])
 752                 else
 753                         AC_MSG_ERROR([
 754         *** Unable to build an empty module.
 755         *** Please run 'make scripts' inside the kernel source tree.])
 756                 fi
 757         ])
 758 ])
 759
 760 dnl #
 761 dnl # Use the atomic implemenation based on global spinlocks.  This
 762 dnl # should only be needed by 32-bit kernels which do not provide
 763 dnl # the atomic64_* API.  It may be optionally enabled as a fallback
 764 dnl # if problems are observed with the direct mapping to the native
 765 dnl # Linux atomic operations.  You may not disable atomic spinlocks
 766 dnl # if you kernel does not an atomic64_* API.
 767 dnl #
 768 AC_DEFUN([SPL_AC_ATOMIC_SPINLOCK], [
 769         AC_ARG_ENABLE([atomic-spinlocks],
 770                 [AS_HELP_STRING([--enable-atomic-spinlocks],
 771                 [Atomic types use spinlocks @<:@default=check@:>@])],
 772                 [],
 773                 [enable_atomic_spinlocks=check])
 774
 775         SPL_LINUX_TRY_COMPILE([
 776                 #include <asm/atomic.h>
 777         ],[
 778                 atomic64_t *ptr __attribute__ ((unused));
 779         ],[
 780                 have_atomic64_t=yes
 781                 AC_DEFINE(HAVE_ATOMIC64_T, 1,
 782                         [kernel defines atomic64_t])
 783         ],[
 784                 have_atomic64_t=no
 785         ])
 786
 787         AS_IF([test "x$enable_atomic_spinlocks" = xcheck], [
 788                 AS_IF([test "x$have_atomic64_t" = xyes], [
 789                         enable_atomic_spinlocks=no
 790                 ],[
 791                         enable_atomic_spinlocks=yes
 792                 ])
 793         ])
 794
 795         AS_IF([test "x$enable_atomic_spinlocks" = xyes], [
 796                 AC_DEFINE([ATOMIC_SPINLOCK], [1],
 797                         [Atomic types use spinlocks])
 798         ],[
 799                 AS_IF([test "x$have_atomic64_t" = xno], [
 800                         AC_MSG_FAILURE(
 801                         [--disable-atomic-spinlocks given but required atomic64 support is unavailable])
 802                 ])
 803         ])
 804
 805         AC_MSG_CHECKING([whether atomic types use spinlocks])
 806         AC_MSG_RESULT([$enable_atomic_spinlocks])
 807
 808         AC_MSG_CHECKING([whether kernel defines atomic64_t])
 809         AC_MSG_RESULT([$have_atomic64_t])
 810 ])
 811
 812 dnl #
 813 dnl # 2.6.24 API change,
 814 dnl # check if atomic64_cmpxchg is defined
 815 dnl #
 816 AC_DEFUN([SPL_AC_TYPE_ATOMIC64_CMPXCHG],
 817         [AC_MSG_CHECKING([whether kernel defines atomic64_cmpxchg])
 818         SPL_LINUX_TRY_COMPILE([
 819                 #include <asm/atomic.h>
 820                 #include <asm/system.h>
 821         ],[
 822                 atomic64_cmpxchg((atomic64_t *)NULL, 0, 0);
 823         ],[
 824                 AC_MSG_RESULT([yes])
 825                 AC_DEFINE(HAVE_ATOMIC64_CMPXCHG, 1,
 826                           [kernel defines atomic64_cmpxchg])
 827         ],[
 828                 AC_MSG_RESULT([no])
 829         ])
 830 ])
 831
 832 dnl #
 833 dnl # 2.6.24 API change,
 834 dnl # check if atomic64_xchg is defined
 835 dnl #
 836 AC_DEFUN([SPL_AC_TYPE_ATOMIC64_XCHG],
 837         [AC_MSG_CHECKING([whether kernel defines atomic64_xchg])
 838         SPL_LINUX_TRY_COMPILE([
 839                 #include <asm/atomic.h>
 840         ],[
 841                 atomic64_xchg((atomic64_t *)NULL, 0);
 842         ],[
 843                 AC_MSG_RESULT([yes])
 844                 AC_DEFINE(HAVE_ATOMIC64_XCHG, 1,
 845                           [kernel defines atomic64_xchg])
 846         ],[
 847                 AC_MSG_RESULT([no])
 848         ])
 849 ])
 850
 851 dnl #
 852 dnl # 2.6.24 API change,
 853 dnl # check if uintptr_t typedef is defined
 854 dnl #
 855 AC_DEFUN([SPL_AC_TYPE_UINTPTR_T],
 856         [AC_MSG_CHECKING([whether kernel defines uintptr_t])
 857         SPL_LINUX_TRY_COMPILE([
 858                 #include <linux/types.h>
 859         ],[
 860                 uintptr_t *ptr __attribute__ ((unused));
 861         ],[
 862                 AC_MSG_RESULT([yes])
 863                 AC_DEFINE(HAVE_UINTPTR_T, 1,
 864                           [kernel defines uintptr_t])
 865         ],[
 866                 AC_MSG_RESULT([no])
 867         ])
 868 ])
 869
 870 dnl #
 871 dnl # 2.6.20 API change,
 872 dnl # INIT_WORK use 2 args and not store data inside
 873 dnl #
 874 AC_DEFUN([SPL_AC_3ARGS_INIT_WORK],
 875         [AC_MSG_CHECKING([whether INIT_WORK wants 3 args])
 876         SPL_LINUX_TRY_COMPILE([
 877                 #include <linux/workqueue.h>
 878         ],[
 879                 struct work_struct work __attribute__ ((unused));
 880                 INIT_WORK(&work, NULL, NULL);
 881         ],[
 882                 AC_MSG_RESULT(yes)
 883                 AC_DEFINE(HAVE_3ARGS_INIT_WORK, 1,
 884                           [INIT_WORK wants 3 args])
 885         ],[
 886                 AC_MSG_RESULT(no)
 887         ])
 888 ])
 889
 890 dnl #
 891 dnl # 2.6.21 API change,
 892 dnl # 'register_sysctl_table' use only one argument instead of two
 893 dnl #
 894 AC_DEFUN([SPL_AC_2ARGS_REGISTER_SYSCTL],
 895         [AC_MSG_CHECKING([whether register_sysctl_table() wants 2 args])
 896         SPL_LINUX_TRY_COMPILE([
 897                 #include <linux/sysctl.h>
 898         ],[
 899                 (void) register_sysctl_table(NULL, 0);
 900         ],[
 901                 AC_MSG_RESULT(yes)
 902                 AC_DEFINE(HAVE_2ARGS_REGISTER_SYSCTL, 1,
 903                           [register_sysctl_table() wants 2 args])
 904         ],[
 905                 AC_MSG_RESULT(no)
 906         ])
 907 ])
 908
 909 dnl #
 910 dnl # 2.6.23 API change
 911 dnl # Old set_shrinker API replaced with register_shrinker
 912 dnl #
 913 AC_DEFUN([SPL_AC_SET_SHRINKER], [
 914         AC_MSG_CHECKING([whether set_shrinker() available])
 915         SPL_LINUX_TRY_COMPILE([
 916                 #include <linux/mm.h>
 917         ],[
 918                 return set_shrinker(DEFAULT_SEEKS, NULL);
 919         ],[
 920                 AC_MSG_RESULT([yes])
 921                 AC_DEFINE(HAVE_SET_SHRINKER, 1,
 922                           [set_shrinker() available])
 923         ],[
 924                 AC_MSG_RESULT([no])
 925         ])
 926 ])
 927
 928 dnl #
 929 dnl # 2.6.35 API change,
 930 dnl # Add context to shrinker callback
 931 dnl #
 932 AC_DEFUN([SPL_AC_3ARGS_SHRINKER_CALLBACK],
 933         [AC_MSG_CHECKING([whether shrinker callback wants 3 args])
 934         tmp_flags="$EXTRA_KCFLAGS"
 935         EXTRA_KCFLAGS="-Werror"
 936         SPL_LINUX_TRY_COMPILE([
 937                 #include <linux/mm.h>
 938
 939                 int shrinker_cb(struct shrinker *, int, unsigned int);
 940         ],[
 941                 struct shrinker cache_shrinker = {
 942                         .shrink = shrinker_cb,
 943                         .seeks = DEFAULT_SEEKS,
 944                 };
 945                 register_shrinker(&cache_shrinker);
 946         ],[
 947                 AC_MSG_RESULT(yes)
 948                 AC_DEFINE(HAVE_3ARGS_SHRINKER_CALLBACK, 1,
 949                           [shrinker callback wants 3 args])
 950         ],[
 951                 AC_MSG_RESULT(no)
 952         ])
 953         EXTRA_KCFLAGS="$tmp_flags"
 954 ])
 955
 956 dnl #
 957 dnl # 2.6.25 API change,
 958 dnl # struct path entry added to struct nameidata
 959 dnl #
 960 AC_DEFUN([SPL_AC_PATH_IN_NAMEIDATA],
 961         [AC_MSG_CHECKING([whether struct path used in struct nameidata])
 962         SPL_LINUX_TRY_COMPILE([
 963                 #include <linux/namei.h>
 964         ],[
 965                 struct nameidata nd __attribute__ ((unused));
 966
 967                 nd.path.mnt = NULL;
 968                 nd.path.dentry = NULL;
 969         ],[
 970                 AC_MSG_RESULT(yes)
 971                 AC_DEFINE(HAVE_PATH_IN_NAMEIDATA, 1,
 972                           [struct path used in struct nameidata])
 973         ],[
 974                 AC_MSG_RESULT(no)
 975         ])
 976 ])
 977
 978 dnl #
 979 dnl # Custom SPL patch may export this system it is not required
 980 dnl #
 981 AC_DEFUN([SPL_AC_TASK_CURR],
 982         [AC_MSG_CHECKING([whether task_curr() is available])
 983         SPL_LINUX_TRY_COMPILE_SYMBOL([
 984                 #include <linux/sched.h>
 985         ], [
 986                 task_curr(NULL);
 987         ], [task_curr], [kernel/sched.c], [
 988                 AC_MSG_RESULT(yes)
 989                 AC_DEFINE(HAVE_TASK_CURR, 1, [task_curr() is available])
 990         ], [
 991                 AC_MSG_RESULT(no)
 992         ])
 993 ])
 994
 995 dnl #
 996 dnl # 2.6.19 API change,
 997 dnl # Use CTL_UNNUMBERED when binary sysctl is not required
 998 dnl #
 999 AC_DEFUN([SPL_AC_CTL_UNNUMBERED],
1000         [AC_MSG_CHECKING([whether unnumbered sysctl support exists])
1001         SPL_LINUX_TRY_COMPILE([
1002                 #include <linux/sysctl.h>
1003         ],[
1004                 #ifndef CTL_UNNUMBERED
1005                 #error CTL_UNNUMBERED undefined
1006                 #endif
1007         ],[
1008                 AC_MSG_RESULT(yes)
1009                 AC_DEFINE(HAVE_CTL_UNNUMBERED, 1,
1010                           [unnumbered sysctl support exists])
1011         ],[
1012                 AC_MSG_RESULT(no)
1013         ])
1014 ])
1015
1016 dnl #
1017 dnl # 2.6.33 API change,
1018 dnl # Removed .ctl_name from struct ctl_table.
1019 dnl #
1020 AC_DEFUN([SPL_AC_CTL_NAME], [
1021         AC_MSG_CHECKING([whether struct ctl_table has ctl_name])
1022         SPL_LINUX_TRY_COMPILE([
1023                 #include <linux/sysctl.h>
1024         ],[
1025                 struct ctl_table ctl __attribute__ ((unused));
1026                 ctl.ctl_name = 0;
1027         ],[
1028                 AC_MSG_RESULT(yes)
1029                 AC_DEFINE(HAVE_CTL_NAME, 1, [struct ctl_table has ctl_name])
1030         ],[
1031                 AC_MSG_RESULT(no)
1032         ])
1033 ])
1034
1035 dnl #
1036 dnl # 2.6.16 API change.
1037 dnl # Check if 'fls64()' is available
1038 dnl #
1039 AC_DEFUN([SPL_AC_FLS64],
1040         [AC_MSG_CHECKING([whether fls64() is available])
1041         SPL_LINUX_TRY_COMPILE([
1042                 #include <linux/bitops.h>
1043         ],[
1044                 return fls64(0);
1045         ],[
1046                 AC_MSG_RESULT(yes)
1047                 AC_DEFINE(HAVE_FLS64, 1, [fls64() is available])
1048         ],[
1049                 AC_MSG_RESULT(no)
1050         ])
1051 ])
1052
1053 dnl #
1054 dnl # 2.6.18 API change, check whether device_create() is available.
1055 dnl # Device_create() was introduced in 2.6.18 and depricated
1056 dnl # class_device_create() which was fully removed in 2.6.26.
1057 dnl #
1058 AC_DEFUN([SPL_AC_DEVICE_CREATE],
1059         [AC_MSG_CHECKING([whether device_create() is available])
1060         SPL_CHECK_SYMBOL_EXPORT([device_create], [drivers/base/core.c], [
1061                 AC_MSG_RESULT(yes)
1062                 AC_DEFINE(HAVE_DEVICE_CREATE, 1,
1063                           [device_create() is available])
1064         ], [
1065                 AC_MSG_RESULT(no)
1066         ])
1067 ])
1068
1069 dnl #
1070 dnl # 2.6.27 API change,
1071 dnl # device_create() uses 5 args, new 'drvdata' argument.
1072 dnl #
1073 AC_DEFUN([SPL_AC_5ARGS_DEVICE_CREATE], [
1074         AC_MSG_CHECKING([whether device_create() wants 5 args])
1075         tmp_flags="$EXTRA_KCFLAGS"
1076         EXTRA_KCFLAGS="-Werror"
1077         SPL_LINUX_TRY_COMPILE([
1078                 #include <linux/device.h>
1079         ],[
1080                 device_create(NULL, NULL, 0, NULL, "%d", 1);
1081         ],[
1082                 AC_MSG_RESULT(yes)
1083                 AC_DEFINE(HAVE_5ARGS_DEVICE_CREATE, 1,
1084                           [device_create wants 5 args])
1085         ],[
1086                 AC_MSG_RESULT(no)
1087         ])
1088         EXTRA_KCFLAGS="$tmp_flags"
1089 ])
1090
1091 dnl #
1092 dnl # 2.6.13 API change, check whether class_device_create() is available.
1093 dnl # Class_device_create() was introduced in 2.6.13 and depricated
1094 dnl # class_simple_device_add() which was fully removed in 2.6.13.
1095 dnl #
1096 AC_DEFUN([SPL_AC_CLASS_DEVICE_CREATE],
1097         [AC_MSG_CHECKING([whether class_device_create() is available])
1098         SPL_LINUX_TRY_COMPILE_SYMBOL([
1099                 #include <linux/device.h>
1100         ], [
1101                 class_device_create(NULL, NULL, 0, NULL, NULL);
1102         ], [class_device_create], [drivers/base/class.c], [
1103                 AC_MSG_RESULT(yes)
1104                 AC_DEFINE(HAVE_CLASS_DEVICE_CREATE, 1,
1105                           [class_device_create() is available])
1106         ], [
1107                 AC_MSG_RESULT(no)
1108         ])
1109 ])
1110
1111 dnl #
1112 dnl # 2.6.26 API change, set_normalized_timespec() is exported.
1113 dnl #
1114 AC_DEFUN([SPL_AC_SET_NORMALIZED_TIMESPEC_EXPORT],
1115         [AC_MSG_CHECKING([whether set_normalized_timespec() is available as export])
1116         SPL_LINUX_TRY_COMPILE_SYMBOL([
1117                 #include <linux/time.h>
1118         ], [
1119                 set_normalized_timespec(NULL, 0, 0);
1120         ], [set_normalized_timespec], [kernel/time.c], [
1121                 AC_MSG_RESULT(yes)
1122                 AC_DEFINE(HAVE_SET_NORMALIZED_TIMESPEC_EXPORT, 1,
1123                           [set_normalized_timespec() is available as export])
1124         ], [
1125                 AC_MSG_RESULT(no)
1126         ])
1127 ])
1128
1129 dnl #
1130 dnl # 2.6.16 API change, set_normalize_timespec() moved to time.c
1131 dnl # previously it was available in time.h as an inline.
1132 dnl #
1133 AC_DEFUN([SPL_AC_SET_NORMALIZED_TIMESPEC_INLINE], [
1134         AC_MSG_CHECKING([whether set_normalized_timespec() is an inline])
1135         SPL_LINUX_TRY_COMPILE([
1136                 #include <linux/time.h>
1137                 void set_normalized_timespec(struct timespec *ts,
1138                                              time_t sec, long nsec) { }
1139         ],
1140         [],
1141         [
1142                 AC_MSG_RESULT(no)
1143         ],[
1144                 AC_MSG_RESULT(yes)
1145                 AC_DEFINE(HAVE_SET_NORMALIZED_TIMESPEC_INLINE, 1,
1146                           [set_normalized_timespec() is available as inline])
1147         ])
1148 ])
1149
1150 dnl #
1151 dnl # 2.6.18 API change,
1152 dnl # timespec_sub() inline function available in linux/time.h
1153 dnl #
1154 AC_DEFUN([SPL_AC_TIMESPEC_SUB], [
1155         AC_MSG_CHECKING([whether timespec_sub() is available])
1156         SPL_LINUX_TRY_COMPILE([
1157                 #include <linux/time.h>
1158         ],[
1159                 struct timespec a = { 0 };
1160                 struct timespec b = { 0 };
1161                 struct timespec c __attribute__ ((unused));
1162                 c = timespec_sub(a, b);
1163         ],[
1164                 AC_MSG_RESULT(yes)
1165                 AC_DEFINE(HAVE_TIMESPEC_SUB, 1, [timespec_sub() is available])
1166         ],[
1167                 AC_MSG_RESULT(no)
1168         ])
1169 ])
1170
1171 dnl #
1172 dnl # 2.6.19 API change,
1173 dnl # check if init_utsname() is available in linux/utsname.h
1174 dnl #
1175 AC_DEFUN([SPL_AC_INIT_UTSNAME], [
1176         AC_MSG_CHECKING([whether init_utsname() is available])
1177         SPL_LINUX_TRY_COMPILE([
1178                 #include <linux/utsname.h>
1179         ],[
1180                 struct new_utsname *a __attribute__ ((unused));
1181                 a = init_utsname();
1182         ],[
1183                 AC_MSG_RESULT(yes)
1184                 AC_DEFINE(HAVE_INIT_UTSNAME, 1, [init_utsname() is available])
1185         ],[
1186                 AC_MSG_RESULT(no)
1187         ])
1188 ])
1189
1190 dnl #
1191 dnl # 2.6.18 API change,
1192 dnl # added linux/uaccess.h
1193 dnl #
1194 AC_DEFUN([SPL_AC_UACCESS_HEADER], [
1195         SPL_CHECK_HEADER([linux/uaccess.h], [UACCESS], [], [])
1196 ])
1197
1198 dnl #
1199 dnl # 2.6.12 API change,
1200 dnl # check whether 'kmalloc_node()' is available.
1201 dnl #
1202 AC_DEFUN([SPL_AC_KMALLOC_NODE], [
1203         AC_MSG_CHECKING([whether kmalloc_node() is available])
1204         SPL_LINUX_TRY_COMPILE([
1205                 #include <linux/slab.h>
1206         ],[
1207                 void *a __attribute__ ((unused));
1208                 a = kmalloc_node(1, GFP_KERNEL, 0);
1209         ],[
1210                 AC_MSG_RESULT(yes)
1211                 AC_DEFINE(HAVE_KMALLOC_NODE, 1, [kmalloc_node() is available])
1212         ],[
1213                 AC_MSG_RESULT(no)
1214         ])
1215 ])
1216
1217 dnl #
1218 dnl # 2.6.9 API change,
1219 dnl # check whether 'monotonic_clock()' is available it may
1220 dnl # be available for some archs but not others.
1221 dnl #
1222 AC_DEFUN([SPL_AC_MONOTONIC_CLOCK],
1223         [AC_MSG_CHECKING([whether monotonic_clock() is available])
1224         SPL_LINUX_TRY_COMPILE_SYMBOL([
1225                 #include <linux/timex.h>
1226         ], [
1227                 monotonic_clock();
1228         ], [monotonic_clock], [], [
1229                 AC_MSG_RESULT(yes)
1230                 AC_DEFINE(HAVE_MONOTONIC_CLOCK, 1,
1231                           [monotonic_clock() is available])
1232         ], [
1233                 AC_MSG_RESULT(no)
1234         ])
1235 ])
1236
1237 dnl #
1238 dnl # 2.6.16 API change,
1239 dnl # check whether 'struct inode' has i_mutex
1240 dnl #
1241 AC_DEFUN([SPL_AC_INODE_I_MUTEX], [
1242         AC_MSG_CHECKING([whether struct inode has i_mutex])
1243         SPL_LINUX_TRY_COMPILE([
1244                 #include <linux/fs.h>
1245                 #include <linux/mutex.h>
1246         ],[
1247                 struct inode i;
1248                 mutex_init(&i.i_mutex);
1249         ],[
1250                 AC_MSG_RESULT(yes)
1251                 AC_DEFINE(HAVE_INODE_I_MUTEX, 1, [struct inode has i_mutex])
1252         ],[
1253                 AC_MSG_RESULT(no)
1254         ])
1255 ])
1256
1257 dnl #
1258 dnl # 2.6.29 API change,
1259 dnl # Adaptive mutexs introduced.
1260 dnl #
1261 AC_DEFUN([SPL_AC_MUTEX_OWNER], [
1262         AC_MSG_CHECKING([whether struct mutex has owner])
1263         SPL_LINUX_TRY_COMPILE([
1264                 #include <linux/mutex.h>
1265         ],[
1266                 struct mutex mtx __attribute__ ((unused));
1267                 mtx.owner = NULL;
1268         ],[
1269                 AC_MSG_RESULT(yes)
1270                 AC_DEFINE(HAVE_MUTEX_OWNER, 1, [struct mutex has owner])
1271         ],[
1272                 AC_MSG_RESULT(no)
1273         ])
1274 ])
1275
1276 dnl #
1277 dnl # 2.6.39 API change,
1278 dnl # Owner type change.  A Linux mutex prior to 2.6.39 would store
1279 dnl # the owner as a thread_info pointer when CONFIG_DEBUG_MUTEXES
1280 dnl # was defined.  As of 2.6.39 this was changed to a task_struct
1281 dnl # pointer which frankly makes a lot more sense.
1282 dnl #
1283 AC_DEFUN([SPL_AC_MUTEX_OWNER_TASK_STRUCT], [
1284         AC_MSG_CHECKING([whether struct mutex owner is a task_struct])
1285         tmp_flags="$EXTRA_KCFLAGS"
1286         EXTRA_KCFLAGS="-Werror"
1287         SPL_LINUX_TRY_COMPILE([
1288                 #include <linux/mutex.h>
1289         ],[
1290                 struct mutex mtx __attribute__ ((unused));
1291                 mtx.owner = current;
1292         ],[
1293                 AC_MSG_RESULT(yes)
1294                 AC_DEFINE(HAVE_MUTEX_OWNER_TASK_STRUCT, 1,
1295                 [struct mutex owner is a task_struct])
1296         ],[
1297                 AC_MSG_RESULT(no)
1298         ])
1299         EXTRA_KCFLAGS="$tmp_flags"
1300 ])
1301
1302 dnl #
1303 dnl # 2.6.18 API change,
1304 dnl # First introduced 'mutex_lock_nested()' in include/linux/mutex.h,
1305 dnl # as part of the mutex validator.  Fallback to using 'mutex_lock()'
1306 dnl # if the mutex validator is disabled or otherwise unavailable.
1307 dnl #
1308 AC_DEFUN([SPL_AC_MUTEX_LOCK_NESTED], [
1309         AC_MSG_CHECKING([whether mutex_lock_nested() is available])
1310         SPL_LINUX_TRY_COMPILE([
1311                 #include <linux/mutex.h>
1312         ],[
1313                 struct mutex mutex;
1314                 mutex_init(&mutex);
1315                 mutex_lock_nested(&mutex, 0);
1316         ],[
1317                 AC_MSG_RESULT(yes)
1318                 AC_DEFINE(HAVE_MUTEX_LOCK_NESTED, 1,
1319                 [mutex_lock_nested() is available])
1320         ],[
1321                 AC_MSG_RESULT(no)
1322         ])
1323 ])
1324
1325 dnl #
1326 dnl # 2.6.27 API change,
1327 dnl # on_each_cpu() uses 3 args, no 'retry' argument
1328 dnl #
1329 AC_DEFUN([SPL_AC_3ARGS_ON_EACH_CPU], [
1330         AC_MSG_CHECKING([whether on_each_cpu() wants 3 args])
1331         SPL_LINUX_TRY_COMPILE([
1332                 #include <linux/smp.h>
1333         ],[
1334                 on_each_cpu(NULL, NULL, 0);
1335         ],[
1336                 AC_MSG_RESULT(yes)
1337                 AC_DEFINE(HAVE_3ARGS_ON_EACH_CPU, 1,
1338                           [on_each_cpu wants 3 args])
1339         ],[
1340                 AC_MSG_RESULT(no)
1341         ])
1342 ])
1343
1344 dnl #
1345 dnl # 2.6.18 API change,
1346 dnl # kallsyms_lookup_name no longer exported
1347 dnl #
1348 AC_DEFUN([SPL_AC_KALLSYMS_LOOKUP_NAME],
1349         [AC_MSG_CHECKING([whether kallsyms_lookup_name() is available])
1350         SPL_LINUX_TRY_COMPILE_SYMBOL([
1351                 #include <linux/kallsyms.h>
1352         ], [
1353                 kallsyms_lookup_name(NULL);
1354         ], [kallsyms_lookup_name], [], [
1355                 AC_MSG_RESULT(yes)
1356                 AC_DEFINE(HAVE_KALLSYMS_LOOKUP_NAME, 1,
1357                           [kallsyms_lookup_name() is available])
1358         ], [
1359                 AC_MSG_RESULT(no)
1360         ])
1361 ])
1362
1363 dnl #
1364 dnl # Proposed API change,
1365 dnl # This symbol is not available in stock kernels.  You may build a
1366 dnl # custom kernel with the *-spl-export-symbols.patch which will export
1367 dnl # these symbols for use.  If your already rolling a custom kernel for
1368 dnl # your environment this is recommended.
1369 dnl #
1370 AC_DEFUN([SPL_AC_GET_VMALLOC_INFO],
1371         [AC_MSG_CHECKING([whether get_vmalloc_info() is available])
1372         SPL_CHECK_SYMBOL_EXPORT([get_vmalloc_info], [], [
1373                 AC_MSG_RESULT(yes)
1374                 AC_DEFINE(HAVE_GET_VMALLOC_INFO, 1,
1375                           [get_vmalloc_info() is available])
1376         ], [
1377                 AC_MSG_RESULT(no)
1378         ])
1379 ])
1380
1381 dnl #
1382 dnl # 2.6.17 API change
1383 dnl # The helper functions first_online_pgdat(), next_online_pgdat(), and
1384 dnl # next_zone() are introduced to simplify for_each_zone().  These symbols
1385 dnl # were exported in 2.6.17 for use by modules which was consistent with
1386 dnl # the previous implementation of for_each_zone().  From 2.6.18 - 2.6.19
1387 dnl # the symbols were exported as 'unused', and by 2.6.20 they exports
1388 dnl # were dropped entirely leaving modules no way to directly iterate over
1389 dnl # the zone list.  Because we need access to the zone helpers we check
1390 dnl # if the kernel contains the old or new implementation.  Then we check
1391 dnl # to see if the symbols we need for each version are available.  If they
1392 dnl # are not, dynamically aquire the addresses with kallsyms_lookup_name().
1393 dnl #
1394 AC_DEFUN([SPL_AC_PGDAT_HELPERS], [
1395         AC_MSG_CHECKING([whether symbol *_pgdat exist])
1396         grep -q -E 'first_online_pgdat' $LINUX/include/linux/mmzone.h 2>/dev/null
1397         rc=$?
1398         if test $rc -eq 0; then
1399                 AC_MSG_RESULT([yes])
1400                 AC_DEFINE(HAVE_PGDAT_HELPERS, 1, [pgdat helpers are available])
1401         else
1402                 AC_MSG_RESULT([no])
1403         fi
1404 ])
1405
1406 dnl #
1407 dnl # Proposed API change,
1408 dnl # This symbol is not available in stock kernels.  You may build a
1409 dnl # custom kernel with the *-spl-export-symbols.patch which will export
1410 dnl # these symbols for use.  If your already rolling a custom kernel for
1411 dnl # your environment this is recommended.
1412 dnl #
1413 AC_DEFUN([SPL_AC_FIRST_ONLINE_PGDAT],
1414         [AC_MSG_CHECKING([whether first_online_pgdat() is available])
1415         SPL_LINUX_TRY_COMPILE_SYMBOL([
1416                 #include <linux/mmzone.h>
1417         ], [
1418                 first_online_pgdat();
1419         ], [first_online_pgdat], [], [
1420                 AC_MSG_RESULT(yes)
1421                 AC_DEFINE(HAVE_FIRST_ONLINE_PGDAT, 1,
1422                           [first_online_pgdat() is available])
1423         ], [
1424                 AC_MSG_RESULT(no)
1425         ])
1426 ])
1427
1428 dnl #
1429 dnl # Proposed API change,
1430 dnl # This symbol is not available in stock kernels.  You may build a
1431 dnl # custom kernel with the *-spl-export-symbols.patch which will export
1432 dnl # these symbols for use.  If your already rolling a custom kernel for
1433 dnl # your environment this is recommended.
1434 dnl #
1435 AC_DEFUN([SPL_AC_NEXT_ONLINE_PGDAT],
1436         [AC_MSG_CHECKING([whether next_online_pgdat() is available])
1437         SPL_LINUX_TRY_COMPILE_SYMBOL([
1438                 #include <linux/mmzone.h>
1439         ], [
1440                 next_online_pgdat(NULL);
1441         ], [next_online_pgdat], [], [
1442                 AC_MSG_RESULT(yes)
1443                 AC_DEFINE(HAVE_NEXT_ONLINE_PGDAT, 1,
1444                           [next_online_pgdat() is available])
1445         ], [
1446                 AC_MSG_RESULT(no)
1447         ])
1448 ])
1449
1450 dnl #
1451 dnl # Proposed API change,
1452 dnl # This symbol is not available in stock kernels.  You may build a
1453 dnl # custom kernel with the *-spl-export-symbols.patch which will export
1454 dnl # these symbols for use.  If your already rolling a custom kernel for
1455 dnl # your environment this is recommended.
1456 dnl #
1457 AC_DEFUN([SPL_AC_NEXT_ZONE],
1458         [AC_MSG_CHECKING([whether next_zone() is available])
1459         SPL_LINUX_TRY_COMPILE_SYMBOL([
1460                 #include <linux/mmzone.h>
1461         ], [
1462                 next_zone(NULL);
1463         ], [next_zone], [], [
1464                 AC_MSG_RESULT(yes)
1465                 AC_DEFINE(HAVE_NEXT_ZONE, 1, [next_zone() is available])
1466         ], [
1467                 AC_MSG_RESULT(no)
1468         ])
1469 ])
1470
1471 dnl #
1472 dnl # 2.6.17 API change,
1473 dnl # See SPL_AC_PGDAT_HELPERS for details.
1474 dnl #
1475 AC_DEFUN([SPL_AC_PGDAT_LIST],
1476         [AC_MSG_CHECKING([whether pgdat_list is available])
1477         SPL_LINUX_TRY_COMPILE_SYMBOL([
1478                 #include <linux/topology.h>
1479                 pg_data_t *tmp = pgdat_list;
1480         ], [], [pgdat_list], [], [
1481                 AC_MSG_RESULT(yes)
1482                 AC_DEFINE(HAVE_PGDAT_LIST, 1, [pgdat_list is available])
1483         ], [
1484                 AC_MSG_RESULT(no)
1485         ])
1486 ])
1487
1488 dnl #
1489 dnl # 2.6.18 API change,
1490 dnl # First introduced global_page_state() support as an inline.
1491 dnl #
1492 AC_DEFUN([SPL_AC_GLOBAL_PAGE_STATE], [
1493         AC_MSG_CHECKING([whether global_page_state() is available])
1494         SPL_LINUX_TRY_COMPILE([
1495                 #include <linux/mm.h>
1496         ],[
1497                 unsigned long state __attribute__ ((unused));
1498                 state = global_page_state(0);
1499         ],[
1500                 AC_MSG_RESULT(yes)
1501                 AC_DEFINE(HAVE_GLOBAL_PAGE_STATE, 1,
1502                           [global_page_state() is available])
1503         ],[
1504                 AC_MSG_RESULT(no)
1505         ])
1506 ])
1507
1508 dnl #
1509 dnl # 2.6.21 API change (plus subsequent naming convention changes),
1510 dnl # Public global zone stats now include a free page count.  However
1511 dnl # the enumerated names of the counters have changed since this API
1512 dnl # was introduced.  We need to deduce the corrent name to use.  This
1513 dnl # replaces the priviate get_zone_counts() interface.
1514 dnl #
1515 dnl # NR_FREE_PAGES was available from 2.6.21 to current kernels, which
1516 dnl # is 2.6.30 as of when this was written.
1517 dnl #
1518 AC_DEFUN([SPL_AC_ZONE_STAT_ITEM_FREE], [
1519         AC_MSG_CHECKING([whether page state NR_FREE_PAGES is available])
1520         SPL_LINUX_TRY_COMPILE([
1521                 #include <linux/mm.h>
1522         ],[
1523                 enum zone_stat_item zsi __attribute__ ((unused));
1524                 zsi = NR_FREE_PAGES;
1525         ],[
1526                 AC_MSG_RESULT(yes)
1527                 AC_DEFINE(HAVE_ZONE_STAT_ITEM_NR_FREE_PAGES, 1,
1528                           [Page state NR_FREE_PAGES is available])
1529         ],[
1530                 AC_MSG_RESULT(no)
1531         ])
1532 ])
1533
1534 dnl #
1535 dnl # 2.6.21 API change (plus subsequent naming convention changes),
1536 dnl # Public global zone stats now include an inactive page count.  However
1537 dnl # the enumerated names of the counters have changed since this API
1538 dnl # was introduced.  We need to deduce the corrent name to use.  This
1539 dnl # replaces the priviate get_zone_counts() interface.
1540 dnl #
1541 dnl # NR_INACTIVE was available from 2.6.21 to 2.6.27 and included both
1542 dnl # anonymous and file inactive pages.  As of 2.6.28 it was split in
1543 dnl # to NR_INACTIVE_ANON and NR_INACTIVE_FILE.
1544 dnl #
1545 AC_DEFUN([SPL_AC_ZONE_STAT_ITEM_INACTIVE], [
1546         AC_MSG_CHECKING([whether page state NR_INACTIVE is available])
1547         SPL_LINUX_TRY_COMPILE([
1548                 #include <linux/mm.h>
1549         ],[
1550                 enum zone_stat_item zsi __attribute__ ((unused));
1551                 zsi = NR_INACTIVE;
1552         ],[
1553                 AC_MSG_RESULT(yes)
1554                 AC_DEFINE(HAVE_ZONE_STAT_ITEM_NR_INACTIVE, 1,
1555                           [Page state NR_INACTIVE is available])
1556         ],[
1557                 AC_MSG_RESULT(no)
1558         ])
1559
1560         AC_MSG_CHECKING([whether page state NR_INACTIVE_ANON is available])
1561         SPL_LINUX_TRY_COMPILE([
1562                 #include <linux/mm.h>
1563         ],[
1564                 enum zone_stat_item zsi __attribute__ ((unused));
1565                 zsi = NR_INACTIVE_ANON;
1566         ],[
1567                 AC_MSG_RESULT(yes)
1568                 AC_DEFINE(HAVE_ZONE_STAT_ITEM_NR_INACTIVE_ANON, 1,
1569                           [Page state NR_INACTIVE_ANON is available])
1570         ],[
1571                 AC_MSG_RESULT(no)
1572         ])
1573
1574         AC_MSG_CHECKING([whether page state NR_INACTIVE_FILE is available])
1575         SPL_LINUX_TRY_COMPILE([
1576                 #include <linux/mm.h>
1577         ],[
1578                 enum zone_stat_item zsi __attribute__ ((unused));
1579                 zsi = NR_INACTIVE_FILE;
1580         ],[
1581                 AC_MSG_RESULT(yes)
1582                 AC_DEFINE(HAVE_ZONE_STAT_ITEM_NR_INACTIVE_FILE, 1,
1583                           [Page state NR_INACTIVE_FILE is available])
1584         ],[
1585                 AC_MSG_RESULT(no)
1586         ])
1587 ])
1588
1589 dnl #
1590 dnl # 2.6.21 API change (plus subsequent naming convention changes),
1591 dnl # Public global zone stats now include an active page count.  However
1592 dnl # the enumerated names of the counters have changed since this API
1593 dnl # was introduced.  We need to deduce the corrent name to use.  This
1594 dnl # replaces the priviate get_zone_counts() interface.
1595 dnl #
1596 dnl # NR_ACTIVE was available from 2.6.21 to 2.6.27 and included both
1597 dnl # anonymous and file active pages.  As of 2.6.28 it was split in
1598 dnl # to NR_ACTIVE_ANON and NR_ACTIVE_FILE.
1599 dnl #
1600 AC_DEFUN([SPL_AC_ZONE_STAT_ITEM_ACTIVE], [
1601         AC_MSG_CHECKING([whether page state NR_ACTIVE is available])
1602         SPL_LINUX_TRY_COMPILE([
1603                 #include <linux/mm.h>
1604         ],[
1605                 enum zone_stat_item zsi __attribute__ ((unused));
1606                 zsi = NR_ACTIVE;
1607         ],[
1608                 AC_MSG_RESULT(yes)
1609                 AC_DEFINE(HAVE_ZONE_STAT_ITEM_NR_ACTIVE, 1,
1610                           [Page state NR_ACTIVE is available])
1611         ],[
1612                 AC_MSG_RESULT(no)
1613         ])
1614
1615         AC_MSG_CHECKING([whether page state NR_ACTIVE_ANON is available])
1616         SPL_LINUX_TRY_COMPILE([
1617                 #include <linux/mm.h>
1618         ],[
1619                 enum zone_stat_item zsi __attribute__ ((unused));
1620                 zsi = NR_ACTIVE_ANON;
1621         ],[
1622                 AC_MSG_RESULT(yes)
1623                 AC_DEFINE(HAVE_ZONE_STAT_ITEM_NR_ACTIVE_ANON, 1,
1624                           [Page state NR_ACTIVE_ANON is available])
1625         ],[
1626                 AC_MSG_RESULT(no)
1627         ])
1628
1629         AC_MSG_CHECKING([whether page state NR_ACTIVE_FILE is available])
1630         SPL_LINUX_TRY_COMPILE([
1631                 #include <linux/mm.h>
1632         ],[
1633                 enum zone_stat_item zsi __attribute__ ((unused));
1634                 zsi = NR_ACTIVE_FILE;
1635         ],[
1636                 AC_MSG_RESULT(yes)
1637                 AC_DEFINE(HAVE_ZONE_STAT_ITEM_NR_ACTIVE_FILE, 1,
1638                           [Page state NR_ACTIVE_FILE is available])
1639         ],[
1640                 AC_MSG_RESULT(no)
1641         ])
1642 ])
1643
1644 dnl #
1645 dnl # Proposed API change for legacy kernels.
1646 dnl # This symbol is not available in older kernels.  For kernels post
1647 dnl # 2.6.21 the global_page_state() API is used to get free/inactive/active
1648 dnl # page state information.  This symbol is only used in legacy kernels
1649 dnl # any only as a last resort.
1650 dnl
1651 AC_DEFUN([SPL_AC_GET_ZONE_COUNTS], [
1652         AC_MSG_CHECKING([whether symbol get_zone_counts is needed])
1653         SPL_LINUX_TRY_COMPILE([
1654         ],[
1655                 #if !defined(HAVE_ZONE_STAT_ITEM_NR_FREE_PAGES)
1656                 #error "global_page_state needs NR_FREE_PAGES"
1657                 #endif
1658
1659                 #if !defined(HAVE_ZONE_STAT_ITEM_NR_ACTIVE) && \
1660                     !defined(HAVE_ZONE_STAT_ITEM_NR_ACTIVE_ANON) && \
1661                     !defined(HAVE_ZONE_STAT_ITEM_NR_ACTIVE_FILE)
1662                 #error "global_page_state needs NR_ACTIVE*"
1663                 #endif
1664
1665                 #if !defined(HAVE_ZONE_STAT_ITEM_NR_INACTIVE) && \
1666                     !defined(HAVE_ZONE_STAT_ITEM_NR_INACTIVE_ANON) && \
1667                     !defined(HAVE_ZONE_STAT_ITEM_NR_INACTIVE_FILE)
1668                 #error "global_page_state needs NR_INACTIVE*"
1669                 #endif
1670         ],[
1671                 AC_MSG_RESULT(no)
1672         ],[
1673                 AC_MSG_RESULT(yes)
1674                 AC_DEFINE(NEED_GET_ZONE_COUNTS, 1,
1675                           [get_zone_counts() is needed])
1676
1677                 AC_MSG_CHECKING([whether get_zone_counts() is available])
1678                 SPL_LINUX_TRY_COMPILE_SYMBOL([
1679                         #include <linux/mmzone.h>
1680                 ], [
1681                         get_zone_counts(NULL, NULL, NULL);
1682                 ], [get_zone_counts], [], [
1683                         AC_MSG_RESULT(yes)
1684                         AC_DEFINE(HAVE_GET_ZONE_COUNTS, 1,
1685                                   [get_zone_counts() is available])
1686                 ], [
1687                         AC_MSG_RESULT(no)
1688                 ])
1689         ])
1690 ])
1691
1692 dnl #
1693 dnl # 2.6.27 API change,
1694 dnl # The user_path_dir() replaces __user_walk()
1695 dnl #
1696 AC_DEFUN([SPL_AC_USER_PATH_DIR],
1697         [AC_MSG_CHECKING([whether user_path_dir() is available])
1698         SPL_LINUX_TRY_COMPILE_SYMBOL([
1699                 #include <linux/fcntl.h>
1700                 #include <linux/namei.h>
1701         ], [
1702                 user_path_dir(NULL, NULL);
1703         ], [user_path_at], [], [
1704                 AC_MSG_RESULT(yes)
1705                 AC_DEFINE(HAVE_USER_PATH_DIR, 1, [user_path_dir() is available])
1706         ], [
1707                 AC_MSG_RESULT(no)
1708         ])
1709 ])
1710
1711 dnl #
1712 dnl # Symbol available in RHEL kernels not in stock kernels.
1713 dnl #
1714 AC_DEFUN([SPL_AC_SET_FS_PWD],
1715         [AC_MSG_CHECKING([whether set_fs_pwd() is available])
1716         SPL_LINUX_TRY_COMPILE_SYMBOL([
1717                 #include <linux/spinlock.h>
1718                 #include <linux/fs_struct.h>
1719         ], [
1720                 (void) set_fs_pwd;
1721         ], [set_fs_pwd], [], [
1722                 AC_MSG_RESULT(yes)
1723                 AC_DEFINE(HAVE_SET_FS_PWD, 1, [set_fs_pwd() is available])
1724         ], [
1725                 AC_MSG_RESULT(no)
1726         ])
1727 ])
1728
1729 dnl #
1730 dnl # 2.6.25 API change,
1731 dnl # Simplied API by replacing mnt+dentry args with a single path arg.
1732 dnl #
1733 AC_DEFUN([SPL_AC_2ARGS_SET_FS_PWD],
1734         [AC_MSG_CHECKING([whether set_fs_pwd() wants 2 args])
1735         SPL_LINUX_TRY_COMPILE([
1736                 #include <linux/sched.h>
1737                 #include <linux/fs_struct.h>
1738         ],[
1739                 set_fs_pwd(NULL, NULL);
1740         ],[
1741                 AC_MSG_RESULT(yes)
1742                 AC_DEFINE(HAVE_2ARGS_SET_FS_PWD, 1,
1743                           [set_fs_pwd() wants 2 args])
1744         ],[
1745                 AC_MSG_RESULT(no)
1746         ])
1747 ])
1748
1749 dnl #
1750 dnl # SLES API change, never adopted in mainline,
1751 dnl # Third 'struct vfsmount *' argument removed.
1752 dnl #
1753 AC_DEFUN([SPL_AC_2ARGS_VFS_UNLINK],
1754         [AC_MSG_CHECKING([whether vfs_unlink() wants 2 args])
1755         SPL_LINUX_TRY_COMPILE([
1756                 #include <linux/fs.h>
1757         ],[
1758                 vfs_unlink(NULL, NULL);
1759         ],[
1760                 AC_MSG_RESULT(yes)
1761                 AC_DEFINE(HAVE_2ARGS_VFS_UNLINK, 1,
1762                           [vfs_unlink() wants 2 args])
1763         ],[
1764                 AC_MSG_RESULT(no)
1765         ])
1766 ])
1767
1768 dnl #
1769 dnl # SLES API change, never adopted in mainline,
1770 dnl # Third and sixth 'struct vfsmount *' argument removed.
1771 dnl #
1772 AC_DEFUN([SPL_AC_4ARGS_VFS_RENAME],
1773         [AC_MSG_CHECKING([whether vfs_rename() wants 4 args])
1774         SPL_LINUX_TRY_COMPILE([
1775                 #include <linux/fs.h>
1776         ],[
1777                 vfs_rename(NULL, NULL, NULL, NULL);
1778         ],[
1779                 AC_MSG_RESULT(yes)
1780                 AC_DEFINE(HAVE_4ARGS_VFS_RENAME, 1,
1781                           [vfs_rename() wants 4 args])
1782         ],[
1783                 AC_MSG_RESULT(no)
1784         ])
1785 ])
1786
1787 dnl #
1788 dnl # 2.6.36 API change,
1789 dnl # The 'struct fs_struct->lock' was changed from a rwlock_t to
1790 dnl # a spinlock_t to improve the fastpath performance.
1791 dnl #
1792 AC_DEFUN([SPL_AC_FS_STRUCT_SPINLOCK], [
1793         AC_MSG_CHECKING([whether struct fs_struct uses spinlock_t])
1794         tmp_flags="$EXTRA_KCFLAGS"
1795         EXTRA_KCFLAGS="-Werror"
1796         SPL_LINUX_TRY_COMPILE([
1797                 #include <linux/sched.h>
1798                 #include <linux/fs_struct.h>
1799         ],[
1800                 struct fs_struct fs;
1801                 spin_lock_init(&fs.lock);
1802         ],[
1803                 AC_MSG_RESULT(yes)
1804                 AC_DEFINE(HAVE_FS_STRUCT_SPINLOCK, 1,
1805                           [struct fs_struct uses spinlock_t])
1806         ],[
1807                 AC_MSG_RESULT(no)
1808         ])
1809         EXTRA_KCFLAGS="$tmp_flags"
1810 ])
1811
1812 dnl #
1813 dnl # 2.6.29 API change,
1814 dnl # check whether 'struct cred' exists
1815 dnl #
1816 AC_DEFUN([SPL_AC_CRED_STRUCT], [
1817         AC_MSG_CHECKING([whether struct cred exists])
1818         SPL_LINUX_TRY_COMPILE([
1819                 #include <linux/cred.h>
1820         ],[
1821                 struct cred *cr __attribute__ ((unused));
1822                 cr  = NULL;
1823         ],[
1824                 AC_MSG_RESULT(yes)
1825                 AC_DEFINE(HAVE_CRED_STRUCT, 1, [struct cred exists])
1826         ],[
1827                 AC_MSG_RESULT(no)
1828         ])
1829 ])
1830
1831 dnl #
1832 dnl # Custom SPL patch may export this symbol.
1833 dnl #
1834 AC_DEFUN([SPL_AC_GROUPS_SEARCH],
1835         [AC_MSG_CHECKING([whether groups_search() is available])
1836         SPL_LINUX_TRY_COMPILE_SYMBOL([
1837                 #include <linux/cred.h>
1838         ], [
1839                 groups_search(NULL, 0);
1840         ], [groups_search], [], [
1841                 AC_MSG_RESULT(yes)
1842                 AC_DEFINE(HAVE_GROUPS_SEARCH, 1, [groups_search() is available])
1843         ], [
1844                 AC_MSG_RESULT(no)
1845         ])
1846 ])
1847
1848 dnl #
1849 dnl # 2.6.x API change,
1850 dnl # __put_task_struct() was exported in RHEL5 but unavailable elsewhere.
1851 dnl #
1852 AC_DEFUN([SPL_AC_PUT_TASK_STRUCT],
1853         [AC_MSG_CHECKING([whether __put_task_struct() is available])
1854         SPL_LINUX_TRY_COMPILE_SYMBOL([
1855                 #include <linux/sched.h>
1856         ], [
1857                 __put_task_struct(NULL);
1858         ], [__put_task_struct], [], [
1859                 AC_MSG_RESULT(yes)
1860                 AC_DEFINE(HAVE_PUT_TASK_STRUCT, 1,
1861                           [__put_task_struct() is available])
1862         ], [
1863                 AC_MSG_RESULT(no)
1864         ])
1865 ])
1866
1867 dnl #
1868 dnl # 2.6.32 API change,
1869 dnl # Unused 'struct file *' removed from prototype.
1870 dnl #
1871 AC_DEFUN([SPL_AC_5ARGS_PROC_HANDLER], [
1872         AC_MSG_CHECKING([whether proc_handler() wants 5 args])
1873         SPL_LINUX_TRY_COMPILE([
1874                 #include <linux/sysctl.h>
1875         ],[
1876                 proc_dostring(NULL, 0, NULL, NULL, NULL);
1877         ],[
1878                 AC_MSG_RESULT(yes)
1879                 AC_DEFINE(HAVE_5ARGS_PROC_HANDLER, 1,
1880                           [proc_handler() wants 5 args])
1881         ],[
1882                 AC_MSG_RESULT(no)
1883         ])
1884 ])
1885
1886 dnl #
1887 dnl # 2.6.x API change,
1888 dnl # kvasprintf() function added.
1889 dnl #
1890 AC_DEFUN([SPL_AC_KVASPRINTF],
1891         [AC_MSG_CHECKING([whether kvasprintf() is available])
1892         SPL_LINUX_TRY_COMPILE_SYMBOL([
1893                 #include <linux/kernel.h>
1894         ], [
1895                 kvasprintf(0, NULL, *((va_list*)NULL));
1896         ], [kvasprintf], [], [
1897                 AC_MSG_RESULT(yes)
1898                 AC_DEFINE(HAVE_KVASPRINTF, 1, [kvasprintf() is available])
1899         ], [
1900                 AC_MSG_RESULT(no)
1901         ])
1902 ])
1903
1904 dnl #
1905 dnl # 2.6.29 API change,
1906 dnl # vfs_fsync() funcation added, prior to this use file_fsync().
1907 dnl #
1908 AC_DEFUN([SPL_AC_VFS_FSYNC],
1909         [AC_MSG_CHECKING([whether vfs_fsync() is available])
1910         SPL_LINUX_TRY_COMPILE_SYMBOL([
1911                 #include <linux/fs.h>
1912         ], [
1913                 (void) vfs_fsync;
1914         ], [vfs_fsync], [fs/sync.c], [
1915                 AC_MSG_RESULT(yes)
1916                 AC_DEFINE(HAVE_VFS_FSYNC, 1, [vfs_fsync() is available])
1917         ], [
1918                 AC_MSG_RESULT(no)
1919         ])
1920 ])
1921
1922 dnl #
1923 dnl # 2.6.35 API change,
1924 dnl # Unused 'struct dentry *' removed from vfs_fsync() prototype.
1925 dnl #
1926 AC_DEFUN([SPL_AC_2ARGS_VFS_FSYNC], [
1927         AC_MSG_CHECKING([whether vfs_fsync() wants 2 args])
1928         SPL_LINUX_TRY_COMPILE([
1929                 #include <linux/fs.h>
1930         ],[
1931                 vfs_fsync(NULL, 0);
1932         ],[
1933                 AC_MSG_RESULT(yes)
1934                 AC_DEFINE(HAVE_2ARGS_VFS_FSYNC, 1, [vfs_fsync() wants 2 args])
1935         ],[
1936                 AC_MSG_RESULT(no)
1937         ])
1938 ])
1939
1940 dnl #
1941 dnl # 3.5 API change,
1942 dnl # inode_operations.truncate_range removed
1943 dnl # (deprecated in favor of FALLOC_FL_PUNCH_HOLE)
1944 dnl #
1945 AC_DEFUN([SPL_AC_INODE_TRUNCATE_RANGE], [
1946         AC_MSG_CHECKING([whether truncate_range() inode operation is available])
1947         SPL_LINUX_TRY_COMPILE([
1948                 #include <linux/fs.h>
1949         ],[
1950                 struct inode_operations ops;
1951                 ops.truncate_range = NULL;
1952         ],[
1953                 AC_MSG_RESULT(yes)
1954                 AC_DEFINE(HAVE_INODE_TRUNCATE_RANGE, 1,
1955                         [truncate_range() inode operation is available])
1956         ],[
1957                 AC_MSG_RESULT(no)
1958         ])
1959 ]))
1960
1961 dnl #
1962 dnl # 2.6.33 API change. Also backported in RHEL5 as of 2.6.18-190.el5.
1963 dnl # Earlier versions of rwsem_is_locked() were inline and had a race
1964 dnl # condition.  The fixed version is exported as a symbol.  The race
1965 dnl # condition is fixed by acquiring sem->wait_lock, so we must not
1966 dnl # call that version while holding sem->wait_lock.
1967 dnl #
1968 AC_DEFUN([SPL_AC_EXPORTED_RWSEM_IS_LOCKED],
1969         [AC_MSG_CHECKING([whether rwsem_is_locked() acquires sem->wait_lock])
1970         SPL_LINUX_TRY_COMPILE_SYMBOL([
1971                 #include <linux/rwsem.h>
1972                 int rwsem_is_locked(struct rw_semaphore *sem) { return 0; }
1973         ], [], [rwsem_is_locked], [lib/rwsem-spinlock.c], [
1974                 AC_MSG_RESULT(yes)
1975                 AC_DEFINE(RWSEM_IS_LOCKED_TAKES_WAIT_LOCK, 1,
1976                           [rwsem_is_locked() acquires sem->wait_lock])
1977         ], [
1978                 AC_MSG_RESULT(no)
1979         ])
1980 ])
1981
1982 dnl #
1983 dnl # 2.6.37 API compat,
1984 dnl # The function invalidate_inodes() is no longer exported by the kernel.
1985 dnl # The prototype however is still available which means it is safe
1986 dnl # to acquire the symbol's address using spl_kallsyms_lookup_name().
1987 dnl #
1988 dnl # The Proxmox VE kernel contains a patch which renames the function
1989 dnl # invalidate_inodes() to invalidate_inodes_check().  In the process
1990 dnl # it adds a 'check' argument and a '#define invalidate_inodes(x)'
1991 dnl # compatibility wrapper for legacy callers.  Therefore, if either
1992 dnl # of these functions are exported invalidate_inodes() can be
1993 dnl # safely used.
1994 dnl #
1995 AC_DEFUN([SPL_AC_KERNEL_INVALIDATE_INODES], [
1996         AC_MSG_CHECKING([whether invalidate_inodes() is available])
1997         SPL_LINUX_TRY_COMPILE_SYMBOL([
1998                 #include <linux/fs.h>
1999         ], [
2000                 invalidate_inodes;
2001         ], [invalidate_inodes], [], [
2002                 AC_MSG_RESULT(yes)
2003                 AC_DEFINE(HAVE_INVALIDATE_INODES, 1,
2004                           [invalidate_inodes() is available])
2005         ], [
2006                 AC_MSG_RESULT(no)
2007         ])
2008
2009         AC_MSG_CHECKING([whether invalidate_inodes_check() is available])
2010         SPL_LINUX_TRY_COMPILE_SYMBOL([
2011                 #include <linux/fs.h>
2012                 #ifndef invalidate_inodes
2013                 #error invalidate_inodes is not a macro
2014                 #endif
2015         ], [ ], [invalidate_inodes_check], [], [
2016                 AC_MSG_RESULT(yes)
2017                 AC_DEFINE(HAVE_INVALIDATE_INODES_CHECK, 1,
2018                           [invalidate_inodes_check() is available])
2019         ], [
2020                 AC_MSG_RESULT(no)
2021         ])
2022 ])
2023
2024 dnl #
2025 dnl # 2.6.39 API compat,
2026 dnl # The function invalidate_inodes() now take 2 arguments.  The second
2027 dnl # 'kill_dirty' argument describes how invalidate_inodes() should
2028 dnl # handle dirty inodes.  Only when set will dirty inodes be discarded,
2029 dnl # otherwise they will be handled as busy.
2030 dnl #
2031 dnl # Unfortunately, we don't have access to the invalidate_inodes()
2032 dnl # prototype so it's not easy to check how many arguments it takes.
2033 dnl # However, this change was done for the benefit of invalidate_device()
2034 dnl # which also added an argument.  The invalidate_device() symbol does
2035 dnl # exist in the development headers so if it takes two arguments we
2036 dnl # can fairly safely infer that invalidate_inodes() takes two arguments
2037 dnl # as well.  See commit 93b270f76e7ef3b81001576860c2701931cdc78b.
2038 dnl #
2039 AC_DEFUN([SPL_AC_KERNEL_2ARGS_INVALIDATE_INODES],
2040         [AC_MSG_CHECKING([whether invalidate_inodes() wants 2 args])
2041         SPL_LINUX_TRY_COMPILE([
2042                 #include <linux/fs.h>
2043         ],[
2044                 return __invalidate_device(NULL, 0);
2045         ],[
2046                 AC_MSG_RESULT(yes)
2047                 AC_DEFINE(HAVE_2ARGS_INVALIDATE_INODES, 1,
2048                           [invalidate_inodes() wants 2 args])
2049         ],[
2050                 AC_MSG_RESULT(no)
2051         ])
2052 ])
2053
2054 dnl #
2055 dnl # 2.6.xx API compat,
2056 dnl # There currently exists no exposed API to partially shrink the dcache.
2057 dnl # The expected mechanism to shrink the cache is a registered shrinker
2058 dnl # which is called during memory pressure.
2059 dnl #
2060 AC_DEFUN([SPL_AC_SHRINK_DCACHE_MEMORY],
2061         [AC_MSG_CHECKING([whether shrink_dcache_memory() is available])
2062         SPL_LINUX_TRY_COMPILE_SYMBOL([
2063                 #include <linux/dcache.h>
2064         ], [
2065                 shrink_dcache_memory(0, 0);
2066         ], [shrink_dcache_memory], [fs/dcache.c], [
2067                 AC_MSG_RESULT(yes)
2068                 AC_DEFINE(HAVE_SHRINK_DCACHE_MEMORY, 1,
2069                           [shrink_dcache_memory() is available])
2070         ], [
2071                 AC_MSG_RESULT(no)
2072         ])
2073 ])
2074
2075 dnl #
2076 dnl # 2.6.xx API compat,
2077 dnl # There currently exists no exposed API to partially shrink the icache.
2078 dnl # The expected mechanism to shrink the cache is a registered shrinker
2079 dnl # which is called during memory pressure.
2080 dnl #
2081 AC_DEFUN([SPL_AC_SHRINK_ICACHE_MEMORY],
2082         [AC_MSG_CHECKING([whether shrink_icache_memory() is available])
2083         SPL_LINUX_TRY_COMPILE_SYMBOL([
2084                 #include <linux/dcache.h>
2085         ], [
2086                 shrink_icache_memory(0, 0);
2087         ], [shrink_icache_memory], [fs/inode.c], [
2088                 AC_MSG_RESULT(yes)
2089                 AC_DEFINE(HAVE_SHRINK_ICACHE_MEMORY, 1,
2090                           [shrink_icache_memory() is available])
2091         ], [
2092                 AC_MSG_RESULT(no)
2093         ])
2094 ])
2095
2096 dnl #
2097 dnl # 2.6.39 API compat,
2098 dnl # The path_lookup() function has been renamed to kern_path_parent()
2099 dnl # and the flags argument has been removed.  The only behavior now
2100 dnl # offered is that of LOOKUP_PARENT.  The spl already always passed
2101 dnl # this flag so dropping the flag does not impact us.
2102 dnl #
2103 AC_DEFUN([SPL_AC_KERN_PATH_PARENT_HEADER], [
2104         SPL_CHECK_SYMBOL_HEADER(
2105                 [kern_path_parent],
2106                 [int kern_path_parent(const char \*, struct nameidata \*)],
2107                 [include/linux/namei.h],
2108                 [AC_DEFINE(HAVE_KERN_PATH_PARENT_HEADER, 1,
2109                 [kern_path_parent() is available])],
2110                 [])
2111 ])
2112
2113 dnl #
2114 dnl # 3.1 API compat,
2115 dnl # The kern_path_parent() symbol is no longer exported by the kernel.
2116 dnl # However, it remains the prefered interface and since we still have
2117 dnl # access to the prototype we dynamically lookup the required address.
2118 dnl #
2119 AC_DEFUN([SPL_AC_KERN_PATH_PARENT_SYMBOL],
2120         [AC_MSG_CHECKING([whether kern_path_parent() is available])
2121         SPL_LINUX_TRY_COMPILE_SYMBOL([
2122                 #include <linux/namei.h>
2123         ], [
2124                 kern_path_parent(NULL, NULL);
2125         ], [kern_path_parent], [fs/namei.c], [
2126                 AC_MSG_RESULT(yes)
2127                 AC_DEFINE(HAVE_KERN_PATH_PARENT_SYMBOL, 1,
2128                           [kern_path_parent() is available])
2129         ], [
2130                 AC_MSG_RESULT(no)
2131         ])
2132 ])
2133
2134 dnl #
2135 dnl # 3.6 API compat,
2136 dnl # The kern_path_parent() function was replaced by the kern_path_locked()
2137 dnl # function to eliminate all struct nameidata usage outside fs/namei.c.
2138 dnl #
2139 AC_DEFUN([SPL_AC_KERN_PATH_LOCKED], [
2140         SPL_CHECK_SYMBOL_HEADER(
2141                 [kern_path_locked],
2142                 [struct dentry \*kern_path_locked(const char \*, struct path \*)],
2143                 [include/linux/namei.h],
2144                 [AC_DEFINE(HAVE_KERN_PATH_LOCKED, 1,
2145                 [kern_path_locked() is available])],
2146                 [])
2147 ])
2148
2149 dnl #
2150 dnl # 2.6.39 API compat,
2151 dnl # The function zlib_deflate_workspacesize() now take 2 arguments.
2152 dnl # This was done to avoid always having to allocate the maximum size
2153 dnl # workspace (268K).  The caller can now specific the windowBits and
2154 dnl # memLevel compression parameters to get a smaller workspace.
2155 dnl #
2156 AC_DEFUN([SPL_AC_2ARGS_ZLIB_DEFLATE_WORKSPACESIZE],
2157         [AC_MSG_CHECKING([whether zlib_deflate_workspacesize() wants 2 args])
2158         SPL_LINUX_TRY_COMPILE([
2159                 #include <linux/zlib.h>
2160         ],[
2161                 return zlib_deflate_workspacesize(MAX_WBITS, MAX_MEM_LEVEL);
2162         ],[
2163                 AC_MSG_RESULT(yes)
2164                 AC_DEFINE(HAVE_2ARGS_ZLIB_DEFLATE_WORKSPACESIZE, 1,
2165                           [zlib_deflate_workspacesize() wants 2 args])
2166         ],[
2167                 AC_MSG_RESULT(no)
2168         ])
2169 ])
2170
2171 dnl #
2172 dnl # 2.6.39 API change,
2173 dnl # Shrinker adjust to use common shrink_control structure.
2174 dnl #
2175 AC_DEFUN([SPL_AC_SHRINK_CONTROL_STRUCT], [
2176         AC_MSG_CHECKING([whether struct shrink_control exists])
2177         SPL_LINUX_TRY_COMPILE([
2178                 #include <linux/mm.h>
2179         ],[
2180                 struct shrink_control sc __attribute__ ((unused));
2181
2182                 sc.nr_to_scan = 0;
2183                 sc.gfp_mask = GFP_KERNEL;
2184         ],[
2185                 AC_MSG_RESULT(yes)
2186                 AC_DEFINE(HAVE_SHRINK_CONTROL_STRUCT, 1,
2187                         [struct shrink_control exists])
2188         ],[
2189                 AC_MSG_RESULT(no)
2190         ])
2191 ])
2192
2193 dnl #
2194 dnl # 3.1 API Change
2195 dnl #
2196 dnl # The rw_semaphore.wait_lock member was changed from spinlock_t to
2197 dnl # raw_spinlock_t at commit ddb6c9b58a19edcfac93ac670b066c836ff729f1.
2198 dnl #
2199 AC_DEFUN([SPL_AC_RWSEM_SPINLOCK_IS_RAW], [
2200         AC_MSG_CHECKING([whether struct rw_semaphore member wait_lock is raw])
2201         tmp_flags="$EXTRA_KCFLAGS"
2202         EXTRA_KCFLAGS="-Werror"
2203         SPL_LINUX_TRY_COMPILE([
2204                 #include <linux/rwsem.h>
2205         ],[
2206                 struct rw_semaphore dummy_semaphore __attribute__ ((unused));
2207                 raw_spinlock_t dummy_lock __attribute__ ((unused));
2208                 dummy_semaphore.wait_lock = dummy_lock;
2209         ],[
2210                 AC_MSG_RESULT(yes)
2211                 AC_DEFINE(RWSEM_SPINLOCK_IS_RAW, 1,
2212                 [struct rw_semaphore member wait_lock is raw_spinlock_t])
2213         ],[
2214                 AC_MSG_RESULT(no)
2215         ])
2216         EXTRA_KCFLAGS="$tmp_flags"
2217 ])