config/spl-build.m4

   1 ###############################################################################
   2 # Copyright (C) 2007-2010 Lawrence Livermore National Security, LLC.
   3 # Copyright (C) 2007 The Regents of the University of California.
   4 # Written by Brian Behlendorf <behlendorf1@llnl.gov>.
   5 ###############################################################################
   6 # SPL_AC_CONFIG_KERNEL: Default SPL kernel configuration.
   7 ###############################################################################
   8
   9 AC_DEFUN([SPL_AC_CONFIG_KERNEL], [
  10         SPL_AC_KERNEL
  11
  12         if test "${LINUX_OBJ}" != "${LINUX}"; then
  13                 KERNELMAKE_PARAMS="$KERNELMAKE_PARAMS O=$LINUX_OBJ"
  14         fi
  15         AC_SUBST(KERNELMAKE_PARAMS)
  16
  17         KERNELCPPFLAGS="$KERNELCPPFLAGS -Wstrict-prototypes"
  18         AC_SUBST(KERNELCPPFLAGS)
  19
  20         SPL_AC_DEBUG
  21         SPL_AC_DEBUG_LOG
  22         SPL_AC_DEBUG_KMEM
  23         SPL_AC_DEBUG_KMEM_TRACKING
  24         SPL_AC_TEST_MODULE
  25         SPL_AC_ATOMIC_SPINLOCK
  26         SPL_AC_TYPE_ATOMIC64_CMPXCHG
  27         SPL_AC_TYPE_ATOMIC64_XCHG
  28         SPL_AC_TYPE_UINTPTR_T
  29         SPL_AC_2ARGS_REGISTER_SYSCTL
  30         SPL_AC_SET_SHRINKER
  31         SPL_AC_3ARGS_SHRINKER_CALLBACK
  32         SPL_AC_PATH_IN_NAMEIDATA
  33         SPL_AC_TASK_CURR
  34         SPL_AC_CTL_UNNUMBERED
  35         SPL_AC_CTL_NAME
  36         SPL_AC_VMALLOC_INFO
  37         SPL_AC_FLS64
  38         SPL_AC_DEVICE_CREATE
  39         SPL_AC_5ARGS_DEVICE_CREATE
  40         SPL_AC_CLASS_DEVICE_CREATE
  41         SPL_AC_SET_NORMALIZED_TIMESPEC_EXPORT
  42         SPL_AC_SET_NORMALIZED_TIMESPEC_INLINE
  43         SPL_AC_TIMESPEC_SUB
  44         SPL_AC_INIT_UTSNAME
  45         SPL_AC_UACCESS_HEADER
  46         SPL_AC_KMALLOC_NODE
  47         SPL_AC_MONOTONIC_CLOCK
  48         SPL_AC_INODE_I_MUTEX
  49         SPL_AC_MUTEX_OWNER
  50         SPL_AC_MUTEX_OWNER_TASK_STRUCT
  51         SPL_AC_MUTEX_LOCK_NESTED
  52         SPL_AC_3ARGS_ON_EACH_CPU
  53         SPL_AC_KALLSYMS_LOOKUP_NAME
  54         SPL_AC_GET_VMALLOC_INFO
  55         SPL_AC_PGDAT_HELPERS
  56         SPL_AC_FIRST_ONLINE_PGDAT
  57         SPL_AC_NEXT_ONLINE_PGDAT
  58         SPL_AC_NEXT_ZONE
  59         SPL_AC_PGDAT_LIST
  60         SPL_AC_GLOBAL_PAGE_STATE
  61         SPL_AC_ZONE_STAT_ITEM_FREE
  62         SPL_AC_ZONE_STAT_ITEM_INACTIVE
  63         SPL_AC_ZONE_STAT_ITEM_ACTIVE
  64         SPL_AC_GET_ZONE_COUNTS
  65         SPL_AC_USER_PATH_DIR
  66         SPL_AC_SET_FS_PWD
  67         SPL_AC_SET_FS_PWD_WITH_CONST
  68         SPL_AC_2ARGS_VFS_UNLINK
  69         SPL_AC_4ARGS_VFS_RENAME
  70         SPL_AC_VFS_FSYNC
  71         SPL_AC_2ARGS_VFS_FSYNC
  72         SPL_AC_INODE_TRUNCATE_RANGE
  73         SPL_AC_FS_STRUCT_SPINLOCK
  74         SPL_AC_CRED_STRUCT
  75         SPL_AC_GROUPS_SEARCH
  76         SPL_AC_PUT_TASK_STRUCT
  77         SPL_AC_5ARGS_PROC_HANDLER
  78         SPL_AC_KVASPRINTF
  79         SPL_AC_EXPORTED_RWSEM_IS_LOCKED
  80         SPL_AC_KERNEL_FALLOCATE
  81         SPL_AC_SHRINK_DCACHE_MEMORY
  82         SPL_AC_SHRINK_ICACHE_MEMORY
  83         SPL_AC_KERN_PATH_PARENT_HEADER
  84         SPL_AC_KERN_PATH_PARENT_SYMBOL
  85         SPL_AC_KERN_PATH_LOCKED
  86         SPL_AC_CONFIG_KALLSYMS
  87         SPL_AC_CONFIG_ZLIB_INFLATE
  88         SPL_AC_CONFIG_ZLIB_DEFLATE
  89         SPL_AC_2ARGS_ZLIB_DEFLATE_WORKSPACESIZE
  90         SPL_AC_SHRINK_CONTROL_STRUCT
  91         SPL_AC_RWSEM_SPINLOCK_IS_RAW
  92         SPL_AC_SCHED_RT_HEADER
  93         SPL_AC_2ARGS_VFS_GETATTR
  94 ])
  95
  96 AC_DEFUN([SPL_AC_MODULE_SYMVERS], [
  97         modpost=$LINUX/scripts/Makefile.modpost
  98         AC_MSG_CHECKING([kernel file name for module symbols])
  99         if test "x$enable_linux_builtin" != xyes -a -f "$modpost"; then
 100                 if grep -q Modules.symvers $modpost; then
 101                         LINUX_SYMBOLS=Modules.symvers
 102                 else
 103                         LINUX_SYMBOLS=Module.symvers
 104                 fi
 105
 106                 if ! test -f "$LINUX_OBJ/$LINUX_SYMBOLS"; then
 107                         AC_MSG_ERROR([
 108         *** Please make sure the kernel devel package for your distribution
 109         *** is installed.  If you are building with a custom kernel, make sure the
 110         *** kernel is configured, built, and the '--with-linux=PATH' configure
 111         *** option refers to the location of the kernel source.])
 112                 fi
 113         else
 114                 LINUX_SYMBOLS=NONE
 115         fi
 116         AC_MSG_RESULT($LINUX_SYMBOLS)
 117         AC_SUBST(LINUX_SYMBOLS)
 118 ])
 119
 120 AC_DEFUN([SPL_AC_KERNEL], [
 121         AC_ARG_WITH([linux],
 122                 AS_HELP_STRING([--with-linux=PATH],
 123                 [Path to kernel source]),
 124                 [kernelsrc="$withval"])
 125
 126         AC_ARG_WITH([linux-obj],
 127                 AS_HELP_STRING([--with-linux-obj=PATH],
 128                 [Path to kernel build objects]),
 129                 [kernelbuild="$withval"])
 130
 131         AC_MSG_CHECKING([kernel source directory])
 132         if test -z "$kernelsrc"; then
 133                 if test -e "/lib/modules/$(uname -r)/source"; then
 134                         headersdir="/lib/modules/$(uname -r)/source"
 135                         sourcelink=$(readlink -f "$headersdir")
 136                 elif test -e "/lib/modules/$(uname -r)/build"; then
 137                         headersdir="/lib/modules/$(uname -r)/build"
 138                         sourcelink=$(readlink -f "$headersdir")
 139                 else
 140                         sourcelink=$(ls -1d /usr/src/kernels/* \
 141                                      /usr/src/linux-* \
 142                                      2>/dev/null | grep -v obj | tail -1)
 143                 fi
 144
 145                 if test -n "$sourcelink" && test -e ${sourcelink}; then
 146                         kernelsrc=`readlink -f ${sourcelink}`
 147                 else
 148                         kernelsrc="[Not found]"
 149                 fi
 150         else
 151                 if test "$kernelsrc" = "NONE"; then
 152                         kernsrcver=NONE
 153                 fi
 154         fi
 155
 156         AC_MSG_RESULT([$kernelsrc])
 157         if test ! -d "$kernelsrc"; then
 158                 AC_MSG_ERROR([
 159         *** Please make sure the kernel devel package for your distribution
 160         *** is installed and then try again.  If that fails, you can specify the
 161         *** location of the kernel source with the '--with-linux=PATH' option.])
 162         fi
 163
 164         AC_MSG_CHECKING([kernel build directory])
 165         if test -z "$kernelbuild"; then
 166                 if test -e "/lib/modules/$(uname -r)/build"; then
 167                         kernelbuild=`readlink -f /lib/modules/$(uname -r)/build`
 168                 elif test -d ${kernelsrc}-obj/${target_cpu}/${target_cpu}; then
 169                         kernelbuild=${kernelsrc}-obj/${target_cpu}/${target_cpu}
 170                 elif test -d ${kernelsrc}-obj/${target_cpu}/default; then
 171                         kernelbuild=${kernelsrc}-obj/${target_cpu}/default
 172                 elif test -d `dirname ${kernelsrc}`/build-${target_cpu}; then
 173                         kernelbuild=`dirname ${kernelsrc}`/build-${target_cpu}
 174                 else
 175                         kernelbuild=${kernelsrc}
 176                 fi
 177         fi
 178         AC_MSG_RESULT([$kernelbuild])
 179
 180         AC_MSG_CHECKING([kernel source version])
 181         utsrelease1=$kernelbuild/include/linux/version.h
 182         utsrelease2=$kernelbuild/include/linux/utsrelease.h
 183         utsrelease3=$kernelbuild/include/generated/utsrelease.h
 184         if test -r $utsrelease1 && fgrep -q UTS_RELEASE $utsrelease1; then
 185                 utsrelease=linux/version.h
 186         elif test -r $utsrelease2 && fgrep -q UTS_RELEASE $utsrelease2; then
 187                 utsrelease=linux/utsrelease.h
 188         elif test -r $utsrelease3 && fgrep -q UTS_RELEASE $utsrelease3; then
 189                 utsrelease=generated/utsrelease.h
 190         fi
 191
 192         if test "$utsrelease"; then
 193                 kernsrcver=`(echo "#include <$utsrelease>";
 194                              echo "kernsrcver=UTS_RELEASE") |
 195                              cpp -I $kernelbuild/include |
 196                              grep "^kernsrcver=" | cut -d \" -f 2`
 197
 198                 if test -z "$kernsrcver"; then
 199                         AC_MSG_RESULT([Not found])
 200                         AC_MSG_ERROR([*** Cannot determine kernel version.])
 201                 fi
 202         else
 203                 AC_MSG_RESULT([Not found])
 204                 if test "x$enable_linux_builtin" != xyes; then
 205                         AC_MSG_ERROR([*** Cannot find UTS_RELEASE definition.])
 206                 else
 207                         AC_MSG_ERROR([
 208         *** Cannot find UTS_RELEASE definition.
 209         *** Please run 'make prepare' inside the kernel source tree.])
 210                 fi
 211         fi
 212
 213         AC_MSG_RESULT([$kernsrcver])
 214
 215         LINUX=${kernelsrc}
 216         LINUX_OBJ=${kernelbuild}
 217         LINUX_VERSION=${kernsrcver}
 218
 219         AC_SUBST(LINUX)
 220         AC_SUBST(LINUX_OBJ)
 221         AC_SUBST(LINUX_VERSION)
 222
 223         SPL_AC_MODULE_SYMVERS
 224 ])
 225
 226 dnl #
 227 dnl # Default SPL user configuration
 228 dnl #
 229 AC_DEFUN([SPL_AC_CONFIG_USER], [])
 230
 231 dnl #
 232 dnl # Check for rpm+rpmbuild to build RPM packages.  If these tools
 233 dnl # are missing, it is non-fatal, but you will not be able to build
 234 dnl # RPM packages and will be warned if you try too.
 235 dnl #
 236 dnl # By default, the generic spec file will be used because it requires
 237 dnl # minimal dependencies.  Distribution specific spec files can be
 238 dnl # placed under the 'rpm/<distribution>' directory and enabled using
 239 dnl # the --with-spec=<distribution> configure option.
 240 dnl #
 241 AC_DEFUN([SPL_AC_RPM], [
 242         RPM=rpm
 243         RPMBUILD=rpmbuild
 244
 245         AC_MSG_CHECKING([whether $RPM is available])
 246         AS_IF([tmp=$($RPM --version 2>/dev/null)], [
 247                 RPM_VERSION=$(echo $tmp | $AWK '/RPM/ { print $[3] }')
 248                 HAVE_RPM=yes
 249                 AC_MSG_RESULT([$HAVE_RPM ($RPM_VERSION)])
 250         ],[
 251                 HAVE_RPM=no
 252                 AC_MSG_RESULT([$HAVE_RPM])
 253         ])
 254
 255         AC_MSG_CHECKING([whether $RPMBUILD is available])
 256         AS_IF([tmp=$($RPMBUILD --version 2>/dev/null)], [
 257                 RPMBUILD_VERSION=$(echo $tmp | $AWK '/RPM/ { print $[3] }')
 258                 HAVE_RPMBUILD=yes
 259                 AC_MSG_RESULT([$HAVE_RPMBUILD ($RPMBUILD_VERSION)])
 260         ],[
 261                 HAVE_RPMBUILD=no
 262                 AC_MSG_RESULT([$HAVE_RPMBUILD])
 263         ])
 264
 265         RPM_DEFINE_COMMON='--define "$(DEBUG_SPL) 1" --define "$(DEBUG_LOG) 1" --define "$(DEBUG_KMEM) 1" --define "$(DEBUG_KMEM_TRACKING) 1"'
 266         RPM_DEFINE_UTIL=
 267         RPM_DEFINE_KMOD='--define "kernels $(LINUX_VERSION)"'
 268         RPM_DEFINE_DKMS=
 269
 270         SRPM_DEFINE_COMMON='--define "build_src_rpm 1"'
 271         SRPM_DEFINE_UTIL=
 272         SRPM_DEFINE_KMOD=
 273         SRPM_DEFINE_DKMS=
 274
 275         RPM_SPEC_DIR="rpm/generic"
 276         AC_ARG_WITH([spec],
 277                 AS_HELP_STRING([--with-spec=SPEC],
 278                 [Spec files 'generic|fedora']),
 279                 [RPM_SPEC_DIR="rpm/$withval"])
 280
 281         AC_MSG_CHECKING([whether spec files are available])
 282         AC_MSG_RESULT([yes ($RPM_SPEC_DIR/*.spec.in)])
 283
 284         AC_SUBST(HAVE_RPM)
 285         AC_SUBST(RPM)
 286         AC_SUBST(RPM_VERSION)
 287
 288         AC_SUBST(HAVE_RPMBUILD)
 289         AC_SUBST(RPMBUILD)
 290         AC_SUBST(RPMBUILD_VERSION)
 291
 292         AC_SUBST(RPM_SPEC_DIR)
 293         AC_SUBST(RPM_DEFINE_UTIL)
 294         AC_SUBST(RPM_DEFINE_KMOD)
 295         AC_SUBST(RPM_DEFINE_DKMS)
 296         AC_SUBST(RPM_DEFINE_COMMON)
 297         AC_SUBST(SRPM_DEFINE_UTIL)
 298         AC_SUBST(SRPM_DEFINE_KMOD)
 299         AC_SUBST(SRPM_DEFINE_DKMS)
 300         AC_SUBST(SRPM_DEFINE_COMMON)
 301 ])
 302
 303 dnl #
 304 dnl # Check for dpkg+dpkg-buildpackage to build DEB packages.  If these
 305 dnl # tools are missing it is non-fatal but you will not be able to build
 306 dnl # DEB packages and will be warned if you try too.
 307 dnl #
 308 AC_DEFUN([SPL_AC_DPKG], [
 309         DPKG=dpkg
 310         DPKGBUILD=dpkg-buildpackage
 311
 312         AC_MSG_CHECKING([whether $DPKG is available])
 313         AS_IF([tmp=$($DPKG --version 2>/dev/null)], [
 314                 DPKG_VERSION=$(echo $tmp | $AWK '/Debian/ { print $[7] }')
 315                 HAVE_DPKG=yes
 316                 AC_MSG_RESULT([$HAVE_DPKG ($DPKG_VERSION)])
 317         ],[
 318                 HAVE_DPKG=no
 319                 AC_MSG_RESULT([$HAVE_DPKG])
 320         ])
 321
 322         AC_MSG_CHECKING([whether $DPKGBUILD is available])
 323         AS_IF([tmp=$($DPKGBUILD --version 2>/dev/null)], [
 324                 DPKGBUILD_VERSION=$(echo $tmp | \
 325                     $AWK '/Debian/ { print $[4] }' | cut -f-4 -d'.')
 326                 HAVE_DPKGBUILD=yes
 327                 AC_MSG_RESULT([$HAVE_DPKGBUILD ($DPKGBUILD_VERSION)])
 328         ],[
 329                 HAVE_DPKGBUILD=no
 330                 AC_MSG_RESULT([$HAVE_DPKGBUILD])
 331         ])
 332
 333         AC_SUBST(HAVE_DPKG)
 334         AC_SUBST(DPKG)
 335         AC_SUBST(DPKG_VERSION)
 336
 337         AC_SUBST(HAVE_DPKGBUILD)
 338         AC_SUBST(DPKGBUILD)
 339         AC_SUBST(DPKGBUILD_VERSION)
 340 ])
 341
 342 dnl #
 343 dnl # Until native packaging for various different packing systems
 344 dnl # can be added the least we can do is attempt to use alien to
 345 dnl # convert the RPM packages to the needed package type.  This is
 346 dnl # a hack but so far it has worked reasonable well.
 347 dnl #
 348 AC_DEFUN([SPL_AC_ALIEN], [
 349         ALIEN=alien
 350
 351         AC_MSG_CHECKING([whether $ALIEN is available])
 352         AS_IF([tmp=$($ALIEN --version 2>/dev/null)], [
 353                 ALIEN_VERSION=$(echo $tmp | $AWK '{ print $[3] }')
 354                 HAVE_ALIEN=yes
 355                 AC_MSG_RESULT([$HAVE_ALIEN ($ALIEN_VERSION)])
 356         ],[
 357                 HAVE_ALIEN=no
 358                 AC_MSG_RESULT([$HAVE_ALIEN])
 359         ])
 360
 361         AC_SUBST(HAVE_ALIEN)
 362         AC_SUBST(ALIEN)
 363         AC_SUBST(ALIEN_VERSION)
 364 ])
 365
 366 dnl #
 367 dnl # Using the VENDOR tag from config.guess set the default
 368 dnl # package type for 'make pkg': (rpm | deb | tgz)
 369 dnl #
 370 AC_DEFUN([SPL_AC_DEFAULT_PACKAGE], [
 371         AC_MSG_CHECKING([linux distribution])
 372         if test -f /etc/toss-release ; then
 373                 VENDOR=toss ;
 374         elif test -f /etc/fedora-release ; then
 375                 VENDOR=fedora ;
 376         elif test -f /etc/redhat-release ; then
 377                 VENDOR=redhat ;
 378         elif test -f /etc/gentoo-release ; then
 379                 VENDOR=gentoo ;
 380         elif test -f /etc/arch-release ; then
 381                 VENDOR=arch ;
 382         elif test -f /etc/SuSE-release ; then
 383                 VENDOR=sles ;
 384         elif test -f /etc/slackware-version ; then
 385                 VENDOR=slackware ;
 386         elif test -f /etc/lunar.release ; then
 387                 VENDOR=lunar ;
 388         elif test -f /etc/lsb-release ; then
 389                 VENDOR=ubuntu ;
 390         elif test -f /etc/debian_version ; then
 391                 VENDOR=debian ;
 392         else
 393                 VENDOR= ;
 394         fi
 395         AC_MSG_RESULT([$VENDOR])
 396         AC_SUBST(VENDOR)
 397
 398         AC_MSG_CHECKING([default package type])
 399         case "$VENDOR" in
 400                 toss)       DEFAULT_PACKAGE=rpm  ;;
 401                 redhat)     DEFAULT_PACKAGE=rpm  ;;
 402                 fedora)     DEFAULT_PACKAGE=rpm  ;;
 403                 gentoo)     DEFAULT_PACKAGE=tgz  ;;
 404                 arch)       DEFAULT_PACKAGE=tgz  ;;
 405                 sles)       DEFAULT_PACKAGE=rpm  ;;
 406                 slackware)  DEFAULT_PACKAGE=tgz  ;;
 407                 lunar)      DEFAULT_PACKAGE=tgz  ;;
 408                 ubuntu)     DEFAULT_PACKAGE=deb  ;;
 409                 debian)     DEFAULT_PACKAGE=deb  ;;
 410                 *)          DEFAULT_PACKAGE=rpm  ;;
 411         esac
 412
 413         AC_MSG_RESULT([$DEFAULT_PACKAGE])
 414         AC_SUBST(DEFAULT_PACKAGE)
 415 ])
 416
 417 dnl #
 418 dnl # Default SPL user configuration
 419 dnl #
 420 AC_DEFUN([SPL_AC_PACKAGE], [
 421         SPL_AC_DEFAULT_PACKAGE
 422         SPL_AC_RPM
 423         SPL_AC_DPKG
 424         SPL_AC_ALIEN
 425 ])
 426
 427 AC_DEFUN([SPL_AC_LICENSE], [
 428         AC_MSG_CHECKING([spl license])
 429         LICENSE=GPL
 430         AC_MSG_RESULT([$LICENSE])
 431         KERNELCPPFLAGS="${KERNELCPPFLAGS} -DHAVE_GPL_ONLY_SYMBOLS"
 432         AC_SUBST(LICENSE)
 433 ])
 434
 435 AC_DEFUN([SPL_AC_CONFIG], [
 436         SPL_CONFIG=all
 437         AC_ARG_WITH([config],
 438                 AS_HELP_STRING([--with-config=CONFIG],
 439                 [Config file 'kernel|user|all|srpm']),
 440                 [SPL_CONFIG="$withval"])
 441         AC_ARG_ENABLE([linux-builtin],
 442                 [AC_HELP_STRING([--enable-linux-builtin],
 443                 [Configure for builtin in-tree kernel modules @<:@default=no@:>@])],
 444                 [],
 445                 [enable_linux_builtin=no])
 446
 447         AC_MSG_CHECKING([spl config])
 448         AC_MSG_RESULT([$SPL_CONFIG]);
 449         AC_SUBST(SPL_CONFIG)
 450
 451         case "$SPL_CONFIG" in
 452                 kernel) SPL_AC_CONFIG_KERNEL ;;
 453                 user)   SPL_AC_CONFIG_USER   ;;
 454                 all)    SPL_AC_CONFIG_KERNEL
 455                         SPL_AC_CONFIG_USER   ;;
 456                 srpm)                        ;;
 457                 *)
 458                 AC_MSG_RESULT([Error!])
 459                 AC_MSG_ERROR([Bad value "$SPL_CONFIG" for --with-config,
 460                              user kernel|user|all|srpm]) ;;
 461         esac
 462
 463         AM_CONDITIONAL([CONFIG_USER],
 464                        [test "$SPL_CONFIG" = user -o "$SPL_CONFIG" = all])
 465         AM_CONDITIONAL([CONFIG_KERNEL],
 466                        [test "$SPL_CONFIG" = kernel -o "$SPL_CONFIG" = all] &&
 467                        [test "x$enable_linux_builtin" != xyes ])
 468 ])
 469
 470 dnl #
 471 dnl # Enable if the SPL should be compiled with internal debugging enabled.
 472 dnl # By default this support is disabled.
 473 dnl #
 474 AC_DEFUN([SPL_AC_DEBUG], [
 475         AC_MSG_CHECKING([whether debugging is enabled])
 476         AC_ARG_ENABLE([debug],
 477                 [AS_HELP_STRING([--enable-debug],
 478                 [Enable generic debug support @<:@default=no@:>@])],
 479                 [],
 480                 [enable_debug=no])
 481
 482         AS_IF([test "x$enable_debug" = xyes],
 483         [
 484                 KERNELCPPFLAGS="${KERNELCPPFLAGS} -DDEBUG -Werror"
 485                 DEBUG_CFLAGS="-DDEBUG -Werror"
 486                 DEBUG_SPL="_with_debug"
 487         ], [
 488                 KERNELCPPFLAGS="${KERNELCPPFLAGS} -DNDEBUG"
 489                 DEBUG_CFLAGS="-DNDEBUG"
 490                 DEBUG_SPL="_without_debug"
 491         ])
 492
 493         AC_SUBST(DEBUG_CFLAGS)
 494         AC_SUBST(DEBUG_SPL)
 495         AC_MSG_RESULT([$enable_debug])
 496 ])
 497
 498 dnl #
 499 dnl # Enabled by default it provides a basic debug log infrastructure.
 500 dnl # Each subsystem registers itself with a name and logs messages
 501 dnl # using predefined types.  If the debug mask it set to allow the
 502 dnl # message type it will be written to the internal log.  The log
 503 dnl # can be dumped to a file by echoing 1 to the 'dump' proc entry,
 504 dnl # after dumping the log it must be decoded using the spl utility.
 505 dnl #
 506 dnl # echo 1 >/proc/sys/kernel/spl/debug/dump
 507 dnl # spl /tmp/spl-log.xxx.yyy /tmp/spl-log.xxx.yyy.txt
 508 dnl #
 509 AC_DEFUN([SPL_AC_DEBUG_LOG], [
 510         AC_ARG_ENABLE([debug-log],
 511                 [AS_HELP_STRING([--enable-debug-log],
 512                 [Enable basic debug logging @<:@default=yes@:>@])],
 513                 [],
 514                 [enable_debug_log=yes])
 515
 516         AS_IF([test "x$enable_debug_log" = xyes],
 517         [
 518                 KERNELCPPFLAGS="${KERNELCPPFLAGS} -DDEBUG_LOG"
 519                 DEBUG_LOG="_with_debug_log"
 520                 AC_DEFINE([DEBUG_LOG], [1],
 521                 [Define to 1 to enable basic debug logging])
 522         ], [
 523                 DEBUG_LOG="_without_debug_log"
 524         ])
 525
 526         AC_SUBST(DEBUG_LOG)
 527         AC_MSG_CHECKING([whether basic debug logging is enabled])
 528         AC_MSG_RESULT([$enable_debug_log])
 529 ])
 530
 531 dnl #
 532 dnl # Enabled by default it provides a minimal level of memory tracking.
 533 dnl # A total count of bytes allocated is kept for each alloc and free.
 534 dnl # Then at module unload time a report to the console will be printed
 535 dnl # if memory was leaked.  Additionally, /proc/spl/kmem/slab will exist
 536 dnl # and provide an easy way to inspect the kmem based slab.
 537 dnl #
 538 AC_DEFUN([SPL_AC_DEBUG_KMEM], [
 539         AC_ARG_ENABLE([debug-kmem],
 540                 [AS_HELP_STRING([--enable-debug-kmem],
 541                 [Enable basic kmem accounting @<:@default=yes@:>@])],
 542                 [],
 543                 [enable_debug_kmem=yes])
 544
 545         AS_IF([test "x$enable_debug_kmem" = xyes],
 546         [
 547                 KERNELCPPFLAGS="${KERNELCPPFLAGS} -DDEBUG_KMEM"
 548                 DEBUG_KMEM="_with_debug_kmem"
 549                 AC_DEFINE([DEBUG_KMEM], [1],
 550                 [Define to 1 to enable basic kmem accounting])
 551         ], [
 552                 DEBUG_KMEM="_without_debug_kmem"
 553         ])
 554
 555         AC_SUBST(DEBUG_KMEM)
 556         AC_MSG_CHECKING([whether basic kmem accounting is enabled])
 557         AC_MSG_RESULT([$enable_debug_kmem])
 558 ])
 559
 560 dnl #
 561 dnl # Disabled by default it provides detailed memory tracking.  This
 562 dnl # feature also requires --enable-debug-kmem to be set.  When enabled
 563 dnl # not only will total bytes be tracked but also the location of every
 564 dnl # alloc and free.  When the SPL module is unloaded a list of all leaked
 565 dnl # addresses and where they were allocated will be dumped to the console.
 566 dnl # Enabling this feature has a significant impact on performance but it
 567 dnl # makes finding memory leaks pretty straight forward.
 568 dnl #
 569 AC_DEFUN([SPL_AC_DEBUG_KMEM_TRACKING], [
 570         AC_ARG_ENABLE([debug-kmem-tracking],
 571                 [AS_HELP_STRING([--enable-debug-kmem-tracking],
 572                 [Enable detailed kmem tracking  @<:@default=no@:>@])],
 573                 [],
 574                 [enable_debug_kmem_tracking=no])
 575
 576         AS_IF([test "x$enable_debug_kmem_tracking" = xyes],
 577         [
 578                 KERNELCPPFLAGS="${KERNELCPPFLAGS} -DDEBUG_KMEM_TRACKING"
 579                 DEBUG_KMEM_TRACKING="_with_debug_kmem_tracking"
 580                 AC_DEFINE([DEBUG_KMEM_TRACKING], [1],
 581                 [Define to 1 to enable detailed kmem tracking])
 582         ], [
 583                 DEBUG_KMEM_TRACKING="_without_debug_kmem_tracking"
 584         ])
 585
 586         AC_SUBST(DEBUG_KMEM_TRACKING)
 587         AC_MSG_CHECKING([whether detailed kmem tracking is enabled])
 588         AC_MSG_RESULT([$enable_debug_kmem_tracking])
 589 ])
 590
 591 dnl #
 592 dnl # SPL_LINUX_CONFTEST
 593 dnl #
 594 AC_DEFUN([SPL_LINUX_CONFTEST], [
 595 cat confdefs.h - <<_ACEOF >conftest.c
 596 $1
 597 _ACEOF
 598 ])
 599
 600 dnl #
 601 dnl # SPL_LANG_PROGRAM(C)([PROLOGUE], [BODY])
 602 dnl #
 603 m4_define([SPL_LANG_PROGRAM], [
 604 $1
 605 int
 606 main (void)
 607 {
 608 dnl Do *not* indent the following line: there may be CPP directives.
 609 dnl Don't move the `;' right after for the same reason.
 610 $2
 611   ;
 612   return 0;
 613 }
 614 ])
 615
 616 dnl #
 617 dnl # SPL_LINUX_COMPILE_IFELSE / like AC_COMPILE_IFELSE
 618 dnl #
 619 AC_DEFUN([SPL_LINUX_COMPILE_IFELSE], [
 620         m4_ifvaln([$1], [SPL_LINUX_CONFTEST([$1])])
 621         rm -Rf build && mkdir -p build && touch build/conftest.mod.c
 622         echo "obj-m := conftest.o" >build/Makefile
 623         modpost_flag=''
 624         test "x$enable_linux_builtin" = xyes && modpost_flag='modpost=true' # fake modpost stage
 625         AS_IF(
 626                 [AC_TRY_COMMAND(cp conftest.c build && make [$2] -C $LINUX_OBJ EXTRA_CFLAGS="-Werror-implicit-function-declaration $EXTRA_KCFLAGS" $ARCH_UM M=$PWD/build $modpost_flag) >/dev/null && AC_TRY_COMMAND([$3])],
 627                 [$4],
 628                 [_AC_MSG_LOG_CONFTEST m4_ifvaln([$5],[$5])]
 629         )
 630         rm -Rf build
 631 ])
 632
 633 dnl #
 634 dnl # SPL_LINUX_TRY_COMPILE like AC_TRY_COMPILE
 635 dnl #
 636 AC_DEFUN([SPL_LINUX_TRY_COMPILE],
 637         [SPL_LINUX_COMPILE_IFELSE(
 638         [AC_LANG_SOURCE([SPL_LANG_PROGRAM([[$1]], [[$2]])])],
 639         [modules],
 640         [test -s build/conftest.o],
 641         [$3], [$4])
 642 ])
 643
 644 dnl #
 645 dnl # SPL_CHECK_SYMBOL_EXPORT
 646 dnl # check symbol exported or not
 647 dnl #
 648 AC_DEFUN([SPL_CHECK_SYMBOL_EXPORT], [
 649         grep -q -E '[[[:space:]]]$1[[[:space:]]]' \
 650                 $LINUX_OBJ/Module*.symvers 2>/dev/null
 651         rc=$?
 652         if test $rc -ne 0; then
 653                 export=0
 654                 for file in $2; do
 655                         grep -q -E "EXPORT_SYMBOL.*($1)" \
 656                                 "$LINUX_OBJ/$file" 2>/dev/null
 657                         rc=$?
 658                         if test $rc -eq 0; then
 659                                 export=1
 660                                 break;
 661                         fi
 662                 done
 663                 if test $export -eq 0; then :
 664                         $4
 665                 else :
 666                         $3
 667                 fi
 668         else :
 669                 $3
 670         fi
 671 ])
 672
 673 dnl #
 674 dnl # SPL_LINUX_TRY_COMPILE_SYMBOL
 675 dnl # like SPL_LINUX_TRY_COMPILE, except SPL_CHECK_SYMBOL_EXPORT
 676 dnl # is called if not compiling for builtin
 677 dnl #
 678 AC_DEFUN([SPL_LINUX_TRY_COMPILE_SYMBOL], [
 679         SPL_LINUX_TRY_COMPILE([$1], [$2], [rc=0], [rc=1])
 680         if test $rc -ne 0; then :
 681                 $6
 682         else
 683                 if test "x$enable_linux_builtin" != xyes; then
 684                         SPL_CHECK_SYMBOL_EXPORT([$3], [$4], [rc=0], [rc=1])
 685                 fi
 686                 if test $rc -ne 0; then :
 687                         $6
 688                 else :
 689                         $5
 690                 fi
 691         fi
 692 ])
 693
 694 dnl #
 695 dnl # SPL_CHECK_SYMBOL_HEADER
 696 dnl # check if a symbol prototype is defined in listed headers.
 697 dnl #
 698 AC_DEFUN([SPL_CHECK_SYMBOL_HEADER], [
 699         AC_MSG_CHECKING([whether symbol $1 exists in header])
 700         header=0
 701         for file in $3; do
 702                 grep -q "$2" "$LINUX/$file" 2>/dev/null
 703                 rc=$?
 704                 if test $rc -eq 0; then
 705                         header=1
 706                         break;
 707                 fi
 708         done
 709         if test $header -eq 0; then
 710                 AC_MSG_RESULT([no])
 711                 $5
 712         else
 713                 AC_MSG_RESULT([yes])
 714                 $4
 715         fi
 716 ])
 717
 718 dnl #
 719 dnl # SPL_CHECK_HEADER
 720 dnl # check whether header exists and define HAVE_$2_HEADER
 721 dnl #
 722 AC_DEFUN([SPL_CHECK_HEADER],
 723         [AC_MSG_CHECKING([whether header $1 exists])
 724         SPL_LINUX_TRY_COMPILE([
 725                 #include <$1>
 726         ],[
 727                 return 0;
 728         ],[
 729                 AC_DEFINE(HAVE_$2_HEADER, 1, [$1 exists])
 730                 AC_MSG_RESULT(yes)
 731                 $3
 732         ],[
 733                 AC_MSG_RESULT(no)
 734                 $4
 735         ])
 736 ])
 737
 738 dnl #
 739 dnl # Basic toolchain sanity check.
 740 dnl #
 741 AC_DEFUN([SPL_AC_TEST_MODULE],
 742         [AC_MSG_CHECKING([whether modules can be built])
 743         SPL_LINUX_TRY_COMPILE([],[],[
 744                 AC_MSG_RESULT([yes])
 745         ],[
 746                 AC_MSG_RESULT([no])
 747                 if test "x$enable_linux_builtin" != xyes; then
 748                         AC_MSG_ERROR([*** Unable to build an empty module.])
 749                 else
 750                         AC_MSG_ERROR([
 751         *** Unable to build an empty module.
 752         *** Please run 'make scripts' inside the kernel source tree.])
 753                 fi
 754         ])
 755 ])
 756
 757 dnl #
 758 dnl # Use the atomic implemenation based on global spinlocks.  This
 759 dnl # should only be needed by 32-bit kernels which do not provide
 760 dnl # the atomic64_* API.  It may be optionally enabled as a fallback
 761 dnl # if problems are observed with the direct mapping to the native
 762 dnl # Linux atomic operations.  You may not disable atomic spinlocks
 763 dnl # if you kernel does not an atomic64_* API.
 764 dnl #
 765 AC_DEFUN([SPL_AC_ATOMIC_SPINLOCK], [
 766         AC_ARG_ENABLE([atomic-spinlocks],
 767                 [AS_HELP_STRING([--enable-atomic-spinlocks],
 768                 [Atomic types use spinlocks @<:@default=check@:>@])],
 769                 [],
 770                 [enable_atomic_spinlocks=check])
 771
 772         SPL_LINUX_TRY_COMPILE([
 773                 #include <linux/fs.h>
 774         ],[
 775                 atomic64_t *ptr __attribute__ ((unused));
 776         ],[
 777                 have_atomic64_t=yes
 778                 AC_DEFINE(HAVE_ATOMIC64_T, 1,
 779                         [kernel defines atomic64_t])
 780         ],[
 781                 have_atomic64_t=no
 782         ])
 783
 784         AS_IF([test "x$enable_atomic_spinlocks" = xcheck], [
 785                 AS_IF([test "x$have_atomic64_t" = xyes], [
 786                         enable_atomic_spinlocks=no
 787                 ],[
 788                         enable_atomic_spinlocks=yes
 789                 ])
 790         ])
 791
 792         AS_IF([test "x$enable_atomic_spinlocks" = xyes], [
 793                 AC_DEFINE([ATOMIC_SPINLOCK], [1],
 794                         [Atomic types use spinlocks])
 795         ],[
 796                 AS_IF([test "x$have_atomic64_t" = xno], [
 797                         AC_MSG_FAILURE(
 798                         [--disable-atomic-spinlocks given but required atomic64 support is unavailable])
 799                 ])
 800         ])
 801
 802         AC_MSG_CHECKING([whether atomic types use spinlocks])
 803         AC_MSG_RESULT([$enable_atomic_spinlocks])
 804
 805         AC_MSG_CHECKING([whether kernel defines atomic64_t])
 806         AC_MSG_RESULT([$have_atomic64_t])
 807 ])
 808
 809 dnl #
 810 dnl # 2.6.24 API change,
 811 dnl # check if atomic64_cmpxchg is defined
 812 dnl #
 813 AC_DEFUN([SPL_AC_TYPE_ATOMIC64_CMPXCHG],
 814         [AC_MSG_CHECKING([whether kernel defines atomic64_cmpxchg])
 815         SPL_LINUX_TRY_COMPILE([
 816                 #include <linux/fs.h>
 817         ],[
 818                 atomic64_cmpxchg((atomic64_t *)NULL, 0, 0);
 819         ],[
 820                 AC_MSG_RESULT([yes])
 821                 AC_DEFINE(HAVE_ATOMIC64_CMPXCHG, 1,
 822                           [kernel defines atomic64_cmpxchg])
 823         ],[
 824                 AC_MSG_RESULT([no])
 825         ])
 826 ])
 827
 828 dnl #
 829 dnl # 2.6.24 API change,
 830 dnl # check if atomic64_xchg is defined
 831 dnl #
 832 AC_DEFUN([SPL_AC_TYPE_ATOMIC64_XCHG],
 833         [AC_MSG_CHECKING([whether kernel defines atomic64_xchg])
 834         SPL_LINUX_TRY_COMPILE([
 835                 #include <linux/fs.h>
 836         ],[
 837                 atomic64_xchg((atomic64_t *)NULL, 0);
 838         ],[
 839                 AC_MSG_RESULT([yes])
 840                 AC_DEFINE(HAVE_ATOMIC64_XCHG, 1,
 841                           [kernel defines atomic64_xchg])
 842         ],[
 843                 AC_MSG_RESULT([no])
 844         ])
 845 ])
 846
 847 dnl #
 848 dnl # 2.6.24 API change,
 849 dnl # check if uintptr_t typedef is defined
 850 dnl #
 851 AC_DEFUN([SPL_AC_TYPE_UINTPTR_T],
 852         [AC_MSG_CHECKING([whether kernel defines uintptr_t])
 853         SPL_LINUX_TRY_COMPILE([
 854                 #include <linux/types.h>
 855         ],[
 856                 uintptr_t *ptr __attribute__ ((unused));
 857         ],[
 858                 AC_MSG_RESULT([yes])
 859                 AC_DEFINE(HAVE_UINTPTR_T, 1,
 860                           [kernel defines uintptr_t])
 861         ],[
 862                 AC_MSG_RESULT([no])
 863         ])
 864 ])
 865
 866 dnl #
 867 dnl # 2.6.21 API change,
 868 dnl # 'register_sysctl_table' use only one argument instead of two
 869 dnl #
 870 AC_DEFUN([SPL_AC_2ARGS_REGISTER_SYSCTL],
 871         [AC_MSG_CHECKING([whether register_sysctl_table() wants 2 args])
 872         SPL_LINUX_TRY_COMPILE([
 873                 #include <linux/sysctl.h>
 874         ],[
 875                 (void) register_sysctl_table(NULL, 0);
 876         ],[
 877                 AC_MSG_RESULT(yes)
 878                 AC_DEFINE(HAVE_2ARGS_REGISTER_SYSCTL, 1,
 879                           [register_sysctl_table() wants 2 args])
 880         ],[
 881                 AC_MSG_RESULT(no)
 882         ])
 883 ])
 884
 885 dnl #
 886 dnl # 2.6.23 API change
 887 dnl # Old set_shrinker API replaced with register_shrinker
 888 dnl #
 889 AC_DEFUN([SPL_AC_SET_SHRINKER], [
 890         AC_MSG_CHECKING([whether set_shrinker() available])
 891         SPL_LINUX_TRY_COMPILE([
 892                 #include <linux/mm.h>
 893         ],[
 894                 return set_shrinker(DEFAULT_SEEKS, NULL);
 895         ],[
 896                 AC_MSG_RESULT([yes])
 897                 AC_DEFINE(HAVE_SET_SHRINKER, 1,
 898                           [set_shrinker() available])
 899         ],[
 900                 AC_MSG_RESULT([no])
 901         ])
 902 ])
 903
 904 dnl #
 905 dnl # 2.6.35 API change,
 906 dnl # Add context to shrinker callback
 907 dnl #
 908 AC_DEFUN([SPL_AC_3ARGS_SHRINKER_CALLBACK],
 909         [AC_MSG_CHECKING([whether shrinker callback wants 3 args])
 910         tmp_flags="$EXTRA_KCFLAGS"
 911         EXTRA_KCFLAGS="-Werror"
 912         SPL_LINUX_TRY_COMPILE([
 913                 #include <linux/mm.h>
 914
 915                 int shrinker_cb(struct shrinker *, int, unsigned int);
 916         ],[
 917                 struct shrinker cache_shrinker = {
 918                         .shrink = shrinker_cb,
 919                         .seeks = DEFAULT_SEEKS,
 920                 };
 921                 register_shrinker(&cache_shrinker);
 922         ],[
 923                 AC_MSG_RESULT(yes)
 924                 AC_DEFINE(HAVE_3ARGS_SHRINKER_CALLBACK, 1,
 925                           [shrinker callback wants 3 args])
 926         ],[
 927                 AC_MSG_RESULT(no)
 928         ])
 929         EXTRA_KCFLAGS="$tmp_flags"
 930 ])
 931
 932 dnl #
 933 dnl # 2.6.25 API change,
 934 dnl # struct path entry added to struct nameidata
 935 dnl #
 936 AC_DEFUN([SPL_AC_PATH_IN_NAMEIDATA],
 937         [AC_MSG_CHECKING([whether struct path used in struct nameidata])
 938         SPL_LINUX_TRY_COMPILE([
 939                 #include <linux/namei.h>
 940         ],[
 941                 struct nameidata nd __attribute__ ((unused));
 942
 943                 nd.path.mnt = NULL;
 944                 nd.path.dentry = NULL;
 945         ],[
 946                 AC_MSG_RESULT(yes)
 947                 AC_DEFINE(HAVE_PATH_IN_NAMEIDATA, 1,
 948                           [struct path used in struct nameidata])
 949         ],[
 950                 AC_MSG_RESULT(no)
 951         ])
 952 ])
 953
 954 dnl #
 955 dnl # Custom SPL patch may export this system it is not required
 956 dnl #
 957 AC_DEFUN([SPL_AC_TASK_CURR],
 958         [AC_MSG_CHECKING([whether task_curr() is available])
 959         SPL_LINUX_TRY_COMPILE_SYMBOL([
 960                 #include <linux/sched.h>
 961         ], [
 962                 task_curr(NULL);
 963         ], [task_curr], [kernel/sched.c], [
 964                 AC_MSG_RESULT(yes)
 965                 AC_DEFINE(HAVE_TASK_CURR, 1, [task_curr() is available])
 966         ], [
 967                 AC_MSG_RESULT(no)
 968         ])
 969 ])
 970
 971 dnl #
 972 dnl # 2.6.19 API change,
 973 dnl # Use CTL_UNNUMBERED when binary sysctl is not required
 974 dnl #
 975 AC_DEFUN([SPL_AC_CTL_UNNUMBERED],
 976         [AC_MSG_CHECKING([whether unnumbered sysctl support exists])
 977         SPL_LINUX_TRY_COMPILE([
 978                 #include <linux/sysctl.h>
 979         ],[
 980                 #ifndef CTL_UNNUMBERED
 981                 #error CTL_UNNUMBERED undefined
 982                 #endif
 983         ],[
 984                 AC_MSG_RESULT(yes)
 985                 AC_DEFINE(HAVE_CTL_UNNUMBERED, 1,
 986                           [unnumbered sysctl support exists])
 987         ],[
 988                 AC_MSG_RESULT(no)
 989         ])
 990 ])
 991
 992 dnl #
 993 dnl # 2.6.33 API change,
 994 dnl # Removed .ctl_name from struct ctl_table.
 995 dnl #
 996 AC_DEFUN([SPL_AC_CTL_NAME], [
 997         AC_MSG_CHECKING([whether struct ctl_table has ctl_name])
 998         SPL_LINUX_TRY_COMPILE([
 999                 #include <linux/sysctl.h>
1000         ],[
1001                 struct ctl_table ctl __attribute__ ((unused));
1002                 ctl.ctl_name = 0;
1003         ],[
1004                 AC_MSG_RESULT(yes)
1005                 AC_DEFINE(HAVE_CTL_NAME, 1, [struct ctl_table has ctl_name])
1006         ],[
1007                 AC_MSG_RESULT(no)
1008         ])
1009 ])
1010
1011 dnl #
1012 dnl # 2.6.16 API change.
1013 dnl # Check if 'fls64()' is available
1014 dnl #
1015 AC_DEFUN([SPL_AC_FLS64],
1016         [AC_MSG_CHECKING([whether fls64() is available])
1017         SPL_LINUX_TRY_COMPILE([
1018                 #include <linux/bitops.h>
1019         ],[
1020                 return fls64(0);
1021         ],[
1022                 AC_MSG_RESULT(yes)
1023                 AC_DEFINE(HAVE_FLS64, 1, [fls64() is available])
1024         ],[
1025                 AC_MSG_RESULT(no)
1026         ])
1027 ])
1028
1029 dnl #
1030 dnl # 2.6.18 API change, check whether device_create() is available.
1031 dnl # Device_create() was introduced in 2.6.18 and depricated
1032 dnl # class_device_create() which was fully removed in 2.6.26.
1033 dnl #
1034 AC_DEFUN([SPL_AC_DEVICE_CREATE],
1035         [AC_MSG_CHECKING([whether device_create() is available])
1036         SPL_CHECK_SYMBOL_EXPORT([device_create], [drivers/base/core.c], [
1037                 AC_MSG_RESULT(yes)
1038                 AC_DEFINE(HAVE_DEVICE_CREATE, 1,
1039                           [device_create() is available])
1040         ], [
1041                 AC_MSG_RESULT(no)
1042         ])
1043 ])
1044
1045 dnl #
1046 dnl # 2.6.27 API change,
1047 dnl # device_create() uses 5 args, new 'drvdata' argument.
1048 dnl #
1049 AC_DEFUN([SPL_AC_5ARGS_DEVICE_CREATE], [
1050         AC_MSG_CHECKING([whether device_create() wants 5 args])
1051         tmp_flags="$EXTRA_KCFLAGS"
1052         EXTRA_KCFLAGS="-Werror"
1053         SPL_LINUX_TRY_COMPILE([
1054                 #include <linux/device.h>
1055         ],[
1056                 device_create(NULL, NULL, 0, NULL, "%d", 1);
1057         ],[
1058                 AC_MSG_RESULT(yes)
1059                 AC_DEFINE(HAVE_5ARGS_DEVICE_CREATE, 1,
1060                           [device_create wants 5 args])
1061         ],[
1062                 AC_MSG_RESULT(no)
1063         ])
1064         EXTRA_KCFLAGS="$tmp_flags"
1065 ])
1066
1067 dnl #
1068 dnl # 2.6.13 API change, check whether class_device_create() is available.
1069 dnl # Class_device_create() was introduced in 2.6.13 and depricated
1070 dnl # class_simple_device_add() which was fully removed in 2.6.13.
1071 dnl #
1072 AC_DEFUN([SPL_AC_CLASS_DEVICE_CREATE],
1073         [AC_MSG_CHECKING([whether class_device_create() is available])
1074         SPL_LINUX_TRY_COMPILE_SYMBOL([
1075                 #include <linux/device.h>
1076         ], [
1077                 class_device_create(NULL, NULL, 0, NULL, NULL);
1078         ], [class_device_create], [drivers/base/class.c], [
1079                 AC_MSG_RESULT(yes)
1080                 AC_DEFINE(HAVE_CLASS_DEVICE_CREATE, 1,
1081                           [class_device_create() is available])
1082         ], [
1083                 AC_MSG_RESULT(no)
1084         ])
1085 ])
1086
1087 dnl #
1088 dnl # 2.6.26 API change, set_normalized_timespec() is exported.
1089 dnl #
1090 AC_DEFUN([SPL_AC_SET_NORMALIZED_TIMESPEC_EXPORT],
1091         [AC_MSG_CHECKING([whether set_normalized_timespec() is available as export])
1092         SPL_LINUX_TRY_COMPILE_SYMBOL([
1093                 #include <linux/time.h>
1094         ], [
1095                 set_normalized_timespec(NULL, 0, 0);
1096         ], [set_normalized_timespec], [kernel/time.c], [
1097                 AC_MSG_RESULT(yes)
1098                 AC_DEFINE(HAVE_SET_NORMALIZED_TIMESPEC_EXPORT, 1,
1099                           [set_normalized_timespec() is available as export])
1100         ], [
1101                 AC_MSG_RESULT(no)
1102         ])
1103 ])
1104
1105 dnl #
1106 dnl # 2.6.16 API change, set_normalize_timespec() moved to time.c
1107 dnl # previously it was available in time.h as an inline.
1108 dnl #
1109 AC_DEFUN([SPL_AC_SET_NORMALIZED_TIMESPEC_INLINE], [
1110         AC_MSG_CHECKING([whether set_normalized_timespec() is an inline])
1111         SPL_LINUX_TRY_COMPILE([
1112                 #include <linux/time.h>
1113                 void set_normalized_timespec(struct timespec *ts,
1114                                              time_t sec, long nsec) { }
1115         ],
1116         [],
1117         [
1118                 AC_MSG_RESULT(no)
1119         ],[
1120                 AC_MSG_RESULT(yes)
1121                 AC_DEFINE(HAVE_SET_NORMALIZED_TIMESPEC_INLINE, 1,
1122                           [set_normalized_timespec() is available as inline])
1123         ])
1124 ])
1125
1126 dnl #
1127 dnl # 2.6.18 API change,
1128 dnl # timespec_sub() inline function available in linux/time.h
1129 dnl #
1130 AC_DEFUN([SPL_AC_TIMESPEC_SUB], [
1131         AC_MSG_CHECKING([whether timespec_sub() is available])
1132         SPL_LINUX_TRY_COMPILE([
1133                 #include <linux/time.h>
1134         ],[
1135                 struct timespec a = { 0 };
1136                 struct timespec b = { 0 };
1137                 struct timespec c __attribute__ ((unused));
1138                 c = timespec_sub(a, b);
1139         ],[
1140                 AC_MSG_RESULT(yes)
1141                 AC_DEFINE(HAVE_TIMESPEC_SUB, 1, [timespec_sub() is available])
1142         ],[
1143                 AC_MSG_RESULT(no)
1144         ])
1145 ])
1146
1147 dnl #
1148 dnl # 2.6.19 API change,
1149 dnl # check if init_utsname() is available in linux/utsname.h
1150 dnl #
1151 AC_DEFUN([SPL_AC_INIT_UTSNAME], [
1152         AC_MSG_CHECKING([whether init_utsname() is available])
1153         SPL_LINUX_TRY_COMPILE([
1154                 #include <linux/utsname.h>
1155         ],[
1156                 struct new_utsname *a __attribute__ ((unused));
1157                 a = init_utsname();
1158         ],[
1159                 AC_MSG_RESULT(yes)
1160                 AC_DEFINE(HAVE_INIT_UTSNAME, 1, [init_utsname() is available])
1161         ],[
1162                 AC_MSG_RESULT(no)
1163         ])
1164 ])
1165
1166 dnl #
1167 dnl # 2.6.18 API change,
1168 dnl # added linux/uaccess.h
1169 dnl #
1170 AC_DEFUN([SPL_AC_UACCESS_HEADER], [
1171         SPL_CHECK_HEADER([linux/uaccess.h], [UACCESS], [], [])
1172 ])
1173
1174 dnl #
1175 dnl # 2.6.12 API change,
1176 dnl # check whether 'kmalloc_node()' is available.
1177 dnl #
1178 AC_DEFUN([SPL_AC_KMALLOC_NODE], [
1179         AC_MSG_CHECKING([whether kmalloc_node() is available])
1180         SPL_LINUX_TRY_COMPILE([
1181                 #include <linux/slab.h>
1182         ],[
1183                 void *a __attribute__ ((unused));
1184                 a = kmalloc_node(1, GFP_KERNEL, 0);
1185         ],[
1186                 AC_MSG_RESULT(yes)
1187                 AC_DEFINE(HAVE_KMALLOC_NODE, 1, [kmalloc_node() is available])
1188         ],[
1189                 AC_MSG_RESULT(no)
1190         ])
1191 ])
1192
1193 dnl #
1194 dnl # 2.6.9 API change,
1195 dnl # check whether 'monotonic_clock()' is available it may
1196 dnl # be available for some archs but not others.
1197 dnl #
1198 AC_DEFUN([SPL_AC_MONOTONIC_CLOCK],
1199         [AC_MSG_CHECKING([whether monotonic_clock() is available])
1200         SPL_LINUX_TRY_COMPILE_SYMBOL([
1201                 #include <linux/timex.h>
1202         ], [
1203                 monotonic_clock();
1204         ], [monotonic_clock], [], [
1205                 AC_MSG_RESULT(yes)
1206                 AC_DEFINE(HAVE_MONOTONIC_CLOCK, 1,
1207                           [monotonic_clock() is available])
1208         ], [
1209                 AC_MSG_RESULT(no)
1210         ])
1211 ])
1212
1213 dnl #
1214 dnl # 2.6.16 API change,
1215 dnl # check whether 'struct inode' has i_mutex
1216 dnl #
1217 AC_DEFUN([SPL_AC_INODE_I_MUTEX], [
1218         AC_MSG_CHECKING([whether struct inode has i_mutex])
1219         SPL_LINUX_TRY_COMPILE([
1220                 #include <linux/fs.h>
1221                 #include <linux/mutex.h>
1222         ],[
1223                 struct inode i;
1224                 mutex_init(&i.i_mutex);
1225         ],[
1226                 AC_MSG_RESULT(yes)
1227                 AC_DEFINE(HAVE_INODE_I_MUTEX, 1, [struct inode has i_mutex])
1228         ],[
1229                 AC_MSG_RESULT(no)
1230         ])
1231 ])
1232
1233 dnl #
1234 dnl # 2.6.29 API change,
1235 dnl # Adaptive mutexs introduced.
1236 dnl #
1237 AC_DEFUN([SPL_AC_MUTEX_OWNER], [
1238         AC_MSG_CHECKING([whether struct mutex has owner])
1239         SPL_LINUX_TRY_COMPILE([
1240                 #include <linux/mutex.h>
1241         ],[
1242                 struct mutex mtx __attribute__ ((unused));
1243                 mtx.owner = NULL;
1244         ],[
1245                 AC_MSG_RESULT(yes)
1246                 AC_DEFINE(HAVE_MUTEX_OWNER, 1, [struct mutex has owner])
1247         ],[
1248                 AC_MSG_RESULT(no)
1249         ])
1250 ])
1251
1252 dnl #
1253 dnl # 2.6.39 API change,
1254 dnl # Owner type change.  A Linux mutex prior to 2.6.39 would store
1255 dnl # the owner as a thread_info pointer when CONFIG_DEBUG_MUTEXES
1256 dnl # was defined.  As of 2.6.39 this was changed to a task_struct
1257 dnl # pointer which frankly makes a lot more sense.
1258 dnl #
1259 AC_DEFUN([SPL_AC_MUTEX_OWNER_TASK_STRUCT], [
1260         AC_MSG_CHECKING([whether struct mutex owner is a task_struct])
1261         tmp_flags="$EXTRA_KCFLAGS"
1262         EXTRA_KCFLAGS="-Werror"
1263         SPL_LINUX_TRY_COMPILE([
1264                 #include <linux/mutex.h>
1265                 #include <linux/sched.h>
1266         ],[
1267                 struct mutex mtx __attribute__ ((unused));
1268                 mtx.owner = current;
1269         ],[
1270                 AC_MSG_RESULT(yes)
1271                 AC_DEFINE(HAVE_MUTEX_OWNER_TASK_STRUCT, 1,
1272                 [struct mutex owner is a task_struct])
1273         ],[
1274                 AC_MSG_RESULT(no)
1275         ])
1276         EXTRA_KCFLAGS="$tmp_flags"
1277 ])
1278
1279 dnl #
1280 dnl # 2.6.18 API change,
1281 dnl # First introduced 'mutex_lock_nested()' in include/linux/mutex.h,
1282 dnl # as part of the mutex validator.  Fallback to using 'mutex_lock()'
1283 dnl # if the mutex validator is disabled or otherwise unavailable.
1284 dnl #
1285 AC_DEFUN([SPL_AC_MUTEX_LOCK_NESTED], [
1286         AC_MSG_CHECKING([whether mutex_lock_nested() is available])
1287         SPL_LINUX_TRY_COMPILE([
1288                 #include <linux/mutex.h>
1289         ],[
1290                 struct mutex mutex;
1291                 mutex_init(&mutex);
1292                 mutex_lock_nested(&mutex, 0);
1293         ],[
1294                 AC_MSG_RESULT(yes)
1295                 AC_DEFINE(HAVE_MUTEX_LOCK_NESTED, 1,
1296                 [mutex_lock_nested() is available])
1297         ],[
1298                 AC_MSG_RESULT(no)
1299         ])
1300 ])
1301
1302 dnl #
1303 dnl # 2.6.27 API change,
1304 dnl # on_each_cpu() uses 3 args, no 'retry' argument
1305 dnl #
1306 AC_DEFUN([SPL_AC_3ARGS_ON_EACH_CPU], [
1307         AC_MSG_CHECKING([whether on_each_cpu() wants 3 args])
1308         SPL_LINUX_TRY_COMPILE([
1309                 #include <linux/interrupt.h>
1310                 #include <linux/smp.h>
1311
1312                 void on_each_cpu_func(void *data) { return; }
1313         ],[
1314                 on_each_cpu(on_each_cpu_func, NULL, 0);
1315         ],[
1316                 AC_MSG_RESULT(yes)
1317                 AC_DEFINE(HAVE_3ARGS_ON_EACH_CPU, 1,
1318                           [on_each_cpu wants 3 args])
1319         ],[
1320                 AC_MSG_RESULT(no)
1321         ])
1322 ])
1323
1324 dnl #
1325 dnl # 2.6.18 API change,
1326 dnl # kallsyms_lookup_name no longer exported
1327 dnl #
1328 AC_DEFUN([SPL_AC_KALLSYMS_LOOKUP_NAME],
1329         [AC_MSG_CHECKING([whether kallsyms_lookup_name() is available])
1330         SPL_LINUX_TRY_COMPILE_SYMBOL([
1331                 #include <linux/kallsyms.h>
1332         ], [
1333                 kallsyms_lookup_name(NULL);
1334         ], [kallsyms_lookup_name], [], [
1335                 AC_MSG_RESULT(yes)
1336                 AC_DEFINE(HAVE_KALLSYMS_LOOKUP_NAME, 1,
1337                           [kallsyms_lookup_name() is available])
1338         ], [
1339                 AC_MSG_RESULT(no)
1340         ])
1341 ])
1342
1343 dnl #
1344 dnl # Proposed API change,
1345 dnl # This symbol is not available in stock kernels.  You may build a
1346 dnl # custom kernel with the *-spl-export-symbols.patch which will export
1347 dnl # these symbols for use.  If your already rolling a custom kernel for
1348 dnl # your environment this is recommended.
1349 dnl #
1350 AC_DEFUN([SPL_AC_GET_VMALLOC_INFO],
1351         [AC_MSG_CHECKING([whether get_vmalloc_info() is available])
1352         SPL_CHECK_SYMBOL_EXPORT([get_vmalloc_info], [], [
1353                 AC_MSG_RESULT(yes)
1354                 AC_DEFINE(HAVE_GET_VMALLOC_INFO, 1,
1355                           [get_vmalloc_info() is available])
1356         ], [
1357                 AC_MSG_RESULT(no)
1358         ])
1359 ])
1360
1361 dnl #
1362 dnl # 3.10 API change,
1363 dnl # struct vmalloc_info is now declared in linux/vmalloc.h
1364 dnl #
1365 AC_DEFUN([SPL_AC_VMALLOC_INFO], [
1366         AC_MSG_CHECKING([whether struct vmalloc_info is declared])
1367         SPL_LINUX_TRY_COMPILE([
1368                 #include <linux/vmalloc.h>
1369                 struct vmalloc_info { void *a; };
1370         ],[
1371                 return 0;
1372         ],[
1373                 AC_MSG_RESULT(no)
1374         ],[
1375                 AC_MSG_RESULT(yes)
1376                 AC_DEFINE(HAVE_VMALLOC_INFO, 1, [yes])
1377         ])
1378 ])
1379
1380 dnl #
1381 dnl # 2.6.17 API change
1382 dnl # The helper functions first_online_pgdat(), next_online_pgdat(), and
1383 dnl # next_zone() are introduced to simplify for_each_zone().  These symbols
1384 dnl # were exported in 2.6.17 for use by modules which was consistent with
1385 dnl # the previous implementation of for_each_zone().  From 2.6.18 - 2.6.19
1386 dnl # the symbols were exported as 'unused', and by 2.6.20 they exports
1387 dnl # were dropped entirely leaving modules no way to directly iterate over
1388 dnl # the zone list.  Because we need access to the zone helpers we check
1389 dnl # if the kernel contains the old or new implementation.  Then we check
1390 dnl # to see if the symbols we need for each version are available.  If they
1391 dnl # are not, dynamically aquire the addresses with kallsyms_lookup_name().
1392 dnl #
1393 AC_DEFUN([SPL_AC_PGDAT_HELPERS], [
1394         AC_MSG_CHECKING([whether symbol *_pgdat exist])
1395         grep -q -E 'first_online_pgdat' $LINUX/include/linux/mmzone.h 2>/dev/null
1396         rc=$?
1397         if test $rc -eq 0; then
1398                 AC_MSG_RESULT([yes])
1399                 AC_DEFINE(HAVE_PGDAT_HELPERS, 1, [pgdat helpers are available])
1400         else
1401                 AC_MSG_RESULT([no])
1402         fi
1403 ])
1404
1405 dnl #
1406 dnl # Proposed API change,
1407 dnl # This symbol is not available in stock kernels.  You may build a
1408 dnl # custom kernel with the *-spl-export-symbols.patch which will export
1409 dnl # these symbols for use.  If your already rolling a custom kernel for
1410 dnl # your environment this is recommended.
1411 dnl #
1412 AC_DEFUN([SPL_AC_FIRST_ONLINE_PGDAT],
1413         [AC_MSG_CHECKING([whether first_online_pgdat() is available])
1414         SPL_LINUX_TRY_COMPILE_SYMBOL([
1415                 #include <linux/mmzone.h>
1416         ], [
1417                 first_online_pgdat();
1418         ], [first_online_pgdat], [], [
1419                 AC_MSG_RESULT(yes)
1420                 AC_DEFINE(HAVE_FIRST_ONLINE_PGDAT, 1,
1421                           [first_online_pgdat() is available])
1422         ], [
1423                 AC_MSG_RESULT(no)
1424         ])
1425 ])
1426
1427 dnl #
1428 dnl # Proposed API change,
1429 dnl # This symbol is not available in stock kernels.  You may build a
1430 dnl # custom kernel with the *-spl-export-symbols.patch which will export
1431 dnl # these symbols for use.  If your already rolling a custom kernel for
1432 dnl # your environment this is recommended.
1433 dnl #
1434 AC_DEFUN([SPL_AC_NEXT_ONLINE_PGDAT],
1435         [AC_MSG_CHECKING([whether next_online_pgdat() is available])
1436         SPL_LINUX_TRY_COMPILE_SYMBOL([
1437                 #include <linux/mmzone.h>
1438         ], [
1439                 next_online_pgdat(NULL);
1440         ], [next_online_pgdat], [], [
1441                 AC_MSG_RESULT(yes)
1442                 AC_DEFINE(HAVE_NEXT_ONLINE_PGDAT, 1,
1443                           [next_online_pgdat() is available])
1444         ], [
1445                 AC_MSG_RESULT(no)
1446         ])
1447 ])
1448
1449 dnl #
1450 dnl # Proposed API change,
1451 dnl # This symbol is not available in stock kernels.  You may build a
1452 dnl # custom kernel with the *-spl-export-symbols.patch which will export
1453 dnl # these symbols for use.  If your already rolling a custom kernel for
1454 dnl # your environment this is recommended.
1455 dnl #
1456 AC_DEFUN([SPL_AC_NEXT_ZONE],
1457         [AC_MSG_CHECKING([whether next_zone() is available])
1458         SPL_LINUX_TRY_COMPILE_SYMBOL([
1459                 #include <linux/mmzone.h>
1460         ], [
1461                 next_zone(NULL);
1462         ], [next_zone], [], [
1463                 AC_MSG_RESULT(yes)
1464                 AC_DEFINE(HAVE_NEXT_ZONE, 1, [next_zone() is available])
1465         ], [
1466                 AC_MSG_RESULT(no)
1467         ])
1468 ])
1469
1470 dnl #
1471 dnl # 2.6.17 API change,
1472 dnl # See SPL_AC_PGDAT_HELPERS for details.
1473 dnl #
1474 AC_DEFUN([SPL_AC_PGDAT_LIST],
1475         [AC_MSG_CHECKING([whether pgdat_list is available])
1476         SPL_LINUX_TRY_COMPILE_SYMBOL([
1477                 #include <linux/topology.h>
1478                 pg_data_t *tmp = pgdat_list;
1479         ], [], [pgdat_list], [], [
1480                 AC_MSG_RESULT(yes)
1481                 AC_DEFINE(HAVE_PGDAT_LIST, 1, [pgdat_list is available])
1482         ], [
1483                 AC_MSG_RESULT(no)
1484         ])
1485 ])
1486
1487 dnl #
1488 dnl # 2.6.18 API change,
1489 dnl # First introduced global_page_state() support as an inline.
1490 dnl #
1491 AC_DEFUN([SPL_AC_GLOBAL_PAGE_STATE], [
1492         AC_MSG_CHECKING([whether global_page_state() is available])
1493         SPL_LINUX_TRY_COMPILE([
1494                 #include <linux/mm.h>
1495         ],[
1496                 unsigned long state __attribute__ ((unused));
1497                 state = global_page_state(0);
1498         ],[
1499                 AC_MSG_RESULT(yes)
1500                 AC_DEFINE(HAVE_GLOBAL_PAGE_STATE, 1,
1501                           [global_page_state() is available])
1502         ],[
1503                 AC_MSG_RESULT(no)
1504         ])
1505 ])
1506
1507 dnl #
1508 dnl # 2.6.21 API change (plus subsequent naming convention changes),
1509 dnl # Public global zone stats now include a free page count.  However
1510 dnl # the enumerated names of the counters have changed since this API
1511 dnl # was introduced.  We need to deduce the corrent name to use.  This
1512 dnl # replaces the priviate get_zone_counts() interface.
1513 dnl #
1514 dnl # NR_FREE_PAGES was available from 2.6.21 to current kernels, which
1515 dnl # is 2.6.30 as of when this was written.
1516 dnl #
1517 AC_DEFUN([SPL_AC_ZONE_STAT_ITEM_FREE], [
1518         AC_MSG_CHECKING([whether page state NR_FREE_PAGES is available])
1519         SPL_LINUX_TRY_COMPILE([
1520                 #include <linux/mm.h>
1521         ],[
1522                 enum zone_stat_item zsi __attribute__ ((unused));
1523                 zsi = NR_FREE_PAGES;
1524         ],[
1525                 AC_MSG_RESULT(yes)
1526                 AC_DEFINE(HAVE_ZONE_STAT_ITEM_NR_FREE_PAGES, 1,
1527                           [Page state NR_FREE_PAGES is available])
1528         ],[
1529                 AC_MSG_RESULT(no)
1530         ])
1531 ])
1532
1533 dnl #
1534 dnl # 2.6.21 API change (plus subsequent naming convention changes),
1535 dnl # Public global zone stats now include an inactive page count.  However
1536 dnl # the enumerated names of the counters have changed since this API
1537 dnl # was introduced.  We need to deduce the corrent name to use.  This
1538 dnl # replaces the priviate get_zone_counts() interface.
1539 dnl #
1540 dnl # NR_INACTIVE was available from 2.6.21 to 2.6.27 and included both
1541 dnl # anonymous and file inactive pages.  As of 2.6.28 it was split in
1542 dnl # to NR_INACTIVE_ANON and NR_INACTIVE_FILE.
1543 dnl #
1544 AC_DEFUN([SPL_AC_ZONE_STAT_ITEM_INACTIVE], [
1545         AC_MSG_CHECKING([whether page state NR_INACTIVE is available])
1546         SPL_LINUX_TRY_COMPILE([
1547                 #include <linux/mm.h>
1548         ],[
1549                 enum zone_stat_item zsi __attribute__ ((unused));
1550                 zsi = NR_INACTIVE;
1551         ],[
1552                 AC_MSG_RESULT(yes)
1553                 AC_DEFINE(HAVE_ZONE_STAT_ITEM_NR_INACTIVE, 1,
1554                           [Page state NR_INACTIVE is available])
1555         ],[
1556                 AC_MSG_RESULT(no)
1557         ])
1558
1559         AC_MSG_CHECKING([whether page state NR_INACTIVE_ANON is available])
1560         SPL_LINUX_TRY_COMPILE([
1561                 #include <linux/mm.h>
1562         ],[
1563                 enum zone_stat_item zsi __attribute__ ((unused));
1564                 zsi = NR_INACTIVE_ANON;
1565         ],[
1566                 AC_MSG_RESULT(yes)
1567                 AC_DEFINE(HAVE_ZONE_STAT_ITEM_NR_INACTIVE_ANON, 1,
1568                           [Page state NR_INACTIVE_ANON is available])
1569         ],[
1570                 AC_MSG_RESULT(no)
1571         ])
1572
1573         AC_MSG_CHECKING([whether page state NR_INACTIVE_FILE is available])
1574         SPL_LINUX_TRY_COMPILE([
1575                 #include <linux/mm.h>
1576         ],[
1577                 enum zone_stat_item zsi __attribute__ ((unused));
1578                 zsi = NR_INACTIVE_FILE;
1579         ],[
1580                 AC_MSG_RESULT(yes)
1581                 AC_DEFINE(HAVE_ZONE_STAT_ITEM_NR_INACTIVE_FILE, 1,
1582                           [Page state NR_INACTIVE_FILE is available])
1583         ],[
1584                 AC_MSG_RESULT(no)
1585         ])
1586 ])
1587
1588 dnl #
1589 dnl # 2.6.21 API change (plus subsequent naming convention changes),
1590 dnl # Public global zone stats now include an active page count.  However
1591 dnl # the enumerated names of the counters have changed since this API
1592 dnl # was introduced.  We need to deduce the corrent name to use.  This
1593 dnl # replaces the priviate get_zone_counts() interface.
1594 dnl #
1595 dnl # NR_ACTIVE was available from 2.6.21 to 2.6.27 and included both
1596 dnl # anonymous and file active pages.  As of 2.6.28 it was split in
1597 dnl # to NR_ACTIVE_ANON and NR_ACTIVE_FILE.
1598 dnl #
1599 AC_DEFUN([SPL_AC_ZONE_STAT_ITEM_ACTIVE], [
1600         AC_MSG_CHECKING([whether page state NR_ACTIVE is available])
1601         SPL_LINUX_TRY_COMPILE([
1602                 #include <linux/mm.h>
1603         ],[
1604                 enum zone_stat_item zsi __attribute__ ((unused));
1605                 zsi = NR_ACTIVE;
1606         ],[
1607                 AC_MSG_RESULT(yes)
1608                 AC_DEFINE(HAVE_ZONE_STAT_ITEM_NR_ACTIVE, 1,
1609                           [Page state NR_ACTIVE is available])
1610         ],[
1611                 AC_MSG_RESULT(no)
1612         ])
1613
1614         AC_MSG_CHECKING([whether page state NR_ACTIVE_ANON is available])
1615         SPL_LINUX_TRY_COMPILE([
1616                 #include <linux/mm.h>
1617         ],[
1618                 enum zone_stat_item zsi __attribute__ ((unused));
1619                 zsi = NR_ACTIVE_ANON;
1620         ],[
1621                 AC_MSG_RESULT(yes)
1622                 AC_DEFINE(HAVE_ZONE_STAT_ITEM_NR_ACTIVE_ANON, 1,
1623                           [Page state NR_ACTIVE_ANON is available])
1624         ],[
1625                 AC_MSG_RESULT(no)
1626         ])
1627
1628         AC_MSG_CHECKING([whether page state NR_ACTIVE_FILE is available])
1629         SPL_LINUX_TRY_COMPILE([
1630                 #include <linux/mm.h>
1631         ],[
1632                 enum zone_stat_item zsi __attribute__ ((unused));
1633                 zsi = NR_ACTIVE_FILE;
1634         ],[
1635                 AC_MSG_RESULT(yes)
1636                 AC_DEFINE(HAVE_ZONE_STAT_ITEM_NR_ACTIVE_FILE, 1,
1637                           [Page state NR_ACTIVE_FILE is available])
1638         ],[
1639                 AC_MSG_RESULT(no)
1640         ])
1641 ])
1642
1643 dnl #
1644 dnl # Proposed API change for legacy kernels.
1645 dnl # This symbol is not available in older kernels.  For kernels post
1646 dnl # 2.6.21 the global_page_state() API is used to get free/inactive/active
1647 dnl # page state information.  This symbol is only used in legacy kernels
1648 dnl # any only as a last resort.
1649 dnl
1650 AC_DEFUN([SPL_AC_GET_ZONE_COUNTS], [
1651         AC_MSG_CHECKING([whether symbol get_zone_counts is needed])
1652         SPL_LINUX_TRY_COMPILE([
1653         ],[
1654                 #if !defined(HAVE_ZONE_STAT_ITEM_NR_FREE_PAGES)
1655                 #error "global_page_state needs NR_FREE_PAGES"
1656                 #endif
1657
1658                 #if !defined(HAVE_ZONE_STAT_ITEM_NR_ACTIVE) && \
1659                     !defined(HAVE_ZONE_STAT_ITEM_NR_ACTIVE_ANON) && \
1660                     !defined(HAVE_ZONE_STAT_ITEM_NR_ACTIVE_FILE)
1661                 #error "global_page_state needs NR_ACTIVE*"
1662                 #endif
1663
1664                 #if !defined(HAVE_ZONE_STAT_ITEM_NR_INACTIVE) && \
1665                     !defined(HAVE_ZONE_STAT_ITEM_NR_INACTIVE_ANON) && \
1666                     !defined(HAVE_ZONE_STAT_ITEM_NR_INACTIVE_FILE)
1667                 #error "global_page_state needs NR_INACTIVE*"
1668                 #endif
1669         ],[
1670                 AC_MSG_RESULT(no)
1671         ],[
1672                 AC_MSG_RESULT(yes)
1673                 AC_DEFINE(NEED_GET_ZONE_COUNTS, 1,
1674                           [get_zone_counts() is needed])
1675
1676                 AC_MSG_CHECKING([whether get_zone_counts() is available])
1677                 SPL_LINUX_TRY_COMPILE_SYMBOL([
1678                         #include <linux/mmzone.h>
1679                 ], [
1680                         get_zone_counts(NULL, NULL, NULL);
1681                 ], [get_zone_counts], [], [
1682                         AC_MSG_RESULT(yes)
1683                         AC_DEFINE(HAVE_GET_ZONE_COUNTS, 1,
1684                                   [get_zone_counts() is available])
1685                 ], [
1686                         AC_MSG_RESULT(no)
1687                 ])
1688         ])
1689 ])
1690
1691 dnl #
1692 dnl # 2.6.27 API change,
1693 dnl # The user_path_dir() replaces __user_walk()
1694 dnl #
1695 AC_DEFUN([SPL_AC_USER_PATH_DIR],
1696         [AC_MSG_CHECKING([whether user_path_dir() is available])
1697         SPL_LINUX_TRY_COMPILE_SYMBOL([
1698                 #include <linux/fcntl.h>
1699                 #include <linux/namei.h>
1700         ], [
1701                 user_path_dir(NULL, NULL);
1702         ], [user_path_at], [], [
1703                 AC_MSG_RESULT(yes)
1704                 AC_DEFINE(HAVE_USER_PATH_DIR, 1, [user_path_dir() is available])
1705         ], [
1706                 AC_MSG_RESULT(no)
1707         ])
1708 ])
1709
1710 dnl #
1711 dnl # Symbol available in RHEL kernels not in stock kernels.
1712 dnl #
1713 AC_DEFUN([SPL_AC_SET_FS_PWD],
1714         [AC_MSG_CHECKING([whether set_fs_pwd() is available])
1715         SPL_LINUX_TRY_COMPILE_SYMBOL([
1716                 #include <linux/spinlock.h>
1717                 #include <linux/fs_struct.h>
1718         ], [
1719                 (void) set_fs_pwd;
1720         ], [set_fs_pwd], [], [
1721                 AC_MSG_RESULT(yes)
1722                 AC_DEFINE(HAVE_SET_FS_PWD, 1, [set_fs_pwd() is available])
1723         ], [
1724                 AC_MSG_RESULT(no)
1725         ])
1726 ])
1727
1728 dnl #
1729 dnl # 3.9 API change
1730 dnl # set_fs_pwd takes const struct path *
1731 dnl #
1732 AC_DEFUN([SPL_AC_SET_FS_PWD_WITH_CONST],
1733         tmp_flags="$EXTRA_KCFLAGS"
1734         EXTRA_KCFLAGS="-Werror"
1735         [AC_MSG_CHECKING([whether set_fs_pwd() requires const struct path *])
1736         SPL_LINUX_TRY_COMPILE([
1737                 #include <linux/spinlock.h>
1738                 #include <linux/fs_struct.h>
1739                 #include <linux/path.h>
1740                 void (*const set_fs_pwd_func)
1741                         (struct fs_struct *, const struct path *)
1742                         = set_fs_pwd;
1743         ],[
1744                 return 0;
1745         ],[
1746                 AC_MSG_RESULT(yes)
1747                 AC_DEFINE(HAVE_SET_FS_PWD_WITH_CONST, 1,
1748                         [set_fs_pwd() needs const path *])
1749         ],[
1750                 SPL_LINUX_TRY_COMPILE([
1751                         #include <linux/spinlock.h>
1752                         #include <linux/fs_struct.h>
1753                         #include <linux/path.h>
1754                         void (*const set_fs_pwd_func)
1755                                 (struct fs_struct *, struct path *)
1756                                 = set_fs_pwd;
1757                 ],[
1758                         return 0;
1759                 ],[
1760                         AC_MSG_RESULT(no)
1761                 ],[
1762                         AC_MSG_ERROR(unknown)
1763                 ])
1764         ])
1765         EXTRA_KCFLAGS="$tmp_flags"
1766 ])
1767
1768 dnl #
1769 dnl # SLES API change, never adopted in mainline,
1770 dnl # Third 'struct vfsmount *' argument removed.
1771 dnl #
1772 AC_DEFUN([SPL_AC_2ARGS_VFS_UNLINK],
1773         [AC_MSG_CHECKING([whether vfs_unlink() wants 2 args])
1774         SPL_LINUX_TRY_COMPILE([
1775                 #include <linux/fs.h>
1776         ],[
1777                 vfs_unlink(NULL, NULL);
1778         ],[
1779                 AC_MSG_RESULT(yes)
1780                 AC_DEFINE(HAVE_2ARGS_VFS_UNLINK, 1,
1781                           [vfs_unlink() wants 2 args])
1782         ],[
1783                 AC_MSG_RESULT(no)
1784         ])
1785 ])
1786
1787 dnl #
1788 dnl # SLES API change, never adopted in mainline,
1789 dnl # Third and sixth 'struct vfsmount *' argument removed.
1790 dnl #
1791 AC_DEFUN([SPL_AC_4ARGS_VFS_RENAME],
1792         [AC_MSG_CHECKING([whether vfs_rename() wants 4 args])
1793         SPL_LINUX_TRY_COMPILE([
1794                 #include <linux/fs.h>
1795         ],[
1796                 vfs_rename(NULL, NULL, NULL, NULL);
1797         ],[
1798                 AC_MSG_RESULT(yes)
1799                 AC_DEFINE(HAVE_4ARGS_VFS_RENAME, 1,
1800                           [vfs_rename() wants 4 args])
1801         ],[
1802                 AC_MSG_RESULT(no)
1803         ])
1804 ])
1805
1806 dnl #
1807 dnl # 2.6.36 API change,
1808 dnl # The 'struct fs_struct->lock' was changed from a rwlock_t to
1809 dnl # a spinlock_t to improve the fastpath performance.
1810 dnl #
1811 AC_DEFUN([SPL_AC_FS_STRUCT_SPINLOCK], [
1812         AC_MSG_CHECKING([whether struct fs_struct uses spinlock_t])
1813         tmp_flags="$EXTRA_KCFLAGS"
1814         EXTRA_KCFLAGS="-Werror"
1815         SPL_LINUX_TRY_COMPILE([
1816                 #include <linux/sched.h>
1817                 #include <linux/fs_struct.h>
1818         ],[
1819                 struct fs_struct fs;
1820                 spin_lock_init(&fs.lock);
1821         ],[
1822                 AC_MSG_RESULT(yes)
1823                 AC_DEFINE(HAVE_FS_STRUCT_SPINLOCK, 1,
1824                           [struct fs_struct uses spinlock_t])
1825         ],[
1826                 AC_MSG_RESULT(no)
1827         ])
1828         EXTRA_KCFLAGS="$tmp_flags"
1829 ])
1830
1831 dnl #
1832 dnl # 2.6.29 API change,
1833 dnl # check whether 'struct cred' exists
1834 dnl #
1835 AC_DEFUN([SPL_AC_CRED_STRUCT], [
1836         AC_MSG_CHECKING([whether struct cred exists])
1837         SPL_LINUX_TRY_COMPILE([
1838                 #include <linux/cred.h>
1839         ],[
1840                 struct cred *cr __attribute__ ((unused));
1841                 cr  = NULL;
1842         ],[
1843                 AC_MSG_RESULT(yes)
1844                 AC_DEFINE(HAVE_CRED_STRUCT, 1, [struct cred exists])
1845         ],[
1846                 AC_MSG_RESULT(no)
1847         ])
1848 ])
1849
1850 dnl #
1851 dnl # Custom SPL patch may export this symbol.
1852 dnl #
1853 AC_DEFUN([SPL_AC_GROUPS_SEARCH],
1854         [AC_MSG_CHECKING([whether groups_search() is available])
1855         SPL_LINUX_TRY_COMPILE_SYMBOL([
1856                 #include <linux/cred.h>
1857         ], [
1858                 groups_search(NULL, 0);
1859         ], [groups_search], [], [
1860                 AC_MSG_RESULT(yes)
1861                 AC_DEFINE(HAVE_GROUPS_SEARCH, 1, [groups_search() is available])
1862         ], [
1863                 AC_MSG_RESULT(no)
1864         ])
1865 ])
1866
1867 dnl #
1868 dnl # 2.6.x API change,
1869 dnl # __put_task_struct() was exported in RHEL5 but unavailable elsewhere.
1870 dnl #
1871 AC_DEFUN([SPL_AC_PUT_TASK_STRUCT],
1872         [AC_MSG_CHECKING([whether __put_task_struct() is available])
1873         SPL_LINUX_TRY_COMPILE_SYMBOL([
1874                 #include <linux/sched.h>
1875         ], [
1876                 __put_task_struct(NULL);
1877         ], [__put_task_struct], [], [
1878                 AC_MSG_RESULT(yes)
1879                 AC_DEFINE(HAVE_PUT_TASK_STRUCT, 1,
1880                           [__put_task_struct() is available])
1881         ], [
1882                 AC_MSG_RESULT(no)
1883         ])
1884 ])
1885
1886 dnl #
1887 dnl # 2.6.32 API change,
1888 dnl # Unused 'struct file *' removed from prototype.
1889 dnl #
1890 AC_DEFUN([SPL_AC_5ARGS_PROC_HANDLER], [
1891         AC_MSG_CHECKING([whether proc_handler() wants 5 args])
1892         SPL_LINUX_TRY_COMPILE([
1893                 #include <linux/sysctl.h>
1894         ],[
1895                 proc_dostring(NULL, 0, NULL, NULL, NULL);
1896         ],[
1897                 AC_MSG_RESULT(yes)
1898                 AC_DEFINE(HAVE_5ARGS_PROC_HANDLER, 1,
1899                           [proc_handler() wants 5 args])
1900         ],[
1901                 AC_MSG_RESULT(no)
1902         ])
1903 ])
1904
1905 dnl #
1906 dnl # 2.6.x API change,
1907 dnl # kvasprintf() function added.
1908 dnl #
1909 AC_DEFUN([SPL_AC_KVASPRINTF],
1910         [AC_MSG_CHECKING([whether kvasprintf() is available])
1911         SPL_LINUX_TRY_COMPILE_SYMBOL([
1912                 #include <linux/kernel.h>
1913         ], [
1914                 kvasprintf(0, NULL, *((va_list*)NULL));
1915         ], [kvasprintf], [], [
1916                 AC_MSG_RESULT(yes)
1917                 AC_DEFINE(HAVE_KVASPRINTF, 1, [kvasprintf() is available])
1918         ], [
1919                 AC_MSG_RESULT(no)
1920         ])
1921 ])
1922
1923 dnl #
1924 dnl # 2.6.29 API change,
1925 dnl # vfs_fsync() funcation added, prior to this use file_fsync().
1926 dnl #
1927 AC_DEFUN([SPL_AC_VFS_FSYNC],
1928         [AC_MSG_CHECKING([whether vfs_fsync() is available])
1929         SPL_LINUX_TRY_COMPILE_SYMBOL([
1930                 #include <linux/fs.h>
1931         ], [
1932                 (void) vfs_fsync;
1933         ], [vfs_fsync], [fs/sync.c], [
1934                 AC_MSG_RESULT(yes)
1935                 AC_DEFINE(HAVE_VFS_FSYNC, 1, [vfs_fsync() is available])
1936         ], [
1937                 AC_MSG_RESULT(no)
1938         ])
1939 ])
1940
1941 dnl #
1942 dnl # 2.6.35 API change,
1943 dnl # Unused 'struct dentry *' removed from vfs_fsync() prototype.
1944 dnl #
1945 AC_DEFUN([SPL_AC_2ARGS_VFS_FSYNC], [
1946         AC_MSG_CHECKING([whether vfs_fsync() wants 2 args])
1947         SPL_LINUX_TRY_COMPILE([
1948                 #include <linux/fs.h>
1949         ],[
1950                 vfs_fsync(NULL, 0);
1951         ],[
1952                 AC_MSG_RESULT(yes)
1953                 AC_DEFINE(HAVE_2ARGS_VFS_FSYNC, 1, [vfs_fsync() wants 2 args])
1954         ],[
1955                 AC_MSG_RESULT(no)
1956         ])
1957 ])
1958
1959 dnl #
1960 dnl # 3.5 API change,
1961 dnl # inode_operations.truncate_range removed
1962 dnl #
1963 AC_DEFUN([SPL_AC_INODE_TRUNCATE_RANGE], [
1964         AC_MSG_CHECKING([whether truncate_range() inode operation is available])
1965         SPL_LINUX_TRY_COMPILE([
1966                 #include <linux/fs.h>
1967         ],[
1968                 struct inode_operations ops;
1969                 ops.truncate_range = NULL;
1970         ],[
1971                 AC_MSG_RESULT(yes)
1972                 AC_DEFINE(HAVE_INODE_TRUNCATE_RANGE, 1,
1973                         [truncate_range() inode operation is available])
1974         ],[
1975                 AC_MSG_RESULT(no)
1976         ])
1977 ])
1978
1979 dnl #
1980 dnl # Linux 2.6.38 - 3.x API
1981 dnl #
1982 AC_DEFUN([SPL_AC_KERNEL_FILE_FALLOCATE], [
1983         AC_MSG_CHECKING([whether fops->fallocate() exists])
1984         SPL_LINUX_TRY_COMPILE([
1985                 #include <linux/fs.h>
1986         ],[
1987                 long (*fallocate) (struct file *, int, loff_t, loff_t) = NULL;
1988                 struct file_operations fops __attribute__ ((unused)) = {
1989                         .fallocate = fallocate,
1990                 };
1991         ],[
1992                 AC_MSG_RESULT(yes)
1993                 AC_DEFINE(HAVE_FILE_FALLOCATE, 1, [fops->fallocate() exists])
1994         ],[
1995                 AC_MSG_RESULT(no)
1996         ])
1997 ])
1998
1999 dnl #
2000 dnl # Linux 2.6.x - 2.6.37 API
2001 dnl #
2002 AC_DEFUN([SPL_AC_KERNEL_INODE_FALLOCATE], [
2003         AC_MSG_CHECKING([whether iops->fallocate() exists])
2004         SPL_LINUX_TRY_COMPILE([
2005                 #include <linux/fs.h>
2006         ],[
2007                 long (*fallocate) (struct inode *, int, loff_t, loff_t) = NULL;
2008                 struct inode_operations fops __attribute__ ((unused)) = {
2009                         .fallocate = fallocate,
2010                 };
2011         ],[
2012                 AC_MSG_RESULT(yes)
2013                 AC_DEFINE(HAVE_INODE_FALLOCATE, 1, [fops->fallocate() exists])
2014         ],[
2015                 AC_MSG_RESULT(no)
2016         ])
2017 ])
2018
2019 dnl #
2020 dnl # PaX Linux 2.6.38 - 3.x API
2021 dnl #
2022 AC_DEFUN([SPL_AC_PAX_KERNEL_FILE_FALLOCATE], [
2023         AC_MSG_CHECKING([whether fops->fallocate() exists])
2024         SPL_LINUX_TRY_COMPILE([
2025                 #include <linux/fs.h>
2026         ],[
2027                 long (*fallocate) (struct file *, int, loff_t, loff_t) = NULL;
2028                 struct file_operations_no_const fops __attribute__ ((unused)) = {
2029                         .fallocate = fallocate,
2030                 };
2031         ],[
2032                 AC_MSG_RESULT(yes)
2033                 AC_DEFINE(HAVE_FILE_FALLOCATE, 1, [fops->fallocate() exists])
2034         ],[
2035                 AC_MSG_RESULT(no)
2036         ])
2037 ])
2038
2039 dnl #
2040 dnl # The fallocate callback was moved from the inode_operations
2041 dnl # structure to the file_operations structure.
2042 dnl #
2043 AC_DEFUN([SPL_AC_KERNEL_FALLOCATE], [
2044         SPL_AC_KERNEL_FILE_FALLOCATE
2045         SPL_AC_KERNEL_INODE_FALLOCATE
2046         SPL_AC_PAX_KERNEL_FILE_FALLOCATE
2047 ])
2048
2049 dnl #
2050 dnl # 2.6.33 API change. Also backported in RHEL5 as of 2.6.18-190.el5.
2051 dnl # Earlier versions of rwsem_is_locked() were inline and had a race
2052 dnl # condition.  The fixed version is exported as a symbol.  The race
2053 dnl # condition is fixed by acquiring sem->wait_lock, so we must not
2054 dnl # call that version while holding sem->wait_lock.
2055 dnl #
2056 AC_DEFUN([SPL_AC_EXPORTED_RWSEM_IS_LOCKED],
2057         [AC_MSG_CHECKING([whether rwsem_is_locked() acquires sem->wait_lock])
2058         SPL_LINUX_TRY_COMPILE_SYMBOL([
2059                 #include <linux/rwsem.h>
2060                 int rwsem_is_locked(struct rw_semaphore *sem) { return 0; }
2061         ], [], [rwsem_is_locked], [lib/rwsem-spinlock.c], [
2062                 AC_MSG_RESULT(yes)
2063                 AC_DEFINE(RWSEM_IS_LOCKED_TAKES_WAIT_LOCK, 1,
2064                           [rwsem_is_locked() acquires sem->wait_lock])
2065         ], [
2066                 AC_MSG_RESULT(no)
2067         ])
2068 ])
2069
2070 dnl #
2071 dnl # 2.6.xx API compat,
2072 dnl # There currently exists no exposed API to partially shrink the dcache.
2073 dnl # The expected mechanism to shrink the cache is a registered shrinker
2074 dnl # which is called during memory pressure.
2075 dnl #
2076 AC_DEFUN([SPL_AC_SHRINK_DCACHE_MEMORY],
2077         [AC_MSG_CHECKING([whether shrink_dcache_memory() is available])
2078         SPL_LINUX_TRY_COMPILE_SYMBOL([
2079                 #include <linux/dcache.h>
2080         ], [
2081                 shrink_dcache_memory(0, 0);
2082         ], [shrink_dcache_memory], [fs/dcache.c], [
2083                 AC_MSG_RESULT(yes)
2084                 AC_DEFINE(HAVE_SHRINK_DCACHE_MEMORY, 1,
2085                           [shrink_dcache_memory() is available])
2086         ], [
2087                 AC_MSG_RESULT(no)
2088         ])
2089 ])
2090
2091 dnl #
2092 dnl # 2.6.xx API compat,
2093 dnl # There currently exists no exposed API to partially shrink the icache.
2094 dnl # The expected mechanism to shrink the cache is a registered shrinker
2095 dnl # which is called during memory pressure.
2096 dnl #
2097 AC_DEFUN([SPL_AC_SHRINK_ICACHE_MEMORY],
2098         [AC_MSG_CHECKING([whether shrink_icache_memory() is available])
2099         SPL_LINUX_TRY_COMPILE_SYMBOL([
2100                 #include <linux/dcache.h>
2101         ], [
2102                 shrink_icache_memory(0, 0);
2103         ], [shrink_icache_memory], [fs/inode.c], [
2104                 AC_MSG_RESULT(yes)
2105                 AC_DEFINE(HAVE_SHRINK_ICACHE_MEMORY, 1,
2106                           [shrink_icache_memory() is available])
2107         ], [
2108                 AC_MSG_RESULT(no)
2109         ])
2110 ])
2111
2112 dnl #
2113 dnl # 2.6.39 API compat,
2114 dnl # The path_lookup() function has been renamed to kern_path_parent()
2115 dnl # and the flags argument has been removed.  The only behavior now
2116 dnl # offered is that of LOOKUP_PARENT.  The spl already always passed
2117 dnl # this flag so dropping the flag does not impact us.
2118 dnl #
2119 AC_DEFUN([SPL_AC_KERN_PATH_PARENT_HEADER], [
2120         SPL_CHECK_SYMBOL_HEADER(
2121                 [kern_path_parent],
2122                 [int kern_path_parent(const char \*, struct nameidata \*)],
2123                 [include/linux/namei.h],
2124                 [AC_DEFINE(HAVE_KERN_PATH_PARENT_HEADER, 1,
2125                 [kern_path_parent() is available])],
2126                 [])
2127 ])
2128
2129 dnl #
2130 dnl # 3.1 API compat,
2131 dnl # The kern_path_parent() symbol is no longer exported by the kernel.
2132 dnl # However, it remains the prefered interface and since we still have
2133 dnl # access to the prototype we dynamically lookup the required address.
2134 dnl #
2135 AC_DEFUN([SPL_AC_KERN_PATH_PARENT_SYMBOL],
2136         [AC_MSG_CHECKING([whether kern_path_parent() is available])
2137         SPL_LINUX_TRY_COMPILE_SYMBOL([
2138                 #include <linux/namei.h>
2139         ], [
2140                 kern_path_parent(NULL, NULL);
2141         ], [kern_path_parent], [fs/namei.c], [
2142                 AC_MSG_RESULT(yes)
2143                 AC_DEFINE(HAVE_KERN_PATH_PARENT_SYMBOL, 1,
2144                           [kern_path_parent() is available])
2145         ], [
2146                 AC_MSG_RESULT(no)
2147         ])
2148 ])
2149
2150 dnl #
2151 dnl # 3.6 API compat,
2152 dnl # The kern_path_parent() function was replaced by the kern_path_locked()
2153 dnl # function to eliminate all struct nameidata usage outside fs/namei.c.
2154 dnl #
2155 AC_DEFUN([SPL_AC_KERN_PATH_LOCKED], [
2156         SPL_CHECK_SYMBOL_HEADER(
2157                 [kern_path_locked],
2158                 [struct dentry \*kern_path_locked(const char \*, struct path \*)],
2159                 [include/linux/namei.h],
2160                 [AC_DEFINE(HAVE_KERN_PATH_LOCKED, 1,
2161                 [kern_path_locked() is available])],
2162                 [])
2163 ])
2164
2165 dnl #
2166 dnl # /proc/kallsyms support,
2167 dnl # Verify the kernel has CONFIG_KALLSYMS support enabled.
2168 dnl #
2169 AC_DEFUN([SPL_AC_CONFIG_KALLSYMS], [
2170         AC_MSG_CHECKING([whether CONFIG_KALLSYMS is defined])
2171         SPL_LINUX_TRY_COMPILE([
2172                 #if !defined(CONFIG_KALLSYMS)
2173                 #error CONFIG_KALLSYMS not defined
2174                 #endif
2175         ],[ ],[
2176                 AC_MSG_RESULT([yes])
2177         ],[
2178                 AC_MSG_RESULT([no])
2179                 AC_MSG_ERROR([
2180         *** This kernel does not include the required kallsyms support.
2181         *** Rebuild the kernel with CONFIG_KALLSYMS=y set.])
2182         ])
2183 ])
2184
2185 dnl #
2186 dnl # zlib inflate compat,
2187 dnl # Verify the kernel has CONFIG_ZLIB_INFLATE support enabled.
2188 dnl #
2189 AC_DEFUN([SPL_AC_CONFIG_ZLIB_INFLATE], [
2190         AC_MSG_CHECKING([whether CONFIG_ZLIB_INFLATE is defined])
2191         SPL_LINUX_TRY_COMPILE([
2192                 #if !defined(CONFIG_ZLIB_INFLATE) && \
2193                     !defined(CONFIG_ZLIB_INFLATE_MODULE)
2194                 #error CONFIG_ZLIB_INFLATE not defined
2195                 #endif
2196         ],[ ],[
2197                 AC_MSG_RESULT([yes])
2198         ],[
2199                 AC_MSG_RESULT([no])
2200                 AC_MSG_ERROR([
2201         *** This kernel does not include the required zlib inflate support.
2202         *** Rebuild the kernel with CONFIG_ZLIB_INFLATE=y|m set.])
2203         ])
2204 ])
2205
2206 dnl #
2207 dnl # zlib deflate compat,
2208 dnl # Verify the kernel has CONFIG_ZLIB_DEFLATE support enabled.
2209 dnl #
2210 AC_DEFUN([SPL_AC_CONFIG_ZLIB_DEFLATE], [
2211         AC_MSG_CHECKING([whether CONFIG_ZLIB_DEFLATE is defined])
2212         SPL_LINUX_TRY_COMPILE([
2213                 #if !defined(CONFIG_ZLIB_DEFLATE) && \
2214                     !defined(CONFIG_ZLIB_DEFLATE_MODULE)
2215                 #error CONFIG_ZLIB_DEFLATE not defined
2216                 #endif
2217         ],[ ],[
2218                 AC_MSG_RESULT([yes])
2219         ],[
2220                 AC_MSG_RESULT([no])
2221                 AC_MSG_ERROR([
2222         *** This kernel does not include the required zlib deflate support.
2223         *** Rebuild the kernel with CONFIG_ZLIB_DEFLATE=y|m set.])
2224         ])
2225 ])
2226
2227 dnl #
2228 dnl # 2.6.39 API compat,
2229 dnl # The function zlib_deflate_workspacesize() now take 2 arguments.
2230 dnl # This was done to avoid always having to allocate the maximum size
2231 dnl # workspace (268K).  The caller can now specific the windowBits and
2232 dnl # memLevel compression parameters to get a smaller workspace.
2233 dnl #
2234 AC_DEFUN([SPL_AC_2ARGS_ZLIB_DEFLATE_WORKSPACESIZE],
2235         [AC_MSG_CHECKING([whether zlib_deflate_workspacesize() wants 2 args])
2236         SPL_LINUX_TRY_COMPILE([
2237                 #include <linux/zlib.h>
2238         ],[
2239                 return zlib_deflate_workspacesize(MAX_WBITS, MAX_MEM_LEVEL);
2240         ],[
2241                 AC_MSG_RESULT(yes)
2242                 AC_DEFINE(HAVE_2ARGS_ZLIB_DEFLATE_WORKSPACESIZE, 1,
2243                           [zlib_deflate_workspacesize() wants 2 args])
2244         ],[
2245                 AC_MSG_RESULT(no)
2246         ])
2247 ])
2248
2249 dnl #
2250 dnl # 2.6.39 API change,
2251 dnl # Shrinker adjust to use common shrink_control structure.
2252 dnl #
2253 AC_DEFUN([SPL_AC_SHRINK_CONTROL_STRUCT], [
2254         AC_MSG_CHECKING([whether struct shrink_control exists])
2255         SPL_LINUX_TRY_COMPILE([
2256                 #include <linux/mm.h>
2257         ],[
2258                 struct shrink_control sc __attribute__ ((unused));
2259
2260                 sc.nr_to_scan = 0;
2261                 sc.gfp_mask = GFP_KERNEL;
2262         ],[
2263                 AC_MSG_RESULT(yes)
2264                 AC_DEFINE(HAVE_SHRINK_CONTROL_STRUCT, 1,
2265                         [struct shrink_control exists])
2266         ],[
2267                 AC_MSG_RESULT(no)
2268         ])
2269 ])
2270
2271 dnl #
2272 dnl # 3.1 API Change
2273 dnl #
2274 dnl # The rw_semaphore.wait_lock member was changed from spinlock_t to
2275 dnl # raw_spinlock_t at commit ddb6c9b58a19edcfac93ac670b066c836ff729f1.
2276 dnl #
2277 AC_DEFUN([SPL_AC_RWSEM_SPINLOCK_IS_RAW], [
2278         AC_MSG_CHECKING([whether struct rw_semaphore member wait_lock is raw])
2279         tmp_flags="$EXTRA_KCFLAGS"
2280         EXTRA_KCFLAGS="-Werror"
2281         SPL_LINUX_TRY_COMPILE([
2282                 #include <linux/rwsem.h>
2283         ],[
2284                 struct rw_semaphore dummy_semaphore __attribute__ ((unused));
2285                 raw_spinlock_t dummy_lock __attribute__ ((unused));
2286                 dummy_semaphore.wait_lock = dummy_lock;
2287         ],[
2288                 AC_MSG_RESULT(yes)
2289                 AC_DEFINE(RWSEM_SPINLOCK_IS_RAW, 1,
2290                 [struct rw_semaphore member wait_lock is raw_spinlock_t])
2291         ],[
2292                 AC_MSG_RESULT(no)
2293         ])
2294         EXTRA_KCFLAGS="$tmp_flags"
2295 ])
2296
2297 dnl #
2298 dnl # 3.9 API change,
2299 dnl # Moved things from linux/sched.h to linux/sched/rt.h
2300 dnl #
2301 AC_DEFUN([SPL_AC_SCHED_RT_HEADER],
2302         [AC_MSG_CHECKING([whether header linux/sched/rt.h exists])
2303         SPL_LINUX_TRY_COMPILE([
2304                 #include <linux/sched.h>
2305                 #include <linux/sched/rt.h>
2306         ],[
2307                 return 0;
2308         ],[
2309                 AC_DEFINE(HAVE_SCHED_RT_HEADER, 1, [linux/sched/rt.h exists])
2310                 AC_MSG_RESULT(yes)
2311         ],[
2312                 AC_MSG_RESULT(no)
2313         ])
2314 ])
2315
2316 dnl #
2317 dnl # 3.9 API change,
2318 dnl # vfs_getattr() uses 2 args
2319 dnl # It takes struct path * instead of struct vfsmount * and struct dentry *
2320 dnl #
2321 AC_DEFUN([SPL_AC_2ARGS_VFS_GETATTR], [
2322         AC_MSG_CHECKING([whether vfs_getattr() wants])
2323         SPL_LINUX_TRY_COMPILE([
2324                 #include <linux/fs.h>
2325         ],[
2326                 vfs_getattr((struct path *) NULL,
2327                         (struct kstat *)NULL);
2328         ],[
2329                 AC_MSG_RESULT(2 args)
2330                 AC_DEFINE(HAVE_2ARGS_VFS_GETATTR, 1,
2331                           [vfs_getattr wants 2 args])
2332         ],[
2333                 SPL_LINUX_TRY_COMPILE([
2334                         #include <linux/fs.h>
2335                 ],[
2336                         vfs_getattr((struct vfsmount *)NULL,
2337                                 (struct dentry *)NULL,
2338                                 (struct kstat *)NULL);
2339                 ],[
2340                         AC_MSG_RESULT(3 args)
2341                 ],[
2342                         AC_MSG_ERROR(unknown)
2343                 ])
2344         ])
2345 ])