config/spl-build.m4

   1 ###############################################################################
   2 # Copyright (C) 2007-2010 Lawrence Livermore National Security, LLC.
   3 # Copyright (C) 2007 The Regents of the University of California.
   4 # Written by Brian Behlendorf <behlendorf1@llnl.gov>.
   5 ###############################################################################
   6 # SPL_AC_CONFIG_KERNEL: Default SPL kernel configuration.
   7 ###############################################################################
   8
   9 AC_DEFUN([SPL_AC_CONFIG_KERNEL], [
  10         SPL_AC_KERNEL
  11
  12         if test "${LINUX_OBJ}" != "${LINUX}"; then
  13                 KERNELMAKE_PARAMS="$KERNELMAKE_PARAMS O=$LINUX_OBJ"
  14         fi
  15         AC_SUBST(KERNELMAKE_PARAMS)
  16
  17         KERNELCPPFLAGS="$KERNELCPPFLAGS -Wstrict-prototypes"
  18         AC_SUBST(KERNELCPPFLAGS)
  19
  20         SPL_AC_DEBUG
  21         SPL_AC_DEBUG_KMEM
  22         SPL_AC_DEBUG_KMEM_TRACKING
  23         SPL_AC_TEST_MODULE
  24         SPL_AC_ATOMIC_SPINLOCK
  25         SPL_AC_SHRINKER_CALLBACK
  26         SPL_AC_CTL_NAME
  27         SPL_AC_PDE_DATA
  28         SPL_AC_SET_FS_PWD_WITH_CONST
  29         SPL_AC_2ARGS_VFS_UNLINK
  30         SPL_AC_4ARGS_VFS_RENAME
  31         SPL_AC_2ARGS_VFS_FSYNC
  32         SPL_AC_INODE_TRUNCATE_RANGE
  33         SPL_AC_FS_STRUCT_SPINLOCK
  34         SPL_AC_KUIDGID_T
  35         SPL_AC_PUT_TASK_STRUCT
  36         SPL_AC_KERNEL_FALLOCATE
  37         SPL_AC_CONFIG_ZLIB_INFLATE
  38         SPL_AC_CONFIG_ZLIB_DEFLATE
  39         SPL_AC_2ARGS_ZLIB_DEFLATE_WORKSPACESIZE
  40         SPL_AC_SHRINK_CONTROL_STRUCT
  41         SPL_AC_RWSEM_SPINLOCK_IS_RAW
  42         SPL_AC_SCHED_RT_HEADER
  43         SPL_AC_2ARGS_VFS_GETATTR
  44         SPL_AC_USLEEP_RANGE
  45         SPL_AC_KMEM_CACHE_ALLOCFLAGS
  46         SPL_AC_WAIT_ON_BIT
  47 ])
  48
  49 AC_DEFUN([SPL_AC_MODULE_SYMVERS], [
  50         modpost=$LINUX/scripts/Makefile.modpost
  51         AC_MSG_CHECKING([kernel file name for module symbols])
  52         if test "x$enable_linux_builtin" != xyes -a -f "$modpost"; then
  53                 if grep -q Modules.symvers $modpost; then
  54                         LINUX_SYMBOLS=Modules.symvers
  55                 else
  56                         LINUX_SYMBOLS=Module.symvers
  57                 fi
  58
  59                 if ! test -f "$LINUX_OBJ/$LINUX_SYMBOLS"; then
  60                         AC_MSG_ERROR([
  61         *** Please make sure the kernel devel package for your distribution
  62         *** is installed.  If you are building with a custom kernel, make sure the
  63         *** kernel is configured, built, and the '--with-linux=PATH' configure
  64         *** option refers to the location of the kernel source.])
  65                 fi
  66         else
  67                 LINUX_SYMBOLS=NONE
  68         fi
  69         AC_MSG_RESULT($LINUX_SYMBOLS)
  70         AC_SUBST(LINUX_SYMBOLS)
  71 ])
  72
  73 AC_DEFUN([SPL_AC_KERNEL], [
  74         AC_ARG_WITH([linux],
  75                 AS_HELP_STRING([--with-linux=PATH],
  76                 [Path to kernel source]),
  77                 [kernelsrc="$withval"])
  78
  79         AC_ARG_WITH([linux-obj],
  80                 AS_HELP_STRING([--with-linux-obj=PATH],
  81                 [Path to kernel build objects]),
  82                 [kernelbuild="$withval"])
  83
  84         AC_MSG_CHECKING([kernel source directory])
  85         if test -z "$kernelsrc"; then
  86                 if test -e "/lib/modules/$(uname -r)/source"; then
  87                         headersdir="/lib/modules/$(uname -r)/source"
  88                         sourcelink=$(readlink -f "$headersdir")
  89                 elif test -e "/lib/modules/$(uname -r)/build"; then
  90                         headersdir="/lib/modules/$(uname -r)/build"
  91                         sourcelink=$(readlink -f "$headersdir")
  92                 else
  93                         sourcelink=$(ls -1d /usr/src/kernels/* \
  94                                      /usr/src/linux-* \
  95                                      2>/dev/null | grep -v obj | tail -1)
  96                 fi
  97
  98                 if test -n "$sourcelink" && test -e ${sourcelink}; then
  99                         kernelsrc=`readlink -f ${sourcelink}`
 100                 else
 101                         kernelsrc="[Not found]"
 102                 fi
 103         else
 104                 if test "$kernelsrc" = "NONE"; then
 105                         kernsrcver=NONE
 106                 fi
 107         fi
 108
 109         AC_MSG_RESULT([$kernelsrc])
 110         if test ! -d "$kernelsrc"; then
 111                 AC_MSG_ERROR([
 112         *** Please make sure the kernel devel package for your distribution
 113         *** is installed and then try again.  If that fails, you can specify the
 114         *** location of the kernel source with the '--with-linux=PATH' option.])
 115         fi
 116
 117         AC_MSG_CHECKING([kernel build directory])
 118         if test -z "$kernelbuild"; then
 119                 if test -e "/lib/modules/$(uname -r)/build"; then
 120                         kernelbuild=`readlink -f /lib/modules/$(uname -r)/build`
 121                 elif test -d ${kernelsrc}-obj/${target_cpu}/${target_cpu}; then
 122                         kernelbuild=${kernelsrc}-obj/${target_cpu}/${target_cpu}
 123                 elif test -d ${kernelsrc}-obj/${target_cpu}/default; then
 124                         kernelbuild=${kernelsrc}-obj/${target_cpu}/default
 125                 elif test -d `dirname ${kernelsrc}`/build-${target_cpu}; then
 126                         kernelbuild=`dirname ${kernelsrc}`/build-${target_cpu}
 127                 else
 128                         kernelbuild=${kernelsrc}
 129                 fi
 130         fi
 131         AC_MSG_RESULT([$kernelbuild])
 132
 133         AC_MSG_CHECKING([kernel source version])
 134         utsrelease1=$kernelbuild/include/linux/version.h
 135         utsrelease2=$kernelbuild/include/linux/utsrelease.h
 136         utsrelease3=$kernelbuild/include/generated/utsrelease.h
 137         if test -r $utsrelease1 && fgrep -q UTS_RELEASE $utsrelease1; then
 138                 utsrelease=linux/version.h
 139         elif test -r $utsrelease2 && fgrep -q UTS_RELEASE $utsrelease2; then
 140                 utsrelease=linux/utsrelease.h
 141         elif test -r $utsrelease3 && fgrep -q UTS_RELEASE $utsrelease3; then
 142                 utsrelease=generated/utsrelease.h
 143         fi
 144
 145         if test "$utsrelease"; then
 146                 kernsrcver=`(echo "#include <$utsrelease>";
 147                              echo "kernsrcver=UTS_RELEASE") |
 148                              cpp -I $kernelbuild/include |
 149                              grep "^kernsrcver=" | cut -d \" -f 2`
 150
 151                 if test -z "$kernsrcver"; then
 152                         AC_MSG_RESULT([Not found])
 153                         AC_MSG_ERROR([*** Cannot determine kernel version.])
 154                 fi
 155         else
 156                 AC_MSG_RESULT([Not found])
 157                 if test "x$enable_linux_builtin" != xyes; then
 158                         AC_MSG_ERROR([*** Cannot find UTS_RELEASE definition.])
 159                 else
 160                         AC_MSG_ERROR([
 161         *** Cannot find UTS_RELEASE definition.
 162         *** Please run 'make prepare' inside the kernel source tree.])
 163                 fi
 164         fi
 165
 166         AC_MSG_RESULT([$kernsrcver])
 167
 168         LINUX=${kernelsrc}
 169         LINUX_OBJ=${kernelbuild}
 170         LINUX_VERSION=${kernsrcver}
 171
 172         AC_SUBST(LINUX)
 173         AC_SUBST(LINUX_OBJ)
 174         AC_SUBST(LINUX_VERSION)
 175
 176         SPL_AC_MODULE_SYMVERS
 177 ])
 178
 179 dnl #
 180 dnl # Default SPL user configuration
 181 dnl #
 182 AC_DEFUN([SPL_AC_CONFIG_USER], [])
 183
 184 dnl #
 185 dnl # Check for rpm+rpmbuild to build RPM packages.  If these tools
 186 dnl # are missing, it is non-fatal, but you will not be able to build
 187 dnl # RPM packages and will be warned if you try too.
 188 dnl #
 189 dnl # By default, the generic spec file will be used because it requires
 190 dnl # minimal dependencies.  Distribution specific spec files can be
 191 dnl # placed under the 'rpm/<distribution>' directory and enabled using
 192 dnl # the --with-spec=<distribution> configure option.
 193 dnl #
 194 AC_DEFUN([SPL_AC_RPM], [
 195         RPM=rpm
 196         RPMBUILD=rpmbuild
 197
 198         AC_MSG_CHECKING([whether $RPM is available])
 199         AS_IF([tmp=$($RPM --version 2>/dev/null)], [
 200                 RPM_VERSION=$(echo $tmp | $AWK '/RPM/ { print $[3] }')
 201                 HAVE_RPM=yes
 202                 AC_MSG_RESULT([$HAVE_RPM ($RPM_VERSION)])
 203         ],[
 204                 HAVE_RPM=no
 205                 AC_MSG_RESULT([$HAVE_RPM])
 206         ])
 207
 208         AC_MSG_CHECKING([whether $RPMBUILD is available])
 209         AS_IF([tmp=$($RPMBUILD --version 2>/dev/null)], [
 210                 RPMBUILD_VERSION=$(echo $tmp | $AWK '/RPM/ { print $[3] }')
 211                 HAVE_RPMBUILD=yes
 212                 AC_MSG_RESULT([$HAVE_RPMBUILD ($RPMBUILD_VERSION)])
 213         ],[
 214                 HAVE_RPMBUILD=no
 215                 AC_MSG_RESULT([$HAVE_RPMBUILD])
 216         ])
 217
 218         RPM_DEFINE_COMMON='--define "$(DEBUG_SPL) 1" --define "$(DEBUG_KMEM) 1" --define "$(DEBUG_KMEM_TRACKING) 1"'
 219         RPM_DEFINE_UTIL=
 220         RPM_DEFINE_KMOD='--define "kernels $(LINUX_VERSION)"'
 221         RPM_DEFINE_DKMS=
 222
 223         SRPM_DEFINE_COMMON='--define "build_src_rpm 1"'
 224         SRPM_DEFINE_UTIL=
 225         SRPM_DEFINE_KMOD=
 226         SRPM_DEFINE_DKMS=
 227
 228         RPM_SPEC_DIR="rpm/generic"
 229         AC_ARG_WITH([spec],
 230                 AS_HELP_STRING([--with-spec=SPEC],
 231                 [Spec files 'generic|redhat']),
 232                 [RPM_SPEC_DIR="rpm/$withval"])
 233
 234         AC_MSG_CHECKING([whether spec files are available])
 235         AC_MSG_RESULT([yes ($RPM_SPEC_DIR/*.spec.in)])
 236
 237         AC_SUBST(HAVE_RPM)
 238         AC_SUBST(RPM)
 239         AC_SUBST(RPM_VERSION)
 240
 241         AC_SUBST(HAVE_RPMBUILD)
 242         AC_SUBST(RPMBUILD)
 243         AC_SUBST(RPMBUILD_VERSION)
 244
 245         AC_SUBST(RPM_SPEC_DIR)
 246         AC_SUBST(RPM_DEFINE_UTIL)
 247         AC_SUBST(RPM_DEFINE_KMOD)
 248         AC_SUBST(RPM_DEFINE_DKMS)
 249         AC_SUBST(RPM_DEFINE_COMMON)
 250         AC_SUBST(SRPM_DEFINE_UTIL)
 251         AC_SUBST(SRPM_DEFINE_KMOD)
 252         AC_SUBST(SRPM_DEFINE_DKMS)
 253         AC_SUBST(SRPM_DEFINE_COMMON)
 254 ])
 255
 256 dnl #
 257 dnl # Check for dpkg+dpkg-buildpackage to build DEB packages.  If these
 258 dnl # tools are missing it is non-fatal but you will not be able to build
 259 dnl # DEB packages and will be warned if you try too.
 260 dnl #
 261 AC_DEFUN([SPL_AC_DPKG], [
 262         DPKG=dpkg
 263         DPKGBUILD=dpkg-buildpackage
 264
 265         AC_MSG_CHECKING([whether $DPKG is available])
 266         AS_IF([tmp=$($DPKG --version 2>/dev/null)], [
 267                 DPKG_VERSION=$(echo $tmp | $AWK '/Debian/ { print $[7] }')
 268                 HAVE_DPKG=yes
 269                 AC_MSG_RESULT([$HAVE_DPKG ($DPKG_VERSION)])
 270         ],[
 271                 HAVE_DPKG=no
 272                 AC_MSG_RESULT([$HAVE_DPKG])
 273         ])
 274
 275         AC_MSG_CHECKING([whether $DPKGBUILD is available])
 276         AS_IF([tmp=$($DPKGBUILD --version 2>/dev/null)], [
 277                 DPKGBUILD_VERSION=$(echo $tmp | \
 278                     $AWK '/Debian/ { print $[4] }' | cut -f-4 -d'.')
 279                 HAVE_DPKGBUILD=yes
 280                 AC_MSG_RESULT([$HAVE_DPKGBUILD ($DPKGBUILD_VERSION)])
 281         ],[
 282                 HAVE_DPKGBUILD=no
 283                 AC_MSG_RESULT([$HAVE_DPKGBUILD])
 284         ])
 285
 286         AC_SUBST(HAVE_DPKG)
 287         AC_SUBST(DPKG)
 288         AC_SUBST(DPKG_VERSION)
 289
 290         AC_SUBST(HAVE_DPKGBUILD)
 291         AC_SUBST(DPKGBUILD)
 292         AC_SUBST(DPKGBUILD_VERSION)
 293 ])
 294
 295 dnl #
 296 dnl # Until native packaging for various different packing systems
 297 dnl # can be added the least we can do is attempt to use alien to
 298 dnl # convert the RPM packages to the needed package type.  This is
 299 dnl # a hack but so far it has worked reasonable well.
 300 dnl #
 301 AC_DEFUN([SPL_AC_ALIEN], [
 302         ALIEN=alien
 303
 304         AC_MSG_CHECKING([whether $ALIEN is available])
 305         AS_IF([tmp=$($ALIEN --version 2>/dev/null)], [
 306                 ALIEN_VERSION=$(echo $tmp | $AWK '{ print $[3] }')
 307                 HAVE_ALIEN=yes
 308                 AC_MSG_RESULT([$HAVE_ALIEN ($ALIEN_VERSION)])
 309         ],[
 310                 HAVE_ALIEN=no
 311                 AC_MSG_RESULT([$HAVE_ALIEN])
 312         ])
 313
 314         AC_SUBST(HAVE_ALIEN)
 315         AC_SUBST(ALIEN)
 316         AC_SUBST(ALIEN_VERSION)
 317 ])
 318
 319 dnl #
 320 dnl # Using the VENDOR tag from config.guess set the default
 321 dnl # package type for 'make pkg': (rpm | deb | tgz)
 322 dnl #
 323 AC_DEFUN([SPL_AC_DEFAULT_PACKAGE], [
 324         AC_MSG_CHECKING([linux distribution])
 325         if test -f /etc/toss-release ; then
 326                 VENDOR=toss ;
 327         elif test -f /etc/fedora-release ; then
 328                 VENDOR=fedora ;
 329         elif test -f /etc/redhat-release ; then
 330                 VENDOR=redhat ;
 331         elif test -f /etc/gentoo-release ; then
 332                 VENDOR=gentoo ;
 333         elif test -f /etc/arch-release ; then
 334                 VENDOR=arch ;
 335         elif test -f /etc/SuSE-release ; then
 336                 VENDOR=sles ;
 337         elif test -f /etc/slackware-version ; then
 338                 VENDOR=slackware ;
 339         elif test -f /etc/lunar.release ; then
 340                 VENDOR=lunar ;
 341         elif test -f /etc/lsb-release ; then
 342                 VENDOR=ubuntu ;
 343         elif test -f /etc/debian_version ; then
 344                 VENDOR=debian ;
 345         else
 346                 VENDOR= ;
 347         fi
 348         AC_MSG_RESULT([$VENDOR])
 349         AC_SUBST(VENDOR)
 350
 351         AC_MSG_CHECKING([default package type])
 352         case "$VENDOR" in
 353                 toss)       DEFAULT_PACKAGE=rpm  ;;
 354                 redhat)     DEFAULT_PACKAGE=rpm  ;;
 355                 fedora)     DEFAULT_PACKAGE=rpm  ;;
 356                 gentoo)     DEFAULT_PACKAGE=tgz  ;;
 357                 arch)       DEFAULT_PACKAGE=tgz  ;;
 358                 sles)       DEFAULT_PACKAGE=rpm  ;;
 359                 slackware)  DEFAULT_PACKAGE=tgz  ;;
 360                 lunar)      DEFAULT_PACKAGE=tgz  ;;
 361                 ubuntu)     DEFAULT_PACKAGE=deb  ;;
 362                 debian)     DEFAULT_PACKAGE=deb  ;;
 363                 *)          DEFAULT_PACKAGE=rpm  ;;
 364         esac
 365
 366         AC_MSG_RESULT([$DEFAULT_PACKAGE])
 367         AC_SUBST(DEFAULT_PACKAGE)
 368 ])
 369
 370 dnl #
 371 dnl # Default SPL user configuration
 372 dnl #
 373 AC_DEFUN([SPL_AC_PACKAGE], [
 374         SPL_AC_DEFAULT_PACKAGE
 375         SPL_AC_RPM
 376         SPL_AC_DPKG
 377         SPL_AC_ALIEN
 378 ])
 379
 380 AC_DEFUN([SPL_AC_LICENSE], [
 381         AC_MSG_CHECKING([spl author])
 382         AC_MSG_RESULT([$SPL_META_AUTHOR])
 383
 384         AC_MSG_CHECKING([spl license])
 385         AC_MSG_RESULT([$SPL_META_LICENSE])
 386 ])
 387
 388 AC_DEFUN([SPL_AC_CONFIG], [
 389         SPL_CONFIG=all
 390         AC_ARG_WITH([config],
 391                 AS_HELP_STRING([--with-config=CONFIG],
 392                 [Config file 'kernel|user|all|srpm']),
 393                 [SPL_CONFIG="$withval"])
 394         AC_ARG_ENABLE([linux-builtin],
 395                 [AC_HELP_STRING([--enable-linux-builtin],
 396                 [Configure for builtin in-tree kernel modules @<:@default=no@:>@])],
 397                 [],
 398                 [enable_linux_builtin=no])
 399
 400         AC_MSG_CHECKING([spl config])
 401         AC_MSG_RESULT([$SPL_CONFIG]);
 402         AC_SUBST(SPL_CONFIG)
 403
 404         case "$SPL_CONFIG" in
 405                 kernel) SPL_AC_CONFIG_KERNEL ;;
 406                 user)   SPL_AC_CONFIG_USER   ;;
 407                 all)    SPL_AC_CONFIG_KERNEL
 408                         SPL_AC_CONFIG_USER   ;;
 409                 srpm)                        ;;
 410                 *)
 411                 AC_MSG_RESULT([Error!])
 412                 AC_MSG_ERROR([Bad value "$SPL_CONFIG" for --with-config,
 413                              user kernel|user|all|srpm]) ;;
 414         esac
 415
 416         AM_CONDITIONAL([CONFIG_USER],
 417                        [test "$SPL_CONFIG" = user -o "$SPL_CONFIG" = all])
 418         AM_CONDITIONAL([CONFIG_KERNEL],
 419                        [test "$SPL_CONFIG" = kernel -o "$SPL_CONFIG" = all] &&
 420                        [test "x$enable_linux_builtin" != xyes ])
 421 ])
 422
 423 dnl #
 424 dnl # Enable if the SPL should be compiled with internal debugging enabled.
 425 dnl # By default this support is disabled.
 426 dnl #
 427 AC_DEFUN([SPL_AC_DEBUG], [
 428         AC_MSG_CHECKING([whether debugging is enabled])
 429         AC_ARG_ENABLE([debug],
 430                 [AS_HELP_STRING([--enable-debug],
 431                 [Enable generic debug support @<:@default=no@:>@])],
 432                 [],
 433                 [enable_debug=no])
 434
 435         AS_IF([test "x$enable_debug" = xyes],
 436         [
 437                 KERNELCPPFLAGS="${KERNELCPPFLAGS} -DDEBUG -Werror"
 438                 DEBUG_CFLAGS="-DDEBUG -Werror"
 439                 DEBUG_SPL="_with_debug"
 440         ], [
 441                 KERNELCPPFLAGS="${KERNELCPPFLAGS} -DNDEBUG"
 442                 DEBUG_CFLAGS="-DNDEBUG"
 443                 DEBUG_SPL="_without_debug"
 444         ])
 445
 446         AC_SUBST(DEBUG_CFLAGS)
 447         AC_SUBST(DEBUG_SPL)
 448         AC_MSG_RESULT([$enable_debug])
 449 ])
 450
 451 dnl #
 452 dnl # Enabled by default it provides a minimal level of memory tracking.
 453 dnl # A total count of bytes allocated is kept for each alloc and free.
 454 dnl # Then at module unload time a report to the console will be printed
 455 dnl # if memory was leaked.
 456 dnl #
 457 AC_DEFUN([SPL_AC_DEBUG_KMEM], [
 458         AC_ARG_ENABLE([debug-kmem],
 459                 [AS_HELP_STRING([--enable-debug-kmem],
 460                 [Enable basic kmem accounting @<:@default=no@:>@])],
 461                 [],
 462                 [enable_debug_kmem=no])
 463
 464         AS_IF([test "x$enable_debug_kmem" = xyes],
 465         [
 466                 KERNELCPPFLAGS="${KERNELCPPFLAGS} -DDEBUG_KMEM"
 467                 DEBUG_KMEM="_with_debug_kmem"
 468                 AC_DEFINE([DEBUG_KMEM], [1],
 469                 [Define to 1 to enable basic kmem accounting])
 470         ], [
 471                 DEBUG_KMEM="_without_debug_kmem"
 472         ])
 473
 474         AC_SUBST(DEBUG_KMEM)
 475         AC_MSG_CHECKING([whether basic kmem accounting is enabled])
 476         AC_MSG_RESULT([$enable_debug_kmem])
 477 ])
 478
 479 dnl #
 480 dnl # Disabled by default it provides detailed memory tracking.  This
 481 dnl # feature also requires --enable-debug-kmem to be set.  When enabled
 482 dnl # not only will total bytes be tracked but also the location of every
 483 dnl # alloc and free.  When the SPL module is unloaded a list of all leaked
 484 dnl # addresses and where they were allocated will be dumped to the console.
 485 dnl # Enabling this feature has a significant impact on performance but it
 486 dnl # makes finding memory leaks pretty straight forward.
 487 dnl #
 488 AC_DEFUN([SPL_AC_DEBUG_KMEM_TRACKING], [
 489         AC_ARG_ENABLE([debug-kmem-tracking],
 490                 [AS_HELP_STRING([--enable-debug-kmem-tracking],
 491                 [Enable detailed kmem tracking  @<:@default=no@:>@])],
 492                 [],
 493                 [enable_debug_kmem_tracking=no])
 494
 495         AS_IF([test "x$enable_debug_kmem_tracking" = xyes],
 496         [
 497                 KERNELCPPFLAGS="${KERNELCPPFLAGS} -DDEBUG_KMEM_TRACKING"
 498                 DEBUG_KMEM_TRACKING="_with_debug_kmem_tracking"
 499                 AC_DEFINE([DEBUG_KMEM_TRACKING], [1],
 500                 [Define to 1 to enable detailed kmem tracking])
 501         ], [
 502                 DEBUG_KMEM_TRACKING="_without_debug_kmem_tracking"
 503         ])
 504
 505         AC_SUBST(DEBUG_KMEM_TRACKING)
 506         AC_MSG_CHECKING([whether detailed kmem tracking is enabled])
 507         AC_MSG_RESULT([$enable_debug_kmem_tracking])
 508 ])
 509
 510 dnl #
 511 dnl # SPL_LINUX_CONFTEST
 512 dnl #
 513 AC_DEFUN([SPL_LINUX_CONFTEST], [
 514 cat confdefs.h - <<_ACEOF >conftest.c
 515 $1
 516 _ACEOF
 517 ])
 518
 519 dnl #
 520 dnl # SPL_LANG_PROGRAM(C)([PROLOGUE], [BODY])
 521 dnl #
 522 m4_define([SPL_LANG_PROGRAM], [
 523 $1
 524 int
 525 main (void)
 526 {
 527 dnl Do *not* indent the following line: there may be CPP directives.
 528 dnl Don't move the `;' right after for the same reason.
 529 $2
 530   ;
 531   return 0;
 532 }
 533 ])
 534
 535 dnl #
 536 dnl # SPL_LINUX_COMPILE_IFELSE / like AC_COMPILE_IFELSE
 537 dnl #
 538 AC_DEFUN([SPL_LINUX_COMPILE_IFELSE], [
 539         m4_ifvaln([$1], [SPL_LINUX_CONFTEST([$1])])
 540         rm -Rf build && mkdir -p build && touch build/conftest.mod.c
 541         echo "obj-m := conftest.o" >build/Makefile
 542         modpost_flag=''
 543         test "x$enable_linux_builtin" = xyes && modpost_flag='modpost=true' # fake modpost stage
 544         AS_IF(
 545                 [AC_TRY_COMMAND(cp conftest.c build && make [$2] -C $LINUX_OBJ EXTRA_CFLAGS="-Werror-implicit-function-declaration $EXTRA_KCFLAGS" $ARCH_UM M=$PWD/build $modpost_flag) >/dev/null && AC_TRY_COMMAND([$3])],
 546                 [$4],
 547                 [_AC_MSG_LOG_CONFTEST m4_ifvaln([$5],[$5])]
 548         )
 549         rm -Rf build
 550 ])
 551
 552 dnl #
 553 dnl # SPL_LINUX_TRY_COMPILE like AC_TRY_COMPILE
 554 dnl #
 555 AC_DEFUN([SPL_LINUX_TRY_COMPILE],
 556         [SPL_LINUX_COMPILE_IFELSE(
 557         [AC_LANG_SOURCE([SPL_LANG_PROGRAM([[$1]], [[$2]])])],
 558         [modules],
 559         [test -s build/conftest.o],
 560         [$3], [$4])
 561 ])
 562
 563 dnl #
 564 dnl # SPL_CHECK_SYMBOL_EXPORT
 565 dnl # check symbol exported or not
 566 dnl #
 567 AC_DEFUN([SPL_CHECK_SYMBOL_EXPORT], [
 568         grep -q -E '[[[:space:]]]$1[[[:space:]]]' \
 569                 $LINUX_OBJ/Module*.symvers 2>/dev/null
 570         rc=$?
 571         if test $rc -ne 0; then
 572                 export=0
 573                 for file in $2; do
 574                         grep -q -E "EXPORT_SYMBOL.*($1)" \
 575                                 "$LINUX_OBJ/$file" 2>/dev/null
 576                         rc=$?
 577                         if test $rc -eq 0; then
 578                                 export=1
 579                                 break;
 580                         fi
 581                 done
 582                 if test $export -eq 0; then :
 583                         $4
 584                 else :
 585                         $3
 586                 fi
 587         else :
 588                 $3
 589         fi
 590 ])
 591
 592 dnl #
 593 dnl # SPL_LINUX_TRY_COMPILE_SYMBOL
 594 dnl # like SPL_LINUX_TRY_COMPILE, except SPL_CHECK_SYMBOL_EXPORT
 595 dnl # is called if not compiling for builtin
 596 dnl #
 597 AC_DEFUN([SPL_LINUX_TRY_COMPILE_SYMBOL], [
 598         SPL_LINUX_TRY_COMPILE([$1], [$2], [rc=0], [rc=1])
 599         if test $rc -ne 0; then :
 600                 $6
 601         else
 602                 if test "x$enable_linux_builtin" != xyes; then
 603                         SPL_CHECK_SYMBOL_EXPORT([$3], [$4], [rc=0], [rc=1])
 604                 fi
 605                 if test $rc -ne 0; then :
 606                         $6
 607                 else :
 608                         $5
 609                 fi
 610         fi
 611 ])
 612
 613 dnl #
 614 dnl # SPL_CHECK_SYMBOL_HEADER
 615 dnl # check if a symbol prototype is defined in listed headers.
 616 dnl #
 617 AC_DEFUN([SPL_CHECK_SYMBOL_HEADER], [
 618         AC_MSG_CHECKING([whether symbol $1 exists in header])
 619         header=0
 620         for file in $3; do
 621                 grep -q "$2" "$LINUX/$file" 2>/dev/null
 622                 rc=$?
 623                 if test $rc -eq 0; then
 624                         header=1
 625                         break;
 626                 fi
 627         done
 628         if test $header -eq 0; then
 629                 AC_MSG_RESULT([no])
 630                 $5
 631         else
 632                 AC_MSG_RESULT([yes])
 633                 $4
 634         fi
 635 ])
 636
 637 dnl #
 638 dnl # SPL_CHECK_HEADER
 639 dnl # check whether header exists and define HAVE_$2_HEADER
 640 dnl #
 641 AC_DEFUN([SPL_CHECK_HEADER],
 642         [AC_MSG_CHECKING([whether header $1 exists])
 643         SPL_LINUX_TRY_COMPILE([
 644                 #include <$1>
 645         ],[
 646                 return 0;
 647         ],[
 648                 AC_DEFINE(HAVE_$2_HEADER, 1, [$1 exists])
 649                 AC_MSG_RESULT(yes)
 650                 $3
 651         ],[
 652                 AC_MSG_RESULT(no)
 653                 $4
 654         ])
 655 ])
 656
 657 dnl #
 658 dnl # Basic toolchain sanity check.  Verify that kernel modules can
 659 dnl # be built and which symbols can be used.
 660 dnl #
 661 AC_DEFUN([SPL_AC_TEST_MODULE],
 662         [AC_MSG_CHECKING([whether modules can be built])
 663         SPL_LINUX_TRY_COMPILE([],[],[
 664                 AC_MSG_RESULT([yes])
 665         ],[
 666                 AC_MSG_RESULT([no])
 667                 if test "x$enable_linux_builtin" != xyes; then
 668                         AC_MSG_ERROR([*** Unable to build an empty module.])
 669                 else
 670                         AC_MSG_ERROR([
 671         *** Unable to build an empty module.
 672         *** Please run 'make scripts' inside the kernel source tree.])
 673                 fi
 674         ])
 675
 676         AC_RUN_IFELSE([
 677                 AC_LANG_PROGRAM([
 678                         #include "$LINUX/include/linux/license.h"
 679                 ], [
 680                         return !license_is_gpl_compatible("$SPL_META_LICENSE");
 681                 ])
 682         ], [
 683                 AC_DEFINE([SPL_IS_GPL_COMPATIBLE], [1],
 684                     [Define to 1 if GPL-only symbols can be used])
 685         ], [
 686         ])
 687 ])
 688
 689 dnl #
 690 dnl # Use the atomic implemenation based on global spinlocks.  This
 691 dnl # should only be needed by 32-bit kernels which do not provide
 692 dnl # the atomic64_* API.  It may be optionally enabled as a fallback
 693 dnl # if problems are observed with the direct mapping to the native
 694 dnl # Linux atomic operations.  You may not disable atomic spinlocks
 695 dnl # if you kernel does not an atomic64_* API.
 696 dnl #
 697 AC_DEFUN([SPL_AC_ATOMIC_SPINLOCK], [
 698         AC_ARG_ENABLE([atomic-spinlocks],
 699                 [AS_HELP_STRING([--enable-atomic-spinlocks],
 700                 [Atomic types use spinlocks @<:@default=check@:>@])],
 701                 [],
 702                 [enable_atomic_spinlocks=check])
 703
 704         SPL_LINUX_TRY_COMPILE([
 705                 #include <linux/fs.h>
 706         ],[
 707                 atomic64_t *ptr __attribute__ ((unused));
 708         ],[
 709                 have_atomic64_t=yes
 710                 AC_DEFINE(HAVE_ATOMIC64_T, 1,
 711                         [kernel defines atomic64_t])
 712         ],[
 713                 have_atomic64_t=no
 714         ])
 715
 716         AS_IF([test "x$enable_atomic_spinlocks" = xcheck], [
 717                 AS_IF([test "x$have_atomic64_t" = xyes], [
 718                         enable_atomic_spinlocks=no
 719                 ],[
 720                         enable_atomic_spinlocks=yes
 721                 ])
 722         ])
 723
 724         AS_IF([test "x$enable_atomic_spinlocks" = xyes], [
 725                 AC_DEFINE([ATOMIC_SPINLOCK], [1],
 726                         [Atomic types use spinlocks])
 727         ],[
 728                 AS_IF([test "x$have_atomic64_t" = xno], [
 729                         AC_MSG_FAILURE(
 730                         [--disable-atomic-spinlocks given but required atomic64 support is unavailable])
 731                 ])
 732         ])
 733
 734         AC_MSG_CHECKING([whether atomic types use spinlocks])
 735         AC_MSG_RESULT([$enable_atomic_spinlocks])
 736
 737         AC_MSG_CHECKING([whether kernel defines atomic64_t])
 738         AC_MSG_RESULT([$have_atomic64_t])
 739 ])
 740
 741 AC_DEFUN([SPL_AC_SHRINKER_CALLBACK],[
 742         tmp_flags="$EXTRA_KCFLAGS"
 743         EXTRA_KCFLAGS="-Werror"
 744         dnl #
 745         dnl # 2.6.23 to 2.6.34 API change
 746         dnl # ->shrink(int nr_to_scan, gfp_t gfp_mask)
 747         dnl #
 748         AC_MSG_CHECKING([whether old 2-argument shrinker exists])
 749         SPL_LINUX_TRY_COMPILE([
 750                 #include <linux/mm.h>
 751
 752                 int shrinker_cb(int nr_to_scan, gfp_t gfp_mask);
 753         ],[
 754                 struct shrinker cache_shrinker = {
 755                         .shrink = shrinker_cb,
 756                         .seeks = DEFAULT_SEEKS,
 757                 };
 758                 register_shrinker(&cache_shrinker);
 759         ],[
 760                 AC_MSG_RESULT(yes)
 761                 AC_DEFINE(HAVE_2ARGS_OLD_SHRINKER_CALLBACK, 1,
 762                         [old shrinker callback wants 2 args])
 763         ],[
 764                 AC_MSG_RESULT(no)
 765                 dnl #
 766                 dnl # 2.6.35 - 2.6.39 API change
 767                 dnl # ->shrink(struct shrinker *,
 768                 dnl #          int nr_to_scan, gfp_t gfp_mask)
 769                 dnl #
 770                 AC_MSG_CHECKING([whether old 3-argument shrinker exists])
 771                 SPL_LINUX_TRY_COMPILE([
 772                         #include <linux/mm.h>
 773
 774                         int shrinker_cb(struct shrinker *, int nr_to_scan,
 775                                         gfp_t gfp_mask);
 776                 ],[
 777                         struct shrinker cache_shrinker = {
 778                                 .shrink = shrinker_cb,
 779                                 .seeks = DEFAULT_SEEKS,
 780                         };
 781                         register_shrinker(&cache_shrinker);
 782                 ],[
 783                         AC_MSG_RESULT(yes)
 784                         AC_DEFINE(HAVE_3ARGS_SHRINKER_CALLBACK, 1,
 785                                 [old shrinker callback wants 3 args])
 786                 ],[
 787                         AC_MSG_RESULT(no)
 788                         dnl #
 789                         dnl # 3.0 - 3.11 API change
 790                         dnl # ->shrink(struct shrinker *,
 791                         dnl #          struct shrink_control *sc)
 792                         dnl #
 793                         AC_MSG_CHECKING(
 794                                 [whether new 2-argument shrinker exists])
 795                         SPL_LINUX_TRY_COMPILE([
 796                                 #include <linux/mm.h>
 797
 798                                 int shrinker_cb(struct shrinker *,
 799                                                 struct shrink_control *sc);
 800                         ],[
 801                                 struct shrinker cache_shrinker = {
 802                                         .shrink = shrinker_cb,
 803                                         .seeks = DEFAULT_SEEKS,
 804                                 };
 805                                 register_shrinker(&cache_shrinker);
 806                         ],[
 807                                 AC_MSG_RESULT(yes)
 808                                 AC_DEFINE(HAVE_2ARGS_NEW_SHRINKER_CALLBACK, 1,
 809                                         [new shrinker callback wants 2 args])
 810                         ],[
 811                                 AC_MSG_RESULT(no)
 812                                 dnl #
 813                                 dnl # 3.12 API change,
 814                                 dnl # ->shrink() is logically split in to
 815                                 dnl # ->count_objects() and ->scan_objects()
 816                                 dnl #
 817                                 AC_MSG_CHECKING(
 818                                     [whether ->count_objects callback exists])
 819                                 SPL_LINUX_TRY_COMPILE([
 820                                         #include <linux/mm.h>
 821
 822                                         unsigned long shrinker_cb(
 823                                                 struct shrinker *,
 824                                                 struct shrink_control *sc);
 825                                 ],[
 826                                         struct shrinker cache_shrinker = {
 827                                                 .count_objects = shrinker_cb,
 828                                                 .scan_objects = shrinker_cb,
 829                                                 .seeks = DEFAULT_SEEKS,
 830                                         };
 831                                         register_shrinker(&cache_shrinker);
 832                                 ],[
 833                                         AC_MSG_RESULT(yes)
 834                                         AC_DEFINE(HAVE_SPLIT_SHRINKER_CALLBACK,
 835                                                 1, [->count_objects exists])
 836                                 ],[
 837                                         AC_MSG_ERROR(error)
 838                                 ])
 839                         ])
 840                 ])
 841         ])
 842         EXTRA_KCFLAGS="$tmp_flags"
 843 ])
 844
 845 dnl #
 846 dnl # 2.6.33 API change,
 847 dnl # Removed .ctl_name from struct ctl_table.
 848 dnl #
 849 AC_DEFUN([SPL_AC_CTL_NAME], [
 850         AC_MSG_CHECKING([whether struct ctl_table has ctl_name])
 851         SPL_LINUX_TRY_COMPILE([
 852                 #include <linux/sysctl.h>
 853         ],[
 854                 struct ctl_table ctl __attribute__ ((unused));
 855                 ctl.ctl_name = 0;
 856         ],[
 857                 AC_MSG_RESULT(yes)
 858                 AC_DEFINE(HAVE_CTL_NAME, 1, [struct ctl_table has ctl_name])
 859         ],[
 860                 AC_MSG_RESULT(no)
 861         ])
 862 ])
 863
 864 dnl #
 865 dnl # 3.10 API change,
 866 dnl # PDE is replaced by PDE_DATA
 867 dnl #
 868 AC_DEFUN([SPL_AC_PDE_DATA], [
 869         AC_MSG_CHECKING([whether PDE_DATA() is available])
 870         SPL_LINUX_TRY_COMPILE_SYMBOL([
 871                 #include <linux/proc_fs.h>
 872         ], [
 873                 PDE_DATA(NULL);
 874         ], [PDE_DATA], [], [
 875                 AC_MSG_RESULT(yes)
 876                 AC_DEFINE(HAVE_PDE_DATA, 1, [yes])
 877         ],[
 878                 AC_MSG_RESULT(no)
 879         ])
 880 ])
 881
 882 dnl #
 883 dnl # 3.9 API change
 884 dnl # set_fs_pwd takes const struct path *
 885 dnl #
 886 AC_DEFUN([SPL_AC_SET_FS_PWD_WITH_CONST],
 887         tmp_flags="$EXTRA_KCFLAGS"
 888         EXTRA_KCFLAGS="-Werror"
 889         [AC_MSG_CHECKING([whether set_fs_pwd() requires const struct path *])
 890         SPL_LINUX_TRY_COMPILE([
 891                 #include <linux/spinlock.h>
 892                 #include <linux/fs_struct.h>
 893                 #include <linux/path.h>
 894                 void (*const set_fs_pwd_func)
 895                         (struct fs_struct *, const struct path *)
 896                         = set_fs_pwd;
 897         ],[
 898                 return 0;
 899         ],[
 900                 AC_MSG_RESULT(yes)
 901                 AC_DEFINE(HAVE_SET_FS_PWD_WITH_CONST, 1,
 902                         [set_fs_pwd() needs const path *])
 903         ],[
 904                 SPL_LINUX_TRY_COMPILE([
 905                         #include <linux/spinlock.h>
 906                         #include <linux/fs_struct.h>
 907                         #include <linux/path.h>
 908                         void (*const set_fs_pwd_func)
 909                                 (struct fs_struct *, struct path *)
 910                                 = set_fs_pwd;
 911                 ],[
 912                         return 0;
 913                 ],[
 914                         AC_MSG_RESULT(no)
 915                 ],[
 916                         AC_MSG_ERROR(unknown)
 917                 ])
 918         ])
 919         EXTRA_KCFLAGS="$tmp_flags"
 920 ])
 921
 922 dnl #
 923 dnl # 3.13 API change
 924 dnl # vfs_unlink() updated to take a third delegated_inode argument.
 925 dnl #
 926 AC_DEFUN([SPL_AC_2ARGS_VFS_UNLINK],
 927         [AC_MSG_CHECKING([whether vfs_unlink() wants 2 args])
 928         SPL_LINUX_TRY_COMPILE([
 929                 #include <linux/fs.h>
 930         ],[
 931                 vfs_unlink((struct inode *) NULL, (struct dentry *) NULL);
 932         ],[
 933                 AC_MSG_RESULT(yes)
 934                 AC_DEFINE(HAVE_2ARGS_VFS_UNLINK, 1,
 935                           [vfs_unlink() wants 2 args])
 936         ],[
 937                 AC_MSG_RESULT(no)
 938                 dnl #
 939                 dnl # Linux 3.13 API change
 940                 dnl # Added delegated inode
 941                 dnl #
 942                 AC_MSG_CHECKING([whether vfs_unlink() wants 3 args])
 943                 SPL_LINUX_TRY_COMPILE([
 944                         #include <linux/fs.h>
 945                 ],[
 946                         vfs_unlink((struct inode *) NULL,
 947                                 (struct dentry *) NULL,
 948                                 (struct inode **) NULL);
 949                 ],[
 950                         AC_MSG_RESULT(yes)
 951                         AC_DEFINE(HAVE_3ARGS_VFS_UNLINK, 1,
 952                                   [vfs_unlink() wants 3 args])
 953                 ],[
 954                         AC_MSG_ERROR(no)
 955                 ])
 956
 957         ])
 958 ])
 959
 960 dnl #
 961 dnl # 3.13 and 3.15 API changes
 962 dnl # Added delegated inode and flags argument.
 963 dnl #
 964 AC_DEFUN([SPL_AC_4ARGS_VFS_RENAME],
 965         [AC_MSG_CHECKING([whether vfs_rename() wants 4 args])
 966         SPL_LINUX_TRY_COMPILE([
 967                 #include <linux/fs.h>
 968         ],[
 969                 vfs_rename((struct inode *) NULL, (struct dentry *) NULL,
 970                         (struct inode *) NULL, (struct dentry *) NULL);
 971         ],[
 972                 AC_MSG_RESULT(yes)
 973                 AC_DEFINE(HAVE_4ARGS_VFS_RENAME, 1,
 974                           [vfs_rename() wants 4 args])
 975         ],[
 976                 AC_MSG_RESULT(no)
 977                 dnl #
 978                 dnl # Linux 3.13 API change
 979                 dnl # Added delegated inode
 980                 dnl #
 981                 AC_MSG_CHECKING([whether vfs_rename() wants 5 args])
 982                 SPL_LINUX_TRY_COMPILE([
 983                         #include <linux/fs.h>
 984                 ],[
 985                         vfs_rename((struct inode *) NULL,
 986                                 (struct dentry *) NULL,
 987                                 (struct inode *) NULL,
 988                                 (struct dentry *) NULL,
 989                                 (struct inode **) NULL);
 990                 ],[
 991                         AC_MSG_RESULT(yes)
 992                         AC_DEFINE(HAVE_5ARGS_VFS_RENAME, 1,
 993                                   [vfs_rename() wants 5 args])
 994                 ],[
 995                         AC_MSG_RESULT(no)
 996                         dnl #
 997                         dnl # Linux 3.15 API change
 998                         dnl # Added flags
 999                         dnl #
1000                         AC_MSG_CHECKING([whether vfs_rename() wants 6 args])
1001                         SPL_LINUX_TRY_COMPILE([
1002                                 #include <linux/fs.h>
1003                         ],[
1004                                 vfs_rename((struct inode *) NULL,
1005                                         (struct dentry *) NULL,
1006                                         (struct inode *) NULL,
1007                                         (struct dentry *) NULL,
1008                                         (struct inode **) NULL,
1009                                         (unsigned int) 0);
1010                         ],[
1011                                 AC_MSG_RESULT(yes)
1012                                 AC_DEFINE(HAVE_6ARGS_VFS_RENAME, 1,
1013                                           [vfs_rename() wants 6 args])
1014                         ],[
1015                                 AC_MSG_ERROR(no)
1016                         ])
1017                 ])
1018         ])
1019 ])
1020
1021 dnl #
1022 dnl # 2.6.36 API change,
1023 dnl # The 'struct fs_struct->lock' was changed from a rwlock_t to
1024 dnl # a spinlock_t to improve the fastpath performance.
1025 dnl #
1026 AC_DEFUN([SPL_AC_FS_STRUCT_SPINLOCK], [
1027         AC_MSG_CHECKING([whether struct fs_struct uses spinlock_t])
1028         tmp_flags="$EXTRA_KCFLAGS"
1029         EXTRA_KCFLAGS="-Werror"
1030         SPL_LINUX_TRY_COMPILE([
1031                 #include <linux/sched.h>
1032                 #include <linux/fs_struct.h>
1033         ],[
1034                 static struct fs_struct fs;
1035                 spin_lock_init(&fs.lock);
1036         ],[
1037                 AC_MSG_RESULT(yes)
1038                 AC_DEFINE(HAVE_FS_STRUCT_SPINLOCK, 1,
1039                           [struct fs_struct uses spinlock_t])
1040         ],[
1041                 AC_MSG_RESULT(no)
1042         ])
1043         EXTRA_KCFLAGS="$tmp_flags"
1044 ])
1045
1046 dnl #
1047 dnl # User namespaces, use kuid_t in place of uid_t
1048 dnl # where available. Not strictly a user namespaces thing
1049 dnl # but it should prevent surprises
1050 dnl #
1051 AC_DEFUN([SPL_AC_KUIDGID_T], [
1052         AC_MSG_CHECKING([whether kuid_t/kgid_t is available])
1053         SPL_LINUX_TRY_COMPILE([
1054                 #include <linux/uidgid.h>
1055         ], [
1056                 kuid_t userid = KUIDT_INIT(0);
1057                 kgid_t groupid = KGIDT_INIT(0);
1058         ],[
1059                 SPL_LINUX_TRY_COMPILE([
1060                         #include <linux/uidgid.h>
1061                 ], [
1062                         kuid_t userid = 0;
1063                         kgid_t groupid = 0;
1064                 ],[
1065                         AC_MSG_RESULT(yes; optional)
1066                 ],[
1067                         AC_MSG_RESULT(yes; mandatory)
1068                         AC_DEFINE(HAVE_KUIDGID_T, 1, [kuid_t/kgid_t in use])
1069                 ])
1070         ],[
1071                 AC_MSG_RESULT(no)
1072         ])
1073 ])
1074
1075 dnl #
1076 dnl # 2.6.39 API change,
1077 dnl # __put_task_struct() was exported by the mainline kernel.
1078 dnl #
1079 AC_DEFUN([SPL_AC_PUT_TASK_STRUCT],
1080         [AC_MSG_CHECKING([whether __put_task_struct() is available])
1081         SPL_LINUX_TRY_COMPILE_SYMBOL([
1082                 #include <linux/sched.h>
1083         ], [
1084                 __put_task_struct(NULL);
1085         ], [__put_task_struct], [], [
1086                 AC_MSG_RESULT(yes)
1087                 AC_DEFINE(HAVE_PUT_TASK_STRUCT, 1,
1088                           [__put_task_struct() is available])
1089         ], [
1090                 AC_MSG_RESULT(no)
1091         ])
1092 ])
1093
1094 dnl #
1095 dnl # 2.6.35 API change,
1096 dnl # Unused 'struct dentry *' removed from vfs_fsync() prototype.
1097 dnl #
1098 AC_DEFUN([SPL_AC_2ARGS_VFS_FSYNC], [
1099         AC_MSG_CHECKING([whether vfs_fsync() wants 2 args])
1100         SPL_LINUX_TRY_COMPILE([
1101                 #include <linux/fs.h>
1102         ],[
1103                 vfs_fsync(NULL, 0);
1104         ],[
1105                 AC_MSG_RESULT(yes)
1106                 AC_DEFINE(HAVE_2ARGS_VFS_FSYNC, 1, [vfs_fsync() wants 2 args])
1107         ],[
1108                 AC_MSG_RESULT(no)
1109         ])
1110 ])
1111
1112 dnl #
1113 dnl # 3.5 API change,
1114 dnl # inode_operations.truncate_range removed
1115 dnl #
1116 AC_DEFUN([SPL_AC_INODE_TRUNCATE_RANGE], [
1117         AC_MSG_CHECKING([whether truncate_range() inode operation is available])
1118         SPL_LINUX_TRY_COMPILE([
1119                 #include <linux/fs.h>
1120         ],[
1121                 struct inode_operations ops;
1122                 ops.truncate_range = NULL;
1123         ],[
1124                 AC_MSG_RESULT(yes)
1125                 AC_DEFINE(HAVE_INODE_TRUNCATE_RANGE, 1,
1126                         [truncate_range() inode operation is available])
1127         ],[
1128                 AC_MSG_RESULT(no)
1129         ])
1130 ])
1131
1132 dnl #
1133 dnl # Linux 2.6.38 - 3.x API
1134 dnl #
1135 AC_DEFUN([SPL_AC_KERNEL_FILE_FALLOCATE], [
1136         AC_MSG_CHECKING([whether fops->fallocate() exists])
1137         SPL_LINUX_TRY_COMPILE([
1138                 #include <linux/fs.h>
1139         ],[
1140                 long (*fallocate) (struct file *, int, loff_t, loff_t) = NULL;
1141                 struct file_operations fops __attribute__ ((unused)) = {
1142                         .fallocate = fallocate,
1143                 };
1144         ],[
1145                 AC_MSG_RESULT(yes)
1146                 AC_DEFINE(HAVE_FILE_FALLOCATE, 1, [fops->fallocate() exists])
1147         ],[
1148                 AC_MSG_RESULT(no)
1149         ])
1150 ])
1151
1152 dnl #
1153 dnl # Linux 2.6.x - 2.6.37 API
1154 dnl #
1155 AC_DEFUN([SPL_AC_KERNEL_INODE_FALLOCATE], [
1156         AC_MSG_CHECKING([whether iops->fallocate() exists])
1157         SPL_LINUX_TRY_COMPILE([
1158                 #include <linux/fs.h>
1159         ],[
1160                 long (*fallocate) (struct inode *, int, loff_t, loff_t) = NULL;
1161                 struct inode_operations fops __attribute__ ((unused)) = {
1162                         .fallocate = fallocate,
1163                 };
1164         ],[
1165                 AC_MSG_RESULT(yes)
1166                 AC_DEFINE(HAVE_INODE_FALLOCATE, 1, [fops->fallocate() exists])
1167         ],[
1168                 AC_MSG_RESULT(no)
1169         ])
1170 ])
1171
1172 dnl #
1173 dnl # PaX Linux 2.6.38 - 3.x API
1174 dnl #
1175 AC_DEFUN([SPL_AC_PAX_KERNEL_FILE_FALLOCATE], [
1176         AC_MSG_CHECKING([whether fops->fallocate() exists])
1177         SPL_LINUX_TRY_COMPILE([
1178                 #include <linux/fs.h>
1179         ],[
1180                 long (*fallocate) (struct file *, int, loff_t, loff_t) = NULL;
1181                 struct file_operations_no_const fops __attribute__ ((unused)) = {
1182                         .fallocate = fallocate,
1183                 };
1184         ],[
1185                 AC_MSG_RESULT(yes)
1186                 AC_DEFINE(HAVE_FILE_FALLOCATE, 1, [fops->fallocate() exists])
1187         ],[
1188                 AC_MSG_RESULT(no)
1189         ])
1190 ])
1191
1192 dnl #
1193 dnl # The fallocate callback was moved from the inode_operations
1194 dnl # structure to the file_operations structure.
1195 dnl #
1196 AC_DEFUN([SPL_AC_KERNEL_FALLOCATE], [
1197         SPL_AC_KERNEL_FILE_FALLOCATE
1198         SPL_AC_KERNEL_INODE_FALLOCATE
1199         SPL_AC_PAX_KERNEL_FILE_FALLOCATE
1200 ])
1201
1202 dnl #
1203 dnl # zlib inflate compat,
1204 dnl # Verify the kernel has CONFIG_ZLIB_INFLATE support enabled.
1205 dnl #
1206 AC_DEFUN([SPL_AC_CONFIG_ZLIB_INFLATE], [
1207         AC_MSG_CHECKING([whether CONFIG_ZLIB_INFLATE is defined])
1208         SPL_LINUX_TRY_COMPILE([
1209                 #if !defined(CONFIG_ZLIB_INFLATE) && \
1210                     !defined(CONFIG_ZLIB_INFLATE_MODULE)
1211                 #error CONFIG_ZLIB_INFLATE not defined
1212                 #endif
1213         ],[ ],[
1214                 AC_MSG_RESULT([yes])
1215         ],[
1216                 AC_MSG_RESULT([no])
1217                 AC_MSG_ERROR([
1218         *** This kernel does not include the required zlib inflate support.
1219         *** Rebuild the kernel with CONFIG_ZLIB_INFLATE=y|m set.])
1220         ])
1221 ])
1222
1223 dnl #
1224 dnl # zlib deflate compat,
1225 dnl # Verify the kernel has CONFIG_ZLIB_DEFLATE support enabled.
1226 dnl #
1227 AC_DEFUN([SPL_AC_CONFIG_ZLIB_DEFLATE], [
1228         AC_MSG_CHECKING([whether CONFIG_ZLIB_DEFLATE is defined])
1229         SPL_LINUX_TRY_COMPILE([
1230                 #if !defined(CONFIG_ZLIB_DEFLATE) && \
1231                     !defined(CONFIG_ZLIB_DEFLATE_MODULE)
1232                 #error CONFIG_ZLIB_DEFLATE not defined
1233                 #endif
1234         ],[ ],[
1235                 AC_MSG_RESULT([yes])
1236         ],[
1237                 AC_MSG_RESULT([no])
1238                 AC_MSG_ERROR([
1239         *** This kernel does not include the required zlib deflate support.
1240         *** Rebuild the kernel with CONFIG_ZLIB_DEFLATE=y|m set.])
1241         ])
1242 ])
1243
1244 dnl #
1245 dnl # 2.6.39 API compat,
1246 dnl # The function zlib_deflate_workspacesize() now take 2 arguments.
1247 dnl # This was done to avoid always having to allocate the maximum size
1248 dnl # workspace (268K).  The caller can now specific the windowBits and
1249 dnl # memLevel compression parameters to get a smaller workspace.
1250 dnl #
1251 AC_DEFUN([SPL_AC_2ARGS_ZLIB_DEFLATE_WORKSPACESIZE],
1252         [AC_MSG_CHECKING([whether zlib_deflate_workspacesize() wants 2 args])
1253         SPL_LINUX_TRY_COMPILE([
1254                 #include <linux/zlib.h>
1255         ],[
1256                 return zlib_deflate_workspacesize(MAX_WBITS, MAX_MEM_LEVEL);
1257         ],[
1258                 AC_MSG_RESULT(yes)
1259                 AC_DEFINE(HAVE_2ARGS_ZLIB_DEFLATE_WORKSPACESIZE, 1,
1260                           [zlib_deflate_workspacesize() wants 2 args])
1261         ],[
1262                 AC_MSG_RESULT(no)
1263         ])
1264 ])
1265
1266 dnl #
1267 dnl # 2.6.39 API change,
1268 dnl # Shrinker adjust to use common shrink_control structure.
1269 dnl #
1270 AC_DEFUN([SPL_AC_SHRINK_CONTROL_STRUCT], [
1271         AC_MSG_CHECKING([whether struct shrink_control exists])
1272         SPL_LINUX_TRY_COMPILE([
1273                 #include <linux/mm.h>
1274         ],[
1275                 struct shrink_control sc __attribute__ ((unused));
1276
1277                 sc.nr_to_scan = 0;
1278                 sc.gfp_mask = GFP_KERNEL;
1279         ],[
1280                 AC_MSG_RESULT(yes)
1281                 AC_DEFINE(HAVE_SHRINK_CONTROL_STRUCT, 1,
1282                         [struct shrink_control exists])
1283         ],[
1284                 AC_MSG_RESULT(no)
1285         ])
1286 ])
1287
1288 dnl #
1289 dnl # 3.1 API Change
1290 dnl #
1291 dnl # The rw_semaphore.wait_lock member was changed from spinlock_t to
1292 dnl # raw_spinlock_t at commit ddb6c9b58a19edcfac93ac670b066c836ff729f1.
1293 dnl #
1294 AC_DEFUN([SPL_AC_RWSEM_SPINLOCK_IS_RAW], [
1295         AC_MSG_CHECKING([whether struct rw_semaphore member wait_lock is raw])
1296         tmp_flags="$EXTRA_KCFLAGS"
1297         EXTRA_KCFLAGS="-Werror"
1298         SPL_LINUX_TRY_COMPILE([
1299                 #include <linux/rwsem.h>
1300         ],[
1301                 struct rw_semaphore dummy_semaphore __attribute__ ((unused));
1302                 raw_spinlock_t dummy_lock __attribute__ ((unused));
1303                 dummy_semaphore.wait_lock = dummy_lock;
1304         ],[
1305                 AC_MSG_RESULT(yes)
1306                 AC_DEFINE(RWSEM_SPINLOCK_IS_RAW, 1,
1307                 [struct rw_semaphore member wait_lock is raw_spinlock_t])
1308         ],[
1309                 AC_MSG_RESULT(no)
1310         ])
1311         EXTRA_KCFLAGS="$tmp_flags"
1312 ])
1313
1314 dnl #
1315 dnl # 3.9 API change,
1316 dnl # Moved things from linux/sched.h to linux/sched/rt.h
1317 dnl #
1318 AC_DEFUN([SPL_AC_SCHED_RT_HEADER],
1319         [AC_MSG_CHECKING([whether header linux/sched/rt.h exists])
1320         SPL_LINUX_TRY_COMPILE([
1321                 #include <linux/sched.h>
1322                 #include <linux/sched/rt.h>
1323         ],[
1324                 return 0;
1325         ],[
1326                 AC_DEFINE(HAVE_SCHED_RT_HEADER, 1, [linux/sched/rt.h exists])
1327                 AC_MSG_RESULT(yes)
1328         ],[
1329                 AC_MSG_RESULT(no)
1330         ])
1331 ])
1332
1333 dnl #
1334 dnl # 3.9 API change,
1335 dnl # vfs_getattr() uses 2 args
1336 dnl # It takes struct path * instead of struct vfsmount * and struct dentry *
1337 dnl #
1338 AC_DEFUN([SPL_AC_2ARGS_VFS_GETATTR], [
1339         AC_MSG_CHECKING([whether vfs_getattr() wants])
1340         SPL_LINUX_TRY_COMPILE([
1341                 #include <linux/fs.h>
1342         ],[
1343                 vfs_getattr((struct path *) NULL,
1344                         (struct kstat *)NULL);
1345         ],[
1346                 AC_MSG_RESULT(2 args)
1347                 AC_DEFINE(HAVE_2ARGS_VFS_GETATTR, 1,
1348                           [vfs_getattr wants 2 args])
1349         ],[
1350                 SPL_LINUX_TRY_COMPILE([
1351                         #include <linux/fs.h>
1352                 ],[
1353                         vfs_getattr((struct vfsmount *)NULL,
1354                                 (struct dentry *)NULL,
1355                                 (struct kstat *)NULL);
1356                 ],[
1357                         AC_MSG_RESULT(3 args)
1358                 ],[
1359                         AC_MSG_ERROR(unknown)
1360                 ])
1361         ])
1362 ])
1363
1364 dnl #
1365 dnl # 2.6.36 API compatibility.
1366 dnl # Added usleep_range timer.
1367 dnl # usleep_range is a finer precision implementation of msleep
1368 dnl # designed to be a drop-in replacement for udelay where a precise
1369 dnl # sleep / busy-wait is unnecessary.
1370 dnl #
1371 AC_DEFUN([SPL_AC_USLEEP_RANGE], [
1372         AC_MSG_CHECKING([whether usleep_range() is available])
1373         SPL_LINUX_TRY_COMPILE([
1374                 #include <linux/delay.h>
1375         ],[
1376                 usleep_range(0, 0);
1377         ],[
1378                 AC_MSG_RESULT(yes)
1379                 AC_DEFINE(HAVE_USLEEP_RANGE, 1,
1380                           [usleep_range is available])
1381         ],[
1382                 AC_MSG_RESULT(no)
1383         ])
1384 ])
1385
1386 dnl #
1387 dnl # 2.6.35 API change,
1388 dnl # The cachep->gfpflags member was renamed cachep->allocflags.  These are
1389 dnl # private allocation flags which are applied when allocating a new slab
1390 dnl # in kmem_getpages().  Unfortunately there is no public API for setting
1391 dnl # non-default flags.
1392 dnl #
1393 AC_DEFUN([SPL_AC_KMEM_CACHE_ALLOCFLAGS], [
1394         AC_MSG_CHECKING([whether struct kmem_cache has allocflags])
1395         SPL_LINUX_TRY_COMPILE([
1396                 #include <linux/slab.h>
1397         ],[
1398                 struct kmem_cache cachep __attribute__ ((unused));
1399                 cachep.allocflags = GFP_KERNEL;
1400         ],[
1401                 AC_MSG_RESULT(yes)
1402                 AC_DEFINE(HAVE_KMEM_CACHE_ALLOCFLAGS, 1,
1403                         [struct kmem_cache has allocflags])
1404         ],[
1405                 AC_MSG_RESULT(no)
1406
1407                 AC_MSG_CHECKING([whether struct kmem_cache has gfpflags])
1408                 SPL_LINUX_TRY_COMPILE([
1409                         #include <linux/slab.h>
1410                 ],[
1411                         struct kmem_cache cachep __attribute__ ((unused));
1412                         cachep.gfpflags = GFP_KERNEL;
1413                 ],[
1414                         AC_MSG_RESULT(yes)
1415                         AC_DEFINE(HAVE_KMEM_CACHE_GFPFLAGS, 1,
1416                                 [struct kmem_cache has gfpflags])
1417                 ],[
1418                         AC_MSG_RESULT(no)
1419                 ])
1420         ])
1421 ])
1422
1423 dnl #
1424 dnl # 3.17 API change,
1425 dnl # wait_on_bit() no longer requires an action argument. The former
1426 dnl # "wait_on_bit" interface required an 'action' function to be provided
1427 dnl # which does the actual waiting. There were over 20 such functions in the
1428 dnl # kernel, many of them identical, though most cases can be satisfied by one
1429 dnl # of just two functions: one which uses io_schedule() and one which just
1430 dnl # uses schedule().  This API change was made to consolidate all of those
1431 dnl # redundant wait functions.
1432 dnl #
1433 AC_DEFUN([SPL_AC_WAIT_ON_BIT], [
1434         AC_MSG_CHECKING([whether wait_on_bit() takes an action])
1435         SPL_LINUX_TRY_COMPILE([
1436                 #include <linux/wait.h>
1437         ],[
1438                 int (*action)(void *) = NULL;
1439                 wait_on_bit(NULL, 0, action, 0);
1440         ],[
1441                 AC_MSG_RESULT(yes)
1442                 AC_DEFINE(HAVE_WAIT_ON_BIT_ACTION, 1, [yes])
1443         ],[
1444                 AC_MSG_RESULT(no)
1445         ])
1446 ])