Update the copyright notice format

[mirror_edk2.git] / EdkCompatibilityPkg / Foundation / Library / EfiCommonLib / Ia32 / EfiSetMem.asm

;/*++\r
;\r
;Copyright (c) 2006, Intel Corporation. All rights reserved.<BR>\r
;This program and the accompanying materials                          \r
;are licensed and made available under the terms and conditions of the BSD License         \r
;which accompanies this distribution.  The full text of the license may be found at        \r
;http://opensource.org/licenses/bsd-license.php                                            \r
;                                                                                          \r
;THE PROGRAM IS DISTRIBUTED UNDER THE BSD LICENSE ON AN "AS IS" BASIS,                     \r
;WITHOUT WARRANTIES OR REPRESENTATIONS OF ANY KIND, EITHER EXPRESS OR IMPLIED.             \r
;\r
;Module Name:\r
;\r
;  EfiSetMem.asm\r
;\r
;Abstract:\r
;\r
;  This is the code that supports IA32-optimized SetMem service\r
;\r
;--*/\r
;---------------------------------------------------------------------------\r
    .686\r
    .model  flat,C\r
    .mmx\r
    .code\r
\r
;---------------------------------------------------------------------------\r
;VOID\r
;EfiCommonLibSetMem (\r
;  IN VOID   *Buffer,\r
;  IN UINTN  Count,\r
;  IN UINT8  Value\r
;  )\r
;/*++\r
;\r
;Input:  VOID   *Buffer - Pointer to buffer to write\r
;        UINTN  Count   - Number of bytes to write\r
;        UINT8  Value   - Value to write\r
;\r
;Output: None.\r
;\r
;Saves:\r
;\r
;Modifies:\r
;\r
;Description:  This function is an optimized set-memory function.\r
;\r
;Notes:  This function tries to set memory 8 bytes at a time. As a result, \r
;        it first picks up any misaligned bytes, then words, before getting \r
;        in the main loop that does the 8-byte clears.\r
;\r
;--*/\r
EfiCommonLibSetMem PROC\r
\r
    push   ebp\r
    mov    ebp, esp\r
    sub    esp, 10h; Reserve space for local variable UINT64 QWordValue @[ebp - 10H] & UINT64 MmxSave @[ebp - 18H]\r
    push   ebx\r
    push   edi\r
\r
    mov edx, [ebp + 0Ch] ; Count\r
    test edx, edx\r
    je _SetMemDone\r
\r
    push ebx\r
  \r
    mov eax, [ebp + 8]  ; Buffer\r
    mov bl, [ebp + 10h] ; Value\r
    mov edi, eax\r
    mov bh, bl\r
  \r
    cmp edx, 256\r
    jb _SetRemindingByte\r
  \r
    and al, 07h\r
    test al, al\r
    je _SetBlock\r
  \r
    mov eax, edi\r
    shr eax, 3\r
    inc eax\r
    shl eax, 3\r
    sub eax, edi\r
    cmp eax, edx\r
    jnb _SetRemindingByte\r
  \r
    sub edx, eax\r
    mov ecx, eax\r
\r
    mov al, bl\r
    rep stosb\r
\r
_SetBlock:\r
    mov eax, edx\r
    shr eax, 6\r
    test eax, eax\r
    je _SetRemindingByte\r
\r
    shl eax, 6\r
    sub edx, eax\r
    shr eax, 6\r
\r
    mov WORD PTR [ebp - 10H],     bx ; QWordValue[0]\r
    mov WORD PTR [ebp - 10H + 2], bx ; QWordValue[2]\r
    mov WORD PTR [ebp - 10H + 4], bx ; QWordValue[4]\r
    mov WORD PTR [ebp - 10H + 6], bx ; QWordValue[6]\r
 \r
  \r
    movq  [ebp - 8], mm0 ; Save mm0 to MmxSave\r
    movq  mm0, [ebp - 10H] ; Load QWordValue to mm0\r
\r
_B:\r
    movq  QWORD PTR ds:[edi], mm0\r
    movq  QWORD PTR ds:[edi+8], mm0\r
    movq  QWORD PTR ds:[edi+16], mm0\r
    movq  QWORD PTR ds:[edi+24], mm0\r
    movq  QWORD PTR ds:[edi+32], mm0\r
    movq  QWORD PTR ds:[edi+40], mm0\r
    movq  QWORD PTR ds:[edi+48], mm0\r
    movq  QWORD PTR ds:[edi+56], mm0\r
    add edi, 64\r
    dec eax\r
    jnz _B\r
  \r
; Restore mm0\r
    movq  mm0, [ebp - 8] ; Restore MmxSave to mm0\r
    emms                                 ; Exit MMX Instruction\r
  \r
_SetRemindingByte:\r
    mov ecx, edx\r
\r
    mov eax, ebx\r
    shl eax, 16\r
    mov ax, bx\r
    shr ecx, 2\r
    rep stosd\r
  \r
    mov ecx, edx\r
    and ecx, 3\r
    rep stosb\r
  \r
    pop ebx\r
\r
_SetMemDone:\r
\r
    pop edi\r
    pop ebx\r
    leave\r
    ret\r
\r
EfiCommonLibSetMem ENDP\r
	END\r