ArmVirt/PrePi: make jump to CEntryPoint relative

[mirror_edk2.git] / ArmVirtPkg / PrePi / AArch64 / ModuleEntryPoint.S

//\r
//  Copyright (c) 2011-2013, ARM Limited. All rights reserved.\r
//  Copyright (c) 2015, Linaro Limited. All rights reserved.\r
//\r
//  This program and the accompanying materials\r
//  are licensed and made available under the terms and conditions of the BSD License\r
//  which accompanies this distribution.  The full text of the license may be found at\r
//  http://opensource.org/licenses/bsd-license.php\r
//\r
//  THE PROGRAM IS DISTRIBUTED UNDER THE BSD LICENSE ON AN "AS IS" BASIS,\r
//  WITHOUT WARRANTIES OR REPRESENTATIONS OF ANY KIND, EITHER EXPRESS OR IMPLIED.\r
//\r
//\r
\r
#include <AsmMacroIoLibV8.h>\r
#include <Base.h>\r
#include <Library/PcdLib.h>\r
#include <AutoGen.h>\r
\r
.text\r
.align 3\r
\r
GCC_ASM_IMPORT(ArmPlatformIsPrimaryCore)\r
GCC_ASM_IMPORT(ArmReadMpidr)\r
GCC_ASM_IMPORT(ArmPlatformPeiBootAction)\r
GCC_ASM_IMPORT(ArmPlatformStackSet)\r
GCC_ASM_EXPORT(_ModuleEntryPoint)\r
ASM_GLOBAL ASM_PFX(mSystemMemoryEnd)\r
\r
ASM_PFX(mSystemMemoryEnd):    .8byte 0\r
\r
ASM_PFX(_ModuleEntryPoint):\r
  //\r
  // We are built as a ET_DYN PIE executable, so we need to process all\r
  // relative relocations regardless of whether or not we are executing from\r
  // the same offset we were linked at. This is only possible if we are\r
  // running from RAM.\r
  //\r
  adr   x8, __reloc_base\r
  adr   x9, __reloc_start\r
  adr   x10, __reloc_end\r
\r
.Lreloc_loop:\r
  cmp   x9, x10\r
  bhs   .Lreloc_done\r
\r
  //\r
  // AArch64 uses the ELF64 RELA format, which means each entry in the\r
  // relocation table consists of\r
  //\r
  //   UINT64 offset          : the relative offset of the value that needs to\r
  //                            be relocated\r
  //   UINT64 info            : relocation type and symbol index (the latter is\r
  //                            not used for R_AARCH64_RELATIVE relocations)\r
  //   UINT64 addend          : value to be added to the value being relocated\r
  //\r
  ldp   x11, x12, [x9], #24   // read offset into x11 and info into x12\r
  cmp   x12, #0x403           // check info == R_AARCH64_RELATIVE?\r
  bne   .Lreloc_loop          // not a relative relocation? then skip\r
