ArmPlatformPkg: use correct ASM decoration for non-function global symbols

[mirror_edk2.git] / ArmPlatformPkg / PrePi / AArch64 / ModuleEntryPoint.S

//\r
//  Copyright (c) 2011-2015, ARM Limited. All rights reserved.\r
//\r
//  This program and the accompanying materials\r
//  are licensed and made available under the terms and conditions of the BSD License\r
//  which accompanies this distribution.  The full text of the license may be found at\r
//  http://opensource.org/licenses/bsd-license.php\r
//\r
//  THE PROGRAM IS DISTRIBUTED UNDER THE BSD LICENSE ON AN "AS IS" BASIS,\r
//  WITHOUT WARRANTIES OR REPRESENTATIONS OF ANY KIND, EITHER EXPRESS OR IMPLIED.\r
//\r
//\r
\r
#include <AsmMacroIoLibV8.h>\r
#include <Base.h>\r
#include <Library/PcdLib.h>\r
#include <AutoGen.h>\r
\r
.text\r
.align 3\r
\r
GCC_ASM_IMPORT(ArmPlatformIsPrimaryCore)\r
GCC_ASM_IMPORT(ArmReadMpidr)\r
GCC_ASM_IMPORT(ArmPlatformPeiBootAction)\r
GCC_ASM_IMPORT(ArmPlatformStackSet)\r
GCC_ASM_EXPORT(_ModuleEntryPoint)\r
ASM_GLOBAL ASM_PFX(mSystemMemoryEnd)\r
\r
StartupAddr:                  .8byte ASM_PFX(CEntryPoint)\r
ASM_PFX(mSystemMemoryEnd):    .8byte 0\r
\r
ASM_PFX(_ModuleEntryPoint):\r
  // Do early platform specific actions\r
  bl    ASM_PFX(ArmPlatformPeiBootAction)\r
\r
  // Get ID of this CPU in Multicore system\r
  bl    ASM_PFX(ArmReadMpidr)\r
  // Keep a copy of the MpId register value\r
  mov   x10, x0\r
\r
_SetSVCMode:\r
// Check if we can install the stack at the top of the System Memory or if we need\r
// to install the stacks at the bottom of the Firmware Device (case the FD is located\r
// at the top of the DRAM)\r
_SystemMemoryEndInit:\r
  ldr   x1, mSystemMemoryEnd\r
\r
  // Is mSystemMemoryEnd initialized?\r
  cmp   x1, #0\r
  bne   _SetupStackPosition\r
\r
  LoadConstantToReg (FixedPcdGet32(PcdSystemMemoryBase), x1)\r
  LoadConstantToReg (FixedPcdGet32(PcdSystemMemorySize), x2)\r
  sub   x2, x2, #1\r
  add   x1, x1, x2\r
  // Update the global variable\r
  adr   x2, mSystemMemoryEnd\r
  str   x1, [x2]\r
\r
_SetupStackPosition:\r
  // r1 = SystemMemoryTop\r
\r
  // Calculate Top of the Firmware Device\r
  LoadConstantToReg (FixedPcdGet32(PcdFdBaseAddress), x2)\r
  LoadConstantToReg (FixedPcdGet32(PcdFdSize), x3)\r
  sub   x3, x3, #1\r
  add   x3, x3, x2      // x3 = FdTop = PcdFdBaseAddress + PcdFdSize\r
\r
  // UEFI Memory Size (stacks are allocated in this region)\r
  LoadConstantToReg (FixedPcdGet32(PcdSystemMemoryUefiRegionSize), x4)\r
\r
  //\r
  // Reserve the memory for the UEFI region (contain stacks on its top)\r
  //\r
\r
  // Calculate how much space there is between the top of the Firmware and the Top of the System Memory\r
  subs  x0, x1, x3   // x0 = SystemMemoryTop - FdTop\r
  b.mi  _SetupStack  // Jump if negative (FdTop > SystemMemoryTop). Case when the PrePi is in XIP memory outside of the DRAM\r
  cmp   x0, x4\r
  b.ge  _SetupStack\r
\r
  // Case the top of stacks is the FdBaseAddress\r
  mov   x1, x2\r
\r
_SetupStack:\r
  // x1 contains the top of the stack (and the UEFI Memory)\r
\r
  // Because the 'push' instruction is equivalent to 'stmdb' (decrement before), we need to increment\r
  // one to the top of the stack. We check if incrementing one does not overflow (case of DRAM at the\r
  // top of the memory space)\r
  adds  x11, x1, #1\r
  b.cs  _SetupOverflowStack\r
\r
_SetupAlignedStack:\r
  mov   x1, x11\r
  b     _GetBaseUefiMemory\r
\r
_SetupOverflowStack:\r
  // Case memory at the top of the address space. Ensure the top of the stack is EFI_PAGE_SIZE\r
  // aligned (4KB)\r
  LoadConstantToReg (EFI_PAGE_MASK, x11)\r
  and   x11, x11, x1\r
  sub   x1, x1, x11\r
\r
_GetBaseUefiMemory:\r
  // Calculate the Base of the UEFI Memory\r
  sub   x11, x1, x4\r
\r
_GetStackBase:\r
  // r1 = The top of the Mpcore Stacks\r
  // Stack for the primary core = PrimaryCoreStack\r
  LoadConstantToReg (FixedPcdGet32(PcdCPUCorePrimaryStackSize), x2)\r
  sub   x12, x1, x2\r
\r
  // Stack for the secondary core = Number of Cores - 1\r
  LoadConstantToReg (FixedPcdGet32(PcdCoreCount), x0)\r
  sub   x0, x0, #1\r
  LoadConstantToReg (FixedPcdGet32(PcdCPUCoreSecondaryStackSize), x1)\r
  mul   x1, x1, x0\r
  sub   x12, x12, x1\r
\r
  // x12 = The base of the MpCore Stacks (primary stack & secondary stacks)\r
  mov   x0, x12\r
  mov   x1, x10\r
  //ArmPlatformStackSet(StackBase, MpId, PrimaryStackSize, SecondaryStackSize)\r
  LoadConstantToReg (FixedPcdGet32(PcdCPUCorePrimaryStackSize), x2)\r
  LoadConstantToReg (FixedPcdGet32(PcdCPUCoreSecondaryStackSize), x3)\r
  bl    ASM_PFX(ArmPlatformStackSet)\r
\r
  // Is it the Primary Core ?\r
  mov   x0, x10\r
  bl    ASM_PFX(ArmPlatformIsPrimaryCore)\r
  cmp   x0, #1\r
  bne   _PrepareArguments\r
\r
_ReserveGlobalVariable:\r
  LoadConstantToReg (FixedPcdGet32(PcdPeiGlobalVariableSize), x0)\r
  // InitializePrimaryStack($GlobalVariableSize, $Tmp1, $Tmp2)\r
  InitializePrimaryStack(x0, x1, x2)\r
\r
_PrepareArguments:\r
  mov   x0, x10\r
  mov   x1, x11\r
  mov   x2, x12\r
  mov   x3, sp\r
\r
  // Move sec startup address into a data register\r
  // Ensure we're jumping to FV version of the code (not boot remapped alias)\r
  ldr   x4, StartupAddr\r
\r
  // Jump to PrePiCore C code\r
  //    x0 = MpId\r
  //    x1 = UefiMemoryBase\r
  //    x2 = StacksBase\r
  //    x3 = GlobalVariableBase\r
  blr   x4\r
\r
_NeverReturn:\r
  b _NeverReturn\r