DAB.pm

   1 package PVE::DAB;
   2
   3 use strict;
   4 use warnings;
   5 use IO::File;
   6 use File::Path;
   7 use File::Basename;
   8 use IO::Select;
   9 use IPC::Open2;
  10 use IPC::Open3;
  11 use POSIX qw (LONG_MAX);
  12 use UUID;
  13 use Cwd;
  14
  15 # fixme: lock container ?
  16
  17 my $dablibdir = "/usr/lib/dab";
  18 my $devicetar = "$dablibdir/devices.tar.gz";
  19 my $default_env = "$dablibdir/scripts/defenv";
  20 my $fake_init = "$dablibdir/scripts/init.pl";
  21 my $script_ssh_init = "$dablibdir/scripts/ssh_gen_host_keys";
  22 my $script_mysql_randompw = "$dablibdir/scripts/mysql_randompw";
  23 my $script_init_urandom = "$dablibdir/scripts/init_urandom";
  24
  25 my $postfix_main_cf = <<EOD;
  26 # See /usr/share/postfix/main.cf.dist for a commented, more complete version
  27
  28 smtpd_banner = \$myhostname ESMTP \$mail_name (Debian/GNU)
  29 biff = no
  30
  31 # appending .domain is the MUA's job.
  32 append_dot_mydomain = no
  33
  34 # Uncomment the next line to generate "delayed mail" warnings
  35 #delay_warning_time = 4h
  36
  37 alias_maps = hash:/etc/aliases
  38 alias_database = hash:/etc/aliases
  39 mydestination = \$myhostname, localhost.\$mydomain, localhost
  40 relayhost =
  41 mynetworks = 127.0.0.0/8
  42 inet_interfaces = loopback-only
  43 recipient_delimiter = +
  44
  45 EOD
  46
  47 # produce apt compatible filenames (/var/lib/apt/lists)
  48 sub __url_to_filename {
  49     my $url = shift;
  50
  51     $url =~ s|^\S+://||;
  52     $url =~ s|_|%5f|g;
  53     $url =~ s|/|_|g;
  54
  55     return $url;
  56 }
  57
  58 sub download {
  59     my ($self, $url, $path) = @_;
  60
  61     $self->logmsg ("download: $url\n");
  62     my $tmpfn = "$path.tmp$$";
  63     eval {
  64         $self->run_command ("wget -q '$url'  -O '$tmpfn'");
  65     };
  66
  67     my $err = $@;
  68     if ($err) {
  69         unlink $tmpfn;
  70         die $err;
  71     }
  72
  73     rename ($tmpfn, $path);
  74 }
  75
  76 sub write_file {
  77     my ($data, $file, $perm) = @_;
  78
  79     die "no filename" if !$file;
  80
  81     unlink $file;
  82
  83     my $fh = IO::File->new ($file, O_WRONLY | O_CREAT, $perm) ||
  84         die "unable to open file '$file'";
  85
  86     print $fh $data;
  87
  88     $fh->close;
  89 }
  90
  91 sub read_file {
  92     my ($file) = @_;
  93
  94     die "no filename" if !$file;
  95
  96     my $fh = IO::File->new ($file) ||
  97         die "unable to open file '$file'";
  98
  99     local $/; # slurp mode
 100
 101     my $data = <$fh>;
 102
 103     $fh->close;
 104
 105     return $data;
 106 }
 107
 108 sub read_config {
 109     my ($filename) = @_;
 110
 111     my $res = {};
 112
 113     my $fh = IO::File->new ("<$filename") || return $res;
 114     my $rec = '';
 115
 116     while (defined (my $line = <$fh>)) {
 117         next if $line =~ m/^\#/;
 118         next if $line =~ m/^\s*$/;
 119         $rec .= $line;
 120     };
 121
 122     close ($fh);
 123
 124     chomp $rec;
 125     $rec .= "\n";
 126
 127     while ($rec) {
 128         if ($rec =~ s/^Description:\s*([^\n]*)(\n\s+.*)*$//si) {
 129             $res->{headline} = $1;
 130             chomp $res->{headline};
 131             my $long = $2;
 132             $long =~ s/^\s+/ /;
 133             $res->{description} = $long;
 134             chomp $res->{description};
 135         } elsif ($rec =~ s/^([^:]+):\s*(.*\S)\s*\n//) {
 136             my ($key, $value) = (lc ($1), $2);
 137             if ($key eq 'source' || $key eq 'mirror') {
 138                 push @{$res->{$key}}, $value;
 139             } else {
 140                 die "duplicate key '$key'\n" if defined ($res->{$key});
 141                 $res->{$key} = $value;
 142             }
 143         } else {
 144             die "unable to parse config file: $rec";
 145         }
 146     }
 147
 148     die "unable to parse config file" if $rec;
 149
 150     return $res;
 151 }
 152
 153 sub run_command {
 154     my ($self, $cmd, $input, $getoutput) = @_;
 155
 156     my $reader = IO::File->new();
 157     my $writer = IO::File->new();
 158     my $error  = IO::File->new();
 159
 160     my $orig_pid = $$;
 161
 162     my $cmdstr = ref ($cmd) eq 'ARRAY' ? join (' ', @$cmd) : $cmd;
 163
 164     my $pid;
 165     eval {
 166         if (ref ($cmd) eq 'ARRAY') {
 167             $pid = open3 ($writer, $reader, $error, @$cmd) || die $!;
 168         } else {
 169             $pid = open3 ($writer, $reader, $error, $cmdstr) || die $!;
 170         }
 171     };
 172
 173     my $err = $@;
 174
 175     # catch exec errors
 176     if ($orig_pid != $$) {
 177         $self->logmsg ("ERROR: command '$cmdstr' failed - fork failed\n");
 178         POSIX::_exit (1);
 179         kill ('KILL', $$);
 180     }
 181
 182     die $err if $err;
 183
 184     print $writer $input if defined $input;
 185     close $writer;
 186
 187     my $select = new IO::Select;
 188     $select->add ($reader);
 189     $select->add ($error);
 190
 191     my $res = '';
 192     my $logfd = $self->{logfd};
 193
 194     while ($select->count) {
 195         my @handles = $select->can_read ();
 196
 197         foreach my $h (@handles) {
 198             my $buf = '';
 199             my $count = sysread ($h, $buf, 4096);
 200             if (!defined ($count)) {
 201                 waitpid ($pid, 0);
 202                 die "command '$cmdstr' failed: $!";
 203             }
 204             $select->remove ($h) if !$count;
 205
 206             print $logfd $buf;
 207
 208             $res .= $buf if $getoutput;
 209         }
 210     }
 211
 212     waitpid ($pid, 0);
 213     my $ec = ($? >> 8);
 214
 215     die "command '$cmdstr' failed with exit code $ec\n" if $ec;
 216
 217     return $res;
 218 }
 219
 220 sub logmsg {
 221     my $self = shift;
 222     print STDERR @_;
 223     $self->writelog (@_);
 224 }
 225
 226 sub writelog {
 227     my $self = shift;
 228     my $fd = $self->{logfd};
 229     print $fd @_;
 230 }
 231
 232 sub __sample_config {
 233     my ($self) = @_;
 234
 235     my $data = '';
 236     my $arch = $self->{config}->{architecture};
 237
 238     my $ostype = $self->{config}->{ostype};
 239
 240     if ($ostype =~ m/^debian-/) {
 241         $data .= "lxc.include = /usr/share/lxc/config/debian.common.conf\n";
 242     } elsif ($ostype =~ m/^ubuntu-/) {
 243         $data .= "lxc.include = /usr/share/lxc/config/ubuntu.common.conf\n";
 244     } else {
 245         die "unknown os type '$ostype'\n";
 246     }
 247     $data .= "lxc.utsname = localhost\n";
 248     $data .= "lxc.rootfs = $self->{rootfs}\n";
 249
 250     return $data;
 251 }
 252
 253 sub __allocate_ve {
 254     my ($self) = @_;
 255
 256     my $cid;
 257     if (my $fd = IO::File->new (".veid")) {
 258         $cid = <$fd>;
 259         chomp $cid;
 260         close ($fd);
 261     }
 262
 263
 264     $self->{working_dir} = getcwd;
 265     $self->{veconffile} = "$self->{working_dir}/config";
 266     $self->{rootfs} = "$self->{working_dir}/rootfs";
 267
 268     if ($cid) {
 269         $self->{veid} = $cid;
 270         return $cid;
 271     }
 272
 273     my $uuid;
 274     my $uuid_str;
 275     UUID::generate($uuid);
 276     UUID::unparse($uuid, $uuid_str);
 277     $self->{veid} = $uuid_str;
 278
 279     my $fd = IO::File->new (">.veid") ||
 280         die "unable to write '.veid'\n";
 281     print $fd "$self->{veid}\n";
 282     close ($fd);
 283
 284     my $cdata = $self->__sample_config();
 285
 286     my $fh = IO::File->new ($self->{veconffile}, O_WRONLY|O_CREAT|O_EXCL) ||
 287         die "unable to write lxc config file '$self->{veconffile}' - $!";
 288     print $fh $cdata;
 289     close ($fh);
 290
 291     mkdir $self->{rootfs} || die "unable to create rootfs - $!";
 292
 293     $self->logmsg ("allocated VE $self->{veid}\n");
 294
 295     return $self->{veid};
 296 }
 297
 298 sub new {
 299     my ($class, $config) = @_;
 300
 301     $class = ref ($class) || $class;
 302
 303     my $self = {};
 304
 305     $config = read_config ('dab.conf') if !$config;
 306
 307     $self->{config} = $config;
 308
 309     bless $self, $class;
 310
 311     $self->{logfile} = "logfile";
 312     $self->{logfd} = IO::File->new (">>$self->{logfile}") ||
 313         die "unable to open log file";
 314
 315     my $arch = $config->{architecture};
 316     die "no 'architecture' specified\n" if !$arch;
 317
 318     die "unsupported architecture '$arch'\n"
 319         if $arch !~ m/^(i386|amd64)$/;
 320
 321     my $suite = $config->{suite} || die "no 'suite' specified\n";
 322     if ($suite eq 'stretch') {
 323         $config->{ostype} = "debian-9.0";
 324     } elsif ($suite eq 'jessie') {
 325          $config->{ostype} = "debian-8.0";
 326     } elsif ($suite eq 'wheezy') {
 327          $config->{ostype} = "debian-7.0";
 328     } elsif ($suite eq 'squeeze') {
 329         $config->{ostype} = "debian-6.0";
 330     } elsif ($suite eq 'lenny') {
 331         $config->{ostype} = "debian-5.0";
 332     } elsif ($suite eq 'etch') {
 333         $config->{ostype} = "debian-4.0";
 334     } elsif ($suite eq 'hardy') {
 335         $config->{ostype} = "ubuntu-8.04";
 336     } elsif ($suite eq 'intrepid') {
 337         $config->{ostype} = "ubuntu-8.10";
 338     } elsif ($suite eq 'jaunty') {
 339         $config->{ostype} = "ubuntu-9.04";
 340     } elsif ($suite eq 'precise') {
 341         $config->{ostype} = "ubuntu-12.04";
 342     } elsif ($suite eq 'trusty') {
 343         $config->{ostype} = "ubuntu-14.04";
 344     } elsif ($suite eq 'vivid') {
 345         $config->{ostype} = "ubuntu-15.04";
 346     } elsif ($suite eq 'wily') {
 347         $config->{ostype} = "ubuntu-15.10";
 348     } elsif ($suite eq 'xenial') {
 349         $config->{ostype} = "ubuntu-16.04";
 350     } elsif ($suite eq 'yakkety') {
 351         $config->{ostype} = "ubuntu-16.10";
 352     } elsif ($suite eq 'zesty') {
 353         $config->{ostype} = "ubuntu-17.04";
 354     } else {
 355         die "unsupported debian suite '$suite'\n";
 356     }
 357
 358     my $name = $config->{name} || die "no 'name' specified\n";
 359
 360     $name =~ m/^[a-z][0-9a-z\-\*\.]+$/ ||
 361         die "illegal characters in name '$name'\n";
 362
 363     my $version = $config->{version};
 364     die "no 'version' specified\n" if !$version;
 365     die "no 'section' specified\n" if !$config->{section};
 366     die "no 'description' specified\n" if !$config->{headline};
 367     die "no 'maintainer' specified\n" if !$config->{maintainer};
 368
 369     if ($name =~ m/^$config->{ostype}/) {
 370         $self->{targetname} = "${name}_${version}_$config->{architecture}";
 371     } else {
 372         $self->{targetname} = "$config->{ostype}-${name}_" .
 373             "${version}_$config->{architecture}";
 374     }
 375
 376     if (!$config->{source}) {
 377         if ($suite eq 'etch' || $suite eq 'lenny') {
 378             push @{$config->{source}}, "http://ftp.debian.org/debian SUITE main contrib";
 379             push @{$config->{source}}, "http://security.debian.org SUITE/updates main contrib";
 380         } elsif ($suite eq 'squeeze' || $suite eq 'wheezy' ||
 381                  $suite eq 'jessie' || $suite eq 'stretch' ) {
 382             push @{$config->{source}}, "http://ftp.debian.org/debian SUITE main contrib";
 383             push @{$config->{source}}, "http://ftp.debian.org/debian SUITE-updates main contrib";
 384             push @{$config->{source}}, "http://security.debian.org SUITE/updates main contrib";
 385         } elsif ($suite eq 'hardy' || $suite eq 'intrepid' || $suite eq 'jaunty' ||
 386                  $suite eq 'xenial' || $suite eq 'wily' || $suite eq 'vivid' ||
 387                  $suite eq 'trusty' || $suite eq 'precise' || $suite eq 'yakkety' ||
 388                  $suite eq 'zesty') {
 389             my $comp = "main restricted universe multiverse";
 390             push @{$config->{source}}, "http://archive.ubuntu.com/ubuntu SUITE $comp";
 391             push @{$config->{source}}, "http://archive.ubuntu.com/ubuntu SUITE-updates $comp";
 392             push @{$config->{source}}, "http://archive.ubuntu.com/ubuntu SUITE-security $comp";
 393         } else {
 394             die "implement me";
 395         }
 396     }
 397
 398     my $sources = undef;
 399
 400     foreach my $s (@{$config->{source}}) {
 401         if ($s =~ m@^\s*((http|ftp)://\S+)\s+(\S+)((\s+(\S+))+)$@) {
 402             my ($url, $su, $components) = ($1, $3, $4);
 403             $su =~ s/SUITE/$suite/;
 404             $components =~ s/^\s+//;
 405             $components =~ s/\s+$//;
 406             my $ca;
 407             foreach my $co (split (/\s+/, $components)) {
 408                 push @$ca, $co;
 409             }
 410             $ca = ['main'] if !$ca;
 411
 412             push @$sources, {
 413                 source => $url,
 414                 comp => $ca,
 415                 suite => $su,
 416             };
 417         } else {
 418             die "syntax error in source spezification '$s'\n";
 419         }
 420     }
 421
 422     foreach my $m (@{$config->{mirror}}) {
 423         if ($m =~ m@^\s*((http|ftp)://\S+)\s*=>\s*((http|ftp)://\S+)\s*$@) {
 424             my ($ms, $md) = ($1, $3);
 425             my $found;
 426             foreach my $ss (@$sources) {
 427                 if ($ss->{source} eq $ms) {
 428                     $found = 1;
 429                     $ss->{mirror} = $md;
 430                     last;
 431                 }
 432             }
 433             die "unusable mirror $ms\n" if !$found;
 434         } else {
 435             die "syntax error in mirror spezification '$m'\n";
 436         }
 437     }
 438
 439     $self->{sources} = $sources;
 440
 441     $self->{infodir} = "info";
 442
 443     $self->__allocate_ve ();
 444
 445     $self->{cachedir} = ($config->{cachedir} || 'cache')  . "/$suite";;
 446
 447     my $incl = [qw (less ssh openssh-server logrotate)];
 448
 449     my $excl = [qw (modutils reiserfsprogs ppp pppconfig pppoe
 450                     pppoeconf nfs-common mtools ntp)];
 451
 452     # ubuntu has too many dependencies on udev, so
 453     # we cannot exclude it (instead we disable udevd)
 454
 455     if ($suite eq 'vivid' || $suite eq 'wily' || $suite eq 'xenial' ||
 456         $suite eq 'yakkety' || $suite eq 'zesty') {
 457         push @$incl, 'isc-dhcp-client';
 458         push @$excl, qw(libmodule-build-perl);
 459     } elsif ($suite eq 'trusty') {
 460         push @$excl, qw(systemd systemd-services libpam-systemd libsystemd-daemon0 memtest86+);
 461    } elsif ($suite eq 'precise') {
 462         push @$excl, qw(systemd systemd-services libpam-systemd libsystemd-daemon0 memtest86+ ubuntu-standard);
 463     } elsif ($suite eq 'hardy') {
 464         push @$excl, qw(kbd);
 465         push @$excl, qw(apparmor apparmor-utils ntfs-3g
 466                         friendly-recovery);
 467     } elsif ($suite eq 'intrepid' || $suite eq 'jaunty') {
 468         push @$excl, qw(apparmor apparmor-utils libapparmor1 libapparmor-perl
 469                         libntfs-3g28 ntfs-3g friendly-recovery);
 470     } elsif ($suite eq 'jessie') {
 471         push @$incl, 'sysvinit-core'; # avoid systemd and udev
 472         push @$incl, 'libperl4-corelibs-perl'; # to make lsof happy
 473         push @$excl, qw(systemd systemd-sysv udev module-init-tools pciutils hdparm
 474                         memtest86+ parted);
 475     } elsif ($suite eq 'stretch') {
 476         push @$excl, qw(module-init-tools pciutils hdparm
 477                         memtest86+ parted);
 478      } else {
 479         push @$excl, qw(udev module-init-tools pciutils hdparm
 480                         memtest86+ parted);
 481     }
 482
 483     $self->{incl} = $incl;
 484     $self->{excl} = $excl;
 485
 486     return $self;
 487 }
 488
 489 sub initialize {
 490     my ($self) = @_;
 491
 492     my $infodir = $self->{infodir};
 493     my $arch = $self->{config}->{architecture};
 494
 495     rmtree $infodir;
 496     mkpath $infodir;
 497
 498     # truncate log
 499     my $logfd = $self->{logfd} = IO::File->new (">$self->{logfile}") ||
 500         die "unable to open log file";
 501
 502     foreach my $ss (@{$self->{sources}}) {
 503         my $src = $ss->{mirror} || $ss->{source};
 504         my $path = "dists/$ss->{suite}/Release";
 505         my $url = "$src/$path";
 506         my $target = __url_to_filename ("$ss->{source}/$path");
 507         eval {
 508             $self->download ($url, "$infodir/$target");
 509             $self->download ("$url.gpg", "$infodir/$target.gpg");
 510             # fixme: impl. verify (needs --keyring option)
 511         };
 512         if (my $err = $@) {
 513             print $logfd $@;
 514             warn "Release info ignored\n";
 515         };
 516         foreach my $comp (@{$ss->{comp}}) {
 517             $path = "dists/$ss->{suite}/$comp/binary-$arch/Packages.gz";
 518             $target = "$infodir/" . __url_to_filename ("$ss->{source}/$path");
 519             my $pkgsrc = "$src/$path";
 520             $self->download ($pkgsrc, $target);
 521             $self->run_command ("gzip -d '$target'");
 522         }
 523     }
 524 }
 525
 526 sub write_config {
 527     my ($self, $filename, $size) = @_;
 528
 529     my $config = $self->{config};
 530
 531     my $data = '';
 532
 533     $data .= "Name: $config->{name}\n";
 534     $data .= "Version: $config->{version}\n";
 535     $data .= "Type: lxc\n";
 536     $data .= "OS: $config->{ostype}\n";
 537     $data .= "Section: $config->{section}\n";
 538     $data .= "Maintainer: $config->{maintainer}\n";
 539     $data .= "Architecture: $config->{architecture}\n";
 540     $data .= "Installed-Size: $size\n";
 541
 542     # optional
 543     $data .= "Infopage: $config->{infopage}\n" if $config->{infopage};
 544     $data .= "ManageUrl: $config->{manageurl}\n" if $config->{manageurl};
 545     $data .= "Certified: $config->{certified}\n" if $config->{certified};
 546
 547     # description
 548     $data .= "Description: $config->{headline}\n";
 549     $data .= "$config->{description}\n" if $config->{description};
 550
 551     write_file ($data, $filename, 0644);
 552 }
 553
 554 sub finalize {
 555     my ($self, $opts) = @_;
 556
 557     my $suite = $self->{config}->{suite};
 558     my $infodir = $self->{infodir};
 559     my $arch = $self->{config}->{architecture};
 560
 561     my $instpkgs = $self->read_installed ();
 562     my $pkginfo = $self->pkginfo();
 563     my $veid = $self->{veid};
 564     my $conffile = $self->{veconffile};
 565     my $rootdir = $self->{rootfs};
 566
 567     my $vestat = $self->ve_status();
 568     die "ve not running - unable to finalize\n" if !$vestat->{running};
 569
 570     # cleanup mysqld
 571     if (-f "$rootdir/etc/init.d/mysql") {
 572         $self->ve_command ("/etc/init.d/mysql stop");
 573     }
 574
 575     if (!($opts->{keepmycnf} || (-f "$rootdir/etc/init.d/mysql_randompw"))) {
 576         unlink "$rootdir/root/.my.cnf";
 577     }
 578
 579     if ($suite eq 'etch') {
 580         # enable apache2 startup
 581         if ($instpkgs->{apache2}) {
 582             write_file ("NO_START=0\n", "$rootdir/etc/default/apache2");
 583         } else {
 584             unlink "$rootdir/etc/default/apache2";
 585         }
 586     }
 587     $self->logmsg ("cleanup package status\n");
 588     # prevent auto selection of all standard, required or important
 589     # packages which are not installed
 590     foreach my $pkg (keys %$pkginfo) {
 591         my $pri = $pkginfo->{$pkg}->{priority};
 592         if ($pri && ($pri eq 'required' || $pri eq 'important'
 593                      || $pri eq 'standard')) {
 594             if (!$instpkgs->{$pkg}) {
 595                 $self->ve_dpkg_set_selection ($pkg, 'purge');
 596             }
 597         }
 598     }
 599
 600     $self->ve_command ("apt-get clean");
 601
 602     $self->logmsg ("update available package list\n");
 603
 604     $self->ve_command ("dpkg --clear-avail");
 605     foreach my $ss (@{$self->{sources}}) {
 606         my $relsrc = __url_to_filename ("$ss->{source}/dists/$ss->{suite}/Release");
 607         if (-f "$infodir/$relsrc" && -f "$infodir/$relsrc.gpg") {
 608             $self->run_command ("cp '$infodir/$relsrc' '$rootdir/var/lib/apt/lists/$relsrc'");
 609             $self->run_command ("cp '$infodir/$relsrc.gpg' '$rootdir/var/lib/apt/lists/$relsrc.gpg'");
 610         }
 611         foreach my $comp (@{$ss->{comp}}) {
 612             my $src = __url_to_filename ("$ss->{source}/dists/$ss->{suite}/" .
 613                                          "$comp/binary-$arch/Packages");
 614             my $target = "/var/lib/apt/lists/$src";
 615             $self->run_command ("cp '$infodir/$src' '$rootdir/$target'");
 616             $self->ve_command ("dpkg --merge-avail '$target'");
 617         }
 618     }
 619
 620     # set dselect default method
 621     write_file ("apt apt\n", "$rootdir/var/lib/dpkg/cmethopt");
 622
 623     $self->ve_divert_remove ("/usr/sbin/policy-rc.d");
 624
 625     $self->ve_divert_remove ("/sbin/start-stop-daemon");
 626
 627     $self->ve_divert_remove ("/sbin/init");
 628
 629     # finally stop the VE
 630     $self->run_command ("lxc-stop -n $veid --rcfile $conffile --kill");
 631
 632     unlink "$rootdir/sbin/defenv";
 633
 634     unlink <$rootdir/root/dead.letter*>;
 635
 636     unlink "$rootdir/var/log/init.log";
 637
 638     unlink "$rootdir/aquota.group";
 639
 640     unlink "$rootdir/aquota.user";
 641
 642     write_file ("", "$rootdir/var/log/syslog");
 643
 644     $self->logmsg ("detecting final size: ");
 645
 646     my $sizestr = $self->run_command ("du -sm $rootdir", undef, 1);
 647     my $size;
 648     if ($sizestr =~ m/^(\d+)\s+\Q$rootdir\E$/) {
 649         $size = $1;
 650     } else {
 651         die "unable to detect size\n";
 652     }
 653     $self->logmsg ("$size MB\n");
 654
 655     $self->write_config ("$rootdir/etc/appliance.info", $size);
 656
 657     $self->logmsg ("creating final appliance archive\n");
 658
 659     my $target = "$self->{targetname}.tar";
 660     unlink $target;
 661     unlink "$target.gz";
 662
 663     $self->run_command ("tar cpf $target --numeric-owner -C '$rootdir' ./etc/appliance.info");
 664     $self->run_command ("tar rpf $target --numeric-owner -C '$rootdir' --exclude ./etc/appliance.info .");
 665     $self->run_command ("gzip $target");
 666 }
 667
 668 sub read_installed {
 669     my ($self) = @_;
 670
 671     my $rootdir = $self->{rootfs};
 672
 673     my $pkgfilelist = "$rootdir/var/lib/dpkg/status";
 674     local $/ = '';
 675     open (PKGLST, "<$pkgfilelist") ||
 676         die "unable to open '$pkgfilelist'";
 677
 678     my $pkglist = {};
 679
 680     while (my $rec = <PKGLST>) {
 681         chomp $rec;
 682         $rec =~ s/\n\s+/ /g;
 683         $rec .= "\n";
 684         my $res = {};
 685
 686         while ($rec =~ s/^([^:]+):\s+(.*)\s*\n//) {
 687             $res->{lc $1} = $2;
 688         }
 689
 690         my $pkg = $res->{'package'};
 691         if (my $status = $res->{status}) {
 692             my @sa = split (/\s+/, $status);
 693             my $stat = $sa[0];
 694             if ($stat && ($stat ne 'purge')) {
 695                 $pkglist->{$pkg} = $res;
 696             }
 697         }
 698     }
 699
 700     close (PKGLST);
 701
 702     return $pkglist;
 703 }
 704
 705 sub ve_status {
 706     my ($self) = @_;
 707
 708     my $veid = $self->{veid};
 709
 710     my $res = { running => 0 };
 711
 712     $res->{exist} = 1 if -d "$self->{rootfs}/usr";
 713
 714     my $filename = "/proc/net/unix";
 715
 716     # similar test is used by lcxcontainers.c: list_active_containers
 717     my $fh = IO::File->new ($filename, "r");
 718     return $res if !$fh;
 719
 720     while (defined(my $line = <$fh>)) {
 721         if ($line =~ m/^[a-f0-9]+:\s\S+\s\S+\s\S+\s\S+\s\S+\s\d+\s(\S+)$/) {
 722             my $path = $1;
 723             if ($path =~ m!^@/\S+/$veid/command$!) {
 724                 $res->{running} = 1;
 725             }
 726         }
 727     }
 728     close($fh);
 729
 730     return $res;
 731 }
 732
 733 sub ve_command {
 734     my ($self, $cmd, $input) = @_;
 735
 736     my $veid = $self->{veid};
 737     my $conffile = $self->{veconffile};
 738
 739     if (ref ($cmd) eq 'ARRAY') {
 740         unshift @$cmd, 'lxc-attach', '-n', $veid, '--rcfile', $conffile, '--clear-env', '--', 'defenv';
 741         $self->run_command ($cmd, $input);
 742     } else {
 743         $self->run_command ("lxc-attach -n $veid --rcfile $conffile --clear-env -- defenv $cmd", $input);
 744     }
 745 }
 746
 747 # like ve_command, but pipes stdin correctly
 748 sub ve_exec {
 749     my ($self, @cmd) = @_;
 750
 751     my $veid = $self->{veid};
 752     my $conffile = $self->{veconffile};
 753
 754     my $reader;
 755     my $pid = open2($reader, "<&STDIN", 'lxc-attach', '-n', $veid,  '--rcfile', $conffile, '--',
 756                     'defenv', @cmd) || die "unable to exec command";
 757
 758     while (defined (my $line = <$reader>)) {
 759         $self->logmsg ($line);
 760     }
 761
 762     waitpid ($pid, 0);
 763     my $rc = $? >> 8;
 764
 765     die "ve_exec failed - status $rc\n" if $rc != 0;
 766 }
 767
 768 sub ve_divert_add {
 769     my ($self, $filename) = @_;
 770
 771     $self->ve_command ("dpkg-divert --add --divert '$filename.distrib' " .
 772                        "--rename '$filename'");
 773 }
 774 sub ve_divert_remove {
 775     my ($self, $filename) = @_;
 776
 777     my $rootdir = $self->{rootfs};
 778
 779     unlink "$rootdir/$filename";
 780     $self->ve_command ("dpkg-divert --remove --rename '$filename'");
 781 }
 782
 783 sub ve_debconfig_set {
 784     my ($self, $dcdata) = @_;
 785
 786     my $rootdir = $self->{rootfs};
 787     my $cfgfile = "/tmp/debconf.txt";
 788     write_file ($dcdata, "$rootdir/$cfgfile");
 789     $self->ve_command ("debconf-set-selections $cfgfile");
 790     unlink "$rootdir/$cfgfile";
 791 }
 792
 793 sub ve_dpkg_set_selection {
 794     my ($self, $pkg, $status) = @_;
 795
 796     $self->ve_command ("dpkg --set-selections", "$pkg $status");
 797 }
 798
 799 sub ve_dpkg {
 800     my ($self, $cmd, @pkglist) = @_;
 801
 802     return if !scalar (@pkglist);
 803
 804     my $pkginfo = $self->pkginfo();
 805
 806     my $rootdir = $self->{rootfs};
 807     my $cachedir = $self->{cachedir};
 808
 809     my @files;
 810
 811     foreach my $pkg (@pkglist) {
 812         my $filename = $self->getpkgfile ($pkg);
 813         $self->run_command ("cp '$cachedir/$filename' '$rootdir/$filename'");
 814         push @files, "/$filename";
 815         $self->logmsg ("$cmd: $pkg\n");
 816     }
 817
 818     my $fl = join (' ', @files);
 819
 820     if ($cmd eq 'install') {
 821         $self->ve_command ("dpkg --force-depends --force-confold --install $fl");
 822     } elsif ($cmd eq 'unpack') {
 823         $self->ve_command ("dpkg --force-depends --unpack $fl");
 824     } else {
 825         die "internal error";
 826     }
 827
 828     foreach my $fn (@files) { unlink "$rootdir$fn"; }
 829 }
 830
 831 sub ve_destroy {
 832     my ($self) = @_;
 833
 834     my $veid = $self->{veid}; # fixme
 835     my $conffile = $self->{veconffile};
 836
 837     my $vestat = $self->ve_status();
 838     if ($vestat->{running}) {
 839         $self->run_command ("lxc-stop -n $veid --rcfile $conffile --kill");
 840     }
 841
 842     rmtree $self->{rootfs};
 843     unlink $self->{veconffile};
 844 }
 845
 846 sub ve_init {
 847     my ($self) = @_;
 848
 849     my $veid = $self->{veid};
 850     my $conffile = $self->{veconffile};
 851
 852     $self->logmsg ("initialize VE $veid\n");
 853
 854     my $vestat = $self->ve_status();
 855     if ($vestat->{running}) {
 856         $self->run_command ("lxc-stop -n $veid --rcfile $conffile --kill");
 857     }
 858
 859     rmtree $self->{rootfs};
 860     mkpath $self->{rootfs};
 861 }
 862
 863 sub __deb_version_cmp {
 864     my ($cur, $op, $new) = @_;
 865
 866     if (system("dpkg", "--compare-versions", $cur, $op, $new) == 0) {
 867         return 1;
 868     }
 869
 870     return 0;
 871 }
 872
 873 sub __parse_packages {
 874     my ($pkginfo, $filename, $src) = @_;
 875
 876     local $/ = '';
 877     open (PKGLST, "<$filename") ||
 878         die "unable to open '$filename'";
 879
 880     while (my $rec = <PKGLST>) {
 881         $rec =~ s/\n\s+/ /g;
 882         chomp $rec;
 883         $rec .= "\n";
 884
 885         my $res = {};
 886
 887         while ($rec =~ s/^([^:]+):\s+(.*)\s*\n//) {
 888             $res->{lc $1} = $2;
 889         }
 890
 891         my $pkg = $res->{'package'};
 892         if ($pkg && $res->{'filename'}) {
 893             my $cur;
 894             if (my $info = $pkginfo->{$pkg}) {
 895                 $cur = $info->{version};
 896             }
 897             my $new = $res->{version};
 898             if (!$cur || __deb_version_cmp ($cur, 'lt', $new)) {
 899                 if ($src) {
 900                     $res->{url} = "$src/$res->{'filename'}";
 901                 } else {
 902                     die "no url for package '$pkg'" if !$res->{url};
 903                 }
 904                 $pkginfo->{$pkg} = $res;
 905             }
 906         }
 907     }
 908
 909     close (PKGLST);
 910 }
 911
 912 sub pkginfo {
 913     my ($self) = @_;
 914
 915     return $self->{pkginfo} if $self->{pkginfo};
 916
 917     my $infodir = $self->{infodir};
 918     my $arch = $self->{config}->{architecture};
 919
 920     my $availfn = "$infodir/available";
 921
 922     my $pkginfo = {};
 923     my $pkgcount = 0;
 924
 925     # reading 'available' is faster, because it only contains latest version
 926     # (no need to do slow version compares)
 927     if (-f $availfn) {
 928             __parse_packages ($pkginfo, $availfn);
 929             $self->{pkginfo} = $pkginfo;
 930             return $pkginfo;
 931     }
 932
 933     $self->logmsg ("generating available package list\n");
 934
 935     foreach my $ss (@{$self->{sources}}) {
 936         foreach my $comp (@{$ss->{comp}}) {
 937             my $url = "$ss->{source}/dists/$ss->{suite}/$comp/binary-$arch/Packages";
 938             my $pkgfilelist = "$infodir/" . __url_to_filename ($url);
 939
 940             my $src = $ss->{mirror} || $ss->{source};
 941
 942             __parse_packages ($pkginfo, $pkgfilelist, $src);
 943         }
 944     }
 945
 946     if (my $dep = $self->{config}->{depends}) {
 947         foreach my $d (split (/,/, $dep)) {
 948             if ($d =~ m/^\s*(\S+)\s*(\((\S+)\s+(\S+)\)\s*)?$/) {
 949                 my ($pkg, $op, $rver) = ($1, $3, $4);
 950                 $self->logmsg ("checking dependencies: $d\n");
 951                 my $info = $pkginfo->{$pkg};
 952                 die "package '$pkg' not available\n" if !$info;
 953                 if ($op) {
 954                     my $cver = $info->{version};
 955                     if (!__deb_version_cmp ($cver, $op, $rver)) {
 956                         die "detected wrong version '$cver'\n";
 957                     }
 958                 }
 959             } else {
 960                 die "syntax error in depends field";
 961             }
 962         }
 963     }
 964
 965     $self->{pkginfo} = $pkginfo;
 966
 967     my $tmpfn = "$availfn.tmp$$";
 968     my $fd = IO::File->new (">$tmpfn");
 969     foreach my $pkg (sort keys %$pkginfo) {
 970         my $info = $pkginfo->{$pkg};
 971         print $fd "package: $pkg\n";
 972         foreach my $k (sort keys %$info) {
 973             next if $k eq 'description';
 974             next if $k eq 'package';
 975             my $v = $info->{$k};
 976             print $fd "$k: $v\n" if $v;
 977         }
 978         print $fd "description: $info->{description}\n" if $info->{description};
 979         print $fd "\n";
 980     }
 981     close ($fd);
 982
 983     rename ($tmpfn, $availfn);
 984
 985     return $pkginfo;
 986 }
 987
 988 sub __record_provides {
 989     my ($pkginfo, $closure, $list, $skipself) = @_;
 990
 991     foreach my $pname (@$list) {
 992         my $info = $pkginfo->{$pname};
 993         # fixme: if someone install packages directly using dpkg, there
 994         # is no entry in 'available', only in 'status'. In that case, we
 995         # should extract info from $instpkgs
 996         if (!$info) {
 997             warn "hint: ignoring provides for '$pname' - package not in 'available' list.\n";
 998             next;
 999         }
1000         if (my $prov = $info->{provides}) {
1001             my @pl = split (',', $prov);
1002             foreach my $p (@pl) {
1003                 $p =~ m/\s*(\S+)/;
1004                 if (!($skipself && (grep { $1 eq $_ } @$list))) {
1005                     $closure->{$1} = 1;
1006                 }
1007             }
1008         }
1009         $closure->{$pname} = 1 if !$skipself;
1010     }
1011 }
1012
1013 sub closure {
1014     my ($self, $closure, $list) = @_;
1015
1016     my $pkginfo = $self->pkginfo();
1017
1018     # first, record provided packages
1019     __record_provides ($pkginfo, $closure, $list, 1);
1020
1021     my $pkgs = {};
1022
1023     # then resolve dependencies
1024     foreach my $pname (@$list) {
1025         __closure_single ($pkginfo, $closure, $pkgs, $pname, $self->{excl});
1026     }
1027
1028     return [ keys %$pkgs ];
1029 }
1030
1031 sub __closure_single {
1032     my ($pkginfo, $closure, $pkgs, $pname, $excl) = @_;
1033
1034     $pname =~ s/^\s+//;
1035     $pname =~ s/\s+$//;
1036     $pname =~ s/:any$//;
1037
1038     return if $closure->{$pname};
1039
1040     my $info = $pkginfo->{$pname} || die "no such package '$pname'";
1041
1042     my $dep = $info->{depends};
1043     my $predep = $info->{'pre-depends'};
1044
1045     my $size = $info->{size};
1046     my $url = $info->{url};
1047
1048     $url || die "$pname: no url for package '$pname'";
1049
1050     $pkgs->{$pname} = 1;
1051
1052     __record_provides ($pkginfo, $closure, [$pname]) if $info->{provides};
1053
1054     $closure->{$pname} = 1;
1055
1056     #print "$url\n";
1057
1058     my @l;
1059
1060     push  @l, split (/,/, $predep) if $predep;
1061     push  @l, split (/,/, $dep) if $dep;
1062
1063   DEPEND: foreach my $p (@l) {
1064       my @l1 = split (/\|/, $p);
1065       foreach my $p1 (@l1) {
1066           if ($p1 =~ m/^\s*(\S+).*/) {
1067               #printf (STDERR "$pname: $p --> $1\n");
1068               if ($closure->{$1}) {
1069                   next DEPEND; # dependency already met
1070               }
1071           }
1072       }
1073       # search for non-excluded alternative
1074       my $found;
1075       foreach my $p1 (@l1) {
1076           if ($p1 =~ m/^\s*(\S+).*/) {
1077               next if grep { $1 eq $_ } @$excl;
1078               $found = $1;
1079               last;
1080           }
1081       }
1082       die "package '$pname' depends on exclusion '$p'\n" if !$found;
1083
1084       #printf (STDERR "$pname: $p --> $found\n");
1085
1086       __closure_single ($pkginfo, $closure, $pkgs, $found, $excl);
1087   }
1088 }
1089
1090 sub cache_packages {
1091     my ($self, $pkglist) = @_;
1092
1093     foreach my $pkg (@$pkglist) {
1094         $self->getpkgfile ($pkg);
1095     }
1096 }
1097
1098 sub getpkgfile {
1099     my ($self, $pkg) = @_;
1100
1101     my $pkginfo = $self->pkginfo();
1102     my $info = $pkginfo->{$pkg} || die "no such package '$pkg'";
1103     my $cachedir = $self->{cachedir};
1104
1105     my $url = $info->{url};
1106
1107     my $filename;
1108     if ($url =~ m|/([^/]+.deb)$|) {
1109         $filename = $1;
1110     } else {
1111         die "internal error";
1112     }
1113
1114     return $filename if -f "$cachedir/$filename";
1115
1116     mkpath $cachedir;
1117
1118     $self->download ($url, "$cachedir/$filename");
1119
1120     return $filename;
1121 }
1122
1123 sub install_init_script {
1124     my ($self, $script, $runlevel, $prio) = @_;
1125
1126     my $suite = $self->{config}->{suite};
1127     my $rootdir = $self->{rootfs};
1128
1129     my $base = basename ($script);
1130     my $target = "$rootdir/etc/init.d/$base";
1131
1132     $self->run_command ("install -m 0755 '$script' '$target'");
1133     if ($suite eq 'etch' || $suite eq 'lenny') {
1134         $self->ve_command ("update-rc.d $base start $prio $runlevel .");
1135     } elsif ($suite eq 'xenial' || $suite eq 'wily' || $suite eq 'vivid' ||
1136              $suite eq 'yakkety' || $suite eq 'zesty') {
1137         die "unable to install init script (system uses systemd)\n";
1138     } elsif ($suite eq 'trusty' || $suite eq 'precise') {
1139         die "unable to install init script (system uses upstart)\n";
1140     } else {
1141         $self->ve_command ("insserv $base");
1142     }
1143
1144     return $target;
1145 }
1146
1147 sub bootstrap {
1148     my ($self, $opts) = @_;
1149
1150     my $pkginfo = $self->pkginfo();
1151     my $veid = $self->{veid};
1152     my $suite = $self->{config}->{suite};
1153
1154     my $important = [ @{$self->{incl}} ];
1155     my $required;
1156     my $standard;
1157
1158     my $mta = $opts->{exim} ? 'exim' : 'postfix';
1159
1160     if ($mta eq 'postfix') {
1161         push @$important, "postfix";
1162     }
1163
1164     foreach my $p (keys %$pkginfo) {
1165         next if grep { $p eq $_ } @{$self->{excl}};
1166         my $pri = $pkginfo->{$p}->{priority};
1167         next if !$pri;
1168         next if $mta ne 'exim' && $p =~ m/exim/;
1169         next if $p =~ m/(selinux|semanage|policycoreutils)/;
1170
1171         push @$required, $p  if $pri eq 'required';
1172         push @$important, $p if $pri eq 'important';
1173         push @$standard, $p if $pri eq 'standard' && !$opts->{minimal};
1174     }
1175
1176     my $closure = {};
1177     $required = $self->closure ($closure, $required);
1178     $important = $self->closure ($closure, $important);
1179
1180     if (!$opts->{minimal}) {
1181         push @$standard, 'xbase-clients';
1182         $standard = $self->closure ($closure, $standard);
1183     }
1184
1185     # test if we have all 'ubuntu-minimal' and 'ubuntu-standard' packages
1186     # except those explicitly excluded
1187     if ($suite eq 'hardy' || $suite eq 'intrepid' || $suite eq 'jaunty') {
1188         my $mdeps = $pkginfo->{'ubuntu-minimal'}->{depends};
1189         foreach my $d (split (/,/, $mdeps)) {
1190             if ($d =~ m/^\s*(\S+)$/) {
1191                 my $pkg = $1;
1192                 next if $closure->{$pkg};
1193                 next if grep { $pkg eq $_ } @{$self->{excl}};
1194                 die "missing ubuntu-minimal package '$pkg'\n";
1195             }
1196         }
1197         if (!$opts->{minimal}) {
1198             $mdeps = $pkginfo->{'ubuntu-standard'}->{depends};
1199             foreach my $d (split (/,/, $mdeps)) {
1200                 if ($d =~ m/^\s*(\S+)$/) {
1201                     my $pkg = $1;
1202                     next if $closure->{$pkg};
1203                     next if grep { $pkg eq $_ } @{$self->{excl}};
1204                     die "missing ubuntu-standard package '$pkg'\n";
1205                 }
1206             }
1207         }
1208     }
1209
1210     # download/cache all files first
1211     $self->cache_packages ($required);
1212     $self->cache_packages ($important);
1213     $self->cache_packages ($standard);
1214
1215     my $rootdir = $self->{rootfs};
1216
1217     # extract required packages first
1218     $self->logmsg ("create basic environment\n");
1219     foreach my $p (@$required) {
1220         my $filename = $self->getpkgfile ($p);
1221         my $content = $self->run_command("ar -t '$self->{cachedir}/$filename'", undef, 1);
1222         if ($content =~ m/^data.tar.xz$/m) {
1223             $self->run_command ("ar -p '$self->{cachedir}/$filename' data.tar.xz | tar -C '$rootdir' -xJf -");
1224         } else {
1225             $self->run_command ("ar -p '$self->{cachedir}/$filename' data.tar.gz | tar -C '$rootdir' -xzf -");
1226         }
1227     }
1228
1229     # fake dpkg status
1230     my $data = "Package: dpkg\n" .
1231         "Version: $pkginfo->{dpkg}->{version}\n" .
1232         "Status: install ok installed\n";
1233
1234     write_file ($data, "$rootdir/var/lib/dpkg/status");
1235     write_file ("", "$rootdir/var/lib/dpkg/info/dpkg.list");
1236     write_file ("", "$rootdir/var/lib/dpkg/available");
1237
1238     $data = '';
1239     foreach my $ss (@{$self->{sources}}) {
1240         my $url = $ss->{source};
1241         my $comp = join (' ', @{$ss->{comp}});
1242         $data .= "deb $url $ss->{suite} $comp\n\n";
1243     }
1244
1245     write_file ($data, "$rootdir/etc/apt/sources.list");
1246
1247     $data = "# UNCONFIGURED FSTAB FOR BASE SYSTEM\n";
1248     write_file ($data, "$rootdir/etc/fstab", 0644);
1249
1250     write_file ("localhost\n", "$rootdir/etc/hostname", 0644);
1251
1252     # avoid warnings about non-existent resolv.conf
1253     write_file ("", "$rootdir/etc/resolv.conf", 0644);
1254
1255     if ($suite eq 'zesty' || $suite eq 'yakkety' ||
1256         $suite eq 'xenial' || $suite eq 'wily') {
1257         # no need to configure loopback device
1258     } else {
1259         $data = "auto lo\niface lo inet loopback\n";
1260         mkdir "$rootdir/etc/network";
1261         write_file ($data, "$rootdir/etc/network/interfaces", 0644);
1262     }
1263
1264     # setup devices
1265     $self->run_command ("tar xzf '$devicetar' -C '$rootdir'");
1266
1267     # avoid warnings about missing default locale
1268     write_file ("LANG=\"C\"\n", "$rootdir/etc/default/locale", 0644);
1269
1270     # fake init
1271     rename ("$rootdir/sbin/init", "$rootdir/sbin/init.org");
1272     $self->run_command ("cp '$fake_init' '$rootdir/sbin/init'");
1273
1274     $self->run_command ("cp '$default_env' '$rootdir/sbin/defenv'");
1275
1276     $self->run_command ("lxc-start -n $veid -f $self->{veconffile}");
1277
1278     $self->logmsg ("initialize ld cache\n");
1279     $self->ve_command ("/sbin/ldconfig");
1280     $self->run_command ("ln -sf mawk '$rootdir/usr/bin/awk'");
1281
1282     $self->logmsg ("installing packages\n");
1283
1284     $self->ve_dpkg ('install', 'base-files', 'base-passwd');
1285
1286     $self->ve_dpkg ('install', 'dpkg');
1287
1288     $self->run_command ("ln -sf /usr/share/zoneinfo/UTC '$rootdir/etc/localtime'");
1289
1290     $self->run_command ("ln -sf bash '$rootdir/bin/sh'");
1291
1292     $self->ve_dpkg ('install', 'libc6');
1293     $self->ve_dpkg ('install', 'perl-base');
1294
1295     unlink "$rootdir/usr/bin/awk";
1296
1297     $self->ve_dpkg ('install', 'mawk');
1298     $self->ve_dpkg ('install', 'debconf');
1299
1300     # unpack required packages
1301     foreach my $p (@$required) {
1302         $self->ve_dpkg ('unpack', $p);
1303     }
1304
1305     rename ("$rootdir/sbin/init.org", "$rootdir/sbin/init");
1306     $self->ve_divert_add ("/sbin/init");
1307     $self->run_command ("cp '$fake_init' '$rootdir/sbin/init'");
1308
1309     # disable service activation
1310     $self->ve_divert_add ("/usr/sbin/policy-rc.d");
1311     $data = "#!/bin/sh\nexit 101\n";
1312     write_file ($data, "$rootdir/usr/sbin/policy-rc.d", 755);
1313
1314     # disable start-stop-daemon
1315     $self->ve_divert_add ("/sbin/start-stop-daemon");
1316     $data = <<EOD;
1317 #!/bin/sh
1318 echo
1319 echo \"Warning: Fake start-stop-daemon called, doing nothing\"
1320 EOD
1321     write_file ($data, "$rootdir/sbin/start-stop-daemon", 0755);
1322
1323     # disable udevd
1324     $self->ve_divert_add ("/sbin/udevd");
1325
1326     if ($suite eq 'etch') {
1327         # disable apache2 startup
1328         write_file ("NO_START=1\n", "$rootdir/etc/default/apache2");
1329     }
1330
1331     $self->logmsg ("configure required packages\n");
1332     $self->ve_command ("dpkg --force-confold --skip-same-version --configure -a");
1333
1334     # set postfix defaults
1335     if ($mta eq 'postfix') {
1336         $data = "postfix postfix/main_mailer_type select Local only\n";
1337         $self->ve_debconfig_set ($data);
1338
1339         $data = "postmaster: root\nwebmaster: root\n";
1340         write_file ($data, "$rootdir/etc/aliases");
1341     }
1342
1343     if ($suite eq 'jaunty') {
1344         # jaunty does not create /var/run/network, so network startup fails.
1345         # so we do not use tmpfs for /var/run and /var/lock
1346         $self->run_command ("sed -e 's/RAMRUN=yes/RAMRUN=no/' -e 's/RAMLOCK=yes/RAMLOCK=no/'  -i $rootdir/etc/default/rcS");
1347         # and create the directory here
1348         $self->run_command ("mkdir $rootdir/var/run/network");
1349     }
1350
1351     # unpack base packages
1352     foreach my $p (@$important) {
1353         $self->ve_dpkg ('unpack', $p);
1354     }
1355
1356     # start loopback
1357     if (-x "$rootdir/sbin/ifconfig") {
1358         $self->ve_command ("ifconfig lo up");
1359     } else {
1360         $self->ve_command ("ip link set lo up");
1361     }
1362
1363     $self->logmsg ("configure important packages\n");
1364     $self->ve_command ("dpkg --force-confold --skip-same-version --configure -a");
1365
1366     if (-d "$rootdir/etc/event.d") {
1367         unlink <$rootdir/etc/event.d/tty*>;
1368     }
1369
1370     if (-f "$rootdir/etc/inittab") {
1371         $self->run_command ("sed -i -e '/getty\\s38400\\stty[23456]/d' '$rootdir/etc/inittab'");
1372     }
1373
1374     # Link /etc/mtab to /proc/mounts, so df and friends will work:
1375     unlink "$rootdir/etc/mtab";
1376     $self->ve_command ("ln -s /proc/mounts /etc/mtab");
1377
1378     # reset password
1379     $self->ve_command ("usermod -L root");
1380
1381     if ($mta eq 'postfix') {
1382         $data = "postfix postfix/main_mailer_type select No configuration\n";
1383         $self->ve_debconfig_set ($data);
1384
1385         unlink "$rootdir/etc/mailname";
1386         write_file ($postfix_main_cf, "$rootdir/etc/postfix/main.cf");
1387     }
1388
1389     if (!$opts->{minimal}) {
1390         # unpack standard packages
1391         foreach my $p (@$standard) {
1392             $self->ve_dpkg ('unpack', $p);
1393         }
1394
1395         $self->logmsg ("configure standard packages\n");
1396         $self->ve_command ("dpkg --force-confold --skip-same-version --configure -a");
1397     }
1398
1399     # disable HWCLOCK access
1400     $self->run_command ("echo 'HWCLOCKACCESS=no' >> '$rootdir/etc/default/rcS'");
1401
1402     # disable hald
1403     $self->ve_divert_add ("/usr/sbin/hald");
1404
1405     # disable /dev/urandom init
1406     $self->run_command ("install -m 0755 '$script_init_urandom' '$rootdir/etc/init.d/urandom'");
1407
1408     if ($suite eq 'etch' || $suite eq 'hardy' || $suite eq 'intrepid' || $suite eq 'jaunty') {
1409         # avoid klogd start
1410         $self->ve_divert_add ("/sbin/klogd");
1411     }
1412
1413     # remove unnecessays sysctl entries to avoid warnings
1414     my $cmd = 'sed';
1415     $cmd .= ' -e \'s/^\(kernel\.printk.*\)/#\1/\'';
1416     $cmd .= ' -e \'s/^\(kernel\.maps_protect.*\)/#\1/\'';
1417     $cmd .= ' -e \'s/^\(fs\.inotify\.max_user_watches.*\)/#\1/\'';
1418     $cmd .= ' -e \'s/^\(vm\.mmap_min_addr.*\)/#\1/\'';
1419     $cmd .= " -i '$rootdir/etc/sysctl.conf'";
1420     $self->run_command ($cmd);
1421
1422     my $bindv6only = "$rootdir/etc/sysctl.d/bindv6only.conf";
1423     if (-f $bindv6only) {
1424         $cmd = 'sed';
1425         $cmd .= ' -e \'s/^\(net\.ipv6\.bindv6only.*\)/#\1/\'';
1426         $cmd .= " -i '$bindv6only'";
1427         $self->run_command ($cmd);
1428     }
1429
1430     if ($suite eq 'hardy' || $suite eq 'intrepid' || $suite eq 'jaunty') {
1431         # disable tty init (console-setup)
1432         my $cmd = 'sed';
1433         $cmd .= ' -e \'s/^\(ACTIVE_CONSOLES=.*\)/ACTIVE_CONSOLES=/\'';
1434         $cmd .= " -i '$rootdir/etc/default/console-setup'";
1435         $self->run_command ($cmd);
1436     }
1437
1438     if ($suite eq 'intrepid') {
1439         # remove sysctl setup (avoid warnings at startup)
1440         my $filelist = "$rootdir/etc/sysctl.d/10-console-messages.conf";
1441         $filelist .= " $rootdir/etc/sysctl.d/10-process-security.conf";
1442         $filelist .= " $rootdir/etc/sysctl.d/10-network-security.conf";
1443         $self->run_command ("rm $filelist");
1444     }
1445     if ($suite eq 'jaunty') {
1446         # remove sysctl setup (avoid warnings at startup)
1447         my $filelist = "$rootdir/etc/sysctl.d/10-console-messages.conf";
1448         $filelist .= " $rootdir/etc/sysctl.d/10-network-security.conf";
1449         $self->run_command ("rm $filelist");
1450     }
1451 }
1452
1453 sub enter {
1454     my ($self) = @_;
1455
1456     my $veid = $self->{veid};
1457     my $conffile = $self->{veconffile};
1458
1459     my $vestat = $self->ve_status();
1460
1461     if (!$vestat->{exist}) {
1462         $self->logmsg ("Please create the appliance first (bootstrap)");
1463         return;
1464     }
1465
1466     if (!$vestat->{running}) {
1467         $self->run_command ("lxc-start -n $veid -f $conffile");
1468     }
1469
1470     system ("lxc-attach -n $veid --rcfile $conffile --clear-env");
1471 }
1472
1473 sub ve_mysql_command {
1474     my ($self, $sql, $password) = @_;
1475
1476     #my $bootstrap = "/usr/sbin/mysqld --bootstrap --user=mysql --skip-grant-tables " .
1477     #"--skip-bdb  --skip-innodb --skip-ndbcluster";
1478
1479     $self->ve_command ("mysql", $sql);
1480 }
1481
1482 sub ve_mysql_bootstrap {
1483     my ($self, $sql, $password) = @_;
1484
1485     my $cmd;
1486
1487     my $suite = $self->{config}->{suite};
1488
1489     if ($suite eq 'jessie') {
1490         my $rootdir = $self->{rootfs};
1491         $self->run_command ("sed -e 's/^key_buffer\\s*=/key_buffer_size =/' -i $rootdir/etc/mysql/my.cnf");
1492     }
1493
1494     if ($suite eq 'squeeze' || $suite eq 'wheezy' || $suite eq 'jessie') {
1495         $cmd = "/usr/sbin/mysqld --bootstrap --user=mysql --skip-grant-tables";
1496
1497     } else {
1498         $cmd = "/usr/sbin/mysqld --bootstrap --user=mysql --skip-grant-tables " .
1499             "--skip-bdb  --skip-innodb --skip-ndbcluster";
1500     }
1501
1502     $self->ve_command ($cmd, $sql);
1503 }
1504
1505 sub compute_required {
1506     my ($self, $pkglist) = @_;
1507
1508     my $pkginfo = $self->pkginfo();
1509     my $instpkgs = $self->read_installed ();
1510
1511     my $closure = {};
1512     __record_provides ($pkginfo, $closure, [keys %$instpkgs]);
1513
1514     return $self->closure ($closure, $pkglist);
1515 }
1516
1517 sub task_postgres {
1518     my ($self, $opts) = @_;
1519
1520     my @supp = ('7.4', '8.1');
1521     my $pgversion = '8.1';
1522
1523     my $suite = $self->{config}->{suite};
1524
1525     if ($suite eq 'lenny' || $suite eq 'hardy' || $suite eq 'intrepid' || $suite eq 'jaunty') {
1526         @supp = ('8.3');
1527         $pgversion = '8.3';
1528     } elsif ($suite eq 'squeeze') {
1529         @supp = ('8.4');
1530         $pgversion = '8.4';
1531     } elsif ($suite eq 'wheezy') {
1532         @supp = ('9.1');
1533         $pgversion = '9.1';
1534     } elsif ($suite eq 'jessie') {
1535         @supp = ('9.4');
1536         $pgversion = '9.4';
1537     } elsif ($suite eq 'stretch') {
1538         @supp = ('9.6');
1539         $pgversion = '9.6';
1540     }
1541
1542     $pgversion = $opts->{version} if $opts->{version};
1543
1544     die "unsupported postgres version '$pgversion'\n"
1545         if !grep { $pgversion eq $_; } @supp;
1546
1547     my $rootdir = $self->{rootfs};
1548
1549     my $required = $self->compute_required (["postgresql-$pgversion"]);
1550
1551     $self->cache_packages ($required);
1552
1553     $self->ve_dpkg ('install', @$required);
1554
1555     my $iscript = "postgresql-$pgversion";
1556     if ($suite eq 'squeeze' || $suite eq 'wheezy' || $suite eq 'jessie' ||
1557         $suite eq 'stretch') {
1558         $iscript = 'postgresql';
1559     }
1560
1561     $self->ve_command ("/etc/init.d/$iscript start") if $opts->{start};
1562 }
1563
1564 sub task_mysql {
1565     my ($self, $opts) = @_;
1566
1567     my $password = $opts->{password};
1568     my $rootdir = $self->{rootfs};
1569
1570     my $suite = $self->{config}->{suite};
1571
1572     my $ver = '5.0';
1573     if ($suite eq 'squeeze') {
1574       $ver = '5.1';
1575     } elsif ($suite eq 'wheezy' || $suite eq 'jessie') {
1576       $ver = '5.5';
1577     } else {
1578         die "task_mysql: unsupported suite '$suite'";
1579     }
1580
1581     my $required = $self->compute_required (['mysql-common', "mysql-server-$ver"]);
1582
1583     $self->cache_packages ($required);
1584
1585     $self->ve_dpkg ('install', @$required);
1586
1587     # fix security (see /usr/bin/mysql_secure_installation)
1588     my $sql = "DELETE FROM mysql.user WHERE User='';\n" .
1589         "DELETE FROM mysql.user WHERE User='root' AND Host!='localhost';\n" .
1590         "FLUSH PRIVILEGES;\n";
1591     $self->ve_mysql_bootstrap ($sql);
1592
1593     if ($password) {
1594
1595         my $rpw = $password eq 'random' ? 'admin' : $password;
1596
1597         my $sql = "USE mysql;\n" .
1598             "UPDATE user SET password=PASSWORD(\"$rpw\") WHERE user='root';\n" .
1599             "FLUSH PRIVILEGES;\n";
1600         $self->ve_mysql_bootstrap ($sql);
1601
1602         write_file ("[client]\nuser=root\npassword=\"$rpw\"\n", "$rootdir/root/.my.cnf", 0600);
1603         if ($password eq 'random') {
1604             $self->install_init_script ($script_mysql_randompw, 2, 20);
1605         }
1606     }
1607
1608     $self->ve_command ("/etc/init.d/mysql start") if $opts->{start};
1609 }
1610
1611 sub task_php {
1612     my ($self, $opts) = @_;
1613
1614     my $memlimit = $opts->{memlimit};
1615     my $rootdir = $self->{rootfs};
1616
1617     my $required = $self->compute_required ([qw (php5 php5-cli libapache2-mod-php5 php5-gd)]);
1618
1619     $self->cache_packages ($required);
1620
1621     $self->ve_dpkg ('install', @$required);
1622
1623     if ($memlimit) {
1624         $self->run_command ("sed -e 's/^\\s*memory_limit\\s*=.*;/memory_limit = ${memlimit}M;/' -i $rootdir/etc/php5/apache2/php.ini");
1625     }
1626 }
1627
1628 sub install {
1629     my ($self, $pkglist, $unpack) = @_;
1630
1631     my $required = $self->compute_required ($pkglist);
1632
1633     $self->cache_packages ($required);
1634
1635     $self->ve_dpkg ($unpack ? 'unpack' : 'install', @$required);
1636 }
1637
1638 sub cleanup {
1639     my ($self, $distclean) = @_;
1640
1641     unlink $self->{logfile};
1642     unlink "$self->{targetname}.tar";
1643     unlink "$self->{targetname}.tar.gz";
1644
1645     $self->ve_destroy ();
1646     unlink ".veid";
1647
1648     rmtree $self->{cachedir} if $distclean && !$self->{config}->{cachedir};
1649
1650     rmtree $self->{infodir};
1651
1652 }
1653
1654 1;