ceph/CMakeLists.txt

   1 cmake_minimum_required(VERSION 3.16)
   2
   3 project(ceph
   4   VERSION 17.2.5
   5   LANGUAGES CXX C ASM)
   6
   7 cmake_policy(SET CMP0028 NEW)
   8 cmake_policy(SET CMP0046 NEW)
   9 cmake_policy(SET CMP0048 NEW)
  10 cmake_policy(SET CMP0051 NEW)
  11 cmake_policy(SET CMP0054 NEW)
  12 cmake_policy(SET CMP0056 NEW)
  13 cmake_policy(SET CMP0065 NEW)
  14 cmake_policy(SET CMP0074 NEW)
  15 cmake_policy(SET CMP0075 NEW)
  16 cmake_policy(SET CMP0093 NEW)
  17 if(POLICY CMP0127)
  18   cmake_policy(SET CMP0127 NEW)
  19 endif()
  20
  21 list(APPEND CMAKE_MODULE_PATH "${CMAKE_SOURCE_DIR}/cmake/modules/")
  22
  23 if(NOT CMAKE_BUILD_TYPE AND EXISTS "${CMAKE_SOURCE_DIR}/.git")
  24   set(default_build_type "Debug")
  25   set(CMAKE_BUILD_TYPE "${default_build_type}" CACHE
  26       STRING "Default BUILD_TYPE is Debug, other options are: RelWithDebInfo, Release, and MinSizeRel." FORCE)
  27 endif()
  28
  29 if(CMAKE_SYSTEM_NAME MATCHES "Linux")
  30   set(LINUX ON)
  31   FIND_PACKAGE(Threads)
  32 elseif(CMAKE_SYSTEM_NAME MATCHES "FreeBSD")
  33   set(FREEBSD ON)
  34   FIND_PACKAGE(Threads)
  35 endif(CMAKE_SYSTEM_NAME MATCHES "Linux")
  36
  37 if(WIN32)
  38   # The Windows headers (e.g. coming from mingw or the Windows SDK) check
  39   # the targeted Windows version. The availability of certain functions and
  40   # structures will depend on it.
  41   set(WIN32_WINNT "0x0A00" CACHE STRING "Targeted Windows version.")
  42   # In order to avoid known winpthread issues, we're using the boost
  43   # shared mutex implementation.
  44   # https://github.com/msys2/MINGW-packages/issues/3319
  45   add_definitions(
  46     -D_WIN32_WINNT=${WIN32_WINNT}
  47     -DBOOST_THREAD_PROVIDES_GENERIC_SHARED_MUTEX_ON_WIN
  48     -DBOOST_THREAD_V2_SHARED_MUTEX
  49   )
  50   set(Boost_THREADAPI "win32")
  51 endif()
  52
  53 if(MINGW)
  54   string(APPEND CMAKE_SHARED_LINKER_FLAGS " -Wl,-allow-multiple-definition")
  55   string(APPEND CMAKE_EXE_LINKER_FLAGS " -Wl,-allow-multiple-definition")
  56
  57   # By default, cmake generates import libs for executables. The issue is that
  58   # for rados and rbd, the executable import lib overrides the library import lib.
  59   # For example, for rados.exe, it will end up generating a librados.dll.a import lib.
  60   # We're providing custom rules to disable import libs for executables.
  61   set(CMAKE_C_LINK_EXECUTABLE
  62     "<CMAKE_C_COMPILER> <FLAGS> <CMAKE_C_LINK_FLAGS> <LINK_FLAGS> <OBJECTS> -o <TARGET> ${CMAKE_GNULD_IMAGE_VERSION} <LINK_LIBRARIES>")
  63   set(CMAKE_CXX_LINK_EXECUTABLE
  64     "<CMAKE_CXX_COMPILER> <FLAGS> <CMAKE_CXX_LINK_FLAGS> <LINK_FLAGS> <OBJECTS> -o <TARGET> ${CMAKE_GNULD_IMAGE_VERSION} <LINK_LIBRARIES>")
  65
  66   link_directories(${MINGW_LINK_DIRECTORIES})
  67 endif()
  68
  69 option(WITH_CCACHE "Build with ccache.")
  70 if(WITH_CCACHE)
  71   find_program(CCACHE_EXECUTABLE ccache)
  72   if(NOT CCACHE_EXECUTABLE)
  73     message(FATAL_ERROR "Can't find ccache. Is it installed?")
  74   endif()
  75   message(STATUS "Building with ccache: ${CCACHE_EXECUTABLE}, CCACHE_DIR=$ENV{CCACHE_DIR}")
  76   set_property(GLOBAL PROPERTY RULE_LAUNCH_COMPILE "${CCACHE_EXECUTABLE}")
  77   # ccache does not accelerate link (ld), but let it handle it. by passing it
  78   # along with cc to python's distutils, we are able to workaround
  79   # https://bugs.python.org/issue8027.
  80   set_property(GLOBAL PROPERTY RULE_LAUNCH_LINK "${CCACHE_EXECUTABLE}")
  81 endif(WITH_CCACHE)
  82
  83 option(WITH_MANPAGE "Build man pages." ON)
  84 if(WITH_MANPAGE)
  85   find_program(SPHINX_BUILD
  86     NAMES sphinx-build sphinx-build-3)
  87   if(NOT SPHINX_BUILD)
  88     message(FATAL_ERROR "Can't find sphinx-build.")
  89   endif(NOT SPHINX_BUILD)
  90 endif(WITH_MANPAGE)
  91
  92 include_directories(
  93   ${PROJECT_BINARY_DIR}/src/include
  94   ${PROJECT_SOURCE_DIR}/src)
  95
  96 if(WIN32)
  97   include_directories(
  98     ${PROJECT_SOURCE_DIR}/src/include/win32)
  99   # Boost complains if winsock2.h (or windows.h) is included before asio.hpp.
 100   add_compile_options("SHELL:-include winsock_wrapper.h")
 101   # Boost is also defining some of the errno values, we'll have
 102   # to avoid mismatches.
 103   add_compile_options("SHELL:-include win32_errno.h")
 104 endif()
 105
 106 if(FREEBSD)
 107   include_directories(SYSTEM /usr/local/include)
 108   link_directories(/usr/local/lib)
 109   list(APPEND CMAKE_REQUIRED_INCLUDES /usr/local/include)
 110 endif(FREEBSD)
 111
 112
 113 #put all the libs and binaries in one place
 114 set(CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib)
 115 set(CMAKE_LIBRARY_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib)
 116 set(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/bin)
 117
 118 include(GNUInstallDirs)
 119 include(CephChecks)
 120 if(CMAKE_GENERATOR MATCHES Ninja)
 121   include(LimitJobs)
 122 endif()
 123
 124 set(CEPH_MAN_DIR "share/man" CACHE STRING "Install location for man pages (relative to prefix).")
 125
 126 option(ENABLE_SHARED "build shared libraries" ON)
 127 if(ENABLE_SHARED)
 128   set(CEPH_SHARED SHARED)
 129 else(ENABLE_SHARED)
 130   set(CEPH_SHARED STATIC)
 131 endif(ENABLE_SHARED)
 132 set(CMAKE_POSITION_INDEPENDENT_CODE ${ENABLE_SHARED})
 133
 134 option(WITH_STATIC_LIBSTDCXX "Link against libstdc++ statically" OFF)
 135 if(WITH_STATIC_LIBSTDCXX)
 136   if(NOT CMAKE_COMPILER_IS_GNUCXX)
 137     message(FATAL_ERROR "Please use GCC to enable WITH_STATIC_LIBSTDCXX")
 138   endif()
 139   set(static_linker_flags "-static-libstdc++ -static-libgcc")
 140   string(APPEND CMAKE_SHARED_LINKER_FLAGS " ${static_linker_flags}")
 141   string(APPEND CMAKE_EXE_LINKER_FLAGS " ${static_linker_flags}")
 142   unset(static_linker_flags)
 143   set(GPERFTOOLS_USE_STATIC_LIBS TRUE)
 144 endif()
 145 include(CheckCxxAtomic)
 146 if(NOT HAVE_CXX11_ATOMIC)
 147   string(APPEND CMAKE_CXX_STANDARD_LIBRARIES
 148     " ${LIBATOMIC_LINK_FLAGS}")
 149 endif()
 150
 151 option(WITH_RDMA "Enable RDMA in async messenger" ON)
 152 if(WITH_RDMA)
 153   find_package(verbs REQUIRED)
 154   set(HAVE_VERBS ${VERBS_FOUND})
 155   find_package(rdmacm REQUIRED)
 156   set(HAVE_RDMACM ${RDMACM_FOUND})
 157   set(HAVE_RDMA TRUE)
 158 endif()
 159
 160 find_package(Backtrace)
 161
 162 option(WITH_RBD "Enable RADOS Block Device related targets" ON)
 163
 164 if(LINUX)
 165   find_package(udev REQUIRED)
 166   set(HAVE_UDEV ${UDEV_FOUND})
 167   find_package(blkid REQUIRED)
 168   set(HAVE_BLKID ${BLKID_FOUND})
 169   find_package(keyutils REQUIRED)
 170   set(HAVE_KEYUTILS ${KEYUTILS_FOUND})
 171 elseif(FREEBSD)
 172   set(HAVE_UDEV OFF)
 173   set(HAVE_LIBAIO OFF)
 174   set(HAVE_BLKID OFF)
 175   set(HAVE_KEYUTILS OFF)
 176 else()
 177   set(HAVE_UDEV OFF)
 178   set(HAVE_BLKID OFF)
 179 endif(LINUX)
 180
 181 option(WITH_OPENLDAP "OPENLDAP is here" ON)
 182 if(WITH_OPENLDAP)
 183   find_package(OpenLDAP REQUIRED)
 184   set(HAVE_OPENLDAP ${OpenLDAP_FOUND})
 185 endif()
 186
 187 option(WITH_GSSAPI "GSSAPI/KRB5 is here" OFF)
 188 if(WITH_GSSAPI)
 189   find_package(GSSApi REQUIRED)
 190   set(HAVE_GSSAPI ${GSSApi_FOUND})
 191 endif()
 192
 193 option(WITH_FUSE "Fuse is here" ON)
 194 if(WITH_FUSE)
 195   find_package(FUSE)
 196   set(HAVE_LIBFUSE ${FUSE_FOUND})
 197 endif()
 198
 199 option(WITH_DOKAN "Dokan is here" OFF)
 200
 201 option(WITH_XFS "XFS is here" ON)
 202 if(WITH_XFS)
 203   find_package(xfs)
 204   set(HAVE_LIBXFS ${XFS_FOUND})
 205 endif()
 206
 207 option(WITH_ZFS "enable LibZFS if found" OFF)
 208 if(WITH_ZFS)
 209   find_package(zfs)
 210   set(HAVE_LIBZFS ${ZFS_FOUND})
 211 endif()
 212
 213 option(WITH_BLUESTORE "Bluestore OSD backend" ON)
 214 if(WITH_BLUESTORE)
 215   if(LINUX)
 216     find_package(aio)
 217     set(HAVE_LIBAIO ${AIO_FOUND})
 218   elseif(FREEBSD)
 219     # POSIX AIO is integrated into FreeBSD kernel, and exposed by libc.
 220     set(HAVE_POSIXAIO ON)
 221   endif()
 222 endif()
 223
 224 # libcryptsetup is only available on linux
 225 if(WITH_RBD AND LINUX)
 226   find_package(libcryptsetup 2.0.5 REQUIRED)
 227   set(HAVE_LIBCRYPTSETUP ${LIBCRYPTSETUP_FOUND})
 228 endif()
 229
 230 include(CMakeDependentOption)
 231
 232 CMAKE_DEPENDENT_OPTION(WITH_ZBD "Enable libzbd bluestore backend" OFF
 233   "WITH_BLUESTORE" OFF)
 234 if(WITH_ZBD)
 235   find_package(zbd REQUIRED)
 236   set(HAVE_LIBZBD ${ZBD_FOUND})
 237 endif()
 238
 239 CMAKE_DEPENDENT_OPTION(WITH_LIBURING "Enable io_uring bluestore backend" ON
 240   "WITH_BLUESTORE;HAVE_LIBAIO" OFF)
 241 set(HAVE_LIBURING ${WITH_LIBURING})
 242
 243 CMAKE_DEPENDENT_OPTION(WITH_SYSTEM_LIBURING "Require and build with system liburing" OFF
 244   "HAVE_LIBAIO;WITH_BLUESTORE" OFF)
 245
 246 CMAKE_DEPENDENT_OPTION(WITH_BLUESTORE_PMEM "Enable PMDK libraries" OFF
 247   "WITH_BLUESTORE" OFF)
 248
 249 CMAKE_DEPENDENT_OPTION(WITH_RBD_MIGRATION_FORMAT_QCOW_V1
 250   "Enable librbd QCOW v1 migration format support" ON
 251   "WITH_RBD" OFF)
 252
 253 CMAKE_DEPENDENT_OPTION(WITH_RBD_RWL "Enable librbd persistent write back cache" OFF
 254   "WITH_RBD" OFF)
 255
 256 CMAKE_DEPENDENT_OPTION(WITH_RBD_SSD_CACHE "Enable librbd persistent write back cache for SSDs" OFF
 257     "WITH_RBD" OFF)
 258
 259 CMAKE_DEPENDENT_OPTION(WITH_SYSTEM_PMDK "Require and build with system PMDK" OFF
 260   "WITH_RBD_RWL OR WITH_BLUESTORE_PMEM" OFF)
 261
 262 if(WITH_BLUESTORE_PMEM)
 263   set(HAVE_BLUESTORE_PMEM ON)
 264 endif()
 265
 266 CMAKE_DEPENDENT_OPTION(WITH_SPDK "Enable SPDK" OFF
 267   "CMAKE_SYSTEM_PROCESSOR MATCHES i386|i686|amd64|x86_64|AMD64|aarch64" OFF)
 268 if(WITH_SPDK)
 269   if(NOT WITH_BLUESTORE)
 270     message(SEND_ERROR "Please enable WITH_BLUESTORE for using SPDK")
 271   endif()
 272   include(BuildSPDK)
 273   build_spdk()
 274   set(HAVE_SPDK TRUE)
 275 endif(WITH_SPDK)
 276
 277 if(WITH_BLUESTORE)
 278   if(NOT AIO_FOUND AND NOT HAVE_POSIXAIO AND NOT WITH_SPDK AND NOT WITH_BLUESTORE_PMEM)
 279     message(SEND_ERROR "WITH_BLUESTORE is ON, "
 280       "but none of the bluestore backends is enabled. "
 281       "Please install libaio, or enable WITH_SPDK or WITH_BLUESTORE_PMEM (experimental)")
 282   endif()
 283 endif()
 284
 285 option(WITH_BLUEFS "libbluefs library" OFF)
 286
 287 option(WITH_QAT "Enable Qat driver" OFF)
 288 if(WITH_QAT)
 289   find_package(QatDrv REQUIRED COMPONENTS qat_s usdm_drv_s)
 290   set(HAVE_QATDRV $(QatDrv_FOUND))
 291 endif()
 292
 293 option(WITH_QATZIP "Enable QATZIP" OFF)
 294 if(WITH_QATZIP)
 295   find_package(qatzip REQUIRED)
 296   set(HAVE_QATZIP ${qatzip_FOUND})
 297 endif(WITH_QATZIP)
 298
 299 # needs mds and? XXX
 300 option(WITH_LIBCEPHFS "libcephfs client library" ON)
 301
 302 option(WITH_LIBCEPHSQLITE "libcephsqlite client library" ON)
 303 if(WITH_LIBCEPHSQLITE)
 304   find_package(SQLite3 REQUIRED)
 305 endif()
 306
 307 # key-value store
 308 option(WITH_KVS "Key value store is here" OFF)
 309
 310 option(WITH_KRBD "Enable Linux krbd support of 'rbd' utility" ON)
 311
 312 if(WITH_KRBD AND NOT WITH_RBD)
 313   message(FATAL_ERROR "Cannot have WITH_KRBD without WITH_RBD.")
 314 endif()
 315 if(LINUX)
 316   if(WITH_LIBCEPHFS OR WITH_KRBD)
 317     # keyutils is only used when talking to the Linux Kernel key store
 318     find_package(keyutils REQUIRED)
 319     set(HAVE_KEYUTILS ${KEYUTILS_FOUND})
 320   endif()
 321 endif()
 322
 323 find_package(snappy REQUIRED)
 324
 325 option(WITH_BROTLI "Brotli compression support" OFF)
 326 if(WITH_BROTLI)
 327   set(HAVE_BROTLI TRUE)
 328 endif()
 329
 330 option(WITH_LZ4 "LZ4 compression support" ON)
 331 if(WITH_LZ4)
 332   find_package(LZ4 1.7 REQUIRED)
 333   set(HAVE_LZ4 ${LZ4_FOUND})
 334 endif(WITH_LZ4)
 335
 336 CMAKE_DEPENDENT_OPTION(WITH_CEPH_DEBUG_MUTEX "Use debug ceph::mutex with lockdep" ON
 337   "CMAKE_BUILD_TYPE STREQUAL Debug" OFF)
 338
 339 #if allocator is set on command line make sure it matches below strings
 340 set(ALLOCATOR "" CACHE STRING
 341   "specify memory allocator to use. currently tcmalloc, tcmalloc_minimal, \
 342 jemalloc, and libc is supported. if not specified, will try to find tcmalloc, \
 343 and then jemalloc. If neither of then is found. use the one in libc.")
 344 if(ALLOCATOR)
 345   if(${ALLOCATOR} MATCHES "tcmalloc(_minimal)?")
 346     find_package(gperftools 2.6.2 REQUIRED)
 347     set(HAVE_LIBTCMALLOC ON)
 348   elseif(${ALLOCATOR} STREQUAL "jemalloc")
 349     find_package(JeMalloc REQUIRED)
 350     set(HAVE_JEMALLOC 1)
 351   elseif(NOT ALLOCATOR STREQUAL "libc")
 352     message(FATAL_ERROR "Unsupported allocator selected: ${ALLOCATOR}")
 353   endif()
 354 else(ALLOCATOR)
 355   find_package(gperftools 2.6.2)
 356   set(HAVE_LIBTCMALLOC ${gperftools_FOUND})
 357   if(NOT gperftools_FOUND)
 358     find_package(JeMalloc)
 359   endif()
 360   if(gperftools_FOUND)
 361     set(ALLOCATOR tcmalloc)
 362   elseif(JeMalloc_FOUND)
 363     set(ALLOCATOR jemalloc)
 364   else()
 365     if(NOT FREEBSD)
 366       # FreeBSD already has jemalloc as its default allocator
 367       message(WARNING "tcmalloc and jemalloc not found, falling back to libc")
 368     endif()
 369     set(ALLOCATOR "libc")
 370   endif(gperftools_FOUND)
 371 endif(ALLOCATOR)
 372
 373 # Mingw generates incorrect entry points when using "-pie".
 374 if(WIN32 OR (HAVE_LIBTCMALLOC AND WITH_STATIC_LIBSTDCXX))
 375   set(EXE_LINKER_USE_PIE FALSE)
 376 else()
 377   set(EXE_LINKER_USE_PIE ${ENABLE_SHARED})
 378 endif()
 379
 380 find_package(CURL REQUIRED)
 381 set(CMAKE_REQUIRED_INCLUDES ${CURL_INCLUDE_DIRS})
 382 set(CMAKE_REQUIRED_LIBRARIES ${CURL_LIBRARIES})
 383 CHECK_SYMBOL_EXISTS(curl_multi_wait curl/curl.h HAVE_CURL_MULTI_WAIT)
 384
 385 find_package(OpenSSL REQUIRED)
 386 set(CRYPTO_LIBS OpenSSL::Crypto)
 387
 388 option(WITH_DPDK "Enable DPDK messaging" OFF)
 389 if(WITH_DPDK)
 390   find_package(dpdk)
 391   if(NOT DPDK_FOUND)
 392     include(BuildDPDK)
 393     build_dpdk(${CMAKE_BINARY_DIR}/src/dpdk)
 394   endif()
 395   set(HAVE_DPDK TRUE)
 396 endif()
 397
 398 option(WITH_BLKIN "Use blkin to emit LTTng tracepoints for Zipkin" OFF)
 399 if(WITH_BLKIN)
 400   find_package(LTTngUST REQUIRED)
 401   set(BLKIN_LIBRARIES blkin ${LTTNGUST_LIBRARIES} lttng-ust-fork)
 402   include_directories(SYSTEM src/blkin/blkin-lib)
 403 endif(WITH_BLKIN)
 404
 405 option(WITH_JAEGER "Enable jaegertracing and it's dependent libraries" OFF)
 406 if(WITH_JAEGER)
 407   set(HAVE_JAEGER TRUE)
 408 endif()
 409
 410 #option for RGW
 411 option(WITH_RADOSGW "Rados Gateway is enabled" ON)
 412 option(WITH_RADOSGW_BEAST_OPENSSL "Rados Gateway's Beast frontend uses OpenSSL" ON)
 413 option(WITH_RADOSGW_AMQP_ENDPOINT "Rados Gateway's pubsub support for AMQP push endpoint" ON)
 414 option(WITH_RADOSGW_KAFKA_ENDPOINT "Rados Gateway's pubsub support for Kafka push endpoint" ON)
 415 option(WITH_RADOSGW_LUA_PACKAGES "Rados Gateway's support for dynamically adding lua packagess" ON)
 416 option(WITH_RADOSGW_DBSTORE "DBStore backend for Rados Gateway" ON)
 417 option(WITH_RADOSGW_SELECT_PARQUET "Support for s3 select on parquet objects" ON)
 418
 419 option(WITH_SYSTEM_ARROW "Use system-provided arrow" OFF)
 420 option(WITH_SYSTEM_UTF8PROC "Use system-provided utf8proc" OFF)
 421
 422 if(WITH_RADOSGW)
 423   find_package(EXPAT REQUIRED)
 424   find_package(OATH REQUIRED)
 425
 426 # https://curl.haxx.se/docs/install.html mentions the
 427 # configure flags for various ssl backends
 428   execute_process(
 429     COMMAND
 430   "sh" "-c"
 431   "curl-config --configure | grep with-ssl"
 432   RESULT_VARIABLE NO_CURL_SSL_LINK
 433   ERROR_VARIABLE CURL_CONFIG_ERRORS
 434   )
 435   if (CURL_CONFIG_ERRORS)
 436     message(WARNING "unable to run curl-config; rgw cannot make ssl requests to external systems reliably")
 437   endif()
 438
 439   if (NOT NO_CURL_SSL_LINK)
 440     message(STATUS "libcurl is linked with openssl: explicitly setting locks")
 441     set(WITH_CURL_OPENSSL ON)
 442   endif() # CURL_SSL_LINK
 443   execute_process(
 444     COMMAND
 445       "sh" "-c"
 446       "objdump -p ${OPENSSL_SSL_LIBRARY} | sed -n 's/^  SONAME  *//p'"
 447     OUTPUT_VARIABLE LIBSSL_SONAME
 448     ERROR_VARIABLE OBJDUMP_ERRORS
 449     RESULT_VARIABLE OBJDUMP_RESULTS
 450     OUTPUT_STRIP_TRAILING_WHITESPACE)
 451   if (OBJDUMP_RESULTS)
 452     message(FATAL_ERROR "can't run objdump: ${OBJDUMP_RESULTS}")
 453   endif()
 454   if (NOT OBJDUMP_ERRORS STREQUAL "")
 455     message(WARNING "message from objdump: ${OBJDUMP_ERRORS}")
 456   endif()
 457   execute_process(
 458     COMMAND
 459       "sh" "-c"
 460       "objdump -p ${OPENSSL_CRYPTO_LIBRARY} | sed -n 's/^  SONAME  *//p'"
 461     OUTPUT_VARIABLE LIBCRYPTO_SONAME
 462     ERROR_VARIABLE OBJDUMP_ERRORS
 463     RESULT_VARIABLE OBJDUMP_RESULTS
 464     OUTPUT_STRIP_TRAILING_WHITESPACE)
 465   if (OBJDUMP_RESULTS)
 466     message(FATAL_ERROR "can't run objdump: ${OBJDUMP_RESULTS}")
 467   endif()
 468   if (NOT OBJDUMP_ERRORS STREQUAL "")
 469     message(WARNING "message from objdump: ${OBJDUMP_ERRORS}")
 470   endif()
 471   message(STATUS "ssl soname: ${LIBSSL_SONAME}")
 472   message(STATUS "crypto soname: ${LIBCRYPTO_SONAME}")
 473 endif (WITH_RADOSGW)
 474
 475 #option for CephFS
 476 option(WITH_CEPHFS "CephFS is enabled" ON)
 477
 478 if(NOT WIN32)
 479 # Please specify 3.[0-7] if you want to build with a certain version of python3.
 480 set(WITH_PYTHON3 "3" CACHE STRING "build with specified python3 version")
 481 find_package(Python3 ${WITH_PYTHON3} EXACT REQUIRED
 482   COMPONENTS Interpreter Development)
 483
 484 option(WITH_MGR "ceph-mgr is enabled" ON)
 485 if(WITH_MGR)
 486   set(MGR_PYTHON_EXECUTABLE ${Python3_EXECUTABLE})
 487   set(MGR_PYTHON_LIBRARIES ${Python3_LIBRARIES})
 488   set(MGR_PYTHON_VERSION_MAJOR ${Python3_VERSION_MAJOR})
 489   set(MGR_PYTHON_VERSION_MINOR ${Python3_VERSION_MINOR})
 490   # Boost dependency check deferred to Boost section
 491 endif(WITH_MGR)
 492 endif(NOT WIN32)
 493
 494 option(WITH_THREAD_SAFE_RES_QUERY "res_query is thread safe" OFF)
 495 if(WITH_THREAD_SAFE_RES_QUERY)
 496   set(HAVE_THREAD_SAFE_RES_QUERY 1 CACHE INTERNAL "Thread safe res_query supported.")
 497 endif()
 498
 499 option(WITH_REENTRANT_STRSIGNAL "strsignal is reentrant" OFF)
 500 if(WITH_REENTRANT_STRSIGNAL)
 501   set(HAVE_REENTRANT_STRSIGNAL 1 CACHE INTERNAL "Reentrant strsignal is supported.")
 502 endif()
 503
 504 # -lz link into kv
 505 find_package(ZLIB REQUIRED)
 506
 507 #option for EventTrace
 508 CMAKE_DEPENDENT_OPTION(
 509   WITH_EVENTTRACE "Event tracing support, requires WITH_LTTNG"
 510   OFF "USE_LTTNG" OFF)
 511
 512 #option for LTTng
 513 option(WITH_LTTNG "LTTng tracing is enabled" ON)
 514 if(${WITH_LTTNG})
 515   find_package(LTTngUST REQUIRED)
 516   find_program(LTTNG_GEN_TP
 517     lttng-gen-tp)
 518   if(NOT LTTNG_GEN_TP)
 519     message(FATAL_ERROR "Can't find lttng-gen-tp.")
 520   endif()
 521 endif(${WITH_LTTNG})
 522
 523 option(WITH_OSD_INSTRUMENT_FUNCTIONS OFF)
 524
 525 #option for Babeltrace
 526 option(WITH_BABELTRACE "Babeltrace libraries are enabled" ON)
 527 if(WITH_BABELTRACE)
 528   set(HAVE_BABELTRACE ON)
 529   find_package(babeltrace REQUIRED)
 530   set(HAVE_BABELTRACE_BABELTRACE_H ${BABELTRACE_FOUND})
 531   set(HAVE_BABELTRACE_CTF_EVENTS_H ${BABELTRACE_FOUND})
 532   set(HAVE_BABELTRACE_CTF_ITERATOR_H ${BABELTRACE_FOUND})
 533 endif(WITH_BABELTRACE)
 534
 535 option(DEBUG_GATHER "C_Gather debugging is enabled" ON)
 536 option(ENABLE_COVERAGE "Coverage is enabled" OFF)
 537 option(PG_DEBUG_REFS "PG Ref debugging is enabled" OFF)
 538
 539 option(WITH_TESTS "enable the build of ceph-test package scripts/binaries" ON)
 540 set(UNIT_TESTS_BUILT ${WITH_TESTS})
 541 set(CEPH_TEST_TIMEOUT 3600 CACHE STRING
 542   "Maximum time before a CTest gets killed" )
 543
 544 # fio
 545 option(WITH_FIO "build with fio plugin enabled" OFF)
 546 if(WITH_FIO)
 547   include(BuildFIO)
 548   build_fio()
 549 endif()
 550
 551 if(LINUX)
 552   add_definitions(-D__linux__)
 553 endif(LINUX)
 554
 555 # ASAN and friends
 556 option(WITH_ASAN "build with ASAN" OFF)
 557 if(WITH_ASAN)
 558   list(APPEND sanitizers "address")
 559 endif()
 560
 561 option(WITH_ASAN_LEAK "explicitly enable ASAN leak detection" OFF)
 562 if(WITH_ASAN_LEAK)
 563   list(APPEND sanitizers "leak")
 564 endif()
 565
 566 option(WITH_TSAN "build with TSAN" OFF)
 567 if(WITH_TSAN)
 568   list(APPEND sanitizers "thread")
 569 endif()
 570
 571 option(WITH_UBSAN "build with UBSAN" OFF)
 572 if(WITH_UBSAN)
 573   list(APPEND sanitizers "undefined_behavior")
 574 endif()
 575
 576 if(sanitizers)
 577   find_package(Sanitizers REQUIRED ${sanitizers})
 578   add_compile_options(${Sanitizers_COMPILE_OPTIONS})
 579   string(REPLACE ";" " " sanitiers_compile_flags "${Sanitizers_COMPILE_OPTIONS}")
 580   string(APPEND CMAKE_EXE_LINKER_FLAGS " ${sanitiers_compile_flags}")
 581   string(APPEND CMAKE_SHARED_LINKER_FLAGS " ${sanitiers_compile_flags}")
 582 endif()
 583
 584 # Rocksdb
 585 option(WITH_SYSTEM_ROCKSDB "require and build with system rocksdb" OFF)
 586 if (WITH_SYSTEM_ROCKSDB)
 587   find_package(RocksDB 5.14 REQUIRED)
 588 endif()
 589
 590 option(WITH_SEASTAR "Build seastar components")
 591 set(HAVE_SEASTAR ${WITH_SEASTAR})
 592
 593 # Boost
 594 option(WITH_SYSTEM_BOOST "require and build with system Boost" OFF)
 595
 596 # Boost::thread depends on Boost::atomic, so list it explicitly.
 597 set(BOOST_COMPONENTS
 598   atomic chrono thread system regex random program_options date_time
 599   iostreams context coroutine)
 600 set(BOOST_HEADER_COMPONENTS container)
 601
 602 if(WITH_MGR)
 603   list(APPEND BOOST_COMPONENTS
 604     python${MGR_PYTHON_VERSION_MAJOR}${MGR_PYTHON_VERSION_MINOR})
 605 endif()
 606 if(WITH_SEASTAR)
 607   list(APPEND BOOST_COMPONENTS timer)
 608 endif()
 609
 610 if(WITH_RADOSGW AND WITH_RADOSGW_LUA_PACKAGES)
 611   list(APPEND BOOST_COMPONENTS filesystem)
 612 endif()
 613
 614 set(Boost_USE_MULTITHREADED ON)
 615 # require minimally the bundled version
 616 if(WITH_SYSTEM_BOOST)
 617   if(ENABLE_SHARED)
 618     set(Boost_USE_STATIC_LIBS OFF)
 619   else()
 620     set(Boost_USE_STATIC_LIBS ON)
 621   endif()
 622   if(BOOST_ROOT AND CMAKE_LIBRARY_ARCHITECTURE)
 623     set(BOOST_LIBRARYDIR "${BOOST_ROOT}/lib/${CMAKE_LIBRARY_ARCHITECTURE}")
 624   endif()
 625   find_package(Boost 1.73 COMPONENTS ${BOOST_COMPONENTS} REQUIRED)
 626   if(NOT ENABLE_SHARED)
 627     set_property(TARGET Boost::iostreams APPEND PROPERTY
 628       INTERFACE_LINK_LIBRARIES ZLIB::ZLIB)
 629   endif()
 630 else()
 631   set(BOOST_J 1 CACHE STRING
 632     "max jobs for Boost build") # override w/-DBOOST_J=<n>
 633   set(Boost_USE_STATIC_LIBS ON)
 634   include(BuildBoost)
 635   build_boost(1.75
 636     COMPONENTS ${BOOST_COMPONENTS} ${BOOST_HEADER_COMPONENTS})
 637 endif()
 638 include_directories(BEFORE SYSTEM ${Boost_INCLUDE_DIRS})
 639
 640 # dashboard angular2 frontend
 641 option(WITH_MGR_DASHBOARD_FRONTEND "Build the mgr/dashboard frontend using `npm`" ON)
 642 option(WITH_SYSTEM_NPM "Assume that dashboard build tools already installed through packages" OFF)
 643 if(WITH_SYSTEM_NPM)
 644   find_program(NPM_EXECUTABLE npm)
 645   if(NOT NPM_EXECUTABLE)
 646     message(FATAL_ERROR "Can't find npm.")
 647   endif()
 648 endif()
 649 set(DASHBOARD_FRONTEND_LANGS "" CACHE STRING
 650   "List of comma separated ceph-dashboard frontend languages to build. \
 651   Use value `ALL` to build all languages")
 652 CMAKE_DEPENDENT_OPTION(WITH_MGR_ROOK_CLIENT "Enable the mgr's Rook support" ON
 653   "WITH_MGR" OFF)
 654
 655 include_directories(SYSTEM ${PROJECT_BINARY_DIR}/include)
 656
 657 find_package(Threads REQUIRED)
 658 find_package(StdFilesystem REQUIRED)
 659
 660 option(WITH_SELINUX "build SELinux policy" OFF)
 661 if(WITH_SELINUX)
 662   find_file(SELINUX_MAKEFILE selinux/devel/Makefile
 663     PATH /usr/share)
 664   if(NOT SELINUX_MAKEFILE)
 665     message(FATAL_ERROR "Can't find selinux's Makefile")
 666   endif()
 667   add_subdirectory(selinux)
 668 endif(WITH_SELINUX)
 669
 670 # enables testing and creates Make check command
 671 add_custom_target(tests
 672   COMMENT "Building tests")
 673 enable_testing()
 674 set(CMAKE_CTEST_COMMAND ctest)
 675 add_custom_target(check
 676   COMMAND ${CMAKE_CTEST_COMMAND}
 677   DEPENDS tests)
 678
 679 option(WITH_SYSTEMD "build with systemd support" ON)
 680
 681 add_subdirectory(src)
 682
 683 add_subdirectory(qa)
 684 add_subdirectory(doc)
 685 if(WITH_MANPAGE)
 686   add_subdirectory(man)
 687 endif(WITH_MANPAGE)
 688
 689 if(WITH_SYSTEMD)
 690   add_subdirectory(systemd)
 691 endif()
 692
 693 if(LINUX)
 694   add_subdirectory(etc/sysctl)
 695 endif()
 696
 697 option(WITH_GRAFANA "install grafana dashboards" OFF)
 698 add_subdirectory(monitoring/ceph-mixin)
 699
 700 CMAKE_DEPENDENT_OPTION(WITH_BOOST_VALGRIND "Boost support for valgrind" OFF
 701   "NOT WITH_SYSTEM_BOOST" OFF)
 702
 703 include(CTags)
 704 option(CTAG_EXCLUDES "Exclude files/directories when running ctag.")
 705 add_tags(ctags
 706   SRC_DIR src
 707   TAG_FILE tags
 708   EXCLUDE_OPTS ${CTAG_EXCLUDES}
 709   EXCLUDES "*.js" "*.css" ".tox" "python-common/build")
 710 add_custom_target(tags DEPENDS ctags)