In autoconf v2.68, AC_LANG_PROGRAM must be quoted

This change updates the AC_LANG_PROGRAM autoconf macro invocations to be
wrapped in quotes. As of autoconf version 2.68, the quotes are necessary
to prevent warnings from appearing. Specifically, the autoconf v2.68
Forward Porting Notes specifies:

    It is important to note that you need to ensure that the call to
    AC_LANG_SOURCE is quoted and not expanded, otherwise that will
    cause the warning to appear nonetheless.

Finally, because of the additional quoting we can drop the extra
quotas used by the ZFS_AC_CONFIG_USER_STACK_GUARD autoconf check.

Signed-off-by: Brian Behlendorf <behlendorf1@llnl.gov>
Closes #464

diff --git a/config/always-no-unused-but-set-variable.m4 b/config/always-no-unused-but-set-variable.m4
index 0e2634da26968b50449ece4e33cdb105599699e3..4a3ceb614af8a688c9c3c69b615bb6f04828ea17 100644 (file)
--- a/config/always-no-unused-but-set-variable.m4
+++ b/config/always-no-unused-but-set-variable.m4
@@ -12,7 +12,7 @@ AC_DEFUN([ZFS_AC_CONFIG_ALWAYS_NO_UNUSED_BUT_SET_VARIABLE], [
        saved_flags="$CFLAGS"
        CFLAGS="$CFLAGS -Wunused-but-set-variable"
 
-       AC_RUN_IFELSE(AC_LANG_PROGRAM( [], []),
+       AC_RUN_IFELSE([AC_LANG_PROGRAM([], [])],
        [
                NO_UNUSED_BUT_SET_VARIABLE=-Wno-unused-but-set-variable
                AC_MSG_RESULT([yes])

diff --git a/config/user-frame-larger-than.m4 b/config/user-frame-larger-than.m4
index 3384f50e4a4677731a5aafb10a35c2b6b6520a9b..7ad86220d7aa2aff31522ace911769a458f3381e 100644 (file)
--- a/config/user-frame-larger-than.m4
+++ b/config/user-frame-larger-than.m4
@@ -7,7 +7,7 @@ AC_DEFUN([ZFS_AC_CONFIG_USER_FRAME_LARGER_THAN], [
        saved_flags="$CFLAGS"
        CFLAGS="$CFLAGS -Wframe-larger-than=1024"
 
-       AC_RUN_IFELSE(AC_LANG_PROGRAM( [], []),
+       AC_RUN_IFELSE([AC_LANG_PROGRAM([], [])],
        [
                FRAME_LARGER_THAN=-Wframe-larger-than=1024
                AC_MSG_RESULT([yes])

diff --git a/config/user-libblkid.m4 b/config/user-libblkid.m4
index 8934d0ab80edec325fdb01bcf488af41d197d86f..276587fd358926d19a166ed917fbb4d60cb5e4ab 100644 (file)
--- a/config/user-libblkid.m4
+++ b/config/user-libblkid.m4
@@ -39,7 +39,7 @@ AC_DEFUN([ZFS_AC_CONFIG_USER_LIBBLKID], [
                        saved_LDFLAGS="$LDFLAGS"
                        LDFLAGS="-lblkid"
 
-                       AC_RUN_IFELSE(AC_LANG_PROGRAM(
+                       AC_RUN_IFELSE([AC_LANG_PROGRAM(
                        [
                                #include <stdio.h>
                                #include <blkid/blkid.h>
@@ -66,7 +66,7 @@ AC_DEFUN([ZFS_AC_CONFIG_USER_LIBBLKID], [
 
                                free(value);
                                blkid_put_cache(cache);
-                       ]),
+                       ])],
                        [
                                rm -f $ZFS_DEV
                                AC_MSG_RESULT([yes])

diff --git a/config/user-nptl_guard_within_stack.m4 b/config/user-nptl_guard_within_stack.m4
index d094da7332ca7b07622bd6a59a5777a2895be921..421eb1c0553da737181720f0f68fe29783391fd9 100644 (file)
--- a/config/user-nptl_guard_within_stack.m4
+++ b/config/user-nptl_guard_within_stack.m4
@@ -12,7 +12,7 @@ AC_DEFUN([ZFS_AC_CONFIG_USER_STACK_GUARD], [
        saved_LDFLAGS="$LDFLAGS"
        LDFLAGS="-lpthread"
 
-       AC_RUN_IFELSE(AC_LANG_PROGRAM(
+       AC_RUN_IFELSE([AC_LANG_PROGRAM(
        [
                #include <pthread.h>
                #include <sys/resource.h>
@@ -25,7 +25,7 @@ AC_DEFUN([ZFS_AC_CONFIG_USER_STACK_GUARD], [
 
                void * func(void *arg)
                {
-                       char buf[[[BUFSIZE]]];
+                       char buf[[BUFSIZE]];
                }
        ],
        [
@@ -41,7 +41,7 @@ AC_DEFUN([ZFS_AC_CONFIG_USER_STACK_GUARD], [
                pthread_attr_setguardsize(&attr, PAGESIZE);
                pthread_create(&tid, &attr, func, NULL);
                pthread_join(tid, NULL);
-       ]),
+       ])],
        [
                AC_MSG_RESULT([no])
        ],