ArmPlatformPkg/ArmPlatformStackLib: use callee preserved registers

[mirror_edk2.git] / ArmPlatformPkg / Library / ArmPlatformStackLib / AArch64 / ArmPlatformStackLib.S

//\r
//  Copyright (c) 2012-2014, ARM Limited. All rights reserved.\r
//\r
//  This program and the accompanying materials\r
//  are licensed and made available under the terms and conditions of the BSD License\r
//  which accompanies this distribution.  The full text of the license may be found at\r
//  http://opensource.org/licenses/bsd-license.php\r
//\r
//  THE PROGRAM IS DISTRIBUTED UNDER THE BSD LICENSE ON AN "AS IS" BASIS,\r
//  WITHOUT WARRANTIES OR REPRESENTATIONS OF ANY KIND, EITHER EXPRESS OR IMPLIED.\r
//\r
//\r
\r
#include <AsmMacroIoLibV8.h>\r
\r
//VOID\r
//ArmPlatformStackSet (\r
//  IN UINTN StackBase,\r
//  IN UINTN MpId,\r
//  IN UINTN PrimaryStackSize,\r
//  IN UINTN SecondaryStackSize\r
//  );\r
ASM_FUNC(ArmPlatformStackSet)\r
  // Save parameters\r
  mov   x26, x3\r
  mov   x25, x2\r
  mov   x24, x1\r
  mov   x23, x0\r
\r
  // Save the Link register\r
  mov   x27, x30\r
\r
  // Identify Stack\r
  mov   x0, x1\r
  bl    ASM_PFX(ArmPlatformIsPrimaryCore)\r
  cmp   x0, #1\r
\r
  // Restore parameters\r
  mov   x0, x23\r
  mov   x1, x24\r
  mov   x2, x25\r
  mov   x3, x26\r
\r
  // Restore the Link register\r
  mov   x30, x27\r
\r
  b.ne  0f\r
\r
  b     ASM_PFX(ArmPlatformStackSetPrimary)\r
0:b     ASM_PFX(ArmPlatformStackSetSecondary)\r
\r
//VOID\r
//ArmPlatformStackSetPrimary (\r
//  IN UINTN StackBase,\r
//  IN UINTN MpId,\r
//  IN UINTN PrimaryStackSize,\r
//  IN UINTN SecondaryStackSize\r
//  );\r
ASM_FUNC(ArmPlatformStackSetPrimary)\r
  // Add size of primary stack to StackBase\r
  add   x0, x0, x2\r
\r
  // Compute SecondaryCoresCount * SecondaryCoreStackSize\r
  MOV32 (w1, FixedPcdGet32(PcdCoreCount) - 1)\r
  mul   x3, x3, x1\r
\r
  // Set Primary Stack ((StackBase + PrimaryStackSize) + (SecondaryCoresCount * SecondaryCoreStackSize))\r
  add   sp, x0, x3\r
\r
  ret\r
\r
//VOID\r
//ArmPlatformStackSetSecondary (\r
//  IN UINTN StackBase,\r
//  IN UINTN MpId,\r
//  IN UINTN PrimaryStackSize,\r
//  IN UINTN SecondaryStackSize\r
//  );\r
ASM_FUNC(ArmPlatformStackSetSecondary)\r
  // Save the Link register\r
  mov   x24, x30\r
  mov   sp, x0\r
\r
  // Get Core Position\r
  mov   x0, x1\r
  bl    ASM_PFX(ArmPlatformGetCorePosition)\r
  mov   x25, x0\r
\r
  // Get Primary Core Position\r
  bl    ASM_PFX(ArmPlatformGetPrimaryCoreMpId)\r
  bl    ASM_PFX(ArmPlatformGetCorePosition)\r
\r
  // Get Secondary Core Position. We should get consecutive secondary stack number from 1...(CoreCount-1)\r
  cmp   x25, x0\r
\r
  // Decrement the position if after the primary core\r
  cinc  x25, x25, ls\r
\r
  // Compute top of the secondary stack\r
  mul   x3, x3, x25\r
\r
  // Set stack\r
  add   sp, sp, x3\r
\r
  ret   x24\r