config/spl-build.m4

   1 ###############################################################################
   2 # Copyright (C) 2007-2010 Lawrence Livermore National Security, LLC.
   3 # Copyright (C) 2007 The Regents of the University of California.
   4 # Written by Brian Behlendorf <behlendorf1@llnl.gov>.
   5 ###############################################################################
   6 # SPL_AC_CONFIG_KERNEL: Default SPL kernel configuration.
   7 ###############################################################################
   8
   9 AC_DEFUN([SPL_AC_CONFIG_KERNEL], [
  10         SPL_AC_KERNEL
  11
  12         if test "${LINUX_OBJ}" != "${LINUX}"; then
  13                 KERNELMAKE_PARAMS="$KERNELMAKE_PARAMS O=$LINUX_OBJ"
  14         fi
  15         AC_SUBST(KERNELMAKE_PARAMS)
  16
  17         KERNELCPPFLAGS="$KERNELCPPFLAGS -Wstrict-prototypes"
  18         AC_SUBST(KERNELCPPFLAGS)
  19
  20         SPL_AC_DEBUG
  21         SPL_AC_DEBUG_LOG
  22         SPL_AC_DEBUG_KMEM
  23         SPL_AC_DEBUG_KMEM_TRACKING
  24         SPL_AC_TEST_MODULE
  25         SPL_AC_ATOMIC_SPINLOCK
  26         SPL_AC_TYPE_ATOMIC64_CMPXCHG
  27         SPL_AC_TYPE_ATOMIC64_XCHG
  28         SPL_AC_TYPE_UINTPTR_T
  29         SPL_AC_2ARGS_REGISTER_SYSCTL
  30         SPL_AC_SET_SHRINKER
  31         SPL_AC_3ARGS_SHRINKER_CALLBACK
  32         SPL_AC_PATH_IN_NAMEIDATA
  33         SPL_AC_TASK_CURR
  34         SPL_AC_CTL_UNNUMBERED
  35         SPL_AC_CTL_NAME
  36         SPL_AC_FLS64
  37         SPL_AC_DEVICE_CREATE
  38         SPL_AC_5ARGS_DEVICE_CREATE
  39         SPL_AC_CLASS_DEVICE_CREATE
  40         SPL_AC_SET_NORMALIZED_TIMESPEC_EXPORT
  41         SPL_AC_SET_NORMALIZED_TIMESPEC_INLINE
  42         SPL_AC_TIMESPEC_SUB
  43         SPL_AC_INIT_UTSNAME
  44         SPL_AC_UACCESS_HEADER
  45         SPL_AC_KMALLOC_NODE
  46         SPL_AC_MONOTONIC_CLOCK
  47         SPL_AC_INODE_I_MUTEX
  48         SPL_AC_MUTEX_OWNER
  49         SPL_AC_MUTEX_OWNER_TASK_STRUCT
  50         SPL_AC_MUTEX_LOCK_NESTED
  51         SPL_AC_3ARGS_ON_EACH_CPU
  52         SPL_AC_KALLSYMS_LOOKUP_NAME
  53         SPL_AC_GET_VMALLOC_INFO
  54         SPL_AC_PGDAT_HELPERS
  55         SPL_AC_FIRST_ONLINE_PGDAT
  56         SPL_AC_NEXT_ONLINE_PGDAT
  57         SPL_AC_NEXT_ZONE
  58         SPL_AC_PGDAT_LIST
  59         SPL_AC_GLOBAL_PAGE_STATE
  60         SPL_AC_ZONE_STAT_ITEM_FREE
  61         SPL_AC_ZONE_STAT_ITEM_INACTIVE
  62         SPL_AC_ZONE_STAT_ITEM_ACTIVE
  63         SPL_AC_GET_ZONE_COUNTS
  64         SPL_AC_USER_PATH_DIR
  65         SPL_AC_SET_FS_PWD
  66         SPL_AC_2ARGS_SET_FS_PWD
  67         SPL_AC_2ARGS_VFS_UNLINK
  68         SPL_AC_4ARGS_VFS_RENAME
  69         SPL_AC_VFS_FSYNC
  70         SPL_AC_2ARGS_VFS_FSYNC
  71         SPL_AC_INODE_TRUNCATE_RANGE
  72         SPL_AC_FS_STRUCT_SPINLOCK
  73         SPL_AC_CRED_STRUCT
  74         SPL_AC_GROUPS_SEARCH
  75         SPL_AC_PUT_TASK_STRUCT
  76         SPL_AC_5ARGS_PROC_HANDLER
  77         SPL_AC_KVASPRINTF
  78         SPL_AC_EXPORTED_RWSEM_IS_LOCKED
  79         SPL_AC_KERNEL_FALLOCATE
  80         SPL_AC_SHRINK_DCACHE_MEMORY
  81         SPL_AC_SHRINK_ICACHE_MEMORY
  82         SPL_AC_KERN_PATH_PARENT_HEADER
  83         SPL_AC_KERN_PATH_PARENT_SYMBOL
  84         SPL_AC_KERN_PATH_LOCKED
  85         SPL_AC_CONFIG_KALLSYMS
  86         SPL_AC_CONFIG_ZLIB_INFLATE
  87         SPL_AC_CONFIG_ZLIB_DEFLATE
  88         SPL_AC_2ARGS_ZLIB_DEFLATE_WORKSPACESIZE
  89         SPL_AC_SHRINK_CONTROL_STRUCT
  90         SPL_AC_RWSEM_SPINLOCK_IS_RAW
  91 ])
  92
  93 AC_DEFUN([SPL_AC_MODULE_SYMVERS], [
  94         modpost=$LINUX/scripts/Makefile.modpost
  95         AC_MSG_CHECKING([kernel file name for module symbols])
  96         if test "x$enable_linux_builtin" != xyes -a -f "$modpost"; then
  97                 if grep -q Modules.symvers $modpost; then
  98                         LINUX_SYMBOLS=Modules.symvers
  99                 else
 100                         LINUX_SYMBOLS=Module.symvers
 101                 fi
 102
 103                 if ! test -f "$LINUX_OBJ/$LINUX_SYMBOLS"; then
 104                         AC_MSG_ERROR([
 105         *** Please make sure the kernel devel package for your distribution
 106         *** is installed.  If your building with a custom kernel make sure the
 107         *** kernel is configured, built, and the '--with-linux=PATH' configure
 108         *** option refers to the location of the kernel source.])
 109                 fi
 110         else
 111                 LINUX_SYMBOLS=NONE
 112         fi
 113         AC_MSG_RESULT($LINUX_SYMBOLS)
 114         AC_SUBST(LINUX_SYMBOLS)
 115 ])
 116
 117 AC_DEFUN([SPL_AC_KERNEL], [
 118         AC_ARG_WITH([linux],
 119                 AS_HELP_STRING([--with-linux=PATH],
 120                 [Path to kernel source]),
 121                 [kernelsrc="$withval"])
 122
 123         AC_ARG_WITH([linux-obj],
 124                 AS_HELP_STRING([--with-linux-obj=PATH],
 125                 [Path to kernel build objects]),
 126                 [kernelbuild="$withval"])
 127
 128         AC_MSG_CHECKING([kernel source directory])
 129         if test -z "$kernelsrc"; then
 130                 if test -e "/lib/modules/$(uname -r)/source"; then
 131                         headersdir="/lib/modules/$(uname -r)/source"
 132                         sourcelink=$(readlink -f "$headersdir")
 133                 elif test -e "/lib/modules/$(uname -r)/build"; then
 134                         headersdir="/lib/modules/$(uname -r)/build"
 135                         sourcelink=$(readlink -f "$headersdir")
 136                 else
 137                         sourcelink=$(ls -1d /usr/src/kernels/* \
 138                                      /usr/src/linux-* \
 139                                      2>/dev/null | grep -v obj | tail -1)
 140                 fi
 141
 142                 if test -n "$sourcelink" && test -e ${sourcelink}; then
 143                         kernelsrc=`readlink -f ${sourcelink}`
 144                 else
 145                         kernelsrc="[Not found]"
 146                 fi
 147         else
 148                 if test "$kernelsrc" = "NONE"; then
 149                         kernsrcver=NONE
 150                 fi
 151         fi
 152
 153         AC_MSG_RESULT([$kernelsrc])
 154         if test ! -d "$kernelsrc"; then
 155                 AC_MSG_ERROR([
 156         *** Please make sure the kernel devel package for your distribution
 157         *** is installed then try again.  If that fails you can specify the
 158         *** location of the kernel source with the '--with-linux=PATH' option.])
 159         fi
 160
 161         AC_MSG_CHECKING([kernel build directory])
 162         if test -z "$kernelbuild"; then
 163                 if test -e "/lib/modules/$(uname -r)/build"; then
 164                         kernelbuild=`readlink -f /lib/modules/$(uname -r)/build`
 165                 elif test -d ${kernelsrc}-obj/${target_cpu}/${target_cpu}; then
 166                         kernelbuild=${kernelsrc}-obj/${target_cpu}/${target_cpu}
 167                 elif test -d ${kernelsrc}-obj/${target_cpu}/default; then
 168                         kernelbuild=${kernelsrc}-obj/${target_cpu}/default
 169                 elif test -d `dirname ${kernelsrc}`/build-${target_cpu}; then
 170                         kernelbuild=`dirname ${kernelsrc}`/build-${target_cpu}
 171                 else
 172                         kernelbuild=${kernelsrc}
 173                 fi
 174         fi
 175         AC_MSG_RESULT([$kernelbuild])
 176
 177         AC_MSG_CHECKING([kernel source version])
 178         utsrelease1=$kernelbuild/include/linux/version.h
 179         utsrelease2=$kernelbuild/include/linux/utsrelease.h
 180         utsrelease3=$kernelbuild/include/generated/utsrelease.h
 181         if test -r $utsrelease1 && fgrep -q UTS_RELEASE $utsrelease1; then
 182                 utsrelease=linux/version.h
 183         elif test -r $utsrelease2 && fgrep -q UTS_RELEASE $utsrelease2; then
 184                 utsrelease=linux/utsrelease.h
 185         elif test -r $utsrelease3 && fgrep -q UTS_RELEASE $utsrelease3; then
 186                 utsrelease=generated/utsrelease.h
 187         fi
 188
 189         if test "$utsrelease"; then
 190                 kernsrcver=`(echo "#include <$utsrelease>";
 191                              echo "kernsrcver=UTS_RELEASE") |
 192                              cpp -I $kernelbuild/include |
 193                              grep "^kernsrcver=" | cut -d \" -f 2`
 194
 195                 if test -z "$kernsrcver"; then
 196                         AC_MSG_RESULT([Not found])
 197                         AC_MSG_ERROR([*** Cannot determine kernel version.])
 198                 fi
 199         else
 200                 AC_MSG_RESULT([Not found])
 201                 if test "x$enable_linux_builtin" != xyes; then
 202                         AC_MSG_ERROR([*** Cannot find UTS_RELEASE definition.])
 203                 else
 204                         AC_MSG_ERROR([
 205         *** Cannot find UTS_RELEASE definition.
 206         *** Please run 'make prepare' inside the kernel source tree.])
 207                 fi
 208         fi
 209
 210         AC_MSG_RESULT([$kernsrcver])
 211
 212         LINUX=${kernelsrc}
 213         LINUX_OBJ=${kernelbuild}
 214         LINUX_VERSION=${kernsrcver}
 215
 216         AC_SUBST(LINUX)
 217         AC_SUBST(LINUX_OBJ)
 218         AC_SUBST(LINUX_VERSION)
 219
 220         SPL_AC_MODULE_SYMVERS
 221 ])
 222
 223 dnl #
 224 dnl # Default SPL user configuration
 225 dnl #
 226 AC_DEFUN([SPL_AC_CONFIG_USER], [])
 227
 228 dnl #
 229 dnl # Check for rpm+rpmbuild to build RPM packages.  If these tools
 230 dnl # are missing it is non-fatal but you will not be able to build
 231 dnl # RPM packages and will be warned if you try too.
 232 dnl #
 233 AC_DEFUN([SPL_AC_RPM], [
 234         RPM=rpm
 235         RPMBUILD=rpmbuild
 236
 237         AC_MSG_CHECKING([whether $RPM is available])
 238         AS_IF([tmp=$($RPM --version 2>/dev/null)], [
 239                 RPM_VERSION=$(echo $tmp | $AWK '/RPM/ { print $[3] }')
 240                 HAVE_RPM=yes
 241                 AC_MSG_RESULT([$HAVE_RPM ($RPM_VERSION)])
 242         ],[
 243                 HAVE_RPM=no
 244                 AC_MSG_RESULT([$HAVE_RPM])
 245         ])
 246
 247         AC_MSG_CHECKING([whether $RPMBUILD is available])
 248         AS_IF([tmp=$($RPMBUILD --version 2>/dev/null)], [
 249                 RPMBUILD_VERSION=$(echo $tmp | $AWK '/RPM/ { print $[3] }')
 250                 HAVE_RPMBUILD=yes
 251                 AC_MSG_RESULT([$HAVE_RPMBUILD ($RPMBUILD_VERSION)])
 252         ],[
 253                 HAVE_RPMBUILD=no
 254                 AC_MSG_RESULT([$HAVE_RPMBUILD])
 255         ])
 256
 257         AC_SUBST(HAVE_RPM)
 258         AC_SUBST(RPM)
 259         AC_SUBST(RPM_VERSION)
 260
 261         AC_SUBST(HAVE_RPMBUILD)
 262         AC_SUBST(RPMBUILD)
 263         AC_SUBST(RPMBUILD_VERSION)
 264 ])
 265
 266 dnl #
 267 dnl # Check for dpkg+dpkg-buildpackage to build DEB packages.  If these
 268 dnl # tools are missing it is non-fatal but you will not be able to build
 269 dnl # DEB packages and will be warned if you try too.
 270 dnl #
 271 AC_DEFUN([SPL_AC_DPKG], [
 272         DPKG=dpkg
 273         DPKGBUILD=dpkg-buildpackage
 274
 275         AC_MSG_CHECKING([whether $DPKG is available])
 276         AS_IF([tmp=$($DPKG --version 2>/dev/null)], [
 277                 DPKG_VERSION=$(echo $tmp | $AWK '/Debian/ { print $[7] }')
 278                 HAVE_DPKG=yes
 279                 AC_MSG_RESULT([$HAVE_DPKG ($DPKG_VERSION)])
 280         ],[
 281                 HAVE_DPKG=no
 282                 AC_MSG_RESULT([$HAVE_DPKG])
 283         ])
 284
 285         AC_MSG_CHECKING([whether $DPKGBUILD is available])
 286         AS_IF([tmp=$($DPKGBUILD --version 2>/dev/null)], [
 287                 DPKGBUILD_VERSION=$(echo $tmp | \
 288                     $AWK '/Debian/ { print $[4] }' | cut -f-4 -d'.')
 289                 HAVE_DPKGBUILD=yes
 290                 AC_MSG_RESULT([$HAVE_DPKGBUILD ($DPKGBUILD_VERSION)])
 291         ],[
 292                 HAVE_DPKGBUILD=no
 293                 AC_MSG_RESULT([$HAVE_DPKGBUILD])
 294         ])
 295
 296         AC_SUBST(HAVE_DPKG)
 297         AC_SUBST(DPKG)
 298         AC_SUBST(DPKG_VERSION)
 299
 300         AC_SUBST(HAVE_DPKGBUILD)
 301         AC_SUBST(DPKGBUILD)
 302         AC_SUBST(DPKGBUILD_VERSION)
 303 ])
 304
 305 dnl #
 306 dnl # Check for pacman+makepkg to build Arch Linux packages.  If these
 307 dnl # tools are missing it is non-fatal but you will not be able to
 308 dnl # build Arch Linux packages and will be warned if you try too.
 309 dnl #
 310 AC_DEFUN([SPL_AC_PACMAN], [
 311         PACMAN=pacman
 312         MAKEPKG=makepkg
 313
 314         AC_MSG_CHECKING([whether $PACMAN is available])
 315         tmp=$($PACMAN --version 2>/dev/null)
 316         AS_IF([test -n "$tmp"], [
 317                 PACMAN_VERSION=$(echo $tmp |
 318                                  $AWK '/Pacman/ { print $[3] }' |
 319                                  $SED 's/^v//')
 320                 HAVE_PACMAN=yes
 321                 AC_MSG_RESULT([$HAVE_PACMAN ($PACMAN_VERSION)])
 322         ],[
 323                 HAVE_PACMAN=no
 324                 AC_MSG_RESULT([$HAVE_PACMAN])
 325         ])
 326
 327         AC_MSG_CHECKING([whether $MAKEPKG is available])
 328         tmp=$($MAKEPKG --version 2>/dev/null)
 329         AS_IF([test -n "$tmp"], [
 330                 MAKEPKG_VERSION=$(echo $tmp | $AWK '/makepkg/ { print $[3] }')
 331                 HAVE_MAKEPKG=yes
 332                 AC_MSG_RESULT([$HAVE_MAKEPKG ($MAKEPKG_VERSION)])
 333         ],[
 334                 HAVE_MAKEPKG=no
 335                 AC_MSG_RESULT([$HAVE_MAKEPKG])
 336         ])
 337
 338         AC_SUBST(HAVE_PACMAN)
 339         AC_SUBST(PACMAN)
 340         AC_SUBST(PACMAN_VERSION)
 341
 342         AC_SUBST(HAVE_MAKEPKG)
 343         AC_SUBST(MAKEPKG)
 344         AC_SUBST(MAKEPKG_VERSION)
 345 ])
 346
 347 dnl #
 348 dnl # Until native packaging for various different packing systems
 349 dnl # can be added the least we can do is attempt to use alien to
 350 dnl # convert the RPM packages to the needed package type.  This is
 351 dnl # a hack but so far it has worked reasonable well.
 352 dnl #
 353 AC_DEFUN([SPL_AC_ALIEN], [
 354         ALIEN=alien
 355
 356         AC_MSG_CHECKING([whether $ALIEN is available])
 357         AS_IF([tmp=$($ALIEN --version 2>/dev/null)], [
 358                 ALIEN_VERSION=$(echo $tmp | $AWK '{ print $[3] }')
 359                 HAVE_ALIEN=yes
 360                 AC_MSG_RESULT([$HAVE_ALIEN ($ALIEN_VERSION)])
 361         ],[
 362                 HAVE_ALIEN=no
 363                 AC_MSG_RESULT([$HAVE_ALIEN])
 364         ])
 365
 366         AC_SUBST(HAVE_ALIEN)
 367         AC_SUBST(ALIEN)
 368         AC_SUBST(ALIEN_VERSION)
 369 ])
 370
 371 dnl #
 372 dnl # Using the VENDOR tag from config.guess set the default
 373 dnl # package type for 'make pkg': (rpm | deb | tgz)
 374 dnl #
 375 AC_DEFUN([SPL_AC_DEFAULT_PACKAGE], [
 376         AC_MSG_CHECKING([linux distribution])
 377         if test -f /etc/toss-release ; then
 378                 VENDOR=toss ;
 379         elif test -f /etc/fedora-release ; then
 380                 VENDOR=fedora ;
 381         elif test -f /etc/redhat-release ; then
 382                 VENDOR=redhat ;
 383         elif test -f /etc/gentoo-release ; then
 384                 VENDOR=gentoo ;
 385         elif test -f /etc/arch-release ; then
 386                 VENDOR=arch ;
 387         elif test -f /etc/SuSE-release ; then
 388                 VENDOR=sles ;
 389         elif test -f /etc/slackware-version ; then
 390                 VENDOR=slackware ;
 391         elif test -f /etc/lunar.release ; then
 392                 VENDOR=lunar ;
 393         elif test -f /etc/lsb-release ; then
 394                 VENDOR=ubuntu ;
 395         elif test -f /etc/debian_version ; then
 396                 VENDOR=debian ;
 397         else
 398                 VENDOR= ;
 399         fi
 400         AC_MSG_RESULT([$VENDOR])
 401         AC_SUBST(VENDOR)
 402
 403         AC_MSG_CHECKING([default package type])
 404         case "$VENDOR" in
 405                 toss)       DEFAULT_PACKAGE=rpm  ;;
 406                 redhat)     DEFAULT_PACKAGE=rpm  ;;
 407                 fedora)     DEFAULT_PACKAGE=rpm  ;;
 408                 gentoo)     DEFAULT_PACKAGE=tgz  ;;
 409                 arch)       DEFAULT_PACKAGE=arch ;;
 410                 sles)       DEFAULT_PACKAGE=rpm  ;;
 411                 slackware)  DEFAULT_PACKAGE=tgz  ;;
 412                 lunar)      DEFAULT_PACKAGE=tgz  ;;
 413                 ubuntu)     DEFAULT_PACKAGE=deb  ;;
 414                 debian)     DEFAULT_PACKAGE=deb  ;;
 415                 *)          DEFAULT_PACKAGE=rpm  ;;
 416         esac
 417
 418         AC_MSG_RESULT([$DEFAULT_PACKAGE])
 419         AC_SUBST(DEFAULT_PACKAGE)
 420 ])
 421
 422 dnl #
 423 dnl # Default SPL user configuration
 424 dnl #
 425 AC_DEFUN([SPL_AC_PACKAGE], [
 426         SPL_AC_DEFAULT_PACKAGE
 427         SPL_AC_RPM
 428         SPL_AC_DPKG
 429         SPL_AC_ALIEN
 430
 431         AS_IF([test "$VENDOR" = "arch"], [SPL_AC_PACMAN])
 432 ])
 433
 434 AC_DEFUN([SPL_AC_LICENSE], [
 435         AC_MSG_CHECKING([spl license])
 436         LICENSE=GPL
 437         AC_MSG_RESULT([$LICENSE])
 438         KERNELCPPFLAGS="${KERNELCPPFLAGS} -DHAVE_GPL_ONLY_SYMBOLS"
 439         AC_SUBST(LICENSE)
 440 ])
 441
 442 AC_DEFUN([SPL_AC_CONFIG], [
 443         SPL_CONFIG=all
 444         AC_ARG_WITH([config],
 445                 AS_HELP_STRING([--with-config=CONFIG],
 446                 [Config file 'kernel|user|all|srpm']),
 447                 [SPL_CONFIG="$withval"])
 448         AC_ARG_ENABLE([linux-builtin],
 449                 [AC_HELP_STRING([--enable-linux-builtin],
 450                 [Configure for builtin in-tree kernel modules @<:@default=no@:>@])],
 451                 [],
 452                 [enable_linux_builtin=no])
 453
 454         AC_MSG_CHECKING([spl config])
 455         AC_MSG_RESULT([$SPL_CONFIG]);
 456         AC_SUBST(SPL_CONFIG)
 457
 458         case "$SPL_CONFIG" in
 459                 kernel) SPL_AC_CONFIG_KERNEL ;;
 460                 user)   SPL_AC_CONFIG_USER   ;;
 461                 all)    SPL_AC_CONFIG_KERNEL
 462                         SPL_AC_CONFIG_USER   ;;
 463                 srpm)                        ;;
 464                 *)
 465                 AC_MSG_RESULT([Error!])
 466                 AC_MSG_ERROR([Bad value "$SPL_CONFIG" for --with-config,
 467                              user kernel|user|all|srpm]) ;;
 468         esac
 469
 470         AM_CONDITIONAL([CONFIG_USER],
 471                        [test "$SPL_CONFIG" = user -o "$SPL_CONFIG" = all])
 472         AM_CONDITIONAL([CONFIG_KERNEL],
 473                        [test "$SPL_CONFIG" = kernel -o "$SPL_CONFIG" = all] &&
 474                        [test "x$enable_linux_builtin" != xyes ])
 475 ])
 476
 477 dnl #
 478 dnl # Enable if the SPL should be compiled with internal debugging enabled.
 479 dnl # By default this support is disabled.
 480 dnl #
 481 AC_DEFUN([SPL_AC_DEBUG], [
 482         AC_MSG_CHECKING([whether debugging is enabled])
 483         AC_ARG_ENABLE([debug],
 484                 [AS_HELP_STRING([--enable-debug],
 485                 [Enable generic debug support @<:@default=no@:>@])],
 486                 [],
 487                 [enable_debug=no])
 488
 489         AS_IF([test "x$enable_debug" = xyes],
 490         [
 491                 KERNELCPPFLAGS="${KERNELCPPFLAGS} -DDEBUG -Werror"
 492                 DEBUG_CFLAGS="-DDEBUG -Werror"
 493                 DEBUG_SPL="_with_debug"
 494         ], [
 495                 KERNELCPPFLAGS="${KERNELCPPFLAGS} -DNDEBUG"
 496                 DEBUG_CFLAGS="-DNDEBUG"
 497                 DEBUG_SPL="_without_debug"
 498         ])
 499
 500         AC_SUBST(DEBUG_CFLAGS)
 501         AC_SUBST(DEBUG_SPL)
 502         AC_MSG_RESULT([$enable_debug])
 503 ])
 504
 505 dnl #
 506 dnl # Enabled by default it provides a basic debug log infrastructure.
 507 dnl # Each subsystem registers itself with a name and logs messages
 508 dnl # using predefined types.  If the debug mask it set to allow the
 509 dnl # message type it will be written to the internal log.  The log
 510 dnl # can be dumped to a file by echoing 1 to the 'dump' proc entry,
 511 dnl # after dumping the log it must be decoded using the spl utility.
 512 dnl #
 513 dnl # echo 1 >/proc/sys/kernel/spl/debug/dump
 514 dnl # spl /tmp/spl-log.xxx.yyy /tmp/spl-log.xxx.yyy.txt
 515 dnl #
 516 AC_DEFUN([SPL_AC_DEBUG_LOG], [
 517         AC_ARG_ENABLE([debug-log],
 518                 [AS_HELP_STRING([--enable-debug-log],
 519                 [Enable basic debug logging @<:@default=yes@:>@])],
 520                 [],
 521                 [enable_debug_log=yes])
 522
 523         AS_IF([test "x$enable_debug_log" = xyes],
 524         [
 525                 KERNELCPPFLAGS="${KERNELCPPFLAGS} -DDEBUG_LOG"
 526                 DEBUG_LOG="_with_debug_log"
 527                 AC_DEFINE([DEBUG_LOG], [1],
 528                 [Define to 1 to enable basic debug logging])
 529         ], [
 530                 DEBUG_LOG="_without_debug_log"
 531         ])
 532
 533         AC_SUBST(DEBUG_LOG)
 534         AC_MSG_CHECKING([whether basic debug logging is enabled])
 535         AC_MSG_RESULT([$enable_debug_log])
 536 ])
 537
 538 dnl #
 539 dnl # Enabled by default it provides a minimal level of memory tracking.
 540 dnl # A total count of bytes allocated is kept for each alloc and free.
 541 dnl # Then at module unload time a report to the console will be printed
 542 dnl # if memory was leaked.  Additionally, /proc/spl/kmem/slab will exist
 543 dnl # and provide an easy way to inspect the kmem based slab.
 544 dnl #
 545 AC_DEFUN([SPL_AC_DEBUG_KMEM], [
 546         AC_ARG_ENABLE([debug-kmem],
 547                 [AS_HELP_STRING([--enable-debug-kmem],
 548                 [Enable basic kmem accounting @<:@default=yes@:>@])],
 549                 [],
 550                 [enable_debug_kmem=yes])
 551
 552         AS_IF([test "x$enable_debug_kmem" = xyes],
 553         [
 554                 KERNELCPPFLAGS="${KERNELCPPFLAGS} -DDEBUG_KMEM"
 555                 DEBUG_KMEM="_with_debug_kmem"
 556                 AC_DEFINE([DEBUG_KMEM], [1],
 557                 [Define to 1 to enable basic kmem accounting])
 558         ], [
 559                 DEBUG_KMEM="_without_debug_kmem"
 560         ])
 561
 562         AC_SUBST(DEBUG_KMEM)
 563         AC_MSG_CHECKING([whether basic kmem accounting is enabled])
 564         AC_MSG_RESULT([$enable_debug_kmem])
 565 ])
 566
 567 dnl #
 568 dnl # Disabled by default it provides detailed memory tracking.  This
 569 dnl # feature also requires --enable-debug-kmem to be set.  When enabled
 570 dnl # not only will total bytes be tracked but also the location of every
 571 dnl # alloc and free.  When the SPL module is unloaded a list of all leaked
 572 dnl # addresses and where they were allocated will be dumped to the console.
 573 dnl # Enabling this feature has a significant impact on performance but it
 574 dnl # makes finding memory leaks pretty straight forward.
 575 dnl #
 576 AC_DEFUN([SPL_AC_DEBUG_KMEM_TRACKING], [
 577         AC_ARG_ENABLE([debug-kmem-tracking],
 578                 [AS_HELP_STRING([--enable-debug-kmem-tracking],
 579                 [Enable detailed kmem tracking  @<:@default=no@:>@])],
 580                 [],
 581                 [enable_debug_kmem_tracking=no])
 582
 583         AS_IF([test "x$enable_debug_kmem_tracking" = xyes],
 584         [
 585                 KERNELCPPFLAGS="${KERNELCPPFLAGS} -DDEBUG_KMEM_TRACKING"
 586                 DEBUG_KMEM_TRACKING="_with_debug_kmem_tracking"
 587                 AC_DEFINE([DEBUG_KMEM_TRACKING], [1],
 588                 [Define to 1 to enable detailed kmem tracking])
 589         ], [
 590                 DEBUG_KMEM_TRACKING="_without_debug_kmem_tracking"
 591         ])
 592
 593         AC_SUBST(DEBUG_KMEM_TRACKING)
 594         AC_MSG_CHECKING([whether detailed kmem tracking is enabled])
 595         AC_MSG_RESULT([$enable_debug_kmem_tracking])
 596 ])
 597
 598 dnl #
 599 dnl # SPL_LINUX_CONFTEST
 600 dnl #
 601 AC_DEFUN([SPL_LINUX_CONFTEST], [
 602 cat confdefs.h - <<_ACEOF >conftest.c
 603 $1
 604 _ACEOF
 605 ])
 606
 607 dnl #
 608 dnl # SPL_LANG_PROGRAM(C)([PROLOGUE], [BODY])
 609 dnl #
 610 m4_define([SPL_LANG_PROGRAM], [
 611 $1
 612 int
 613 main (void)
 614 {
 615 dnl Do *not* indent the following line: there may be CPP directives.
 616 dnl Don't move the `;' right after for the same reason.
 617 $2
 618   ;
 619   return 0;
 620 }
 621 ])
 622
 623 dnl #
 624 dnl # SPL_LINUX_COMPILE_IFELSE / like AC_COMPILE_IFELSE
 625 dnl #
 626 AC_DEFUN([SPL_LINUX_COMPILE_IFELSE], [
 627         m4_ifvaln([$1], [SPL_LINUX_CONFTEST([$1])])
 628         rm -Rf build && mkdir -p build && touch build/conftest.mod.c
 629         echo "obj-m := conftest.o" >build/Makefile
 630         modpost_flag=''
 631         test "x$enable_linux_builtin" = xyes && modpost_flag='modpost=true' # fake modpost stage
 632         AS_IF(
 633                 [AC_TRY_COMMAND(cp conftest.c build && make [$2] -C $LINUX_OBJ EXTRA_CFLAGS="-Werror-implicit-function-declaration $EXTRA_KCFLAGS" $ARCH_UM M=$PWD/build $modpost_flag) >/dev/null && AC_TRY_COMMAND([$3])],
 634                 [$4],
 635                 [_AC_MSG_LOG_CONFTEST m4_ifvaln([$5],[$5])]
 636         )
 637         rm -Rf build
 638 ])
 639
 640 dnl #
 641 dnl # SPL_LINUX_TRY_COMPILE like AC_TRY_COMPILE
 642 dnl #
 643 AC_DEFUN([SPL_LINUX_TRY_COMPILE],
 644         [SPL_LINUX_COMPILE_IFELSE(
 645         [AC_LANG_SOURCE([SPL_LANG_PROGRAM([[$1]], [[$2]])])],
 646         [modules],
 647         [test -s build/conftest.o],
 648         [$3], [$4])
 649 ])
 650
 651 dnl #
 652 dnl # SPL_CHECK_SYMBOL_EXPORT
 653 dnl # check symbol exported or not
 654 dnl #
 655 AC_DEFUN([SPL_CHECK_SYMBOL_EXPORT], [
 656         grep -q -E '[[[:space:]]]$1[[[:space:]]]' \
 657                 $LINUX_OBJ/Module*.symvers 2>/dev/null
 658         rc=$?
 659         if test $rc -ne 0; then
 660                 export=0
 661                 for file in $2; do
 662                         grep -q -E "EXPORT_SYMBOL.*($1)" \
 663                                 "$LINUX_OBJ/$file" 2>/dev/null
 664                         rc=$?
 665                         if test $rc -eq 0; then
 666                                 export=1
 667                                 break;
 668                         fi
 669                 done
 670                 if test $export -eq 0; then :
 671                         $4
 672                 else :
 673                         $3
 674                 fi
 675         else :
 676                 $3
 677         fi
 678 ])
 679
 680 dnl #
 681 dnl # SPL_LINUX_TRY_COMPILE_SYMBOL
 682 dnl # like SPL_LINUX_TRY_COMPILE, except SPL_CHECK_SYMBOL_EXPORT
 683 dnl # is called if not compiling for builtin
 684 dnl #
 685 AC_DEFUN([SPL_LINUX_TRY_COMPILE_SYMBOL], [
 686         SPL_LINUX_TRY_COMPILE([$1], [$2], [rc=0], [rc=1])
 687         if test $rc -ne 0; then :
 688                 $6
 689         else
 690                 if test "x$enable_linux_builtin" != xyes; then
 691                         SPL_CHECK_SYMBOL_EXPORT([$3], [$4], [rc=0], [rc=1])
 692                 fi
 693                 if test $rc -ne 0; then :
 694                         $6
 695                 else :
 696                         $5
 697                 fi
 698         fi
 699 ])
 700
 701 dnl #
 702 dnl # SPL_CHECK_SYMBOL_HEADER
 703 dnl # check if a symbol prototype is defined in listed headers.
 704 dnl #
 705 AC_DEFUN([SPL_CHECK_SYMBOL_HEADER], [
 706         AC_MSG_CHECKING([whether symbol $1 exists in header])
 707         header=0
 708         for file in $3; do
 709                 grep -q "$2" "$LINUX/$file" 2>/dev/null
 710                 rc=$?
 711                 if test $rc -eq 0; then
 712                         header=1
 713                         break;
 714                 fi
 715         done
 716         if test $header -eq 0; then
 717                 AC_MSG_RESULT([no])
 718                 $5
 719         else
 720                 AC_MSG_RESULT([yes])
 721                 $4
 722         fi
 723 ])
 724
 725 dnl #
 726 dnl # SPL_CHECK_HEADER
 727 dnl # check whether header exists and define HAVE_$2_HEADER
 728 dnl #
 729 AC_DEFUN([SPL_CHECK_HEADER],
 730         [AC_MSG_CHECKING([whether header $1 exists])
 731         SPL_LINUX_TRY_COMPILE([
 732                 #include <$1>
 733         ],[
 734                 return 0;
 735         ],[
 736                 AC_DEFINE(HAVE_$2_HEADER, 1, [$1 exists])
 737                 AC_MSG_RESULT(yes)
 738                 $3
 739         ],[
 740                 AC_MSG_RESULT(no)
 741                 $4
 742         ])
 743 ])
 744
 745 dnl #
 746 dnl # Basic toolchain sanity check.
 747 dnl #
 748 AC_DEFUN([SPL_AC_TEST_MODULE],
 749         [AC_MSG_CHECKING([whether modules can be built])
 750         SPL_LINUX_TRY_COMPILE([],[],[
 751                 AC_MSG_RESULT([yes])
 752         ],[
 753                 AC_MSG_RESULT([no])
 754                 if test "x$enable_linux_builtin" != xyes; then
 755                         AC_MSG_ERROR([*** Unable to build an empty module.])
 756                 else
 757                         AC_MSG_ERROR([
 758         *** Unable to build an empty module.
 759         *** Please run 'make scripts' inside the kernel source tree.])
 760                 fi
 761         ])
 762 ])
 763
 764 dnl #
 765 dnl # Use the atomic implemenation based on global spinlocks.  This
 766 dnl # should only be needed by 32-bit kernels which do not provide
 767 dnl # the atomic64_* API.  It may be optionally enabled as a fallback
 768 dnl # if problems are observed with the direct mapping to the native
 769 dnl # Linux atomic operations.  You may not disable atomic spinlocks
 770 dnl # if you kernel does not an atomic64_* API.
 771 dnl #
 772 AC_DEFUN([SPL_AC_ATOMIC_SPINLOCK], [
 773         AC_ARG_ENABLE([atomic-spinlocks],
 774                 [AS_HELP_STRING([--enable-atomic-spinlocks],
 775                 [Atomic types use spinlocks @<:@default=check@:>@])],
 776                 [],
 777                 [enable_atomic_spinlocks=check])
 778
 779         SPL_LINUX_TRY_COMPILE([
 780                 #include <linux/fs.h>
 781         ],[
 782                 atomic64_t *ptr __attribute__ ((unused));
 783         ],[
 784                 have_atomic64_t=yes
 785                 AC_DEFINE(HAVE_ATOMIC64_T, 1,
 786                         [kernel defines atomic64_t])
 787         ],[
 788                 have_atomic64_t=no
 789         ])
 790
 791         AS_IF([test "x$enable_atomic_spinlocks" = xcheck], [
 792                 AS_IF([test "x$have_atomic64_t" = xyes], [
 793                         enable_atomic_spinlocks=no
 794                 ],[
 795                         enable_atomic_spinlocks=yes
 796                 ])
 797         ])
 798
 799         AS_IF([test "x$enable_atomic_spinlocks" = xyes], [
 800                 AC_DEFINE([ATOMIC_SPINLOCK], [1],
 801                         [Atomic types use spinlocks])
 802         ],[
 803                 AS_IF([test "x$have_atomic64_t" = xno], [
 804                         AC_MSG_FAILURE(
 805                         [--disable-atomic-spinlocks given but required atomic64 support is unavailable])
 806                 ])
 807         ])
 808
 809         AC_MSG_CHECKING([whether atomic types use spinlocks])
 810         AC_MSG_RESULT([$enable_atomic_spinlocks])
 811
 812         AC_MSG_CHECKING([whether kernel defines atomic64_t])
 813         AC_MSG_RESULT([$have_atomic64_t])
 814 ])
 815
 816 dnl #
 817 dnl # 2.6.24 API change,
 818 dnl # check if atomic64_cmpxchg is defined
 819 dnl #
 820 AC_DEFUN([SPL_AC_TYPE_ATOMIC64_CMPXCHG],
 821         [AC_MSG_CHECKING([whether kernel defines atomic64_cmpxchg])
 822         SPL_LINUX_TRY_COMPILE([
 823                 #include <linux/fs.h>
 824         ],[
 825                 atomic64_cmpxchg((atomic64_t *)NULL, 0, 0);
 826         ],[
 827                 AC_MSG_RESULT([yes])
 828                 AC_DEFINE(HAVE_ATOMIC64_CMPXCHG, 1,
 829                           [kernel defines atomic64_cmpxchg])
 830         ],[
 831                 AC_MSG_RESULT([no])
 832         ])
 833 ])
 834
 835 dnl #
 836 dnl # 2.6.24 API change,
 837 dnl # check if atomic64_xchg is defined
 838 dnl #
 839 AC_DEFUN([SPL_AC_TYPE_ATOMIC64_XCHG],
 840         [AC_MSG_CHECKING([whether kernel defines atomic64_xchg])
 841         SPL_LINUX_TRY_COMPILE([
 842                 #include <linux/fs.h>
 843         ],[
 844                 atomic64_xchg((atomic64_t *)NULL, 0);
 845         ],[
 846                 AC_MSG_RESULT([yes])
 847                 AC_DEFINE(HAVE_ATOMIC64_XCHG, 1,
 848                           [kernel defines atomic64_xchg])
 849         ],[
 850                 AC_MSG_RESULT([no])
 851         ])
 852 ])
 853
 854 dnl #
 855 dnl # 2.6.24 API change,
 856 dnl # check if uintptr_t typedef is defined
 857 dnl #
 858 AC_DEFUN([SPL_AC_TYPE_UINTPTR_T],
 859         [AC_MSG_CHECKING([whether kernel defines uintptr_t])
 860         SPL_LINUX_TRY_COMPILE([
 861                 #include <linux/types.h>
 862         ],[
 863                 uintptr_t *ptr __attribute__ ((unused));
 864         ],[
 865                 AC_MSG_RESULT([yes])
 866                 AC_DEFINE(HAVE_UINTPTR_T, 1,
 867                           [kernel defines uintptr_t])
 868         ],[
 869                 AC_MSG_RESULT([no])
 870         ])
 871 ])
 872
 873 dnl #
 874 dnl # 2.6.21 API change,
 875 dnl # 'register_sysctl_table' use only one argument instead of two
 876 dnl #
 877 AC_DEFUN([SPL_AC_2ARGS_REGISTER_SYSCTL],
 878         [AC_MSG_CHECKING([whether register_sysctl_table() wants 2 args])
 879         SPL_LINUX_TRY_COMPILE([
 880                 #include <linux/sysctl.h>
 881         ],[
 882                 (void) register_sysctl_table(NULL, 0);
 883         ],[
 884                 AC_MSG_RESULT(yes)
 885                 AC_DEFINE(HAVE_2ARGS_REGISTER_SYSCTL, 1,
 886                           [register_sysctl_table() wants 2 args])
 887         ],[
 888                 AC_MSG_RESULT(no)
 889         ])
 890 ])
 891
 892 dnl #
 893 dnl # 2.6.23 API change
 894 dnl # Old set_shrinker API replaced with register_shrinker
 895 dnl #
 896 AC_DEFUN([SPL_AC_SET_SHRINKER], [
 897         AC_MSG_CHECKING([whether set_shrinker() available])
 898         SPL_LINUX_TRY_COMPILE([
 899                 #include <linux/mm.h>
 900         ],[
 901                 return set_shrinker(DEFAULT_SEEKS, NULL);
 902         ],[
 903                 AC_MSG_RESULT([yes])
 904                 AC_DEFINE(HAVE_SET_SHRINKER, 1,
 905                           [set_shrinker() available])
 906         ],[
 907                 AC_MSG_RESULT([no])
 908         ])
 909 ])
 910
 911 dnl #
 912 dnl # 2.6.35 API change,
 913 dnl # Add context to shrinker callback
 914 dnl #
 915 AC_DEFUN([SPL_AC_3ARGS_SHRINKER_CALLBACK],
 916         [AC_MSG_CHECKING([whether shrinker callback wants 3 args])
 917         tmp_flags="$EXTRA_KCFLAGS"
 918         EXTRA_KCFLAGS="-Werror"
 919         SPL_LINUX_TRY_COMPILE([
 920                 #include <linux/mm.h>
 921
 922                 int shrinker_cb(struct shrinker *, int, unsigned int);
 923         ],[
 924                 struct shrinker cache_shrinker = {
 925                         .shrink = shrinker_cb,
 926                         .seeks = DEFAULT_SEEKS,
 927                 };
 928                 register_shrinker(&cache_shrinker);
 929         ],[
 930                 AC_MSG_RESULT(yes)
 931                 AC_DEFINE(HAVE_3ARGS_SHRINKER_CALLBACK, 1,
 932                           [shrinker callback wants 3 args])
 933         ],[
 934                 AC_MSG_RESULT(no)
 935         ])
 936         EXTRA_KCFLAGS="$tmp_flags"
 937 ])
 938
 939 dnl #
 940 dnl # 2.6.25 API change,
 941 dnl # struct path entry added to struct nameidata
 942 dnl #
 943 AC_DEFUN([SPL_AC_PATH_IN_NAMEIDATA],
 944         [AC_MSG_CHECKING([whether struct path used in struct nameidata])
 945         SPL_LINUX_TRY_COMPILE([
 946                 #include <linux/namei.h>
 947         ],[
 948                 struct nameidata nd __attribute__ ((unused));
 949
 950                 nd.path.mnt = NULL;
 951                 nd.path.dentry = NULL;
 952         ],[
 953                 AC_MSG_RESULT(yes)
 954                 AC_DEFINE(HAVE_PATH_IN_NAMEIDATA, 1,
 955                           [struct path used in struct nameidata])
 956         ],[
 957                 AC_MSG_RESULT(no)
 958         ])
 959 ])
 960
 961 dnl #
 962 dnl # Custom SPL patch may export this system it is not required
 963 dnl #
 964 AC_DEFUN([SPL_AC_TASK_CURR],
 965         [AC_MSG_CHECKING([whether task_curr() is available])
 966         SPL_LINUX_TRY_COMPILE_SYMBOL([
 967                 #include <linux/sched.h>
 968         ], [
 969                 task_curr(NULL);
 970         ], [task_curr], [kernel/sched.c], [
 971                 AC_MSG_RESULT(yes)
 972                 AC_DEFINE(HAVE_TASK_CURR, 1, [task_curr() is available])
 973         ], [
 974                 AC_MSG_RESULT(no)
 975         ])
 976 ])
 977
 978 dnl #
 979 dnl # 2.6.19 API change,
 980 dnl # Use CTL_UNNUMBERED when binary sysctl is not required
 981 dnl #
 982 AC_DEFUN([SPL_AC_CTL_UNNUMBERED],
 983         [AC_MSG_CHECKING([whether unnumbered sysctl support exists])
 984         SPL_LINUX_TRY_COMPILE([
 985                 #include <linux/sysctl.h>
 986         ],[
 987                 #ifndef CTL_UNNUMBERED
 988                 #error CTL_UNNUMBERED undefined
 989                 #endif
 990         ],[
 991                 AC_MSG_RESULT(yes)
 992                 AC_DEFINE(HAVE_CTL_UNNUMBERED, 1,
 993                           [unnumbered sysctl support exists])
 994         ],[
 995                 AC_MSG_RESULT(no)
 996         ])
 997 ])
 998
 999 dnl #
1000 dnl # 2.6.33 API change,
1001 dnl # Removed .ctl_name from struct ctl_table.
1002 dnl #
1003 AC_DEFUN([SPL_AC_CTL_NAME], [
1004         AC_MSG_CHECKING([whether struct ctl_table has ctl_name])
1005         SPL_LINUX_TRY_COMPILE([
1006                 #include <linux/sysctl.h>
1007         ],[
1008                 struct ctl_table ctl __attribute__ ((unused));
1009                 ctl.ctl_name = 0;
1010         ],[
1011                 AC_MSG_RESULT(yes)
1012                 AC_DEFINE(HAVE_CTL_NAME, 1, [struct ctl_table has ctl_name])
1013         ],[
1014                 AC_MSG_RESULT(no)
1015         ])
1016 ])
1017
1018 dnl #
1019 dnl # 2.6.16 API change.
1020 dnl # Check if 'fls64()' is available
1021 dnl #
1022 AC_DEFUN([SPL_AC_FLS64],
1023         [AC_MSG_CHECKING([whether fls64() is available])
1024         SPL_LINUX_TRY_COMPILE([
1025                 #include <linux/bitops.h>
1026         ],[
1027                 return fls64(0);
1028         ],[
1029                 AC_MSG_RESULT(yes)
1030                 AC_DEFINE(HAVE_FLS64, 1, [fls64() is available])
1031         ],[
1032                 AC_MSG_RESULT(no)
1033         ])
1034 ])
1035
1036 dnl #
1037 dnl # 2.6.18 API change, check whether device_create() is available.
1038 dnl # Device_create() was introduced in 2.6.18 and depricated
1039 dnl # class_device_create() which was fully removed in 2.6.26.
1040 dnl #
1041 AC_DEFUN([SPL_AC_DEVICE_CREATE],
1042         [AC_MSG_CHECKING([whether device_create() is available])
1043         SPL_CHECK_SYMBOL_EXPORT([device_create], [drivers/base/core.c], [
1044                 AC_MSG_RESULT(yes)
1045                 AC_DEFINE(HAVE_DEVICE_CREATE, 1,
1046                           [device_create() is available])
1047         ], [
1048                 AC_MSG_RESULT(no)
1049         ])
1050 ])
1051
1052 dnl #
1053 dnl # 2.6.27 API change,
1054 dnl # device_create() uses 5 args, new 'drvdata' argument.
1055 dnl #
1056 AC_DEFUN([SPL_AC_5ARGS_DEVICE_CREATE], [
1057         AC_MSG_CHECKING([whether device_create() wants 5 args])
1058         tmp_flags="$EXTRA_KCFLAGS"
1059         EXTRA_KCFLAGS="-Werror"
1060         SPL_LINUX_TRY_COMPILE([
1061                 #include <linux/device.h>
1062         ],[
1063                 device_create(NULL, NULL, 0, NULL, "%d", 1);
1064         ],[
1065                 AC_MSG_RESULT(yes)
1066                 AC_DEFINE(HAVE_5ARGS_DEVICE_CREATE, 1,
1067                           [device_create wants 5 args])
1068         ],[
1069                 AC_MSG_RESULT(no)
1070         ])
1071         EXTRA_KCFLAGS="$tmp_flags"
1072 ])
1073
1074 dnl #
1075 dnl # 2.6.13 API change, check whether class_device_create() is available.
1076 dnl # Class_device_create() was introduced in 2.6.13 and depricated
1077 dnl # class_simple_device_add() which was fully removed in 2.6.13.
1078 dnl #
1079 AC_DEFUN([SPL_AC_CLASS_DEVICE_CREATE],
1080         [AC_MSG_CHECKING([whether class_device_create() is available])
1081         SPL_LINUX_TRY_COMPILE_SYMBOL([
1082                 #include <linux/device.h>
1083         ], [
1084                 class_device_create(NULL, NULL, 0, NULL, NULL);
1085         ], [class_device_create], [drivers/base/class.c], [
1086                 AC_MSG_RESULT(yes)
1087                 AC_DEFINE(HAVE_CLASS_DEVICE_CREATE, 1,
1088                           [class_device_create() is available])
1089         ], [
1090                 AC_MSG_RESULT(no)
1091         ])
1092 ])
1093
1094 dnl #
1095 dnl # 2.6.26 API change, set_normalized_timespec() is exported.
1096 dnl #
1097 AC_DEFUN([SPL_AC_SET_NORMALIZED_TIMESPEC_EXPORT],
1098         [AC_MSG_CHECKING([whether set_normalized_timespec() is available as export])
1099         SPL_LINUX_TRY_COMPILE_SYMBOL([
1100                 #include <linux/time.h>
1101         ], [
1102                 set_normalized_timespec(NULL, 0, 0);
1103         ], [set_normalized_timespec], [kernel/time.c], [
1104                 AC_MSG_RESULT(yes)
1105                 AC_DEFINE(HAVE_SET_NORMALIZED_TIMESPEC_EXPORT, 1,
1106                           [set_normalized_timespec() is available as export])
1107         ], [
1108                 AC_MSG_RESULT(no)
1109         ])
1110 ])
1111
1112 dnl #
1113 dnl # 2.6.16 API change, set_normalize_timespec() moved to time.c
1114 dnl # previously it was available in time.h as an inline.
1115 dnl #
1116 AC_DEFUN([SPL_AC_SET_NORMALIZED_TIMESPEC_INLINE], [
1117         AC_MSG_CHECKING([whether set_normalized_timespec() is an inline])
1118         SPL_LINUX_TRY_COMPILE([
1119                 #include <linux/time.h>
1120                 void set_normalized_timespec(struct timespec *ts,
1121                                              time_t sec, long nsec) { }
1122         ],
1123         [],
1124         [
1125                 AC_MSG_RESULT(no)
1126         ],[
1127                 AC_MSG_RESULT(yes)
1128                 AC_DEFINE(HAVE_SET_NORMALIZED_TIMESPEC_INLINE, 1,
1129                           [set_normalized_timespec() is available as inline])
1130         ])
1131 ])
1132
1133 dnl #
1134 dnl # 2.6.18 API change,
1135 dnl # timespec_sub() inline function available in linux/time.h
1136 dnl #
1137 AC_DEFUN([SPL_AC_TIMESPEC_SUB], [
1138         AC_MSG_CHECKING([whether timespec_sub() is available])
1139         SPL_LINUX_TRY_COMPILE([
1140                 #include <linux/time.h>
1141         ],[
1142                 struct timespec a = { 0 };
1143                 struct timespec b = { 0 };
1144                 struct timespec c __attribute__ ((unused));
1145                 c = timespec_sub(a, b);
1146         ],[
1147                 AC_MSG_RESULT(yes)
1148                 AC_DEFINE(HAVE_TIMESPEC_SUB, 1, [timespec_sub() is available])
1149         ],[
1150                 AC_MSG_RESULT(no)
1151         ])
1152 ])
1153
1154 dnl #
1155 dnl # 2.6.19 API change,
1156 dnl # check if init_utsname() is available in linux/utsname.h
1157 dnl #
1158 AC_DEFUN([SPL_AC_INIT_UTSNAME], [
1159         AC_MSG_CHECKING([whether init_utsname() is available])
1160         SPL_LINUX_TRY_COMPILE([
1161                 #include <linux/utsname.h>
1162         ],[
1163                 struct new_utsname *a __attribute__ ((unused));
1164                 a = init_utsname();
1165         ],[
1166                 AC_MSG_RESULT(yes)
1167                 AC_DEFINE(HAVE_INIT_UTSNAME, 1, [init_utsname() is available])
1168         ],[
1169                 AC_MSG_RESULT(no)
1170         ])
1171 ])
1172
1173 dnl #
1174 dnl # 2.6.18 API change,
1175 dnl # added linux/uaccess.h
1176 dnl #
1177 AC_DEFUN([SPL_AC_UACCESS_HEADER], [
1178         SPL_CHECK_HEADER([linux/uaccess.h], [UACCESS], [], [])
1179 ])
1180
1181 dnl #
1182 dnl # 2.6.12 API change,
1183 dnl # check whether 'kmalloc_node()' is available.
1184 dnl #
1185 AC_DEFUN([SPL_AC_KMALLOC_NODE], [
1186         AC_MSG_CHECKING([whether kmalloc_node() is available])
1187         SPL_LINUX_TRY_COMPILE([
1188                 #include <linux/slab.h>
1189         ],[
1190                 void *a __attribute__ ((unused));
1191                 a = kmalloc_node(1, GFP_KERNEL, 0);
1192         ],[
1193                 AC_MSG_RESULT(yes)
1194                 AC_DEFINE(HAVE_KMALLOC_NODE, 1, [kmalloc_node() is available])
1195         ],[
1196                 AC_MSG_RESULT(no)
1197         ])
1198 ])
1199
1200 dnl #
1201 dnl # 2.6.9 API change,
1202 dnl # check whether 'monotonic_clock()' is available it may
1203 dnl # be available for some archs but not others.
1204 dnl #
1205 AC_DEFUN([SPL_AC_MONOTONIC_CLOCK],
1206         [AC_MSG_CHECKING([whether monotonic_clock() is available])
1207         SPL_LINUX_TRY_COMPILE_SYMBOL([
1208                 #include <linux/timex.h>
1209         ], [
1210                 monotonic_clock();
1211         ], [monotonic_clock], [], [
1212                 AC_MSG_RESULT(yes)
1213                 AC_DEFINE(HAVE_MONOTONIC_CLOCK, 1,
1214                           [monotonic_clock() is available])
1215         ], [
1216                 AC_MSG_RESULT(no)
1217         ])
1218 ])
1219
1220 dnl #
1221 dnl # 2.6.16 API change,
1222 dnl # check whether 'struct inode' has i_mutex
1223 dnl #
1224 AC_DEFUN([SPL_AC_INODE_I_MUTEX], [
1225         AC_MSG_CHECKING([whether struct inode has i_mutex])
1226         SPL_LINUX_TRY_COMPILE([
1227                 #include <linux/fs.h>
1228                 #include <linux/mutex.h>
1229         ],[
1230                 struct inode i;
1231                 mutex_init(&i.i_mutex);
1232         ],[
1233                 AC_MSG_RESULT(yes)
1234                 AC_DEFINE(HAVE_INODE_I_MUTEX, 1, [struct inode has i_mutex])
1235         ],[
1236                 AC_MSG_RESULT(no)
1237         ])
1238 ])
1239
1240 dnl #
1241 dnl # 2.6.29 API change,
1242 dnl # Adaptive mutexs introduced.
1243 dnl #
1244 AC_DEFUN([SPL_AC_MUTEX_OWNER], [
1245         AC_MSG_CHECKING([whether struct mutex has owner])
1246         SPL_LINUX_TRY_COMPILE([
1247                 #include <linux/mutex.h>
1248         ],[
1249                 struct mutex mtx __attribute__ ((unused));
1250                 mtx.owner = NULL;
1251         ],[
1252                 AC_MSG_RESULT(yes)
1253                 AC_DEFINE(HAVE_MUTEX_OWNER, 1, [struct mutex has owner])
1254         ],[
1255                 AC_MSG_RESULT(no)
1256         ])
1257 ])
1258
1259 dnl #
1260 dnl # 2.6.39 API change,
1261 dnl # Owner type change.  A Linux mutex prior to 2.6.39 would store
1262 dnl # the owner as a thread_info pointer when CONFIG_DEBUG_MUTEXES
1263 dnl # was defined.  As of 2.6.39 this was changed to a task_struct
1264 dnl # pointer which frankly makes a lot more sense.
1265 dnl #
1266 AC_DEFUN([SPL_AC_MUTEX_OWNER_TASK_STRUCT], [
1267         AC_MSG_CHECKING([whether struct mutex owner is a task_struct])
1268         tmp_flags="$EXTRA_KCFLAGS"
1269         EXTRA_KCFLAGS="-Werror"
1270         SPL_LINUX_TRY_COMPILE([
1271                 #include <linux/mutex.h>
1272         ],[
1273                 struct mutex mtx __attribute__ ((unused));
1274                 mtx.owner = current;
1275         ],[
1276                 AC_MSG_RESULT(yes)
1277                 AC_DEFINE(HAVE_MUTEX_OWNER_TASK_STRUCT, 1,
1278                 [struct mutex owner is a task_struct])
1279         ],[
1280                 AC_MSG_RESULT(no)
1281         ])
1282         EXTRA_KCFLAGS="$tmp_flags"
1283 ])
1284
1285 dnl #
1286 dnl # 2.6.18 API change,
1287 dnl # First introduced 'mutex_lock_nested()' in include/linux/mutex.h,
1288 dnl # as part of the mutex validator.  Fallback to using 'mutex_lock()'
1289 dnl # if the mutex validator is disabled or otherwise unavailable.
1290 dnl #
1291 AC_DEFUN([SPL_AC_MUTEX_LOCK_NESTED], [
1292         AC_MSG_CHECKING([whether mutex_lock_nested() is available])
1293         SPL_LINUX_TRY_COMPILE([
1294                 #include <linux/mutex.h>
1295         ],[
1296                 struct mutex mutex;
1297                 mutex_init(&mutex);
1298                 mutex_lock_nested(&mutex, 0);
1299         ],[
1300                 AC_MSG_RESULT(yes)
1301                 AC_DEFINE(HAVE_MUTEX_LOCK_NESTED, 1,
1302                 [mutex_lock_nested() is available])
1303         ],[
1304                 AC_MSG_RESULT(no)
1305         ])
1306 ])
1307
1308 dnl #
1309 dnl # 2.6.27 API change,
1310 dnl # on_each_cpu() uses 3 args, no 'retry' argument
1311 dnl #
1312 AC_DEFUN([SPL_AC_3ARGS_ON_EACH_CPU], [
1313         AC_MSG_CHECKING([whether on_each_cpu() wants 3 args])
1314         SPL_LINUX_TRY_COMPILE([
1315                 #include <linux/interrupt.h>
1316                 #include <linux/smp.h>
1317
1318                 void on_each_cpu_func(void *data) { return; }
1319         ],[
1320                 on_each_cpu(on_each_cpu_func, NULL, 0);
1321         ],[
1322                 AC_MSG_RESULT(yes)
1323                 AC_DEFINE(HAVE_3ARGS_ON_EACH_CPU, 1,
1324                           [on_each_cpu wants 3 args])
1325         ],[
1326                 AC_MSG_RESULT(no)
1327         ])
1328 ])
1329
1330 dnl #
1331 dnl # 2.6.18 API change,
1332 dnl # kallsyms_lookup_name no longer exported
1333 dnl #
1334 AC_DEFUN([SPL_AC_KALLSYMS_LOOKUP_NAME],
1335         [AC_MSG_CHECKING([whether kallsyms_lookup_name() is available])
1336         SPL_LINUX_TRY_COMPILE_SYMBOL([
1337                 #include <linux/kallsyms.h>
1338         ], [
1339                 kallsyms_lookup_name(NULL);
1340         ], [kallsyms_lookup_name], [], [
1341                 AC_MSG_RESULT(yes)
1342                 AC_DEFINE(HAVE_KALLSYMS_LOOKUP_NAME, 1,
1343                           [kallsyms_lookup_name() is available])
1344         ], [
1345                 AC_MSG_RESULT(no)
1346         ])
1347 ])
1348
1349 dnl #
1350 dnl # Proposed API change,
1351 dnl # This symbol is not available in stock kernels.  You may build a
1352 dnl # custom kernel with the *-spl-export-symbols.patch which will export
1353 dnl # these symbols for use.  If your already rolling a custom kernel for
1354 dnl # your environment this is recommended.
1355 dnl #
1356 AC_DEFUN([SPL_AC_GET_VMALLOC_INFO],
1357         [AC_MSG_CHECKING([whether get_vmalloc_info() is available])
1358         SPL_CHECK_SYMBOL_EXPORT([get_vmalloc_info], [], [
1359                 AC_MSG_RESULT(yes)
1360                 AC_DEFINE(HAVE_GET_VMALLOC_INFO, 1,
1361                           [get_vmalloc_info() is available])
1362         ], [
1363                 AC_MSG_RESULT(no)
1364         ])
1365 ])
1366
1367 dnl #
1368 dnl # 2.6.17 API change
1369 dnl # The helper functions first_online_pgdat(), next_online_pgdat(), and
1370 dnl # next_zone() are introduced to simplify for_each_zone().  These symbols
1371 dnl # were exported in 2.6.17 for use by modules which was consistent with
1372 dnl # the previous implementation of for_each_zone().  From 2.6.18 - 2.6.19
1373 dnl # the symbols were exported as 'unused', and by 2.6.20 they exports
1374 dnl # were dropped entirely leaving modules no way to directly iterate over
1375 dnl # the zone list.  Because we need access to the zone helpers we check
1376 dnl # if the kernel contains the old or new implementation.  Then we check
1377 dnl # to see if the symbols we need for each version are available.  If they
1378 dnl # are not, dynamically aquire the addresses with kallsyms_lookup_name().
1379 dnl #
1380 AC_DEFUN([SPL_AC_PGDAT_HELPERS], [
1381         AC_MSG_CHECKING([whether symbol *_pgdat exist])
1382         grep -q -E 'first_online_pgdat' $LINUX/include/linux/mmzone.h 2>/dev/null
1383         rc=$?
1384         if test $rc -eq 0; then
1385                 AC_MSG_RESULT([yes])
1386                 AC_DEFINE(HAVE_PGDAT_HELPERS, 1, [pgdat helpers are available])
1387         else
1388                 AC_MSG_RESULT([no])
1389         fi
1390 ])
1391
1392 dnl #
1393 dnl # Proposed API change,
1394 dnl # This symbol is not available in stock kernels.  You may build a
1395 dnl # custom kernel with the *-spl-export-symbols.patch which will export
1396 dnl # these symbols for use.  If your already rolling a custom kernel for
1397 dnl # your environment this is recommended.
1398 dnl #
1399 AC_DEFUN([SPL_AC_FIRST_ONLINE_PGDAT],
1400         [AC_MSG_CHECKING([whether first_online_pgdat() is available])
1401         SPL_LINUX_TRY_COMPILE_SYMBOL([
1402                 #include <linux/mmzone.h>
1403         ], [
1404                 first_online_pgdat();
1405         ], [first_online_pgdat], [], [
1406                 AC_MSG_RESULT(yes)
1407                 AC_DEFINE(HAVE_FIRST_ONLINE_PGDAT, 1,
1408                           [first_online_pgdat() is available])
1409         ], [
1410                 AC_MSG_RESULT(no)
1411         ])
1412 ])
1413
1414 dnl #
1415 dnl # Proposed API change,
1416 dnl # This symbol is not available in stock kernels.  You may build a
1417 dnl # custom kernel with the *-spl-export-symbols.patch which will export
1418 dnl # these symbols for use.  If your already rolling a custom kernel for
1419 dnl # your environment this is recommended.
1420 dnl #
1421 AC_DEFUN([SPL_AC_NEXT_ONLINE_PGDAT],
1422         [AC_MSG_CHECKING([whether next_online_pgdat() is available])
1423         SPL_LINUX_TRY_COMPILE_SYMBOL([
1424                 #include <linux/mmzone.h>
1425         ], [
1426                 next_online_pgdat(NULL);
1427         ], [next_online_pgdat], [], [
1428                 AC_MSG_RESULT(yes)
1429                 AC_DEFINE(HAVE_NEXT_ONLINE_PGDAT, 1,
1430                           [next_online_pgdat() is available])
1431         ], [
1432                 AC_MSG_RESULT(no)
1433         ])
1434 ])
1435
1436 dnl #
1437 dnl # Proposed API change,
1438 dnl # This symbol is not available in stock kernels.  You may build a
1439 dnl # custom kernel with the *-spl-export-symbols.patch which will export
1440 dnl # these symbols for use.  If your already rolling a custom kernel for
1441 dnl # your environment this is recommended.
1442 dnl #
1443 AC_DEFUN([SPL_AC_NEXT_ZONE],
1444         [AC_MSG_CHECKING([whether next_zone() is available])
1445         SPL_LINUX_TRY_COMPILE_SYMBOL([
1446                 #include <linux/mmzone.h>
1447         ], [
1448                 next_zone(NULL);
1449         ], [next_zone], [], [
1450                 AC_MSG_RESULT(yes)
1451                 AC_DEFINE(HAVE_NEXT_ZONE, 1, [next_zone() is available])
1452         ], [
1453                 AC_MSG_RESULT(no)
1454         ])
1455 ])
1456
1457 dnl #
1458 dnl # 2.6.17 API change,
1459 dnl # See SPL_AC_PGDAT_HELPERS for details.
1460 dnl #
1461 AC_DEFUN([SPL_AC_PGDAT_LIST],
1462         [AC_MSG_CHECKING([whether pgdat_list is available])
1463         SPL_LINUX_TRY_COMPILE_SYMBOL([
1464                 #include <linux/topology.h>
1465                 pg_data_t *tmp = pgdat_list;
1466         ], [], [pgdat_list], [], [
1467                 AC_MSG_RESULT(yes)
1468                 AC_DEFINE(HAVE_PGDAT_LIST, 1, [pgdat_list is available])
1469         ], [
1470                 AC_MSG_RESULT(no)
1471         ])
1472 ])
1473
1474 dnl #
1475 dnl # 2.6.18 API change,
1476 dnl # First introduced global_page_state() support as an inline.
1477 dnl #
1478 AC_DEFUN([SPL_AC_GLOBAL_PAGE_STATE], [
1479         AC_MSG_CHECKING([whether global_page_state() is available])
1480         SPL_LINUX_TRY_COMPILE([
1481                 #include <linux/mm.h>
1482         ],[
1483                 unsigned long state __attribute__ ((unused));
1484                 state = global_page_state(0);
1485         ],[
1486                 AC_MSG_RESULT(yes)
1487                 AC_DEFINE(HAVE_GLOBAL_PAGE_STATE, 1,
1488                           [global_page_state() is available])
1489         ],[
1490                 AC_MSG_RESULT(no)
1491         ])
1492 ])
1493
1494 dnl #
1495 dnl # 2.6.21 API change (plus subsequent naming convention changes),
1496 dnl # Public global zone stats now include a free page count.  However
1497 dnl # the enumerated names of the counters have changed since this API
1498 dnl # was introduced.  We need to deduce the corrent name to use.  This
1499 dnl # replaces the priviate get_zone_counts() interface.
1500 dnl #
1501 dnl # NR_FREE_PAGES was available from 2.6.21 to current kernels, which
1502 dnl # is 2.6.30 as of when this was written.
1503 dnl #
1504 AC_DEFUN([SPL_AC_ZONE_STAT_ITEM_FREE], [
1505         AC_MSG_CHECKING([whether page state NR_FREE_PAGES is available])
1506         SPL_LINUX_TRY_COMPILE([
1507                 #include <linux/mm.h>
1508         ],[
1509                 enum zone_stat_item zsi __attribute__ ((unused));
1510                 zsi = NR_FREE_PAGES;
1511         ],[
1512                 AC_MSG_RESULT(yes)
1513                 AC_DEFINE(HAVE_ZONE_STAT_ITEM_NR_FREE_PAGES, 1,
1514                           [Page state NR_FREE_PAGES is available])
1515         ],[
1516                 AC_MSG_RESULT(no)
1517         ])
1518 ])
1519
1520 dnl #
1521 dnl # 2.6.21 API change (plus subsequent naming convention changes),
1522 dnl # Public global zone stats now include an inactive page count.  However
1523 dnl # the enumerated names of the counters have changed since this API
1524 dnl # was introduced.  We need to deduce the corrent name to use.  This
1525 dnl # replaces the priviate get_zone_counts() interface.
1526 dnl #
1527 dnl # NR_INACTIVE was available from 2.6.21 to 2.6.27 and included both
1528 dnl # anonymous and file inactive pages.  As of 2.6.28 it was split in
1529 dnl # to NR_INACTIVE_ANON and NR_INACTIVE_FILE.
1530 dnl #
1531 AC_DEFUN([SPL_AC_ZONE_STAT_ITEM_INACTIVE], [
1532         AC_MSG_CHECKING([whether page state NR_INACTIVE is available])
1533         SPL_LINUX_TRY_COMPILE([
1534                 #include <linux/mm.h>
1535         ],[
1536                 enum zone_stat_item zsi __attribute__ ((unused));
1537                 zsi = NR_INACTIVE;
1538         ],[
1539                 AC_MSG_RESULT(yes)
1540                 AC_DEFINE(HAVE_ZONE_STAT_ITEM_NR_INACTIVE, 1,
1541                           [Page state NR_INACTIVE is available])
1542         ],[
1543                 AC_MSG_RESULT(no)
1544         ])
1545
1546         AC_MSG_CHECKING([whether page state NR_INACTIVE_ANON is available])
1547         SPL_LINUX_TRY_COMPILE([
1548                 #include <linux/mm.h>
1549         ],[
1550                 enum zone_stat_item zsi __attribute__ ((unused));
1551                 zsi = NR_INACTIVE_ANON;
1552         ],[
1553                 AC_MSG_RESULT(yes)
1554                 AC_DEFINE(HAVE_ZONE_STAT_ITEM_NR_INACTIVE_ANON, 1,
1555                           [Page state NR_INACTIVE_ANON is available])
1556         ],[
1557                 AC_MSG_RESULT(no)
1558         ])
1559
1560         AC_MSG_CHECKING([whether page state NR_INACTIVE_FILE is available])
1561         SPL_LINUX_TRY_COMPILE([
1562                 #include <linux/mm.h>
1563         ],[
1564                 enum zone_stat_item zsi __attribute__ ((unused));
1565                 zsi = NR_INACTIVE_FILE;
1566         ],[
1567                 AC_MSG_RESULT(yes)
1568                 AC_DEFINE(HAVE_ZONE_STAT_ITEM_NR_INACTIVE_FILE, 1,
1569                           [Page state NR_INACTIVE_FILE is available])
1570         ],[
1571                 AC_MSG_RESULT(no)
1572         ])
1573 ])
1574
1575 dnl #
1576 dnl # 2.6.21 API change (plus subsequent naming convention changes),
1577 dnl # Public global zone stats now include an active page count.  However
1578 dnl # the enumerated names of the counters have changed since this API
1579 dnl # was introduced.  We need to deduce the corrent name to use.  This
1580 dnl # replaces the priviate get_zone_counts() interface.
1581 dnl #
1582 dnl # NR_ACTIVE was available from 2.6.21 to 2.6.27 and included both
1583 dnl # anonymous and file active pages.  As of 2.6.28 it was split in
1584 dnl # to NR_ACTIVE_ANON and NR_ACTIVE_FILE.
1585 dnl #
1586 AC_DEFUN([SPL_AC_ZONE_STAT_ITEM_ACTIVE], [
1587         AC_MSG_CHECKING([whether page state NR_ACTIVE is available])
1588         SPL_LINUX_TRY_COMPILE([
1589                 #include <linux/mm.h>
1590         ],[
1591                 enum zone_stat_item zsi __attribute__ ((unused));
1592                 zsi = NR_ACTIVE;
1593         ],[
1594                 AC_MSG_RESULT(yes)
1595                 AC_DEFINE(HAVE_ZONE_STAT_ITEM_NR_ACTIVE, 1,
1596                           [Page state NR_ACTIVE is available])
1597         ],[
1598                 AC_MSG_RESULT(no)
1599         ])
1600
1601         AC_MSG_CHECKING([whether page state NR_ACTIVE_ANON is available])
1602         SPL_LINUX_TRY_COMPILE([
1603                 #include <linux/mm.h>
1604         ],[
1605                 enum zone_stat_item zsi __attribute__ ((unused));
1606                 zsi = NR_ACTIVE_ANON;
1607         ],[
1608                 AC_MSG_RESULT(yes)
1609                 AC_DEFINE(HAVE_ZONE_STAT_ITEM_NR_ACTIVE_ANON, 1,
1610                           [Page state NR_ACTIVE_ANON is available])
1611         ],[
1612                 AC_MSG_RESULT(no)
1613         ])
1614
1615         AC_MSG_CHECKING([whether page state NR_ACTIVE_FILE is available])
1616         SPL_LINUX_TRY_COMPILE([
1617                 #include <linux/mm.h>
1618         ],[
1619                 enum zone_stat_item zsi __attribute__ ((unused));
1620                 zsi = NR_ACTIVE_FILE;
1621         ],[
1622                 AC_MSG_RESULT(yes)
1623                 AC_DEFINE(HAVE_ZONE_STAT_ITEM_NR_ACTIVE_FILE, 1,
1624                           [Page state NR_ACTIVE_FILE is available])
1625         ],[
1626                 AC_MSG_RESULT(no)
1627         ])
1628 ])
1629
1630 dnl #
1631 dnl # Proposed API change for legacy kernels.
1632 dnl # This symbol is not available in older kernels.  For kernels post
1633 dnl # 2.6.21 the global_page_state() API is used to get free/inactive/active
1634 dnl # page state information.  This symbol is only used in legacy kernels
1635 dnl # any only as a last resort.
1636 dnl
1637 AC_DEFUN([SPL_AC_GET_ZONE_COUNTS], [
1638         AC_MSG_CHECKING([whether symbol get_zone_counts is needed])
1639         SPL_LINUX_TRY_COMPILE([
1640         ],[
1641                 #if !defined(HAVE_ZONE_STAT_ITEM_NR_FREE_PAGES)
1642                 #error "global_page_state needs NR_FREE_PAGES"
1643                 #endif
1644
1645                 #if !defined(HAVE_ZONE_STAT_ITEM_NR_ACTIVE) && \
1646                     !defined(HAVE_ZONE_STAT_ITEM_NR_ACTIVE_ANON) && \
1647                     !defined(HAVE_ZONE_STAT_ITEM_NR_ACTIVE_FILE)
1648                 #error "global_page_state needs NR_ACTIVE*"
1649                 #endif
1650
1651                 #if !defined(HAVE_ZONE_STAT_ITEM_NR_INACTIVE) && \
1652                     !defined(HAVE_ZONE_STAT_ITEM_NR_INACTIVE_ANON) && \
1653                     !defined(HAVE_ZONE_STAT_ITEM_NR_INACTIVE_FILE)
1654                 #error "global_page_state needs NR_INACTIVE*"
1655                 #endif
1656         ],[
1657                 AC_MSG_RESULT(no)
1658         ],[
1659                 AC_MSG_RESULT(yes)
1660                 AC_DEFINE(NEED_GET_ZONE_COUNTS, 1,
1661                           [get_zone_counts() is needed])
1662
1663                 AC_MSG_CHECKING([whether get_zone_counts() is available])
1664                 SPL_LINUX_TRY_COMPILE_SYMBOL([
1665                         #include <linux/mmzone.h>
1666                 ], [
1667                         get_zone_counts(NULL, NULL, NULL);
1668                 ], [get_zone_counts], [], [
1669                         AC_MSG_RESULT(yes)
1670                         AC_DEFINE(HAVE_GET_ZONE_COUNTS, 1,
1671                                   [get_zone_counts() is available])
1672                 ], [
1673                         AC_MSG_RESULT(no)
1674                 ])
1675         ])
1676 ])
1677
1678 dnl #
1679 dnl # 2.6.27 API change,
1680 dnl # The user_path_dir() replaces __user_walk()
1681 dnl #
1682 AC_DEFUN([SPL_AC_USER_PATH_DIR],
1683         [AC_MSG_CHECKING([whether user_path_dir() is available])
1684         SPL_LINUX_TRY_COMPILE_SYMBOL([
1685                 #include <linux/fcntl.h>
1686                 #include <linux/namei.h>
1687         ], [
1688                 user_path_dir(NULL, NULL);
1689         ], [user_path_at], [], [
1690                 AC_MSG_RESULT(yes)
1691                 AC_DEFINE(HAVE_USER_PATH_DIR, 1, [user_path_dir() is available])
1692         ], [
1693                 AC_MSG_RESULT(no)
1694         ])
1695 ])
1696
1697 dnl #
1698 dnl # Symbol available in RHEL kernels not in stock kernels.
1699 dnl #
1700 AC_DEFUN([SPL_AC_SET_FS_PWD],
1701         [AC_MSG_CHECKING([whether set_fs_pwd() is available])
1702         SPL_LINUX_TRY_COMPILE_SYMBOL([
1703                 #include <linux/spinlock.h>
1704                 #include <linux/fs_struct.h>
1705         ], [
1706                 (void) set_fs_pwd;
1707         ], [set_fs_pwd], [], [
1708                 AC_MSG_RESULT(yes)
1709                 AC_DEFINE(HAVE_SET_FS_PWD, 1, [set_fs_pwd() is available])
1710         ], [
1711                 AC_MSG_RESULT(no)
1712         ])
1713 ])
1714
1715 dnl #
1716 dnl # 2.6.25 API change,
1717 dnl # Simplied API by replacing mnt+dentry args with a single path arg.
1718 dnl #
1719 AC_DEFUN([SPL_AC_2ARGS_SET_FS_PWD],
1720         [AC_MSG_CHECKING([whether set_fs_pwd() wants 2 args])
1721         SPL_LINUX_TRY_COMPILE([
1722                 #include <linux/sched.h>
1723                 #include <linux/fs_struct.h>
1724         ],[
1725                 set_fs_pwd(NULL, NULL);
1726         ],[
1727                 AC_MSG_RESULT(yes)
1728                 AC_DEFINE(HAVE_2ARGS_SET_FS_PWD, 1,
1729                           [set_fs_pwd() wants 2 args])
1730         ],[
1731                 AC_MSG_RESULT(no)
1732         ])
1733 ])
1734
1735 dnl #
1736 dnl # SLES API change, never adopted in mainline,
1737 dnl # Third 'struct vfsmount *' argument removed.
1738 dnl #
1739 AC_DEFUN([SPL_AC_2ARGS_VFS_UNLINK],
1740         [AC_MSG_CHECKING([whether vfs_unlink() wants 2 args])
1741         SPL_LINUX_TRY_COMPILE([
1742                 #include <linux/fs.h>
1743         ],[
1744                 vfs_unlink(NULL, NULL);
1745         ],[
1746                 AC_MSG_RESULT(yes)
1747                 AC_DEFINE(HAVE_2ARGS_VFS_UNLINK, 1,
1748                           [vfs_unlink() wants 2 args])
1749         ],[
1750                 AC_MSG_RESULT(no)
1751         ])
1752 ])
1753
1754 dnl #
1755 dnl # SLES API change, never adopted in mainline,
1756 dnl # Third and sixth 'struct vfsmount *' argument removed.
1757 dnl #
1758 AC_DEFUN([SPL_AC_4ARGS_VFS_RENAME],
1759         [AC_MSG_CHECKING([whether vfs_rename() wants 4 args])
1760         SPL_LINUX_TRY_COMPILE([
1761                 #include <linux/fs.h>
1762         ],[
1763                 vfs_rename(NULL, NULL, NULL, NULL);
1764         ],[
1765                 AC_MSG_RESULT(yes)
1766                 AC_DEFINE(HAVE_4ARGS_VFS_RENAME, 1,
1767                           [vfs_rename() wants 4 args])
1768         ],[
1769                 AC_MSG_RESULT(no)
1770         ])
1771 ])
1772
1773 dnl #
1774 dnl # 2.6.36 API change,
1775 dnl # The 'struct fs_struct->lock' was changed from a rwlock_t to
1776 dnl # a spinlock_t to improve the fastpath performance.
1777 dnl #
1778 AC_DEFUN([SPL_AC_FS_STRUCT_SPINLOCK], [
1779         AC_MSG_CHECKING([whether struct fs_struct uses spinlock_t])
1780         tmp_flags="$EXTRA_KCFLAGS"
1781         EXTRA_KCFLAGS="-Werror"
1782         SPL_LINUX_TRY_COMPILE([
1783                 #include <linux/sched.h>
1784                 #include <linux/fs_struct.h>
1785         ],[
1786                 struct fs_struct fs;
1787                 spin_lock_init(&fs.lock);
1788         ],[
1789                 AC_MSG_RESULT(yes)
1790                 AC_DEFINE(HAVE_FS_STRUCT_SPINLOCK, 1,
1791                           [struct fs_struct uses spinlock_t])
1792         ],[
1793                 AC_MSG_RESULT(no)
1794         ])
1795         EXTRA_KCFLAGS="$tmp_flags"
1796 ])
1797
1798 dnl #
1799 dnl # 2.6.29 API change,
1800 dnl # check whether 'struct cred' exists
1801 dnl #
1802 AC_DEFUN([SPL_AC_CRED_STRUCT], [
1803         AC_MSG_CHECKING([whether struct cred exists])
1804         SPL_LINUX_TRY_COMPILE([
1805                 #include <linux/cred.h>
1806         ],[
1807                 struct cred *cr __attribute__ ((unused));
1808                 cr  = NULL;
1809         ],[
1810                 AC_MSG_RESULT(yes)
1811                 AC_DEFINE(HAVE_CRED_STRUCT, 1, [struct cred exists])
1812         ],[
1813                 AC_MSG_RESULT(no)
1814         ])
1815 ])
1816
1817 dnl #
1818 dnl # Custom SPL patch may export this symbol.
1819 dnl #
1820 AC_DEFUN([SPL_AC_GROUPS_SEARCH],
1821         [AC_MSG_CHECKING([whether groups_search() is available])
1822         SPL_LINUX_TRY_COMPILE_SYMBOL([
1823                 #include <linux/cred.h>
1824         ], [
1825                 groups_search(NULL, 0);
1826         ], [groups_search], [], [
1827                 AC_MSG_RESULT(yes)
1828                 AC_DEFINE(HAVE_GROUPS_SEARCH, 1, [groups_search() is available])
1829         ], [
1830                 AC_MSG_RESULT(no)
1831         ])
1832 ])
1833
1834 dnl #
1835 dnl # 2.6.x API change,
1836 dnl # __put_task_struct() was exported in RHEL5 but unavailable elsewhere.
1837 dnl #
1838 AC_DEFUN([SPL_AC_PUT_TASK_STRUCT],
1839         [AC_MSG_CHECKING([whether __put_task_struct() is available])
1840         SPL_LINUX_TRY_COMPILE_SYMBOL([
1841                 #include <linux/sched.h>
1842         ], [
1843                 __put_task_struct(NULL);
1844         ], [__put_task_struct], [], [
1845                 AC_MSG_RESULT(yes)
1846                 AC_DEFINE(HAVE_PUT_TASK_STRUCT, 1,
1847                           [__put_task_struct() is available])
1848         ], [
1849                 AC_MSG_RESULT(no)
1850         ])
1851 ])
1852
1853 dnl #
1854 dnl # 2.6.32 API change,
1855 dnl # Unused 'struct file *' removed from prototype.
1856 dnl #
1857 AC_DEFUN([SPL_AC_5ARGS_PROC_HANDLER], [
1858         AC_MSG_CHECKING([whether proc_handler() wants 5 args])
1859         SPL_LINUX_TRY_COMPILE([
1860                 #include <linux/sysctl.h>
1861         ],[
1862                 proc_dostring(NULL, 0, NULL, NULL, NULL);
1863         ],[
1864                 AC_MSG_RESULT(yes)
1865                 AC_DEFINE(HAVE_5ARGS_PROC_HANDLER, 1,
1866                           [proc_handler() wants 5 args])
1867         ],[
1868                 AC_MSG_RESULT(no)
1869         ])
1870 ])
1871
1872 dnl #
1873 dnl # 2.6.x API change,
1874 dnl # kvasprintf() function added.
1875 dnl #
1876 AC_DEFUN([SPL_AC_KVASPRINTF],
1877         [AC_MSG_CHECKING([whether kvasprintf() is available])
1878         SPL_LINUX_TRY_COMPILE_SYMBOL([
1879                 #include <linux/kernel.h>
1880         ], [
1881                 kvasprintf(0, NULL, *((va_list*)NULL));
1882         ], [kvasprintf], [], [
1883                 AC_MSG_RESULT(yes)
1884                 AC_DEFINE(HAVE_KVASPRINTF, 1, [kvasprintf() is available])
1885         ], [
1886                 AC_MSG_RESULT(no)
1887         ])
1888 ])
1889
1890 dnl #
1891 dnl # 2.6.29 API change,
1892 dnl # vfs_fsync() funcation added, prior to this use file_fsync().
1893 dnl #
1894 AC_DEFUN([SPL_AC_VFS_FSYNC],
1895         [AC_MSG_CHECKING([whether vfs_fsync() is available])
1896         SPL_LINUX_TRY_COMPILE_SYMBOL([
1897                 #include <linux/fs.h>
1898         ], [
1899                 (void) vfs_fsync;
1900         ], [vfs_fsync], [fs/sync.c], [
1901                 AC_MSG_RESULT(yes)
1902                 AC_DEFINE(HAVE_VFS_FSYNC, 1, [vfs_fsync() is available])
1903         ], [
1904                 AC_MSG_RESULT(no)
1905         ])
1906 ])
1907
1908 dnl #
1909 dnl # 2.6.35 API change,
1910 dnl # Unused 'struct dentry *' removed from vfs_fsync() prototype.
1911 dnl #
1912 AC_DEFUN([SPL_AC_2ARGS_VFS_FSYNC], [
1913         AC_MSG_CHECKING([whether vfs_fsync() wants 2 args])
1914         SPL_LINUX_TRY_COMPILE([
1915                 #include <linux/fs.h>
1916         ],[
1917                 vfs_fsync(NULL, 0);
1918         ],[
1919                 AC_MSG_RESULT(yes)
1920                 AC_DEFINE(HAVE_2ARGS_VFS_FSYNC, 1, [vfs_fsync() wants 2 args])
1921         ],[
1922                 AC_MSG_RESULT(no)
1923         ])
1924 ])
1925
1926 dnl #
1927 dnl # 3.5 API change,
1928 dnl # inode_operations.truncate_range removed
1929 dnl #
1930 AC_DEFUN([SPL_AC_INODE_TRUNCATE_RANGE], [
1931         AC_MSG_CHECKING([whether truncate_range() inode operation is available])
1932         SPL_LINUX_TRY_COMPILE([
1933                 #include <linux/fs.h>
1934         ],[
1935                 struct inode_operations ops;
1936                 ops.truncate_range = NULL;
1937         ],[
1938                 AC_MSG_RESULT(yes)
1939                 AC_DEFINE(HAVE_INODE_TRUNCATE_RANGE, 1,
1940                         [truncate_range() inode operation is available])
1941         ],[
1942                 AC_MSG_RESULT(no)
1943         ])
1944 ])
1945
1946 dnl #
1947 dnl # Linux 2.6.38 - 3.x API
1948 dnl #
1949 AC_DEFUN([SPL_AC_KERNEL_FILE_FALLOCATE], [
1950         AC_MSG_CHECKING([whether fops->fallocate() exists])
1951         SPL_LINUX_TRY_COMPILE([
1952                 #include <linux/fs.h>
1953         ],[
1954                 long (*fallocate) (struct file *, int, loff_t, loff_t) = NULL;
1955                 struct file_operations fops __attribute__ ((unused)) = {
1956                         .fallocate = fallocate,
1957                 };
1958         ],[
1959                 AC_MSG_RESULT(yes)
1960                 AC_DEFINE(HAVE_FILE_FALLOCATE, 1, [fops->fallocate() exists])
1961         ],[
1962                 AC_MSG_RESULT(no)
1963         ])
1964 ])
1965
1966 dnl #
1967 dnl # Linux 2.6.x - 2.6.37 API
1968 dnl #
1969 AC_DEFUN([SPL_AC_KERNEL_INODE_FALLOCATE], [
1970         AC_MSG_CHECKING([whether iops->fallocate() exists])
1971         SPL_LINUX_TRY_COMPILE([
1972                 #include <linux/fs.h>
1973         ],[
1974                 long (*fallocate) (struct inode *, int, loff_t, loff_t) = NULL;
1975                 struct inode_operations fops __attribute__ ((unused)) = {
1976                         .fallocate = fallocate,
1977                 };
1978         ],[
1979                 AC_MSG_RESULT(yes)
1980                 AC_DEFINE(HAVE_INODE_FALLOCATE, 1, [fops->fallocate() exists])
1981         ],[
1982                 AC_MSG_RESULT(no)
1983         ])
1984 ])
1985
1986 dnl #
1987 dnl # PaX Linux 2.6.38 - 3.x API
1988 dnl #
1989 AC_DEFUN([SPL_AC_PAX_KERNEL_FILE_FALLOCATE], [
1990         AC_MSG_CHECKING([whether fops->fallocate() exists])
1991         SPL_LINUX_TRY_COMPILE([
1992                 #include <linux/fs.h>
1993         ],[
1994                 long (*fallocate) (struct file *, int, loff_t, loff_t) = NULL;
1995                 struct file_operations_no_const fops __attribute__ ((unused)) = {
1996                         .fallocate = fallocate,
1997                 };
1998         ],[
1999                 AC_MSG_RESULT(yes)
2000                 AC_DEFINE(HAVE_FILE_FALLOCATE, 1, [fops->fallocate() exists])
2001         ],[
2002                 AC_MSG_RESULT(no)
2003         ])
2004 ])
2005
2006 dnl #
2007 dnl # The fallocate callback was moved from the inode_operations
2008 dnl # structure to the file_operations structure.
2009 dnl #
2010 AC_DEFUN([SPL_AC_KERNEL_FALLOCATE], [
2011         SPL_AC_KERNEL_FILE_FALLOCATE
2012         SPL_AC_KERNEL_INODE_FALLOCATE
2013         SPL_AC_PAX_KERNEL_FILE_FALLOCATE
2014 ])
2015
2016 dnl #
2017 dnl # 2.6.33 API change. Also backported in RHEL5 as of 2.6.18-190.el5.
2018 dnl # Earlier versions of rwsem_is_locked() were inline and had a race
2019 dnl # condition.  The fixed version is exported as a symbol.  The race
2020 dnl # condition is fixed by acquiring sem->wait_lock, so we must not
2021 dnl # call that version while holding sem->wait_lock.
2022 dnl #
2023 AC_DEFUN([SPL_AC_EXPORTED_RWSEM_IS_LOCKED],
2024         [AC_MSG_CHECKING([whether rwsem_is_locked() acquires sem->wait_lock])
2025         SPL_LINUX_TRY_COMPILE_SYMBOL([
2026                 #include <linux/rwsem.h>
2027                 int rwsem_is_locked(struct rw_semaphore *sem) { return 0; }
2028         ], [], [rwsem_is_locked], [lib/rwsem-spinlock.c], [
2029                 AC_MSG_RESULT(yes)
2030                 AC_DEFINE(RWSEM_IS_LOCKED_TAKES_WAIT_LOCK, 1,
2031                           [rwsem_is_locked() acquires sem->wait_lock])
2032         ], [
2033                 AC_MSG_RESULT(no)
2034         ])
2035 ])
2036
2037 dnl #
2038 dnl # 2.6.xx API compat,
2039 dnl # There currently exists no exposed API to partially shrink the dcache.
2040 dnl # The expected mechanism to shrink the cache is a registered shrinker
2041 dnl # which is called during memory pressure.
2042 dnl #
2043 AC_DEFUN([SPL_AC_SHRINK_DCACHE_MEMORY],
2044         [AC_MSG_CHECKING([whether shrink_dcache_memory() is available])
2045         SPL_LINUX_TRY_COMPILE_SYMBOL([
2046                 #include <linux/dcache.h>
2047         ], [
2048                 shrink_dcache_memory(0, 0);
2049         ], [shrink_dcache_memory], [fs/dcache.c], [
2050                 AC_MSG_RESULT(yes)
2051                 AC_DEFINE(HAVE_SHRINK_DCACHE_MEMORY, 1,
2052                           [shrink_dcache_memory() is available])
2053         ], [
2054                 AC_MSG_RESULT(no)
2055         ])
2056 ])
2057
2058 dnl #
2059 dnl # 2.6.xx API compat,
2060 dnl # There currently exists no exposed API to partially shrink the icache.
2061 dnl # The expected mechanism to shrink the cache is a registered shrinker
2062 dnl # which is called during memory pressure.
2063 dnl #
2064 AC_DEFUN([SPL_AC_SHRINK_ICACHE_MEMORY],
2065         [AC_MSG_CHECKING([whether shrink_icache_memory() is available])
2066         SPL_LINUX_TRY_COMPILE_SYMBOL([
2067                 #include <linux/dcache.h>
2068         ], [
2069                 shrink_icache_memory(0, 0);
2070         ], [shrink_icache_memory], [fs/inode.c], [
2071                 AC_MSG_RESULT(yes)
2072                 AC_DEFINE(HAVE_SHRINK_ICACHE_MEMORY, 1,
2073                           [shrink_icache_memory() is available])
2074         ], [
2075                 AC_MSG_RESULT(no)
2076         ])
2077 ])
2078
2079 dnl #
2080 dnl # 2.6.39 API compat,
2081 dnl # The path_lookup() function has been renamed to kern_path_parent()
2082 dnl # and the flags argument has been removed.  The only behavior now
2083 dnl # offered is that of LOOKUP_PARENT.  The spl already always passed
2084 dnl # this flag so dropping the flag does not impact us.
2085 dnl #
2086 AC_DEFUN([SPL_AC_KERN_PATH_PARENT_HEADER], [
2087         SPL_CHECK_SYMBOL_HEADER(
2088                 [kern_path_parent],
2089                 [int kern_path_parent(const char \*, struct nameidata \*)],
2090                 [include/linux/namei.h],
2091                 [AC_DEFINE(HAVE_KERN_PATH_PARENT_HEADER, 1,
2092                 [kern_path_parent() is available])],
2093                 [])
2094 ])
2095
2096 dnl #
2097 dnl # 3.1 API compat,
2098 dnl # The kern_path_parent() symbol is no longer exported by the kernel.
2099 dnl # However, it remains the prefered interface and since we still have
2100 dnl # access to the prototype we dynamically lookup the required address.
2101 dnl #
2102 AC_DEFUN([SPL_AC_KERN_PATH_PARENT_SYMBOL],
2103         [AC_MSG_CHECKING([whether kern_path_parent() is available])
2104         SPL_LINUX_TRY_COMPILE_SYMBOL([
2105                 #include <linux/namei.h>
2106         ], [
2107                 kern_path_parent(NULL, NULL);
2108         ], [kern_path_parent], [fs/namei.c], [
2109                 AC_MSG_RESULT(yes)
2110                 AC_DEFINE(HAVE_KERN_PATH_PARENT_SYMBOL, 1,
2111                           [kern_path_parent() is available])
2112         ], [
2113                 AC_MSG_RESULT(no)
2114         ])
2115 ])
2116
2117 dnl #
2118 dnl # 3.6 API compat,
2119 dnl # The kern_path_parent() function was replaced by the kern_path_locked()
2120 dnl # function to eliminate all struct nameidata usage outside fs/namei.c.
2121 dnl #
2122 AC_DEFUN([SPL_AC_KERN_PATH_LOCKED], [
2123         SPL_CHECK_SYMBOL_HEADER(
2124                 [kern_path_locked],
2125                 [struct dentry \*kern_path_locked(const char \*, struct path \*)],
2126                 [include/linux/namei.h],
2127                 [AC_DEFINE(HAVE_KERN_PATH_LOCKED, 1,
2128                 [kern_path_locked() is available])],
2129                 [])
2130 ])
2131
2132 dnl #
2133 dnl # /proc/kallsyms support,
2134 dnl # Verify the kernel has CONFIG_KALLSYMS support enabled.
2135 dnl #
2136 AC_DEFUN([SPL_AC_CONFIG_KALLSYMS], [
2137         AC_MSG_CHECKING([whether CONFIG_KALLSYMS is defined])
2138         SPL_LINUX_TRY_COMPILE([
2139                 #if !defined(CONFIG_KALLSYMS)
2140                 #error CONFIG_KALLSYMS not defined
2141                 #endif
2142         ],[ ],[
2143                 AC_MSG_RESULT([yes])
2144         ],[
2145                 AC_MSG_RESULT([no])
2146                 AC_MSG_ERROR([
2147         *** This kernel does not include the required kallsyms support.
2148         *** Rebuild the kernel with CONFIG_KALLSYMS=y set.])
2149         ])
2150 ])
2151
2152 dnl #
2153 dnl # zlib inflate compat,
2154 dnl # Verify the kernel has CONFIG_ZLIB_INFLATE support enabled.
2155 dnl #
2156 AC_DEFUN([SPL_AC_CONFIG_ZLIB_INFLATE], [
2157         AC_MSG_CHECKING([whether CONFIG_ZLIB_INFLATE is defined])
2158         SPL_LINUX_TRY_COMPILE([
2159                 #if !defined(CONFIG_ZLIB_INFLATE) && \
2160                     !defined(CONFIG_ZLIB_INFLATE_MODULE)
2161                 #error CONFIG_ZLIB_INFLATE not defined
2162                 #endif
2163         ],[ ],[
2164                 AC_MSG_RESULT([yes])
2165         ],[
2166                 AC_MSG_RESULT([no])
2167                 AC_MSG_ERROR([
2168         *** This kernel does not include the required zlib inflate support.
2169         *** Rebuild the kernel with CONFIG_ZLIB_INFLATE=y|m set.])
2170         ])
2171 ])
2172
2173 dnl #
2174 dnl # zlib deflate compat,
2175 dnl # Verify the kernel has CONFIG_ZLIB_DEFLATE support enabled.
2176 dnl #
2177 AC_DEFUN([SPL_AC_CONFIG_ZLIB_DEFLATE], [
2178         AC_MSG_CHECKING([whether CONFIG_ZLIB_DEFLATE is defined])
2179         SPL_LINUX_TRY_COMPILE([
2180                 #if !defined(CONFIG_ZLIB_DEFLATE) && \
2181                     !defined(CONFIG_ZLIB_DEFLATE_MODULE)
2182                 #error CONFIG_ZLIB_DEFLATE not defined
2183                 #endif
2184         ],[ ],[
2185                 AC_MSG_RESULT([yes])
2186         ],[
2187                 AC_MSG_RESULT([no])
2188                 AC_MSG_ERROR([
2189         *** This kernel does not include the required zlib deflate support.
2190         *** Rebuild the kernel with CONFIG_ZLIB_DEFLATE=y|m set.])
2191         ])
2192 ])
2193
2194 dnl #
2195 dnl # 2.6.39 API compat,
2196 dnl # The function zlib_deflate_workspacesize() now take 2 arguments.
2197 dnl # This was done to avoid always having to allocate the maximum size
2198 dnl # workspace (268K).  The caller can now specific the windowBits and
2199 dnl # memLevel compression parameters to get a smaller workspace.
2200 dnl #
2201 AC_DEFUN([SPL_AC_2ARGS_ZLIB_DEFLATE_WORKSPACESIZE],
2202         [AC_MSG_CHECKING([whether zlib_deflate_workspacesize() wants 2 args])
2203         SPL_LINUX_TRY_COMPILE([
2204                 #include <linux/zlib.h>
2205         ],[
2206                 return zlib_deflate_workspacesize(MAX_WBITS, MAX_MEM_LEVEL);
2207         ],[
2208                 AC_MSG_RESULT(yes)
2209                 AC_DEFINE(HAVE_2ARGS_ZLIB_DEFLATE_WORKSPACESIZE, 1,
2210                           [zlib_deflate_workspacesize() wants 2 args])
2211         ],[
2212                 AC_MSG_RESULT(no)
2213         ])
2214 ])
2215
2216 dnl #
2217 dnl # 2.6.39 API change,
2218 dnl # Shrinker adjust to use common shrink_control structure.
2219 dnl #
2220 AC_DEFUN([SPL_AC_SHRINK_CONTROL_STRUCT], [
2221         AC_MSG_CHECKING([whether struct shrink_control exists])
2222         SPL_LINUX_TRY_COMPILE([
2223                 #include <linux/mm.h>
2224         ],[
2225                 struct shrink_control sc __attribute__ ((unused));
2226
2227                 sc.nr_to_scan = 0;
2228                 sc.gfp_mask = GFP_KERNEL;
2229         ],[
2230                 AC_MSG_RESULT(yes)
2231                 AC_DEFINE(HAVE_SHRINK_CONTROL_STRUCT, 1,
2232                         [struct shrink_control exists])
2233         ],[
2234                 AC_MSG_RESULT(no)
2235         ])
2236 ])
2237
2238 dnl #
2239 dnl # 3.1 API Change
2240 dnl #
2241 dnl # The rw_semaphore.wait_lock member was changed from spinlock_t to
2242 dnl # raw_spinlock_t at commit ddb6c9b58a19edcfac93ac670b066c836ff729f1.
2243 dnl #
2244 AC_DEFUN([SPL_AC_RWSEM_SPINLOCK_IS_RAW], [
2245         AC_MSG_CHECKING([whether struct rw_semaphore member wait_lock is raw])
2246         tmp_flags="$EXTRA_KCFLAGS"
2247         EXTRA_KCFLAGS="-Werror"
2248         SPL_LINUX_TRY_COMPILE([
2249                 #include <linux/rwsem.h>
2250         ],[
2251                 struct rw_semaphore dummy_semaphore __attribute__ ((unused));
2252                 raw_spinlock_t dummy_lock __attribute__ ((unused));
2253                 dummy_semaphore.wait_lock = dummy_lock;
2254         ],[
2255                 AC_MSG_RESULT(yes)
2256                 AC_DEFINE(RWSEM_SPINLOCK_IS_RAW, 1,
2257                 [struct rw_semaphore member wait_lock is raw_spinlock_t])
2258         ],[
2259                 AC_MSG_RESULT(no)
2260         ])
2261         EXTRA_KCFLAGS="$tmp_flags"
2262 ])