Renamed remotely

[mirror_edk2.git] / EdkCompatibilityPkg / Foundation / Library / CompilerStub / X64 / memcpy.asm

diff --git a/EdkCompatibilityPkg/Foundation/Library/CompilerStub/X64/memcpy.asm b/EdkCompatibilityPkg/Foundation/Library/CompilerStub/X64/memcpy.asm
new file mode 100644 (file)
index 0000000..7e04431
--- /dev/null
+++ b/EdkCompatibilityPkg/Foundation/Library/CompilerStub/X64/memcpy.asm
@@ -0,0 +1,73 @@
+;------------------------------------------------------------------------------\r
+;\r
+; Copyright (c) 2007, Intel Corporation\r
+; All rights reserved. This program and the accompanying materials\r
+; are licensed and made available under the terms and conditions of the BSD License\r
+; which accompanies this distribution.  The full text of the license may be found at\r
+; http://opensource.org/licenses/bsd-license.php\r
+;\r
+; THE PROGRAM IS DISTRIBUTED UNDER THE BSD LICENSE ON AN "AS IS" BASIS,\r
+; WITHOUT WARRANTIES OR REPRESENTATIONS OF ANY KIND, EITHER EXPRESS OR IMPLIED.\r
+;\r
+; Module Name:\r
+;\r
+;   CopyMem.asm\r
+;\r
+; Abstract:\r
+;\r
+;   memcpy function\r
+;\r
+; Notes:\r
+;\r
+;------------------------------------------------------------------------------\r
+\r
+    .code\r
+\r
+;------------------------------------------------------------------------------\r
+; VOID *\r
+; memcpy (\r
+;   OUT     VOID                      *DestinationBuffer,\r
+;   IN      CONST VOID                *SourceBuffer,\r
+;   IN      UINTN                     Length\r
+;   );\r
+;------------------------------------------------------------------------------\r
+memcpy  PROC    USES    rsi rdi\r
+    mov     rax, rcx                    ; rax <- Destination as return value\r
+    cmp     rdx, rcx                    ; if Source == Destination, do nothing\r
+    je      @CopyMemDone\r
+    cmp     r8, 0                       ; if Count == 0, do nothing\r
+    je      @CopyMemDone\r
+    mov     rsi, rdx                    ; rsi <- Source\r
+    mov     rdi, rcx                    ; rdi <- Destination\r
+    lea     r9, [rsi + r8 - 1]          ; r9 <- End of Source\r
+    cmp     rsi, rdi\r
+    jae     @F\r
+    cmp     r9, rdi\r
+    jae     @CopyBackward               ; Copy backward if overlapped\r
+@@:\r
+    mov     rcx, r8\r
+    and     r8, 7\r
+    shr     rcx, 3                      ; rcx <- # of Qwords to copy\r
+    jz      @CopyBytes\r
+    DB      49h, 0fh, 7eh, 0c2h         ; movd r10, mm0 (Save mm0 in r10)\r
+@@:\r
+    DB      0fh, 6fh, 06h               ; movd mm0, [rsi]\r
+    DB      48h, 0fh, 7eh, 07h          ; movd [rdi], mm0\r
+    add     rsi, 8\r
+    add     rdi, 8\r
+    loop    @B\r
+    DB      49h, 0fh, 6eh, 0c2h         ; movd mm0, r10 (Restore mm0)\r
+    jmp     @CopyBytes\r
+@CopyBackward:\r
+    mov     rsi, r9                     ; rsi <- End of Source\r
+    lea     rdi, [rdi + r8 - 1]         ; rdi <- End of Destination\r
+    std                                 ; set direction flag\r
+@CopyBytes:\r
+    mov     rcx, r8\r
+    rep     movsb                       ; Copy bytes backward\r
+    cld\r
+@CopyMemDone:   \r
+    ret\r
+memcpy  ENDP\r
+\r
+    END\r