cmake/SelectGSSAPI.cmake

   1 INCLUDE(SanitizeBool)
   2
   3 # We try to find any packages our backends might use
   4 FIND_PACKAGE(GSSAPI)
   5 IF (CMAKE_SYSTEM_NAME MATCHES "Darwin")
   6         INCLUDE(FindGSSFramework)
   7 ENDIF()
   8
   9 IF(USE_GSSAPI)
  10         # Auto-select GSS backend
  11         SanitizeBool(USE_GSSAPI)
  12         IF (USE_GSSAPI STREQUAL ON)
  13                 IF (GSSFRAMEWORK_FOUND)
  14                         SET(USE_GSSAPI "GSS.framework")
  15                 ELSEIF(GSSAPI_FOUND)
  16                         SET(USE_GSSAPI "gssapi")
  17                 ELSE()
  18                         MESSAGE(FATAL_ERROR "Unable to autodetect a usable GSS backend."
  19                                 "Please pass the backend name explicitly (-DUSE_GSS=backend)")
  20                 ENDIF()
  21         ENDIF()
  22
  23         # Check that we can find what's required for the selected backend
  24         IF (USE_GSSAPI STREQUAL "GSS.framework")
  25                 IF (NOT GSSFRAMEWORK_FOUND)
  26                         MESSAGE(FATAL_ERROR "Asked for GSS.framework backend, but it wasn't found")
  27                 ENDIF()
  28
  29                 LIST(APPEND LIBGIT2_LIBS ${GSSFRAMEWORK_LIBRARIES})
  30
  31                 SET(GIT_GSSFRAMEWORK 1)
  32                 ADD_FEATURE_INFO(SPNEGO GIT_GSSFRAMEWORK "SPNEGO authentication support (${USE_GSSAPI})")
  33         ELSEIF (USE_GSSAPI STREQUAL "gssapi")
  34                 IF (NOT GSSAPI_FOUND)
  35                         MESSAGE(FATAL_ERROR "Asked for gssapi GSS backend, but it wasn't found")
  36                 ENDIF()
  37
  38                 LIST(APPEND LIBGIT2_LIBS ${GSSAPI_LIBRARIES})
  39
  40                 SET(GIT_GSSAPI 1)
  41                 ADD_FEATURE_INFO(SPNEGO GIT_GSSAPI "SPNEGO authentication support (${USE_GSSAPI})")
  42         ELSE()
  43                 MESSAGE(FATAL_ERROR "Asked for backend ${USE_GSSAPI} but it wasn't found")
  44         ENDIF()
  45 ELSE()
  46         SET(GIT_GSSAPI 0)
  47         ADD_FEATURE_INFO(SPNEGO NO "SPNEGO authentication support")
  48 ENDIF()