\r
  ldr   x12, [x9, #-8]        // read addend into x12\r
  add   x12, x12, x8          // add reloc base to addend to get relocated value\r
  str   x12, [x11, x8]        // write relocated value at offset\r
  b     .Lreloc_loop\r
.Lreloc_done:\r
\r
  // Do early platform specific actions\r
  bl    ASM_PFX(ArmPlatformPeiBootAction)\r
\r
  // Get ID of this CPU in Multicore system\r
  bl    ASM_PFX(ArmReadMpidr)\r
  // Keep a copy of the MpId register value\r
  mov   x20, x0\r
\r
// Check if we can install the stack at the top of the System Memory or if we need\r
// to install the stacks at the bottom of the Firmware Device (case the FD is located\r
// at the top of the DRAM)\r
_SetupStackPosition:\r
  // Compute Top of System Memory\r
  ldr   x1, PcdGet64 (PcdSystemMemoryBase)\r
  ldr   x2, PcdGet64 (PcdSystemMemorySize)\r
  sub   x2, x2, #1\r
  add   x1, x1, x2      // x1 = SystemMemoryTop = PcdSystemMemoryBase + PcdSystemMemorySize\r
  adr   x2, mSystemMemoryEnd\r
  str   x1, [x2]\r
\r
  // Calculate Top of the Firmware Device\r
  ldr   x2, PcdGet64 (PcdFdBaseAddress)\r
  ldr   w3, PcdGet32 (PcdFdSize)\r
  sub   x3, x3, #1\r
  add   x3, x3, x2      // x3 = FdTop = PcdFdBaseAddress + PcdFdSize\r
\r
  // UEFI Memory Size (stacks are allocated in this region)\r
  LoadConstantToReg (FixedPcdGet32(PcdSystemMemoryUefiRegionSize), x4)\r
\r
  //\r
  // Reserve the memory for the UEFI region (contain stacks on its top)\r
  //\r
\r
  // Calculate how much space there is between the top of the Firmware and the Top of the System Memory\r
  subs  x0, x1, x3   // x0 = SystemMemoryTop - FdTop\r
  b.mi  _SetupStack  // Jump if negative (FdTop > SystemMemoryTop). Case when the PrePi is in XIP memory outside of the DRAM\r
  cmp   x0, x4\r
  b.ge  _SetupStack\r
\r
  // Case the top of stacks is the FdBaseAddress\r
  mov   x1, x2\r
\r
_SetupStack:\r
  // x1 contains the top of the stack (and the UEFI Memory)\r
\r
  // Because the 'push' instruction is equivalent to 'stmdb' (decrement before), we need to increment\r
  // one to the top of the stack. We check if incrementing one does not overflow (case of DRAM at the\r
  // top of the memory space)\r
  adds  x21, x1, #1\r
  b.cs  _SetupOverflowStack\r
\r
_SetupAlignedStack:\r
  mov   x1, x21\r
  b     _GetBaseUefiMemory\r
\r
_SetupOverflowStack:\r
  // Case memory at the top of the address space. Ensure the top of the stack is EFI_PAGE_SIZE\r
  // aligned (4KB)\r
  LoadConstantToReg (EFI_PAGE_MASK, x21)\r
  and   x21, x21, x1\r
  sub   x1, x1, x21\r
\r
_GetBaseUefiMemory:\r
  // Calculate the Base of the UEFI Memory\r
  sub   x21, x1, x4\r
\r
_GetStackBase:\r
  // r1 = The top of the Mpcore Stacks\r
  // Stack for the primary core = PrimaryCoreStack\r
  LoadConstantToReg (FixedPcdGet32(PcdCPUCorePrimaryStackSize), x2)\r
  sub   x22, x1, x2\r
\r
  // Stack for the secondary core = Number of Cores - 1\r
  LoadConstantToReg (FixedPcdGet32(PcdCoreCount), x0)\r
  sub   x0, x0, #1\r
  LoadConstantToReg (FixedPcdGet32(PcdCPUCoreSecondaryStackSize), x1)\r
  mul   x1, x1, x0\r
  sub   x22, x22, x1\r
\r
  // x22 = The base of the MpCore Stacks (primary stack & secondary stacks)\r
  mov   x0, x22\r
  mov   x1, x20\r
  //ArmPlatformStackSet(StackBase, MpId, PrimaryStackSize, SecondaryStackSize)\r
  LoadConstantToReg (FixedPcdGet32(PcdCPUCorePrimaryStackSize), x2)\r
  LoadConstantToReg (FixedPcdGet32(PcdCPUCoreSecondaryStackSize), x3)\r
  bl    ASM_PFX(ArmPlatformStackSet)\r
\r
  // Is it the Primary Core ?\r
  mov   x0, x10\r
  bl    ASM_PFX(ArmPlatformIsPrimaryCore)\r
  cmp   x0, #1\r
  bne   _PrepareArguments\r
\r
_PrepareArguments:\r
  mov   x0, x20\r
  mov   x1, x21\r
  mov   x2, x22\r
\r
  // Jump to PrePiCore C code\r
  //    x0 = MpId\r
  //    x1 = UefiMemoryBase\r
  //    x2 = StacksBase\r
  bl    ASM_PFX(CEntryPoint)\r
\r
_NeverReturn:\r
  b _NeverReturn\r