elf_arm_efi.lds

   1 OUTPUT_FORMAT("elf32-littlearm", "elf32-littlearm", "elf32-littlearm")
   2 OUTPUT_ARCH(arm)
   3 ENTRY(_start)
   4 SECTIONS
   5 {
   6   .text 0x0 : {
   7     _text = .;
   8     *(.text.head)
   9     *(.text)
  10     *(.text.*)
  11     *(.gnu.linkonce.t.*)
  12     *(.srodata)
  13     *(.rodata*)
  14     . = ALIGN(16);
  15     _etext = .;
  16   }
  17   .dynamic  : { *(.dynamic) }
  18
  19   . = ALIGN(4096);
  20   .note.gnu.build-id : {
  21     *(.note.gnu.build-id)
  22   }
  23
  24   . = ALIGN(4096);
  25   .data.ident : {
  26     *(.data.ident)
  27   }
  28
  29   . = ALIGN(4096);
  30   .data :
  31   {
  32    _data = .;
  33    *(.sdata)
  34    *(.data)
  35    *(.data1)
  36    *(.data*)
  37    *(.got.plt)
  38    *(.got)
  39
  40    /* the EFI loader doesn't seem to like a .bss section, so we stick
  41       it all into .data: */
  42    . = ALIGN(16);
  43    _bss = .;
  44    *(.sbss)
  45    *(.scommon)
  46    *(.dynbss)
  47    *(.bss)
  48    *(COMMON)
  49    . = ALIGN(16);
  50    _bss_end = .;
  51   }
  52
  53   . = ALIGN(4096);
  54   .vendor_cert :
  55   {
  56     *(.vendor_cert)
  57   }
  58   . = ALIGN(4096);
  59   .rel :
  60   {
  61     *(.rel.dyn)
  62     *(.rel.plt)
  63     *(.rel.got)
  64     *(.rel.data)
  65     *(.rel.data*)
  66   }
  67   _edata = .;
  68   _data_size = . - _data;
  69   . = ALIGN(4096);
  70   .sbat :
  71   {
  72     _sbat = .;
  73     *(.sbat)
  74     *(.sbat.*)
  75   }
  76   _esbat = .;
  77   _sbat_vsize = . - _sbat;
  78   . = ALIGN(4096);
  79   _sbat_size = . - _sbat;
  80   _alldata_size = . - _data;
  81
  82   . = ALIGN(4096);
  83   .dynsym   : { *(.dynsym) }
  84   . = ALIGN(4096);
  85   .dynstr   : { *(.dynstr) }
  86   . = ALIGN(4096);
  87   /DISCARD/ :
  88   {
  89     *(.rel.reloc)
  90     *(.eh_frame)
  91     *(.note.GNU-stack)
  92   }
  93   .comment 0 : { *(.comment) }
  94 }