ArmVirtPkg: clean up assembly source files

[mirror_edk2.git] / ArmVirtPkg / PrePi / Arm / ModuleEntryPoint.S

//\r
//  Copyright (c) 2011-2013, ARM Limited. All rights reserved.\r
//  Copyright (c) 2015-2016, Linaro Limited. All rights reserved.\r
//\r
//  This program and the accompanying materials\r
//  are licensed and made available under the terms and conditions of the BSD License\r
//  which accompanies this distribution.  The full text of the license may be found at\r
//  http://opensource.org/licenses/bsd-license.php\r
//\r
//  THE PROGRAM IS DISTRIBUTED UNDER THE BSD LICENSE ON AN "AS IS" BASIS,\r
//  WITHOUT WARRANTIES OR REPRESENTATIONS OF ANY KIND, EITHER EXPRESS OR IMPLIED.\r
//\r
//\r
\r
#include <AsmMacroIoLib.h>\r
\r
ASM_GLOBAL ASM_PFX(mSystemMemoryEnd)\r
\r
ASM_FUNC(_ModuleEntryPoint)\r
  //\r
  // We are built as a ET_DYN PIE executable, so we need to process all\r
  // relative relocations if we are executing from a different offset than we\r
  // were linked at. This is only possible if we are running from RAM.\r
  //\r
  ADRL  (r4, __reloc_base)\r
  ADRL  (r5, __reloc_start)\r
  ADRL  (r6, __reloc_end)\r
\r
.Lreloc_loop:\r
  cmp   r5, r6\r
  bhs   .Lreloc_done\r
\r
  //\r
  // AArch32 uses the ELF32 REL format, which means each entry in the\r
  // relocation table consists of\r
  //\r
  //   UINT32 offset          : the relative offset of the value that needs to\r
  //                            be relocated\r
  //   UINT32 info            : relocation type and symbol index (the latter is\r
  //                            not used for R_ARM_RELATIVE relocations)\r
  //\r
  ldrd  r8, r9, [r5], #8      // read offset into r8 and info into r9\r
  cmp   r9, #23               // check info == R_ARM_RELATIVE?\r
  bne   .Lreloc_loop          // not a relative relocation? then skip\r
\r
  ldr   r9, [r8, r4]          // read addend into r9\r
  add   r9, r9, r1            // add image base to addend to get relocated value\r
  str   r9, [r8, r4]          // write relocated value at offset\r
  b     .Lreloc_loop\r
.Lreloc_done:\r
\r
  // Do early platform specific actions\r
  bl    ASM_PFX(ArmPlatformPeiBootAction)\r
\r
  // Get ID of this CPU in Multicore system\r
  bl    ASM_PFX(ArmReadMpidr)\r
  // Keep a copy of the MpId register value\r
  mov   r10, r0\r
\r
// Check if we can install the stack at the top of the System Memory or if we need\r
// to install the stacks at the bottom of the Firmware Device (case the FD is located\r
// at the top of the DRAM)\r
_SetupStackPosition:\r
  // Compute Top of System Memory\r
  LDRL  (r1, PcdGet64 (PcdSystemMemoryBase))\r
  ADRL  (r12, PcdGet64 (PcdSystemMemorySize))\r
  ldrd  r2, r3, [r12]\r
\r
  // calculate the top of memory, and record it in mSystemMemoryEnd\r
  adds  r2, r2, r1\r
  sub   r2, r2, #1\r
  addcs r3, r3, #1\r
  adr   r12, mSystemMemoryEnd\r
  strd  r2, r3, [r12]\r
\r
  // truncate the memory used by UEFI to 4 GB range\r
  teq   r3, #0\r
  movne r1, #-1\r
  moveq r1, r2\r
\r
  // Calculate Top of the Firmware Device\r
  LDRL  (r2, PcdGet64 (PcdFdBaseAddress))\r
  MOV32 (r3, FixedPcdGet32 (PcdFdSize) - 1)\r
  add   r3, r3, r2      // r3 = FdTop = PcdFdBaseAddress + PcdFdSize\r
\r
  // UEFI Memory Size (stacks are allocated in this region)\r
  MOV32 (r4, FixedPcdGet32(PcdSystemMemoryUefiRegionSize))\r
\r
  //\r
  // Reserve the memory for the UEFI region (contain stacks on its top)\r
  //\r
\r
  // Calculate how much space there is between the top of the Firmware and the Top of the System Memory\r
  subs  r0, r1, r3   // r0 = SystemMemoryTop - FdTop\r
  bmi   _SetupStack  // Jump if negative (FdTop > SystemMemoryTop). Case when the PrePi is in XIP memory outside of the DRAM\r
  cmp   r0, r4\r
  bge   _SetupStack\r
\r
  // Case the top of stacks is the FdBaseAddress\r
  mov   r1, r2\r
\r
_SetupStack:\r
  // r1 contains the top of the stack (and the UEFI Memory)\r
\r
  // Because the 'push' instruction is equivalent to 'stmdb' (decrement before), we need to increment\r
  // one to the top of the stack. We check if incrementing one does not overflow (case of DRAM at the\r
  // top of the memory space)\r
  adds  r11, r1, #1\r
  bcs   _SetupOverflowStack\r
\r
_SetupAlignedStack:\r
  mov   r1, r11\r
  b     _GetBaseUefiMemory\r
\r
_SetupOverflowStack:\r
  // Case memory at the top of the address space. Ensure the top of the stack is EFI_PAGE_SIZE\r
  // aligned (4KB)\r
  MOV32 (r11, (~EFI_PAGE_MASK) & 0xffffffff)\r
  and   r1, r1, r11\r
\r
_GetBaseUefiMemory:\r
  // Calculate the Base of the UEFI Memory\r
  sub   r11, r1, r4\r
\r
_GetStackBase:\r
  // r1 = The top of the Mpcore Stacks\r
  // Stack for the primary core = PrimaryCoreStack\r
  MOV32 (r2, FixedPcdGet32(PcdCPUCorePrimaryStackSize))\r
  sub   r9, r1, r2\r
\r
  // Stack for the secondary core = Number of Cores - 1\r
  MOV32 (r1, (FixedPcdGet32(PcdCoreCount) - 1) * FixedPcdGet32(PcdCPUCoreSecondaryStackSize))\r
  sub   r9, r9, r1\r
\r
  // r9 = The base of the MpCore Stacks (primary stack & secondary stacks)\r
  mov   r0, r9\r
  mov   r1, r10\r
  //ArmPlatformStackSet(StackBase, MpId, PrimaryStackSize, SecondaryStackSize)\r
  MOV32 (r2, FixedPcdGet32(PcdCPUCorePrimaryStackSize))\r
  MOV32 (r3, FixedPcdGet32(PcdCPUCoreSecondaryStackSize))\r
  bl    ASM_PFX(ArmPlatformStackSet)\r
\r
  // Is it the Primary Core ?\r
  mov   r0, r10\r
  bl    ASM_PFX(ArmPlatformIsPrimaryCore)\r
  cmp   r0, #1\r
  bne   _PrepareArguments\r
\r
_PrepareArguments:\r
  mov   r0, r10\r
  mov   r1, r11\r
  mov   r2, r9\r
\r
  // Jump to PrePiCore C code\r
  //    r0 = MpId\r
  //    r1 = UefiMemoryBase\r
  //    r2 = StacksBase\r
  bl    ASM_PFX(CEntryPoint)\r
\r
_NeverReturn:\r
  b _NeverReturn\r
\r
ASM_PFX(mSystemMemoryEnd):    .quad 0\r