config/zfs-build.m4

   1 AC_DEFUN([ZFS_AC_LICENSE], [
   2         AC_MSG_CHECKING([zfs author])
   3         AC_MSG_RESULT([$ZFS_META_AUTHOR])
   4
   5         AC_MSG_CHECKING([zfs license])
   6         AC_MSG_RESULT([$ZFS_META_LICENSE])
   7 ])
   8
   9 AC_DEFUN([ZFS_AC_DEBUG_ENABLE], [
  10         KERNELCPPFLAGS="${KERNELCPPFLAGS} -DDEBUG -Werror"
  11         HOSTCFLAGS="${HOSTCFLAGS} -DDEBUG -Werror"
  12         DEBUG_CFLAGS="-DDEBUG -Werror"
  13         DEBUG_STACKFLAGS="-fstack-check"
  14         DEBUG_ZFS="_with_debug"
  15         AC_DEFINE(ZFS_DEBUG, 1, [zfs debugging enabled])
  16 ])
  17
  18 AC_DEFUN([ZFS_AC_DEBUG_DISABLE], [
  19         KERNELCPPFLAGS="${KERNELCPPFLAGS} -DNDEBUG "
  20         HOSTCFLAGS="${HOSTCFLAGS} -DNDEBUG "
  21         DEBUG_CFLAGS="-DNDEBUG"
  22         DEBUG_STACKFLAGS=""
  23         DEBUG_ZFS="_without_debug"
  24 ])
  25
  26 AC_DEFUN([ZFS_AC_DEBUG], [
  27         AC_MSG_CHECKING([whether assertion support will be enabled])
  28         AC_ARG_ENABLE([debug],
  29                 [AS_HELP_STRING([--enable-debug],
  30                 [Enable assertion support @<:@default=no@:>@])],
  31                 [],
  32                 [enable_debug=no])
  33
  34         AS_CASE(["x$enable_debug"],
  35                 ["xyes"],
  36                 [ZFS_AC_DEBUG_ENABLE],
  37                 ["xno"],
  38                 [ZFS_AC_DEBUG_DISABLE],
  39                 [AC_MSG_ERROR([Unknown option $enable_debug])])
  40
  41         AC_SUBST(DEBUG_STACKFLAGS)
  42         AC_SUBST(DEBUG_ZFS)
  43         AC_MSG_RESULT([$enable_debug])
  44 ])
  45
  46 AC_DEFUN([ZFS_AC_DEBUGINFO_KERNEL], [
  47         KERNELMAKE_PARAMS="$KERNELMAKE_PARAMS CONFIG_DEBUG_INFO=y"
  48 ])
  49
  50 AC_DEFUN([ZFS_AC_DEBUGINFO_USER], [
  51         DEBUG_CFLAGS="$DEBUG_CFLAGS -g"
  52 ])
  53
  54 AC_DEFUN([ZFS_AC_DEBUGINFO], [
  55         AC_MSG_CHECKING([whether debuginfo support will be forced])
  56         AC_ARG_ENABLE([debuginfo],
  57                 [AS_HELP_STRING([--enable-debuginfo],
  58                 [Force generation of debuginfo @<:@default=no@:>@])],
  59                 [],
  60                 [enable_debuginfo=no])
  61
  62         AS_CASE(["x$enable_debuginfo"],
  63                 ["xyes"],
  64                 [ZFS_AC_DEBUGINFO_KERNEL
  65                 ZFS_AC_DEBUGINFO_USER],
  66                 ["xkernel"],
  67                 [ZFS_AC_DEBUGINFO_KERNEL],
  68                 ["xuser"],
  69                 [ZFS_AC_DEBUGINFO_USER],
  70                 ["xno"],
  71                 [],
  72                 [AC_MSG_ERROR([Unknown option $enable_debug])])
  73
  74         AC_SUBST(DEBUG_CFLAGS)
  75         AC_MSG_RESULT([$enable_debuginfo])
  76 ])
  77
  78 AC_DEFUN([ZFS_AC_GCOV_KERNEL], [
  79 ])
  80
  81 AC_DEFUN([ZFS_AC_GCOV_USER], [
  82         DEBUG_CFLAGS="$DEBUG_CFLAGS -fprofile-arcs -ftest-coverage"
  83 ])
  84
  85 AC_DEFUN([ZFS_AC_GCOV], [
  86         AC_MSG_CHECKING([whether gcov profiling will be enabled])
  87         AC_ARG_ENABLE([gcov],
  88                 [AS_HELP_STRING([--enable-gcov],
  89                 [Enable gcov profiling @<:@default=no@:>@])],
  90                 [],
  91                 [enable_gcov=no])
  92
  93         AS_CASE(["x$enable_gcov"],
  94                 ["xyes"],
  95                 [ZFS_AC_GCOV_KERNEL
  96                 ZFS_AC_GCOV_USER],
  97                 ["xkernel"],
  98                 [ZFS_AC_GCOV_KERNEL],
  99                 ["xuser"],
 100                 [ZFS_AC_GCOV_USER],
 101                 ["xno"],
 102                 [],
 103                 [AC_MSG_ERROR([Unknown option $enable_gcov])])
 104
 105         AC_SUBST(DEBUG_CFLAGS)
 106         AC_MSG_RESULT([$enable_gcov])
 107 ])
 108
 109 AC_DEFUN([ZFS_AC_CONFIG_ALWAYS], [
 110         ZFS_AC_CONFIG_ALWAYS_NO_UNUSED_BUT_SET_VARIABLE
 111         ZFS_AC_CONFIG_ALWAYS_NO_BOOL_COMPARE
 112         ZFS_AC_CONFIG_ALWAYS_TOOLCHAIN_SIMD
 113         ZFS_AC_CONFIG_ALWAYS_ARCH
 114 ])
 115
 116 AC_DEFUN([ZFS_AC_CONFIG], [
 117         ZFS_CONFIG=all
 118         AC_ARG_WITH([config],
 119                 AS_HELP_STRING([--with-config=CONFIG],
 120                 [Config file 'kernel|user|all|srpm']),
 121                 [ZFS_CONFIG="$withval"])
 122         AC_ARG_ENABLE([linux-builtin],
 123                 [AC_HELP_STRING([--enable-linux-builtin],
 124                 [Configure for builtin in-tree kernel modules @<:@default=no@:>@])],
 125                 [],
 126                 [enable_linux_builtin=no])
 127
 128         AC_MSG_CHECKING([zfs config])
 129         AC_MSG_RESULT([$ZFS_CONFIG]);
 130         AC_SUBST(ZFS_CONFIG)
 131
 132         ZFS_AC_CONFIG_ALWAYS
 133
 134         case "$ZFS_CONFIG" in
 135                 kernel) ZFS_AC_CONFIG_KERNEL ;;
 136                 user)   ZFS_AC_CONFIG_USER   ;;
 137                 all)    ZFS_AC_CONFIG_USER
 138                         ZFS_AC_CONFIG_KERNEL ;;
 139                 srpm)                        ;;
 140                 *)
 141                 AC_MSG_RESULT([Error!])
 142                 AC_MSG_ERROR([Bad value "$ZFS_CONFIG" for --with-config,
 143                               user kernel|user|all|srpm]) ;;
 144         esac
 145
 146         AM_CONDITIONAL([CONFIG_USER],
 147             [test "$ZFS_CONFIG" = user -o "$ZFS_CONFIG" = all])
 148         AM_CONDITIONAL([CONFIG_KERNEL],
 149             [test "$ZFS_CONFIG" = kernel -o "$ZFS_CONFIG" = all] &&
 150             [test "x$enable_linux_builtin" != xyes ])
 151         AM_CONDITIONAL([WANT_DEVNAME2DEVID],
 152             [test "x$user_libudev" = xyes ])
 153         AM_CONDITIONAL([CONFIG_QAT],
 154             [test "$ZFS_CONFIG" = kernel -o "$ZFS_CONFIG" = all] &&
 155             [test "x$qatsrc" != x ])
 156 ])
 157
 158 dnl #
 159 dnl # Check for rpm+rpmbuild to build RPM packages.  If these tools
 160 dnl # are missing it is non-fatal but you will not be able to build
 161 dnl # RPM packages and will be warned if you try too.
 162 dnl #
 163 dnl # By default the generic spec file will be used because it requires
 164 dnl # minimal dependencies.  Distribution specific spec files can be
 165 dnl # placed under the 'rpm/<distribution>' directory and enabled using
 166 dnl # the --with-spec=<distribution> configure option.
 167 dnl #
 168 AC_DEFUN([ZFS_AC_RPM], [
 169         RPM=rpm
 170         RPMBUILD=rpmbuild
 171
 172         AC_MSG_CHECKING([whether $RPM is available])
 173         AS_IF([tmp=$($RPM --version 2>/dev/null)], [
 174                 RPM_VERSION=$(echo $tmp | $AWK '/RPM/ { print $[3] }')
 175                 HAVE_RPM=yes
 176                 AC_MSG_RESULT([$HAVE_RPM ($RPM_VERSION)])
 177         ],[
 178                 HAVE_RPM=no
 179                 AC_MSG_RESULT([$HAVE_RPM])
 180         ])
 181
 182         AC_MSG_CHECKING([whether $RPMBUILD is available])
 183         AS_IF([tmp=$($RPMBUILD --version 2>/dev/null)], [
 184                 RPMBUILD_VERSION=$(echo $tmp | $AWK '/RPM/ { print $[3] }')
 185                 HAVE_RPMBUILD=yes
 186                 AC_MSG_RESULT([$HAVE_RPMBUILD ($RPMBUILD_VERSION)])
 187         ],[
 188                 HAVE_RPMBUILD=no
 189                 AC_MSG_RESULT([$HAVE_RPMBUILD])
 190         ])
 191
 192         RPM_DEFINE_COMMON='--define "$(DEBUG_ZFS) 1"'
 193         RPM_DEFINE_UTIL='--define "_dracutdir $(dracutdir)" --define "_udevdir $(udevdir)" --define "_udevruledir $(udevruledir)" --define "_initconfdir $(DEFAULT_INITCONF_DIR)" $(DEFINE_INITRAMFS)'
 194         RPM_DEFINE_KMOD='--define "kernels $(LINUX_VERSION)" --define "require_spldir $(SPL)" --define "require_splobj $(SPL_OBJ)" --define "ksrc $(LINUX)" --define "kobj $(LINUX_OBJ)"'
 195         RPM_DEFINE_DKMS=
 196
 197         SRPM_DEFINE_COMMON='--define "build_src_rpm 1"'
 198         SRPM_DEFINE_UTIL=
 199         SRPM_DEFINE_KMOD=
 200         SRPM_DEFINE_DKMS=
 201
 202         RPM_SPEC_DIR="rpm/generic"
 203         AC_ARG_WITH([spec],
 204                 AS_HELP_STRING([--with-spec=SPEC],
 205                 [Spec files 'generic|redhat']),
 206                 [RPM_SPEC_DIR="rpm/$withval"])
 207
 208         AC_MSG_CHECKING([whether spec files are available])
 209         AC_MSG_RESULT([yes ($RPM_SPEC_DIR/*.spec.in)])
 210
 211         AC_SUBST(HAVE_RPM)
 212         AC_SUBST(RPM)
 213         AC_SUBST(RPM_VERSION)
 214
 215         AC_SUBST(HAVE_RPMBUILD)
 216         AC_SUBST(RPMBUILD)
 217         AC_SUBST(RPMBUILD_VERSION)
 218
 219         AC_SUBST(RPM_SPEC_DIR)
 220         AC_SUBST(RPM_DEFINE_UTIL)
 221         AC_SUBST(RPM_DEFINE_KMOD)
 222         AC_SUBST(RPM_DEFINE_DKMS)
 223         AC_SUBST(RPM_DEFINE_COMMON)
 224         AC_SUBST(SRPM_DEFINE_UTIL)
 225         AC_SUBST(SRPM_DEFINE_KMOD)
 226         AC_SUBST(SRPM_DEFINE_DKMS)
 227         AC_SUBST(SRPM_DEFINE_COMMON)
 228 ])
 229
 230 dnl #
 231 dnl # Check for dpkg+dpkg-buildpackage to build DEB packages.  If these
 232 dnl # tools are missing it is non-fatal but you will not be able to build
 233 dnl # DEB packages and will be warned if you try too.
 234 dnl #
 235 AC_DEFUN([ZFS_AC_DPKG], [
 236         DPKG=dpkg
 237         DPKGBUILD=dpkg-buildpackage
 238
 239         AC_MSG_CHECKING([whether $DPKG is available])
 240         AS_IF([tmp=$($DPKG --version 2>/dev/null)], [
 241                 DPKG_VERSION=$(echo $tmp | $AWK '/Debian/ { print $[7] }')
 242                 HAVE_DPKG=yes
 243                 AC_MSG_RESULT([$HAVE_DPKG ($DPKG_VERSION)])
 244         ],[
 245                 HAVE_DPKG=no
 246                 AC_MSG_RESULT([$HAVE_DPKG])
 247         ])
 248
 249         AC_MSG_CHECKING([whether $DPKGBUILD is available])
 250         AS_IF([tmp=$($DPKGBUILD --version 2>/dev/null)], [
 251                 DPKGBUILD_VERSION=$(echo $tmp | \
 252                     $AWK '/Debian/ { print $[4] }' | cut -f-4 -d'.')
 253                 HAVE_DPKGBUILD=yes
 254                 AC_MSG_RESULT([$HAVE_DPKGBUILD ($DPKGBUILD_VERSION)])
 255         ],[
 256                 HAVE_DPKGBUILD=no
 257                 AC_MSG_RESULT([$HAVE_DPKGBUILD])
 258         ])
 259
 260         AC_SUBST(HAVE_DPKG)
 261         AC_SUBST(DPKG)
 262         AC_SUBST(DPKG_VERSION)
 263
 264         AC_SUBST(HAVE_DPKGBUILD)
 265         AC_SUBST(DPKGBUILD)
 266         AC_SUBST(DPKGBUILD_VERSION)
 267 ])
 268
 269 dnl #
 270 dnl # Until native packaging for various different packing systems
 271 dnl # can be added the least we can do is attempt to use alien to
 272 dnl # convert the RPM packages to the needed package type.  This is
 273 dnl # a hack but so far it has worked reasonable well.
 274 dnl #
 275 AC_DEFUN([ZFS_AC_ALIEN], [
 276         ALIEN=alien
 277
 278         AC_MSG_CHECKING([whether $ALIEN is available])
 279         AS_IF([tmp=$($ALIEN --version 2>/dev/null)], [
 280                 ALIEN_VERSION=$(echo $tmp | $AWK '{ print $[3] }')
 281                 HAVE_ALIEN=yes
 282                 AC_MSG_RESULT([$HAVE_ALIEN ($ALIEN_VERSION)])
 283         ],[
 284                 HAVE_ALIEN=no
 285                 AC_MSG_RESULT([$HAVE_ALIEN])
 286         ])
 287
 288         AC_SUBST(HAVE_ALIEN)
 289         AC_SUBST(ALIEN)
 290         AC_SUBST(ALIEN_VERSION)
 291 ])
 292
 293 dnl #
 294 dnl # Using the VENDOR tag from config.guess set the default
 295 dnl # package type for 'make pkg': (rpm | deb | tgz)
 296 dnl #
 297 AC_DEFUN([ZFS_AC_DEFAULT_PACKAGE], [
 298         AC_MSG_CHECKING([linux distribution])
 299         if test -f /etc/toss-release ; then
 300                 VENDOR=toss ;
 301         elif test -f /etc/fedora-release ; then
 302                 VENDOR=fedora ;
 303         elif test -f /etc/redhat-release ; then
 304                 VENDOR=redhat ;
 305         elif test -f /etc/gentoo-release ; then
 306                 VENDOR=gentoo ;
 307         elif test -f /etc/arch-release ; then
 308                 VENDOR=arch ;
 309         elif test -f /etc/SuSE-release ; then
 310                 VENDOR=sles ;
 311         elif test -f /etc/slackware-version ; then
 312                 VENDOR=slackware ;
 313         elif test -f /etc/lunar.release ; then
 314                 VENDOR=lunar ;
 315         elif test -f /etc/lsb-release ; then
 316                 VENDOR=ubuntu ;
 317         elif test -f /etc/debian_version ; then
 318                 VENDOR=debian ;
 319         elif test -f /etc/alpine-release ; then
 320                 VENDOR=alpine ;
 321         else
 322                 VENDOR= ;
 323         fi
 324         AC_MSG_RESULT([$VENDOR])
 325         AC_SUBST(VENDOR)
 326
 327         AC_MSG_CHECKING([default package type])
 328         case "$VENDOR" in
 329                 toss)       DEFAULT_PACKAGE=rpm  ;;
 330                 redhat)     DEFAULT_PACKAGE=rpm  ;;
 331                 fedora)     DEFAULT_PACKAGE=rpm  ;;
 332                 gentoo)     DEFAULT_PACKAGE=tgz  ;;
 333                 alpine)     DEFAULT_PACKAGE=tgz  ;;
 334                 arch)       DEFAULT_PACKAGE=tgz  ;;
 335                 sles)       DEFAULT_PACKAGE=rpm  ;;
 336                 slackware)  DEFAULT_PACKAGE=tgz  ;;
 337                 lunar)      DEFAULT_PACKAGE=tgz  ;;
 338                 ubuntu)     DEFAULT_PACKAGE=deb  ;;
 339                 debian)     DEFAULT_PACKAGE=deb  ;;
 340                 *)          DEFAULT_PACKAGE=rpm  ;;
 341         esac
 342         AC_MSG_RESULT([$DEFAULT_PACKAGE])
 343         AC_SUBST(DEFAULT_PACKAGE)
 344
 345         DEFAULT_INIT_DIR=$sysconfdir/init.d
 346         AC_MSG_CHECKING([default init directory])
 347         AC_MSG_RESULT([$DEFAULT_INIT_DIR])
 348         AC_SUBST(DEFAULT_INIT_DIR)
 349
 350         AC_MSG_CHECKING([default init script type])
 351         case "$VENDOR" in
 352                 toss)       DEFAULT_INIT_SCRIPT=redhat ;;
 353                 redhat)     DEFAULT_INIT_SCRIPT=redhat ;;
 354                 fedora)     DEFAULT_INIT_SCRIPT=fedora ;;
 355                 gentoo)     DEFAULT_INIT_SCRIPT=openrc ;;
 356                 alpine)     DEFAULT_INIT_SCRIPT=openrc ;;
 357                 arch)       DEFAULT_INIT_SCRIPT=lsb    ;;
 358                 sles)       DEFAULT_INIT_SCRIPT=lsb    ;;
 359                 slackware)  DEFAULT_INIT_SCRIPT=lsb    ;;
 360                 lunar)      DEFAULT_INIT_SCRIPT=lunar  ;;
 361                 ubuntu)     DEFAULT_INIT_SCRIPT=lsb    ;;
 362                 debian)     DEFAULT_INIT_SCRIPT=lsb    ;;
 363                 *)          DEFAULT_INIT_SCRIPT=lsb    ;;
 364         esac
 365         AC_MSG_RESULT([$DEFAULT_INIT_SCRIPT])
 366         AC_SUBST(DEFAULT_INIT_SCRIPT)
 367
 368         AC_MSG_CHECKING([default init config direectory])
 369         case "$VENDOR" in
 370                 alpine)     DEFAULT_INITCONF_DIR=/etc/conf.d    ;;
 371                 gentoo)     DEFAULT_INITCONF_DIR=/etc/conf.d    ;;
 372                 toss)       DEFAULT_INITCONF_DIR=/etc/sysconfig ;;
 373                 redhat)     DEFAULT_INITCONF_DIR=/etc/sysconfig ;;
 374                 fedora)     DEFAULT_INITCONF_DIR=/etc/sysconfig ;;
 375                 sles)       DEFAULT_INITCONF_DIR=/etc/sysconfig ;;
 376                 ubuntu)     DEFAULT_INITCONF_DIR=/etc/default   ;;
 377                 debian)     DEFAULT_INITCONF_DIR=/etc/default   ;;
 378                 *)          DEFAULT_INITCONF_DIR=/etc/default   ;;
 379         esac
 380         AC_MSG_RESULT([$DEFAULT_INITCONF_DIR])
 381         AC_SUBST(DEFAULT_INITCONF_DIR)
 382
 383         AC_MSG_CHECKING([whether initramfs-tools is available])
 384         if test -d /usr/share/initramfs-tools ; then
 385                 DEFINE_INITRAMFS='--define "_initramfs 1"'
 386                 AC_MSG_RESULT([yes])
 387         else
 388                 DEFINE_INITRAMFS=''
 389                 AC_MSG_RESULT([no])
 390         fi
 391         AC_SUBST(DEFINE_INITRAMFS)
 392 ])
 393
 394 dnl #
 395 dnl # Default ZFS package configuration
 396 dnl #
 397 AC_DEFUN([ZFS_AC_PACKAGE], [
 398         ZFS_AC_DEFAULT_PACKAGE
 399         ZFS_AC_RPM
 400         ZFS_AC_DPKG
 401         ZFS_AC_ALIEN
 402 ])