ceph/CMakeLists.txt

   1 cmake_minimum_required(VERSION 2.8.11)
   2
   3 project(ceph)
   4 set(VERSION 12.1.0)
   5
   6 if(POLICY CMP0046)
   7   # Tweak policies (this one disables "missing" dependency warning)
   8   cmake_policy(SET CMP0046 OLD)
   9 endif()
  10 # we use LINK_PRIVATE keyword instead of PRIVATE, but do not specify the LINK_PUBLIC
  11 # for target_link_libraries() command when PUBLIC should be used instead, it's just
  12 # for backward compatibility with cmake 2.8.11.
  13 if (POLICY CMP0022)
  14 cmake_policy(SET CMP0022 OLD)
  15 endif (POLICY CMP0022)
  16 if (POLICY CMP0023)
  17 cmake_policy(SET CMP0023 OLD)
  18 endif (POLICY CMP0023)
  19 if(POLICY CMP0056)
  20   cmake_policy(SET CMP0056 NEW)
  21 endif()
  22 if(POLICY CMP0065)
  23   cmake_policy(SET CMP0065 NEW)
  24 endif()
  25 if(POLICY CMP0051)
  26   # cmake 3.1 and higher include generator expressions in SOURCES property.
  27   # in BuildBoost.cmake, get_target_property(<var> <target> SOURCES) is used
  28   # to retrieve the source files of a target. in that case, we are only
  29   # interested in the *source* files. and i don't want to bother stripping off
  30   # the TARGET_OBJECTS elements from the returned SOURCES. so let's stick with
  31   # the old behavior now.
  32   cmake_policy(SET CMP0051 OLD)
  33 endif()
  34 list(APPEND CMAKE_MODULE_PATH "${CMAKE_SOURCE_DIR}/cmake/modules/")
  35
  36 if(CMAKE_SYSTEM_NAME MATCHES "Linux")
  37   set(LINUX ON)
  38   FIND_PACKAGE(Threads)
  39 elseif(CMAKE_SYSTEM_NAME MATCHES "FreeBSD")
  40   set(FREEBSD ON)
  41   FIND_PACKAGE(Threads)
  42 elseif(APPLE)
  43   set(OperatingSystem "Mac OS X")
  44 else()
  45   message(STATUS "No systemtype selected for building")
  46 endif(CMAKE_SYSTEM_NAME MATCHES "Linux")
  47
  48 option(WITH_CCACHE "Build with ccache.")
  49 if(WITH_CCACHE)
  50   find_program(CCACHE_FOUND ccache)
  51   if(CCACHE_FOUND)
  52     message(STATUS "Building with ccache: ${CCACHE_FOUND}, CCACHE_DIR=$ENV{CCACHE_DIR}")
  53     set_property(GLOBAL PROPERTY RULE_LAUNCH_COMPILE ccache)
  54     # ccache does not accelerate link (ld), but let it handle it. by passing it
  55     # along with cc to python's distutils, we are able to workaround
  56     # https://bugs.python.org/issue8027.
  57     set_property(GLOBAL PROPERTY RULE_LAUNCH_LINK ccache)
  58   else(CCACHE_FOUND)
  59     message(FATAL_ERROR "Can't find ccache. Is it installed?")
  60   endif(CCACHE_FOUND)
  61 endif(WITH_CCACHE)
  62
  63 option(WITH_MANPAGE "Build man pages." ON)
  64 if(WITH_MANPAGE)
  65   find_program(SPHINX_BUILD
  66     sphinx-build)
  67   if(NOT SPHINX_BUILD)
  68     message(FATAL_ERROR "Can't find sphinx-build.")
  69   endif(NOT SPHINX_BUILD)
  70 endif(WITH_MANPAGE)
  71
  72 include_directories(
  73   ${PROJECT_BINARY_DIR}/src/include
  74   ${PROJECT_SOURCE_DIR}/src)
  75
  76 if(OFED_PREFIX)
  77   include_directories(${OFED_PREFIX}/include)
  78   link_directories(${OFED_PREFIX}/lib)
  79 endif()
  80
  81 if(FREEBSD)
  82   include_directories(/usr/local/include)
  83   link_directories(/usr/local/lib)
  84   list(APPEND CMAKE_REQUIRED_INCLUDES /usr/local/include)
  85 endif(FREEBSD)
  86
  87 #Check Includes
  88 include(CheckIncludeFiles)
  89 include(CheckIncludeFileCXX)
  90 include(CheckFunctionExists)
  91
  92 #put all the libs and binaries in one place
  93 set(CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib)
  94 set(CMAKE_LIBRARY_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib)
  95 set(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/bin)
  96
  97
  98 CHECK_FUNCTION_EXISTS(fallocate CEPH_HAVE_FALLOCATE)
  99 CHECK_FUNCTION_EXISTS(posix_fadvise HAVE_POSIX_FADVISE)
 100 CHECK_FUNCTION_EXISTS(posix_fallocate HAVE_POSIX_FALLOCATE)
 101 CHECK_FUNCTION_EXISTS(syncfs HAVE_SYS_SYNCFS)
 102 CHECK_FUNCTION_EXISTS(sync_file_range HAVE_SYNC_FILE_RANGE)
 103 CHECK_FUNCTION_EXISTS(pwritev HAVE_PWRITEV)
 104 CHECK_FUNCTION_EXISTS(splice CEPH_HAVE_SPLICE)
 105 CHECK_FUNCTION_EXISTS(getgrouplist HAVE_GETGROUPLIST)
 106 CHECK_FUNCTION_EXISTS(fdatasync HAVE_FDATASYNC)
 107 CHECK_FUNCTION_EXISTS(strerror_r HAVE_STRERROR_R)
 108 CHECK_FUNCTION_EXISTS(name_to_handle_at HAVE_NAME_TO_HANDLE_AT)
 109 CHECK_FUNCTION_EXISTS(pipe2 HAVE_PIPE2)
 110 set(CMAKE_REQUIRED_LIBRARIES pthread)
 111 CHECK_FUNCTION_EXISTS(pthread_spin_init HAVE_PTHREAD_SPINLOCK)
 112 CHECK_FUNCTION_EXISTS(pthread_set_name_np HAVE_PTHREAD_SET_NAME_NP)
 113 CHECK_FUNCTION_EXISTS(pthread_setname_np HAVE_PTHREAD_SETNAME_NP)
 114 CHECK_FUNCTION_EXISTS(pthread_getname_np HAVE_PTHREAD_GETNAME_NP)
 115 CHECK_FUNCTION_EXISTS(eventfd HAVE_EVENTFD)
 116 CHECK_FUNCTION_EXISTS(getprogname HAVE_GETPROGNAME)
 117
 118 CHECK_INCLUDE_FILES("linux/types.h" HAVE_LINUX_TYPES_H)
 119 CHECK_INCLUDE_FILES("linux/version.h" HAVE_LINUX_VERSION_H)
 120 CHECK_INCLUDE_FILES("arpa/nameser_compat.h" HAVE_ARPA_NAMESER_COMPAT_H)
 121 CHECK_INCLUDE_FILES("sys/mount.h" HAVE_SYS_MOUNT_H)
 122 CHECK_INCLUDE_FILES("sys/param.h" HAVE_SYS_PARAM_H)
 123 CHECK_INCLUDE_FILES("sys/types.h" HAVE_SYS_TYPES_H)
 124 CHECK_INCLUDE_FILES("sys/vfs.h" HAVE_SYS_VFS_H)
 125 CHECK_INCLUDE_FILES("sys/prctl.h" HAVE_SYS_PRCTL_H)
 126 CHECK_INCLUDE_FILES("execinfo.h" HAVE_EXECINFO_H)
 127 if(LINUX)
 128   CHECK_INCLUDE_FILES("sched.h" HAVE_SCHED)
 129 endif(LINUX)
 130 CHECK_INCLUDE_FILES("valgrind/helgrind.h" HAVE_VALGRIND_HELGRIND_H)
 131
 132 include(CheckTypeSize)
 133 set(CMAKE_EXTRA_INCLUDE_FILES "linux/types.h")
 134 CHECK_TYPE_SIZE(__be16 __BE16)
 135 CHECK_TYPE_SIZE(__be32 __BE32)
 136 CHECK_TYPE_SIZE(__be64 __BE64)
 137 CHECK_TYPE_SIZE(__le16 __LE16)
 138 CHECK_TYPE_SIZE(__le32 __LE32)
 139 CHECK_TYPE_SIZE(__le64 __LE64)
 140 CHECK_TYPE_SIZE(__u8 __U8)
 141 CHECK_TYPE_SIZE(__u16 __U16)
 142 CHECK_TYPE_SIZE(__u32 __U32)
 143 CHECK_TYPE_SIZE(__u64 __U64)
 144 CHECK_TYPE_SIZE(__s8 __S8)
 145 CHECK_TYPE_SIZE(__s16 __S16)
 146 CHECK_TYPE_SIZE(__s32 __S32)
 147 CHECK_TYPE_SIZE(__s64 __S64)
 148 unset(CMAKE_EXTRA_INCLUDE_FILES)
 149
 150 include(CheckSymbolExists)
 151 CHECK_SYMBOL_EXISTS(res_nquery "resolv.h" HAVE_RES_NQUERY)
 152 CHECK_SYMBOL_EXISTS(F_SETPIPE_SZ "linux/fcntl.h" CEPH_HAVE_SETPIPE_SZ)
 153 CHECK_SYMBOL_EXISTS(__func__ "" HAVE_FUNC)
 154 CHECK_SYMBOL_EXISTS(__PRETTY_FUNCTION__ "" HAVE_PRETTY_FUNC)
 155
 156 include(CheckCXXSourceCompiles)
 157 CHECK_CXX_SOURCE_COMPILES("
 158   #include <string.h>
 159   int main() { char x = *strerror_r(0, &x, sizeof(x)); return 0; }
 160   " STRERROR_R_CHAR_P)
 161
 162 include(CheckStructHasMember)
 163 CHECK_STRUCT_HAS_MEMBER("struct stat" st_mtim.tv_nsec sys/stat.h
 164   HAVE_STAT_ST_MTIM_TV_NSEC LANGUAGE C)
 165 CHECK_STRUCT_HAS_MEMBER("struct stat" st_mtimespec.tv_nsec sys/stat.h
 166   HAVE_STAT_ST_MTIMESPEC_TV_NSEC LANGUAGE C)
 167
 168 set(CEPH_MAN_DIR "share/man" CACHE STRING "Install location for man pages (relative to prefix).")
 169
 170 option(ENABLE_SHARED "build shared libraries" ON)
 171 if(ENABLE_SHARED)
 172   set(CEPH_SHARED SHARED)
 173 else(ENABLE_SHARED)
 174   set(CEPH_SHARED STATIC)
 175 endif(ENABLE_SHARED)
 176 set(CMAKE_POSITION_INDEPENDENT_CODE ${ENABLE_SHARED})
 177
 178 option(WITH_RDMA "Enable RDMA in async messenger" ON)
 179 if(WITH_RDMA)
 180   find_package(rdma REQUIRED)
 181   set(HAVE_RDMA ${RDMA_FOUND})
 182 endif(WITH_RDMA)
 183
 184 find_package(Backtrace)
 185
 186 if(LINUX)
 187   find_package(udev REQUIRED)
 188   set(HAVE_UDEV ${UDEV_FOUND})
 189
 190   find_package(aio REQUIRED)
 191   set(HAVE_LIBAIO ${AIO_FOUND})
 192
 193   find_package(blkid REQUIRED)
 194   set(HAVE_BLKID ${BLKID_FOUND})
 195 else()
 196   set(HAVE_UDEV OFF)
 197   message(STATUS "Not using udev")
 198   set(HAVE_LIBAIO OFF)
 199   message(STATUS "Not using AIO")
 200   set(HAVE_BLKID OFF)
 201   message(STATUS "Not using BLKID")
 202 endif(LINUX)
 203
 204 option(WITH_OPENLDAP "OPENLDAP is here" ON)
 205 if(${WITH_OPENLDAP})
 206 find_package(OpenLdap REQUIRED)
 207 set(HAVE_OPENLDAP ${OPENLDAP_FOUND})
 208 endif(${WITH_OPENLDAP})
 209
 210 option(WITH_FUSE "Fuse is here" ON)
 211 if(${WITH_FUSE})
 212 find_package(fuse)
 213 set(HAVE_LIBFUSE ${FUSE_FOUND})
 214 endif(${WITH_FUSE})
 215
 216 option(WITH_XFS "XFS is here" ON)
 217 if(${WITH_XFS})
 218 find_package(xfs)
 219 set(HAVE_LIBXFS ${XFS_FOUND})
 220 endif(${WITH_XFS})
 221
 222 option(WITH_SPDK "Enable SPDK" OFF)
 223 if(WITH_SPDK)
 224   find_package(dpdk REQUIRED)
 225   set(HAVE_SPDK TRUE)
 226 endif(WITH_SPDK)
 227
 228 option(WITH_PMEM "Enable PMEM" OFF)
 229 if(WITH_PMEM)
 230   find_package(pmem REQUIRED)
 231   set(HAVE_PMEM ${PMEM_FOUND})
 232 endif(WITH_PMEM)
 233
 234 # needs mds and? XXX
 235 option(WITH_LIBCEPHFS "libcephfs client library" ON)
 236
 237 # key-value store
 238 option(WITH_KVS "Key value store is here" ON)
 239
 240 # remote block storage
 241 option(WITH_RBD "Remote block storage is here" ON)
 242
 243 # KERNEL remote block storage
 244 option(WITH_KRBD "Kernel Remote block storage is here" ON)
 245
 246 if(WITH_KRBD AND WITHOUT_RBD)
 247   message(FATAL_ERROR "Cannot have WITH_KRBD with WITH_RBD.")
 248 endif()
 249
 250 # embedded ceph daemon static library
 251 # NOTE: Ceph is mostly LGPL (see COPYING), which means that
 252 # static linking brings with it restrictions. Please be sure
 253 # to look at the LGPL license carefully before linking this library to
 254 # your code. See http://www.gnu.org/licenses/gpl-faq.html#LGPLStaticVsDynamic.
 255 option(WITH_EMBEDDED "build the embedded ceph daemon library" ON)
 256
 257 option(WITH_LEVELDB "LevelDB is here" ON)
 258 if(WITH_LEVELDB)
 259   if(LEVELDB_PREFIX)
 260     include_directories(${LEVELDB_PREFIX}/include)
 261     link_directories(${LEVELDB_PREFIX}/lib)
 262   endif()
 263   find_package(leveldb REQUIRED)
 264   find_file(HAVE_LEVELDB_FILTER_POLICY leveldb/filter_policy.h PATHS ${LEVELDB_INCLUDE_DIR})
 265 endif(WITH_LEVELDB)
 266
 267 find_package(snappy REQUIRED)
 268
 269 option(WITH_LZ4 "LZ4 compression support" OFF)
 270 if(WITH_LZ4)
 271   find_package(LZ4 REQUIRED)
 272   set(HAVE_LZ4 ${LZ4_FOUND})
 273 endif(WITH_LZ4)
 274
 275 #if allocator is set on command line make sure it matches below strings
 276 if(ALLOCATOR)
 277   if(${ALLOCATOR} MATCHES "tcmalloc(_minimal)?")
 278     find_package(gperftools REQUIRED)
 279     set(HAVE_LIBTCMALLOC ON)
 280   elseif(${ALLOCATOR} STREQUAL "jemalloc")
 281     find_package(JeMalloc REQUIRED)
 282     set(HAVE_LIBJEMALLOC ${JEMALLOC_FOUND})
 283     set(HAVE_JEMALLOC 1)
 284   endif()
 285 else(ALLOCATOR)
 286   find_package(gperftools)
 287   set(HAVE_LIBTCMALLOC ${GPERFTOOLS_FOUND})
 288   if(NOT GPERFTOOLS_FOUND)
 289     find_package(JeMalloc)
 290     set(HAVE_LIBJEMALLOC ${JEMALLOC_FOUND})
 291   endif(NOT GPERFTOOLS_FOUND)
 292   if(GPERFTOOLS_FOUND)
 293     set(ALLOCATOR tcmalloc)
 294   elseif(JEMALLOC_FOUND)
 295     set(ALLOCATOR jemalloc)
 296   else()
 297     if(NOT FREEBSD)
 298       # FreeBSD already has jemalloc as its default allocator
 299       message(WARNING "tcmalloc and jemalloc not found, falling back to libc")
 300     endif()
 301     set(ALLOCATOR "libc")
 302   endif(GPERFTOOLS_FOUND)
 303 endif(ALLOCATOR)
 304
 305
 306 if(WITH_LIBCEPHFS OR WITH_KRBD)
 307   find_package(keyutils REQUIRED)
 308 endif()
 309
 310 find_package(CURL REQUIRED)
 311 set(CMAKE_REQUIRED_INCLUDES ${CURL_INCLUDE_DIRS})
 312 set(CMAKE_REQUIRED_LIBRARIES ${CURL_LIBRARIES})
 313 CHECK_SYMBOL_EXISTS(curl_multi_wait curl/curl.h HAVE_CURL_MULTI_WAIT)
 314
 315 # nss or cryptopp?
 316 option(WITH_NSS "Use NSS crypto and SSL implementations" ON)
 317 if (${WITH_NSS})
 318   find_package(NSS REQUIRED)
 319     set(USE_NSS 1)
 320     find_package(NSPR REQUIRED)
 321     set(CRYPTO_LIBS ${NSS_LIBRARIES} ${NSPR_LIBRARIES})
 322 else ()
 323   find_package(cryptopp REQUIRED)
 324     set(CRYPTO_LIBS ${CRYPTOPP_LIBRARIES})
 325     set(USE_CRYPTOPP 1)
 326 endif (${WITH_NSS})
 327
 328 option(WITH_SSL "SSL build selected" ON)
 329 if(USE_NSS)
 330   #nss
 331   set(SSL_LIBRARIES ${NSS_LIBRARIES})
 332   message(STATUS "SSL with NSS selected (Libs: ${SSL_LIBRARIES})")
 333 else(USE_NSS)
 334   #openssl
 335   find_package(OpenSSL REQUIRED)
 336   set(USE_OPENSSL ON)
 337   set(SSL_LIBRARIES ${OPENSSL_LIBRARIES})
 338   message(STATUS "SSL with OpenSSL selected (Libs: ${SSL_LIBRARIES})")
 339 endif(USE_NSS)
 340
 341 option(WITH_XIO "Enable XIO messaging" OFF)
 342 if(WITH_XIO)
 343   find_package(xio REQUIRED)
 344 set(HAVE_XIO ${XIO_FOUND})
 345 endif(WITH_XIO)
 346
 347 option(WITH_DPDK "Enable DPDK messaging" OFF)
 348 if(WITH_DPDK)
 349 find_package(dpdk)
 350 set(HAVE_DPDK ${DPDK_FOUND})
 351 endif(WITH_DPDK)
 352
 353 option(WITH_BLKIN "Use blkin to emit LTTng tracepoints for Zipkin" OFF)
 354 if(WITH_BLKIN)
 355   set(BLKIN_LIBRARIES blkin lttng-ust)
 356   include_directories(src/blkin/blkin-lib)
 357 endif(WITH_BLKIN)
 358
 359 #option for RGW
 360 option(WITH_RADOSGW "Rados Gateway is enabled" ON)
 361 option(WITH_RADOSGW_FCGI_FRONTEND "Rados Gateway's FCGI frontend is enabled" OFF)
 362 option(WITH_RADOSGW_BEAST_FRONTEND "Rados Gateway's Beast frontend is enabled" ON)
 363 if(WITH_RADOSGW)
 364   find_package(EXPAT REQUIRED)
 365   if(WITH_RADOSGW_FCGI_FRONTEND)
 366     find_package(fcgi REQUIRED)
 367   endif()
 368 endif(WITH_RADOSGW)
 369
 370
 371 if (WITH_RADOSGW)
 372   if (NOT DEFINED OPENSSL_FOUND)
 373     message(STATUS "Looking for openssl anyways, because radosgw selected")
 374     find_package(OpenSSL)
 375   endif()
 376   if (OPENSSL_FOUND)
 377     execute_process(
 378       COMMAND
 379         "sh" "-c"
 380         "objdump -p ${OPENSSL_SSL_LIBRARY} | sed -n 's/^  SONAME  *//p'"
 381       OUTPUT_VARIABLE LIBSSL_SONAME
 382       ERROR_VARIABLE OBJDUMP_ERRORS
 383       RESULT_VARIABLE OBJDUMP_RESULTS
 384       OUTPUT_STRIP_TRAILING_WHITESPACE)
 385     if (OBJDUMP_RESULTS)
 386       message(FATAL_ERROR "can't run objdump: ${OBJDUMP_RESULTS}")
 387     endif()
 388     if (NOT OBJDUMP_ERRORS STREQUAL "")
 389       message(WARNING "message from objdump: ${OBJDUMP_ERRORS}")
 390     endif()
 391     execute_process(
 392       COMMAND
 393         "sh" "-c"
 394         "objdump -p ${OPENSSL_CRYPTO_LIBRARY} | sed -n 's/^  SONAME  *//p'"
 395       OUTPUT_VARIABLE LIBCRYPTO_SONAME
 396       ERROR_VARIABLE OBJDUMP_ERRORS
 397       RESULT_VARIABLE OBJDUMP_RESULTS
 398       OUTPUT_STRIP_TRAILING_WHITESPACE)
 399     if (OBJDUMP_RESULTS)
 400       message(FATAL_ERROR "can't run objdump: ${OBJDUMP_RESULTS}")
 401     endif()
 402     if (NOT OBJDUMP_ERRORS STREQUAL "")
 403       message(WARNING "message from objdump: ${OBJDUMP_ERRORS}")
 404     endif()
 405     message(STATUS "ssl soname: ${LIBSSL_SONAME}")
 406     message(STATUS "crypto soname: ${LIBCRYPTO_SONAME}")
 407   else()
 408     message(WARNING "ssl not found: rgw civetweb may fail to dlopen libssl libcrypto")
 409   endif()
 410 endif (WITH_RADOSGW)
 411
 412 #option for CephFS
 413 option(WITH_CEPHFS "CephFS is enabled" ON)
 414
 415 #option for Mgr
 416 option(WITH_MGR "ceph-mgr is enabled" ON)
 417 if(WITH_MGR)
 418     set(Python_ADDITIONAL_VERSIONS 2.7)
 419     find_package(PythonInterp 2.7 REQUIRED)
 420     find_package(PythonLibs 2.7 REQUIRED)
 421     # Boost dependency check deferred to Boost section
 422 endif(WITH_MGR)
 423
 424 option(WITH_THREAD_SAFE_RES_QUERY "res_query is thread safe" OFF)
 425 if(WITH_THREAD_SAFE_RES_QUERY)
 426     set(HAVE_THREAD_SAFE_RES_QUERY 1 CACHE INTERNAL "Thread safe res_query supported.")
 427 endif(WITH_THREAD_SAFE_RES_QUERY)
 428
 429 option(WITH_REENTRANT_STRSIGNAL "strsignal is reentrant" OFF)
 430 if(WITH_REENTRANT_STRSIGNAL)
 431     set(HAVE_REENTRANT_STRSIGNAL 1 CACHE INTERNAL "Reentrant strsignal is supported.")
 432 endif(WITH_REENTRANT_STRSIGNAL)
 433
 434 set(HAVE_LIBROCKSDB 1)
 435
 436 # -lz link into kv
 437 find_package(ZLIB REQUIRED)
 438
 439 #option for EventTrace
 440 option(WITH_EVENTTRACE "Event tracing support" OFF)
 441
 442 #option for LTTng
 443 option(WITH_LTTNG "LTTng tracing is enabled" ON)
 444 if(${WITH_LTTNG})
 445   find_package(LTTngUST REQUIRED)
 446   find_program(LTTNG_GEN_TP
 447     lttng-gen-tp)
 448   if(NOT LTTNG_GEN_TP)
 449     message(FATAL_ERROR "Can't find lttng-gen-tp.")
 450   endif()
 451 endif(${WITH_LTTNG})
 452
 453 option(WITH_OSD_INSTRUMENT_FUNCTIONS OFF)
 454
 455 #option for Babeltrace
 456 option(HAVE_BABELTRACE "Babeltrace libraries are enabled" ON)
 457 if(${HAVE_BABELTRACE})
 458   find_package(babeltrace REQUIRED)
 459   set(WITH_BABELTRACE ${BABELTRACE_FOUND})
 460   set(HAVE_BABELTRACE_BABELTRACE_H ${BABELTRACE_FOUND})
 461   set(HAVE_BABELTRACE_CTF_EVENTS_H ${BABELTRACE_FOUND})
 462   set(HAVE_BABELTRACE_CTF_ITERATOR_H ${BABELTRACE_FOUND})
 463 endif(${HAVE_BABELTRACE})
 464
 465 option(DEBUG_GATHER "C_Gather debugging is enabled" ON)
 466 option(HAVE_LIBZFS "LibZFS is enabled" OFF)
 467 option(ENABLE_COVERAGE "Coverage is enabled" OFF)
 468 option(PG_DEBUG_REFS "PG Ref debugging is enabled" OFF)
 469
 470 option(WITH_TESTS "enable the build of ceph-test package scripts/binaries" ON)
 471
 472 option(WITH_FIO "Support for fio engines" OFF)
 473 if(WITH_FIO)
 474   find_package(fio REQUIRED)
 475 endif(WITH_FIO)
 476
 477 if(LINUX)
 478   add_definitions(-D__linux__)
 479 endif(LINUX)
 480
 481 # ASAN and friends
 482 option(WITH_ASAN "build with ASAN" OFF)
 483 option(WITH_ASAN_LEAK "explicitly enable ASAN leak detection" OFF)
 484
 485 if(WITH_ASAN)
 486   set(ASAN_CFLAGS "-fsanitize=address -fno-omit-frame-pointer")
 487   if(WITH_ASAN_LEAK)
 488     set(ASAN_CFLAGS "${ASAN_CFLAGS} -fsanitize=leak")
 489   endif()
 490   set(ASAN_LFLAGS "${CMAKE_EXE_LINKER_FLAGS} ${ASAN_CFLAGS} -lasan")
 491   set(CMAKE_EXE_LINKER_FLAGS "${ASAN_LFLAGS}")
 492   set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${ASAN_CFLAGS}")
 493   set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} ${ASAN_CFLAGS}")
 494   if(HAVE_JEMALLOC)
 495     message(FATAL "ASAN does not work well with JeMalloc")
 496   endif()
 497 endif()
 498
 499 option(WITH_TSAN "build with TSAN" OFF)
 500 if(WITH_TSAN)
 501   if (WITH_ASAN AND WITH_ASAN_LEAK)
 502     message(FATAL_ERROR "Cannot combine -fsanitize-leak w/-fsanitize-thread")
 503   endif()
 504   set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -fsanitize=thread -fno-omit-frame-pointer -pie -ltsan ")
 505   set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -fsanitize=thread -fno-omit-frame-pointer -fPIC")
 506   set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -fsanitize=thread -fno-omit-frame-pointer -fPIC")
 507   if(HAVE_JEMALLOC)
 508     message(FATAL "TSAN does not work well with JeMalloc")
 509   endif()
 510 endif()
 511
 512 option(WITH_UBSAN "build with UBSAN" OFF)
 513 if(WITH_UBSAN)
 514   set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -fsanitize=undefined")
 515   set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -fsanitize=undefined")
 516   set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -fsanitize=undefined")
 517   if(HAVE_JEMALLOC)
 518     message(FATAL "UBSAN does not work well with JeMalloc")
 519   endif()
 520 endif()
 521
 522 # Rocksdb
 523 option(WITH_SYSTEM_ROCKSDB "require and build with system rocksdb" OFF)
 524 if (WITH_SYSTEM_ROCKSDB)
 525   find_package(rocksdb REQUIRED)
 526 endif()
 527
 528 # Boost
 529 option(WITH_SYSTEM_BOOST "require and build with system Boost" OFF)
 530
 531 # Boost::thread depends on Boost::atomic, so list it explicitly.
 532 set(BOOST_COMPONENTS
 533   atomic thread system regex random program_options date_time iostreams
 534   filesystem)
 535 set(BOOST_HEADER_COMPONENTS container)
 536
 537 if(WITH_MGR)
 538         list(APPEND BOOST_COMPONENTS python)
 539 endif()
 540
 541 if(WITH_RADOSGW_BEAST_FRONTEND)
 542         list(APPEND BOOST_COMPONENTS coroutine context)
 543 endif()
 544
 545 set(Boost_USE_MULTITHREADED ON)
 546 # require minimally the bundled version
 547 if(WITH_SYSTEM_BOOST)
 548   if(ENABLE_SHARED)
 549     set(Boost_USE_STATIC_LIBS OFF)
 550   else()
 551     set(Boost_USE_STATIC_LIBS ON)
 552   endif()
 553   find_package(Boost 1.61 COMPONENTS ${BOOST_COMPONENTS} REQUIRED)
 554 else()
 555   set(BOOST_J 1 CACHE STRING
 556     "max jobs for Boost build") # override w/-DBOOST_J=<n>
 557   set(Boost_USE_STATIC_LIBS ON)
 558   include(BuildBoost)
 559   build_boost(1.63
 560     COMPONENTS ${BOOST_COMPONENTS} ${BOOST_HEADER_COMPONENTS})
 561   include_directories(BEFORE SYSTEM ${Boost_INCLUDE_DIRS})
 562 endif()
 563 set(Boost_USE_MULTITHREADED ON)
 564
 565 include_directories(SYSTEM ${PROJECT_BINARY_DIR}/include)
 566
 567 find_package(Threads REQUIRED)
 568
 569 option(WITH_SELINUX "build SELinux policy" OFF)
 570 if(WITH_SELINUX)
 571   find_file(SELINUX_MAKEFILE selinux/devel/Makefile
 572     PATH /usr/share)
 573   if(NOT SELINUX_MAKEFILE)
 574     message(FATAL_ERROR "Can't find selinux's Makefile")
 575   endif()
 576   add_subdirectory(selinux)
 577 endif(WITH_SELINUX)
 578
 579 # enables testing and creates Make check command
 580 add_custom_target(tests
 581   COMMENT "Building tests")
 582 enable_testing()
 583 set(CMAKE_CTEST_COMMAND ctest)
 584 add_custom_target(check
 585   COMMAND ${CMAKE_CTEST_COMMAND}
 586   DEPENDS tests)
 587
 588 add_subdirectory(src)
 589
 590 add_subdirectory(doc)
 591 if(WITH_MANPAGE)
 592   add_subdirectory(man)
 593 endif(WITH_MANPAGE)
 594
 595 option(WITH_SYSTEMD "install systemd target and service files" OFF)
 596 if(WITH_SYSTEMD)
 597   add_subdirectory(systemd)
 598 endif()
 599
 600 include(CTags)
 601 option(CTAG_EXCLUDES "Exclude files/directories when running ctag.")
 602 add_tags(ctags
 603   SRC_DIR src
 604   TAG_FILE tags
 605   EXCLUDE_OPTS ${CTAG_EXCLUDES}
 606   EXCLUDES "*.js" "*.css")
 607 add_custom_target(tags DEPENDS ctags)