config/zfs-build.m4

   1 AC_DEFUN([ZFS_AC_LICENSE], [
   2         AC_MSG_CHECKING([zfs author])
   3         AC_MSG_RESULT([$ZFS_META_AUTHOR])
   4
   5         AC_MSG_CHECKING([zfs license])
   6         AC_MSG_RESULT([$ZFS_META_LICENSE])
   7 ])
   8
   9 AC_DEFUN([ZFS_AC_DEBUG], [
  10         AC_MSG_CHECKING([whether debugging is enabled])
  11         AC_ARG_ENABLE([debug],
  12                 [AS_HELP_STRING([--enable-debug],
  13                 [Enable generic debug support @<:@default=no@:>@])],
  14                 [],
  15                 [enable_debug=no])
  16
  17         AS_IF([test "x$enable_debug" = xyes],
  18         [
  19                 KERNELCPPFLAGS="${KERNELCPPFLAGS} -DDEBUG -Werror"
  20                 HOSTCFLAGS="${HOSTCFLAGS} -DDEBUG -Werror"
  21                 DEBUG_CFLAGS="-DDEBUG -Werror"
  22                 DEBUG_STACKFLAGS="-fstack-check"
  23         ],
  24         [
  25                 KERNELCPPFLAGS="${KERNELCPPFLAGS} -DNDEBUG "
  26                 HOSTCFLAGS="${HOSTCFLAGS} -DNDEBUG "
  27                 DEBUG_CFLAGS="-DNDEBUG"
  28                 DEBUG_STACKFLAGS=""
  29         ])
  30
  31         AC_SUBST(DEBUG_CFLAGS)
  32         AC_SUBST(DEBUG_STACKFLAGS)
  33         AC_MSG_RESULT([$enable_debug])
  34 ])
  35
  36 AC_DEFUN([ZFS_AC_CONFIG_SCRIPT], [
  37         cat >.script-config <<EOF
  38 KERNELSRC=${LINUX}
  39 KERNELBUILD=${LINUX_OBJ}
  40 KERNELSRCVER=${LINUX_VERSION}
  41 KERNELMOD=/lib/modules/\${KERNELSRCVER}/kernel
  42
  43 SPLSRC=${SPL}
  44 SPLBUILD=${SPL_OBJ}
  45 SPLSRCVER=${SPL_VERSION}
  46
  47 TOPDIR=${TOPDIR}
  48 BUILDDIR=${BUILDDIR}
  49 LIBDIR=${LIBDIR}
  50 CMDDIR=${CMDDIR}
  51 MODDIR=${MODDIR}
  52 SCRIPTDIR=${SCRIPTDIR}
  53 ETCDIR=\${TOPDIR}/etc
  54 DEVDIR=\${TOPDIR}/dev
  55 ZPOOLDIR=\${TOPDIR}/scripts/zpool-config
  56 ZPIOSDIR=\${TOPDIR}/scripts/zpios-test
  57 ZPIOSPROFILEDIR=\${TOPDIR}/scripts/zpios-profile
  58
  59 ZDB=\${CMDDIR}/zdb/zdb
  60 ZFS=\${CMDDIR}/zfs/zfs
  61 ZINJECT=\${CMDDIR}/zinject/zinject
  62 ZPOOL=\${CMDDIR}/zpool/zpool
  63 ZPOOL_ID=\${CMDDIR}/zpool_id/zpool_id
  64 ZTEST=\${CMDDIR}/ztest/ztest
  65 ZPIOS=\${CMDDIR}/zpios/zpios
  66
  67 COMMON_SH=\${SCRIPTDIR}/common.sh
  68 ZFS_SH=\${SCRIPTDIR}/zfs.sh
  69 ZPOOL_CREATE_SH=\${SCRIPTDIR}/zpool-create.sh
  70 ZPIOS_SH=\${SCRIPTDIR}/zpios.sh
  71 ZPIOS_SURVEY_SH=\${SCRIPTDIR}/zpios-survey.sh
  72
  73 INTREE=1
  74 LDMOD=/sbin/insmod
  75
  76 KERNEL_MODULES=(                                      \\
  77         \${KERNELMOD}/lib/zlib_deflate/zlib_deflate.ko \\
  78 )
  79
  80 SPL_MODULES=(                                         \\
  81         \${SPLBUILD}/spl/spl.ko                        \\
  82         \${SPLBUILD}/splat/splat.ko                    \\
  83 )
  84
  85 ZFS_MODULES=(                                         \\
  86         \${MODDIR}/avl/zavl.ko                         \\
  87         \${MODDIR}/nvpair/znvpair.ko                   \\
  88         \${MODDIR}/unicode/zunicode.ko                 \\
  89         \${MODDIR}/zcommon/zcommon.ko                  \\
  90         \${MODDIR}/zfs/zfs.ko                          \\
  91 )
  92
  93 ZPIOS_MODULES=(                                       \\
  94         \${MODDIR}/zpios/zpios.ko                      \\
  95 )
  96
  97 MODULES=(                                             \\
  98         \${KERNEL_MODULES[[*]]}                          \\
  99         \${SPL_MODULES[[*]]}                             \\
 100         \${ZFS_MODULES[[*]]}                             \\
 101 )
 102 EOF
 103 ])
 104
 105 AC_DEFUN([ZFS_AC_CONFIG], [
 106         TOPDIR=`readlink -f ${srcdir}`
 107         BUILDDIR=$TOPDIR
 108         LIBDIR=$TOPDIR/lib
 109         CMDDIR=$TOPDIR/cmd
 110         MODDIR=$TOPDIR/module
 111         SCRIPTDIR=$TOPDIR/scripts
 112         TARGET_ASM_DIR=asm-generic
 113
 114         AC_SUBST(TOPDIR)
 115         AC_SUBST(BUILDDIR)
 116         AC_SUBST(LIBDIR)
 117         AC_SUBST(CMDDIR)
 118         AC_SUBST(MODDIR)
 119         AC_SUBST(SCRIPTDIR)
 120         AC_SUBST(TARGET_ASM_DIR)
 121
 122         ZFS_CONFIG=all
 123         AC_ARG_WITH([config],
 124                 AS_HELP_STRING([--with-config=CONFIG],
 125                 [Config file 'kernel|user|all|srpm']),
 126                 [ZFS_CONFIG="$withval"])
 127
 128         AC_MSG_CHECKING([zfs config])
 129         AC_MSG_RESULT([$ZFS_CONFIG]);
 130         AC_SUBST(ZFS_CONFIG)
 131
 132         case "$ZFS_CONFIG" in
 133                 kernel) ZFS_AC_CONFIG_KERNEL ;;
 134                 user)   ZFS_AC_CONFIG_USER   ;;
 135                 all)    ZFS_AC_CONFIG_KERNEL
 136                         ZFS_AC_CONFIG_USER   ;;
 137                 srpm)                        ;;
 138                 *)
 139                 AC_MSG_RESULT([Error!])
 140                 AC_MSG_ERROR([Bad value "$ZFS_CONFIG" for --with-config,
 141                               user kernel|user|all|srpm]) ;;
 142         esac
 143
 144         AM_CONDITIONAL([CONFIG_USER],
 145                        [test "$ZFS_CONFIG" = user] ||
 146                        [test "$ZFS_CONFIG" = all])
 147         AM_CONDITIONAL([CONFIG_KERNEL],
 148                        [test "$ZFS_CONFIG" = kernel] ||
 149                        [test "$ZFS_CONFIG" = all])
 150
 151         ZFS_AC_CONFIG_SCRIPT
 152 ])
 153
 154 dnl #
 155 dnl # Check for rpm+rpmbuild to build RPM packages.  If these tools
 156 dnl # are missing it is non-fatal but you will not be able to build
 157 dnl # RPM packages and will be warned if you try too.
 158 dnl #
 159 AC_DEFUN([ZFS_AC_RPM], [
 160         RPM=rpm
 161         RPMBUILD=rpmbuild
 162
 163         AC_MSG_CHECKING([whether $RPM is available])
 164         AS_IF([tmp=$($RPM --version 2>/dev/null)], [
 165                 RPM_VERSION=$(echo $tmp | $AWK '/RPM/ { print $[3] }')
 166                 HAVE_RPM=yes
 167                 AC_MSG_RESULT([$HAVE_RPM ($RPM_VERSION)])
 168         ],[
 169                 HAVE_RPM=no
 170                 AC_MSG_RESULT([$HAVE_RPM])
 171         ])
 172
 173         AC_MSG_CHECKING([whether $RPMBUILD is available])
 174         AS_IF([tmp=$($RPMBUILD --version 2>/dev/null)], [
 175                 RPMBUILD_VERSION=$(echo $tmp | $AWK '/RPM/ { print $[3] }')
 176                 HAVE_RPMBUILD=yes
 177                 AC_MSG_RESULT([$HAVE_RPMBUILD ($RPMBUILD_VERSION)])
 178         ],[
 179                 HAVE_RPMBUILD=no
 180                 AC_MSG_RESULT([$HAVE_RPMBUILD])
 181         ])
 182
 183         AC_SUBST(HAVE_RPM)
 184         AC_SUBST(RPM)
 185         AC_SUBST(RPM_VERSION)
 186
 187         AC_SUBST(HAVE_RPMBUILD)
 188         AC_SUBST(RPMBUILD)
 189         AC_SUBST(RPMBUILD_VERSION)
 190 ])
 191
 192 dnl #
 193 dnl # Check for dpkg+dpkg-buildpackage to build DEB packages.  If these
 194 dnl # tools are missing it is non-fatal but you will not be able to build
 195 dnl # DEB packages and will be warned if you try too.
 196 dnl #
 197 AC_DEFUN([ZFS_AC_DPKG], [
 198         DPKG=dpkg
 199         DPKGBUILD=dpkg-buildpackage
 200
 201         AC_MSG_CHECKING([whether $DPKG is available])
 202         AS_IF([tmp=$($DPKG --version 2>/dev/null)], [
 203                 DPKG_VERSION=$(echo $tmp | $AWK '/Debian/ { print $[7] }')
 204                 HAVE_DPKG=yes
 205                 AC_MSG_RESULT([$HAVE_DPKG ($DPKG_VERSION)])
 206         ],[
 207                 HAVE_DPKG=no
 208                 AC_MSG_RESULT([$HAVE_DPKG])
 209         ])
 210
 211         AC_MSG_CHECKING([whether $DPKGBUILD is available])
 212         AS_IF([tmp=$($DPKGBUILD --version 2>/dev/null)], [
 213                 DPKGBUILD_VERSION=$(echo $tmp | \
 214                     $AWK '/Debian/ { print $[4] }' | cut -f-4 -d'.')
 215                 HAVE_DPKGBUILD=yes
 216                 AC_MSG_RESULT([$HAVE_DPKGBUILD ($DPKGBUILD_VERSION)])
 217         ],[
 218                 HAVE_DPKGBUILD=no
 219                 AC_MSG_RESULT([$HAVE_DPKGBUILD])
 220         ])
 221
 222         AC_SUBST(HAVE_DPKG)
 223         AC_SUBST(DPKG)
 224         AC_SUBST(DPKG_VERSION)
 225
 226         AC_SUBST(HAVE_DPKGBUILD)
 227         AC_SUBST(DPKGBUILD)
 228         AC_SUBST(DPKGBUILD_VERSION)
 229 ])
 230
 231 dnl #
 232 dnl # Until native packaging for various different packing systems
 233 dnl # can be added the least we can do is attempt to use alien to
 234 dnl # convert the RPM packages to the needed package type.  This is
 235 dnl # a hack but so far it has worked reasonable well.
 236 dnl #
 237 AC_DEFUN([ZFS_AC_ALIEN], [
 238         ALIEN=alien
 239
 240         AC_MSG_CHECKING([whether $ALIEN is available])
 241         AS_IF([tmp=$($ALIEN --version 2>/dev/null)], [
 242                 ALIEN_VERSION=$(echo $tmp | $AWK '{ print $[3] }')
 243                 HAVE_ALIEN=yes
 244                 AC_MSG_RESULT([$HAVE_ALIEN ($ALIEN_VERSION)])
 245         ],[
 246                 HAVE_ALIEN=no
 247                 AC_MSG_RESULT([$HAVE_ALIEN])
 248         ])
 249
 250         AC_SUBST(HAVE_ALIEN)
 251         AC_SUBST(ALIEN)
 252         AC_SUBST(ALIEN_VERSION)
 253 ])
 254
 255 dnl #
 256 dnl # Using the VENDOR tag from config.guess set the default
 257 dnl # package type for 'make pkg': (rpm | deb | tgz)
 258 dnl #
 259 AC_DEFUN([ZFS_AC_DEFAULT_PACKAGE], [
 260         AC_MSG_CHECKING([linux distribution])
 261         if test -f /etc/redhat-release ; then
 262                 VENDOR=redhat ;
 263         elif test -f /etc/fedora-release ; then
 264                 VENDOR=fedora ;
 265         elif test -f /etc/debian_version ; then
 266                 VENDOR=debian ;
 267         elif test -f /etc/lsb-release ; then
 268                 VENDOR=ubuntu ;
 269         elif test -f /etc/SuSE-release ; then
 270                 VENDOR=sles ;
 271         elif test -f /etc/slackware-version ; then
 272                 VENDOR=slackware ;
 273         elif test -f /etc/gentoo-release ; then
 274                 VENDOR=gentoo ;
 275         else
 276                 VENDOR= ;
 277         fi
 278         AC_MSG_RESULT([$VENDOR])
 279         AC_SUBST(VENDOR)
 280
 281         AC_MSG_CHECKING([default package type])
 282         case "$VENDOR" in
 283                 fedora)     DEFAULT_PACKAGE=rpm ;;
 284                 redhat)     DEFAULT_PACKAGE=rpm ;;
 285                 sles)       DEFAULT_PACKAGE=rpm ;;
 286                 ubuntu)     DEFAULT_PACKAGE=deb ;;
 287                 debian)     DEFAULT_PACKAGE=deb ;;
 288                 slackware)  DEFAULT_PACKAGE=tgz ;;
 289                 *)          DEFAULT_PACKAGE=rpm ;;
 290         esac
 291
 292         AC_MSG_RESULT([$DEFAULT_PACKAGE])
 293         AC_SUBST(DEFAULT_PACKAGE)
 294 ])
 295
 296 dnl #
 297 dnl # Default ZFS package configuration
 298 dnl #
 299 AC_DEFUN([ZFS_AC_PACKAGE], [
 300         ZFS_AC_RPM
 301         ZFS_AC_DPKG
 302         ZFS_AC_ALIEN
 303         ZFS_AC_DEFAULT_PACKAGE
 304 ])