ceph/src/rgw/CMakeLists.txt

   1 add_custom_target(civetweb_h
   2   COMMAND ${CMAKE_COMMAND} -E make_directory
   3   "${CMAKE_BINARY_DIR}/src/include/civetweb"
   4   COMMAND ${CMAKE_COMMAND} -E copy_if_different
   5   "${CMAKE_SOURCE_DIR}/src/civetweb/include/civetweb.h"
   6   "${CMAKE_BINARY_DIR}/src/include/civetweb"
   7   COMMENT "keep civetweb.h up-to-date")
   8
   9 find_program(GPERF gperf)
  10 if(NOT GPERF)
  11   message(FATAL_ERROR "Can't find gperf")
  12 endif()
  13 function(gperf_generate input output)
  14   add_custom_command(
  15     OUTPUT ${output}
  16     COMMAND ${GPERF} ${input} | sed "s/register //g" > ${output}
  17     DEPENDS ${input}
  18     COMMENT "Generate ${output}"
  19     )
  20 endfunction()
  21
  22 set(librgw_common_srcs
  23   services/svc_finisher.cc
  24   services/svc_bi_rados.cc
  25   services/svc_bilog_rados.cc
  26   services/svc_bucket.cc
  27   services/svc_bucket_sobj.cc
  28   services/svc_bucket_sync_sobj.cc
  29   services/svc_cls.cc
  30   services/svc_config_key_rados.cc
  31   services/svc_datalog_rados.cc
  32   services/svc_mdlog.cc
  33   services/svc_meta.cc
  34   services/svc_meta_be.cc
  35   services/svc_meta_be_otp.cc
  36   services/svc_meta_be_sobj.cc
  37   services/svc_notify.cc
  38   services/svc_otp.cc
  39   services/svc_quota.cc
  40   services/svc_sync_modules.cc
  41   services/svc_rados.cc
  42   services/svc_sys_obj.cc
  43   services/svc_sys_obj_cache.cc
  44   services/svc_sys_obj_core.cc
  45   services/svc_tier_rados.cc
  46   services/svc_user.cc
  47   services/svc_user_rados.cc
  48   services/svc_zone.cc
  49   services/svc_zone_utils.cc
  50   rgw_service.cc
  51   rgw_acl.cc
  52   rgw_acl_s3.cc
  53   rgw_acl_swift.cc
  54   rgw_aio.cc
  55   rgw_aio_throttle.cc
  56   rgw_auth.cc
  57   rgw_auth_s3.cc
  58   rgw_arn.cc
  59   rgw_basic_types.cc
  60   rgw_bucket.cc
  61   rgw_bucket_sync.cc
  62   rgw_cache.cc
  63   rgw_common.cc
  64   rgw_compression.cc
  65   rgw_etag_verifier.cc
  66   rgw_cors.cc
  67   rgw_cors_s3.cc
  68   rgw_dencoder.cc
  69   rgw_env.cc
  70   rgw_es_query.cc
  71   rgw_formats.cc
  72   rgw_gc.cc
  73   rgw_gc_log.cc
  74   rgw_http_client.cc
  75   rgw_json_enc.cc
  76   rgw_keystone.cc
  77   rgw_ldap.cc
  78   rgw_lc.cc
  79   rgw_lc_s3.cc
  80   rgw_metadata.cc
  81   rgw_multi.cc
  82   rgw_multi_del.cc
  83   rgw_obj_manifest.cc
  84   rgw_pubsub.cc
  85   rgw_sync.cc
  86   rgw_data_sync.cc
  87   rgw_sync_counters.cc
  88   rgw_sync_module.cc
  89   rgw_sync_module_aws.cc
  90   rgw_sync_module_es.cc
  91   rgw_sync_module_es_rest.cc
  92   rgw_sync_module_log.cc
  93   rgw_sync_module_pubsub.cc
  94   rgw_sync_policy.cc
  95   rgw_pubsub_push.cc
  96   rgw_notify.cc
  97   rgw_notify_event_type.cc
  98   rgw_sync_module_pubsub_rest.cc
  99   rgw_sync_trace.cc
 100   rgw_trim_bilog.cc
 101   rgw_trim_datalog.cc
 102   rgw_trim_mdlog.cc
 103   rgw_period_history.cc
 104   rgw_period_puller.cc
 105   rgw_reshard.cc
 106   rgw_coroutine.cc
 107   rgw_cr_rados.cc
 108   rgw_cr_rest.cc
 109   rgw_cr_tools.cc
 110   rgw_object_expirer_core.cc
 111   rgw_op.cc
 112   rgw_otp.cc
 113   rgw_policy_s3.cc
 114   rgw_public_access.cc
 115   rgw_putobj.cc
 116   rgw_putobj_processor.cc
 117   rgw_quota.cc
 118   rgw_rados.cc
 119   rgw_resolve.cc
 120   rgw_rest.cc
 121   rgw_rest_client.cc
 122   rgw_rest_conn.cc
 123   rgw_rest_log.cc
 124   rgw_rest_metadata.cc
 125   rgw_rest_pubsub.cc
 126   rgw_rest_pubsub_common.cc
 127   rgw_rest_realm.cc
 128   rgw_rest_role.cc
 129   rgw_rest_s3.cc
 130   rgw_role.cc
 131   rgw_sal.cc
 132   rgw_string.cc
 133   rgw_tag.cc
 134   rgw_tag_s3.cc
 135   rgw_tools.cc
 136   rgw_user.cc
 137   rgw_website.cc
 138   rgw_xml.cc
 139   rgw_xml_enc.cc
 140   rgw_torrent.cc
 141   rgw_crypt.cc
 142   rgw_crypt_sanitize.cc
 143   rgw_iam_policy.cc
 144   rgw_rest_user_policy.cc
 145   rgw_zone.cc
 146   rgw_sts.cc
 147   rgw_rest_sts.cc
 148   rgw_perf_counters.cc
 149   rgw_rest_oidc_provider.cc
 150   rgw_rest_iam.cc
 151   rgw_object_lock.cc
 152   rgw_kms.cc
 153   rgw_url.cc
 154   rgw_oidc_provider)
 155
 156 if(WITH_RADOSGW_AMQP_ENDPOINT)
 157   list(APPEND librgw_common_srcs rgw_amqp.cc)
 158 endif()
 159 if(WITH_RADOSGW_KAFKA_ENDPOINT)
 160   list(APPEND librgw_common_srcs rgw_kafka.cc)
 161 endif()
 162
 163 add_library(rgw_common OBJECT ${librgw_common_srcs})
 164
 165 target_include_directories(rgw_common SYSTEM PUBLIC "services")
 166 target_include_directories(rgw_common PUBLIC "${CMAKE_SOURCE_DIR}/src/dmclock/support/src")
 167 target_include_directories(rgw_common PUBLIC "${CMAKE_SOURCE_DIR}/src/fmt/include")
 168 target_include_directories(rgw_common PUBLIC "${CMAKE_SOURCE_DIR}/src/rgw")
 169
 170 if(WITH_BOOST_CONTEXT)
 171   target_include_directories(rgw_common PRIVATE
 172     $<TARGET_PROPERTY:spawn,INTERFACE_INCLUDE_DIRECTORIES>)
 173 endif()
 174
 175 if(WITH_LTTNG)
 176   # rgw/rgw_op.cc includes "tracing/rgw_op.h"
 177   # rgw/rgw_rados.cc includes "tracing/rgw_rados.h"
 178   add_dependencies(rgw_common rgw_op-tp rgw_rados-tp)
 179 endif()
 180
 181 set(rgw_a_srcs
 182   rgw_auth_keystone.cc
 183   rgw_client_io.cc
 184   rgw_frontend.cc
 185   rgw_http_client_curl.cc
 186   rgw_loadgen.cc
 187   rgw_log.cc
 188   rgw_period_pusher.cc
 189   rgw_realm_reloader.cc
 190   rgw_realm_watcher.cc
 191   rgw_os_lib.cc
 192   rgw_process.cc
 193   rgw_rest_bucket.cc
 194   rgw_rest_config.cc
 195   rgw_rest_log.cc
 196   rgw_rest_metadata.cc
 197   rgw_rest_realm.cc
 198   rgw_rest_swift.cc
 199   rgw_rest_usage.cc
 200   rgw_rest_user.cc
 201   rgw_swift_auth.cc
 202   rgw_usage.cc
 203   rgw_opa.cc
 204   rgw_sts.cc
 205   rgw_rest_sts.cc)
 206
 207 gperf_generate(${CMAKE_SOURCE_DIR}/src/rgw/rgw_iam_policy_keywords.gperf
 208   rgw_iam_policy_keywords.frag.cc)
 209 set_source_files_properties(rgw_iam_policy.cc PROPERTIES
 210   OBJECT_DEPENDS ${CMAKE_BINARY_DIR}/src/rgw/rgw_iam_policy_keywords.frag.cc
 211   COMPILE_FLAGS -I${CMAKE_BINARY_DIR}/src/rgw)
 212
 213
 214 if (WITH_RADOSGW_FCGI_FRONTEND)
 215   list(APPEND rgw_a_srcs rgw_fcgi.cc)
 216 endif()
 217
 218 add_library(rgw_a STATIC
 219     ${rgw_a_srcs}
 220     $<TARGET_OBJECTS:rgw_common>)
 221
 222 add_dependencies(rgw_a civetweb_h)
 223
 224 target_compile_definitions(rgw_a PUBLIC "-DCLS_CLIENT_HIDE_IOCTX")
 225 target_include_directories(rgw_a PUBLIC "${CMAKE_SOURCE_DIR}/src/dmclock/support/src")
 226 target_include_directories(rgw_a SYSTEM PUBLIC "../rapidjson/include")
 227 target_include_directories(rgw_a SYSTEM PUBLIC "${CMAKE_SOURCE_DIR}/src/rgw")
 228
 229 if(WITH_RADOSGW_AMQP_ENDPOINT)
 230   find_package(RabbitMQ REQUIRED)
 231 endif()
 232 if(WITH_RADOSGW_KAFKA_ENDPOINT)
 233   find_package(RDKafka 0.9.2 REQUIRED)
 234 endif()
 235
 236 target_link_libraries(rgw_a
 237   PRIVATE
 238   librados cls_otp_client cls_lock_client cls_rgw_client cls_refcount_client
 239   cls_log_client cls_timeindex_client cls_version_client
 240   cls_user_client cls_rgw_gc_client ceph-common common_utf8 global
 241   ${CURL_LIBRARIES}
 242   ${EXPAT_LIBRARIES}
 243   ${OPENLDAP_LIBRARIES} ${CRYPTO_LIBS}
 244   OATH::OATH)
 245
 246 if(WITH_CURL_OPENSSL)
 247   # used by rgw_http_client_curl.cc
 248   target_link_libraries(rgw_a PRIVATE OpenSSL::Crypto)
 249 endif()
 250
 251 if(WITH_BOOST_CONTEXT)
 252   target_link_libraries(rgw_a PUBLIC spawn)
 253 endif()
 254
 255 set(rgw_libs rgw_a)
 256 if(WITH_RADOSGW_AMQP_ENDPOINT)
 257   # used by rgw_amqp.cc
 258   list(APPEND rgw_libs RabbitMQ::RabbitMQ)
 259 endif()
 260 if(WITH_RADOSGW_KAFKA_ENDPOINT)
 261   # used by rgw_kafka.cc
 262   list(APPEND rgw_libs RDKafka::RDKafka)
 263 endif()
 264
 265 set(rgw_schedulers_srcs
 266   rgw_dmclock_scheduler_ctx.cc
 267   rgw_dmclock_sync_scheduler.cc)
 268 set(radosgw_srcs
 269   rgw_loadgen_process.cc
 270   rgw_civetweb.cc
 271   rgw_civetweb_frontend.cc
 272   rgw_civetweb_log.cc)
 273 if (WITH_RADOSGW_FCGI_FRONTEND)
 274   list(APPEND radosgw_srcs rgw_fcgi_process.cc)
 275 endif()
 276
 277 if(WITH_RADOSGW_BEAST_FRONTEND)
 278   list(APPEND radosgw_srcs
 279     rgw_asio_client.cc
 280     rgw_asio_frontend.cc)
 281   list(APPEND rgw_schedulers_srcs
 282     rgw_dmclock_async_scheduler.cc)
 283 endif()
 284
 285 add_library(rgw_schedulers STATIC ${rgw_schedulers_srcs})
 286 target_link_libraries(rgw_schedulers
 287   PUBLIC dmclock::dmclock)
 288
 289 add_library(radosgw SHARED ${radosgw_srcs} ${rgw_a_srcs} rgw_main.cc
 290   $<TARGET_OBJECTS:civetweb_common_objs>)
 291
 292 add_dependencies(radosgw civetweb_h)
 293
 294 target_compile_definitions(radosgw PUBLIC "-DCLS_CLIENT_HIDE_IOCTX")
 295 target_include_directories(radosgw PUBLIC "${CMAKE_SOURCE_DIR}/src/dmclock/support/src")
 296 target_include_directories(radosgw SYSTEM PUBLIC "../rapidjson/include")
 297
 298 target_link_libraries(radosgw
 299   PRIVATE ${rgw_libs} rgw_schedulers
 300   PUBLIC dmclock::dmclock
 301 )
 302 if(WITH_RADOSGW_BEAST_FRONTEND)
 303   target_link_libraries(rgw_schedulers PUBLIC spawn)
 304   if(WITH_RADOSGW_BEAST_OPENSSL)
 305     # used by rgw_asio_frontend.cc
 306     target_link_libraries(radosgw PRIVATE OpenSSL::SSL)
 307   endif()
 308 endif()
 309 set_target_properties(radosgw PROPERTIES OUTPUT_NAME radosgw VERSION 2.0.0
 310   SOVERSION 2)
 311 install(TARGETS radosgw DESTINATION ${CMAKE_INSTALL_LIBDIR})
 312
 313 add_executable(radosgwd radosgw.cc)
 314 target_link_libraries(radosgwd radosgw librados
 315   cls_rgw_client cls_otp_client cls_lock_client cls_refcount_client
 316   cls_log_client cls_timeindex_client
 317   cls_version_client cls_user_client
 318   global
 319   ${FCGI_LIBRARY} ${LIB_RESOLV}
 320   ${CURL_LIBRARIES} ${EXPAT_LIBRARIES} ${BLKID_LIBRARIES}
 321   ${ALLOC_LIBS})
 322 set_target_properties(radosgwd PROPERTIES OUTPUT_NAME radosgw)
 323 install(TARGETS radosgwd DESTINATION bin)
 324
 325 set(radosgw_admin_srcs
 326   rgw_admin.cc
 327   rgw_orphan.cc)
 328 add_executable(radosgw-admin ${radosgw_admin_srcs})
 329 target_link_libraries(radosgw-admin ${rgw_libs} librados
 330   cls_rgw_client cls_otp_client cls_lock_client cls_refcount_client
 331   cls_log_client cls_timeindex_client
 332   cls_version_client cls_user_client
 333   global ${FCGI_LIBRARY} ${LIB_RESOLV}
 334   ${CURL_LIBRARIES} ${EXPAT_LIBRARIES} ${BLKID_LIBRARIES})
 335 install(TARGETS radosgw-admin DESTINATION bin)
 336
 337 set(radosgw_es_srcs
 338   rgw_es_main.cc)
 339 add_executable(radosgw-es ${radosgw_es_srcs})
 340 target_link_libraries(radosgw-es ${rgw_libs} librados
 341   cls_rgw_client cls_otp_client cls_lock_client cls_refcount_client
 342   cls_log_client cls_timeindex_client
 343   cls_version_client cls_user_client
 344   global ${FCGI_LIBRARY} ${LIB_RESOLV}
 345   ${CURL_LIBRARIES} ${EXPAT_LIBRARIES} ${BLKID_LIBRARIES})
 346 install(TARGETS radosgw-es DESTINATION bin)
 347
 348 set(radosgw_token_srcs
 349   rgw_token.cc)
 350 add_executable(radosgw-token ${radosgw_token_srcs})
 351 target_link_libraries(radosgw-token librados
 352   global ${ALLOC_LIBS})
 353 install(TARGETS radosgw-token DESTINATION bin)
 354
 355 set(radosgw_object_expirer_srcs
 356   rgw_object_expirer.cc)
 357 add_executable(radosgw-object-expirer ${radosgw_object_expirer_srcs})
 358 target_link_libraries(radosgw-object-expirer ${rgw_libs} librados
 359   cls_rgw_client cls_otp_client cls_lock_client cls_refcount_client
 360   cls_log_client cls_timeindex_client
 361   cls_version_client cls_user_client
 362   global ${FCGI_LIBRARY} ${LIB_RESOLV}
 363   ${CURL_LIBRARIES} ${EXPAT_LIBRARIES})
 364 install(TARGETS radosgw-object-expirer DESTINATION bin)
 365
 366 set(librgw_srcs
 367   librgw.cc
 368   rgw_file.cc)
 369 add_library(rgw SHARED ${librgw_srcs})
 370 target_link_libraries(rgw
 371   PRIVATE
 372   ${rgw_libs}
 373   librados
 374   cls_rgw_client
 375   cls_otp_client
 376   cls_lock_client
 377   cls_refcount_client
 378   cls_log_client
 379   cls_timeindex_client
 380   cls_version_client
 381   cls_user_client
 382   global
 383   ${LIB_RESOLV}
 384   ${CURL_LIBRARIES}
 385   ${EXPAT_LIBRARIES}
 386   PUBLIC
 387   dmclock::dmclock)
 388
 389 if(WITH_RADOSGW_AMQP_ENDPOINT)
 390   target_link_libraries(rgw PRIVATE RabbitMQ::RabbitMQ)
 391 endif()
 392
 393 if(WITH_RADOSGW_KAFKA_ENDPOINT)
 394   target_link_libraries(rgw PRIVATE RDKafka::RDKafka)
 395 endif()
 396
 397 set_target_properties(rgw PROPERTIES OUTPUT_NAME rgw VERSION 2.0.0
 398   SOVERSION 2)
 399 install(TARGETS rgw DESTINATION ${CMAKE_INSTALL_LIBDIR})
 400
 401 if(WITH_TESTS)
 402   add_executable(ceph_rgw_jsonparser
 403     rgw_jsonparser.cc)
 404   target_link_libraries(ceph_rgw_jsonparser
 405     ${rgw_libs}
 406     global)
 407
 408   add_executable(ceph_rgw_multiparser
 409     rgw_multiparser.cc)
 410   target_link_libraries(ceph_rgw_multiparser
 411     ${rgw_libs}
 412     global)
 413
 414   install(TARGETS
 415     ceph_rgw_jsonparser
 416     ceph_rgw_multiparser
 417     DESTINATION bin)
 418 endif(WITH_TESTS)
 419
 420 install(PROGRAMS rgw-orphan-list
 421   DESTINATION bin)