BaseTools/VfrCompile: Remove framework VFR support

[mirror_edk2.git] / BaseTools / get_vsvars.bat

@REM @file\r
@REM   Windows batch file to find the Visual Studio set up script\r
@REM\r
@REM Copyright (c) 2013-2014, ARM Limited. All rights reserved.\r
\r
@REM SPDX-License-Identifier: BSD-2-Clause-Patent\r
@REM\r
\r
\r
@echo off\r
goto  :main\r
\r
:set_vsvars\r
for /f "usebackq tokens=1* delims=: " %%i in (`%*`) do (\r
  if /i "%%i"=="installationPath" call "%%j\VC\Auxiliary\Build\vcvars32.bat"\r
)\r
goto :EOF\r
\r
:read_vsvars\r
@rem Do nothing if already found, otherwise call vsvars32.bat if there\r
if defined VCINSTALLDIR goto :EOF\r
  set GET_VSVARS_BAT_CHECK_DIR=%*\r
  set GET_VSVARS_BAT_CHECK_DIR=%GET_VSVARS_BAT_CHECK_DIR:"=%\r
  if exist  "%GET_VSVARS_BAT_CHECK_DIR%\vsvars32.bat"  call "%GET_VSVARS_BAT_CHECK_DIR%\vsvars32.bat"\r
:vsvars_done\r
goto :EOF\r
\r
\r
REM NOTE: This file will find the most recent Visual Studio installation\r
REM       apparent from the environment.\r
REM       To use an older version, modify your environment set up.\r
REM       (Or invoke the relevant vsvars32 file beforehand).\r
\r
:main\r
if defined VCINSTALLDIR goto :done\r
  if exist "%ProgramFiles(x86)%\Microsoft Visual Studio\Installer\vswhere.exe"  call :set_vsvars "%ProgramFiles(x86)%\Microsoft Visual Studio\Installer\vswhere.exe"\r
  if exist "%ProgramFiles%\Microsoft Visual Studio\Installer\vswhere.exe"       call :set_vsvars "%ProgramFiles%\Microsoft Visual Studio\Installer\vswhere.exe"\r
  if defined VS140COMNTOOLS  call :read_vsvars  "%VS140COMNTOOLS%"\r
  if defined VS120COMNTOOLS  call :read_vsvars  "%VS120COMNTOOLS%"\r
  if defined VS110COMNTOOLS  call :read_vsvars  "%VS110COMNTOOLS%"\r
  if defined VS100COMNTOOLS  call :read_vsvars  "%VS100COMNTOOLS%"\r
  if defined VS90COMNTOOLS   call :read_vsvars  "%VS90COMNTOOLS%"\r
  if defined VS80COMNTOOLS   call :read_vsvars  "%VS80COMNTOOLS%"\r
  if defined VS71COMNTOOLS   call :read_vsvars  "%VS71COMNTOOLS%"\r
\r
:done\r
set GET_VSVARS_BAT_CHECK_DIR=\r