Update the copyright notice format

[mirror_edk2.git] / EdkCompatibilityPkg / Foundation / Library / Pei / PeiLib / X64 / ProcessorAsms.Asm

;------------------------------------------------------------------------------\r
;\r
; Copyright (c) 2005 - 2007, Intel Corporation                                                         \r
; All rights reserved. This program and the accompanying materials                          \r
; are licensed and made available under the terms and conditions of the BSD License         \r
; which accompanies this distribution.  The full text of the license may be found at        \r
; http://opensource.org/licenses/bsd-license.php                                            \r
;                                                                                           \r
; THE PROGRAM IS DISTRIBUTED UNDER THE BSD LICENSE ON AN "AS IS" BASIS,                     \r
; WITHOUT WARRANTIES OR REPRESENTATIONS OF ANY KIND, EITHER EXPRESS OR IMPLIED.             \r
; \r
; Module Name:\r
;   ProcessorAsms.Asm\r
;\r
; Abstract:\r
;   This is separated from processor.c to allow this functions to be built with /O1\r
;\r
;\r
;------------------------------------------------------------------------------\r
\r
text  SEGMENT\r
\r
\r
;\r
; Routine Description:\r
;   This allows the caller to switch the stack and goes to the new entry point\r
;\r
; Arguments:\r
;   EntryPoint      - Pointer to the location to enter // rcx\r
;   Parameter       - Parameter to pass in             // rdx\r
;   NewStack        - New Location of the stack        // r8\r
;   NewBsp          - New BSP                          // r9 - not used\r
;\r
; Returns:\r
;   Nothing. Goes to the Entry Point passing in the new parameters\r
;\r
SwitchStacks  PROC  PUBLIC\r
\r
    ; Adjust stack for\r
    ;   1) leave 4 registers space\r
    ;   2) let it 16 bytes aligned after call\r
    sub   r8, 20h\r
    and   r8w, 0fff0h    ; do not assume 16 bytes aligned\r
\r
    mov   rsp,  r8       ; rsp = NewStack\r
    mov   r10,  rcx      ; save EntryPoint\r
    mov   rcx,  rdx      ; Arg1 = Parameter\r
    call  r10            ; r10 = copy of EntryPoint\r
 ;\r
 ; no ret as we have a new stack and we jumped to the new location\r
 ;     \r
    ret\r
  \r
SwitchStacks    ENDP\r
\r
\r
EFI_SUCCESS                     equ     0\r
EFI_WARN_RETURN_FROM_LONG_JUMP  equ     5\r
\r
;\r
; Generated by h2inc run manually\r
;\r
_EFI_JUMP_BUFFER                STRUCT 2t\r
_rbx            QWORD           ?\r
_rsp            QWORD           ?\r
_rbp            QWORD           ?\r
_rdi            QWORD           ?\r
_rsi            QWORD           ?\r
_r10            QWORD           ?\r
_r11            QWORD           ?\r
_r12            QWORD           ?\r
_r13            QWORD           ?\r
_r14            QWORD           ?\r
_r15            QWORD           ?\r
_rip            QWORD           ?\r
_EFI_JUMP_BUFFER                ENDS\r
\r
EFI_JUMP_BUFFER         TYPEDEF         _EFI_JUMP_BUFFER\r
\r
\r
;\r
;Routine Description:\r
;\r
;  This routine implements the x64 variant of the SetJump call.  Its\r
;  responsibility is to store system state information for a possible\r
;  subsequent LongJump.\r
;\r
;Arguments:\r
;\r
;  Pointer to CPU context save buffer.\r
;\r
;Returns:\r
;\r
;  EFI_SUCCESS\r
;\r
; EFI_STATUS\r
; EFIAPI\r
; TransferControlLongJump (\r
;   IN EFI_PEI_TRANSFER_CONTROL_PROTOCOL  *This,\r
;   IN EFI_JUMP_BUFFER                    *Jump\r
;   );\r
;\r
; rcx - *This\r
; rdx - JumpBuffer\r
;\r
PUBLIC  TransferControlSetJump\r
TransferControlSetJump  PROC  \r
  mov   (EFI_JUMP_BUFFER PTR [rdx])._rbx, rbx\r
  mov   (EFI_JUMP_BUFFER PTR [rdx])._rsp, rsp\r
  mov   (EFI_JUMP_BUFFER PTR [rdx])._rbp, rbp\r
  mov   (EFI_JUMP_BUFFER PTR [rdx])._rdi, rdi\r
  mov   (EFI_JUMP_BUFFER PTR [rdx])._rsi, rsi\r
  mov   (EFI_JUMP_BUFFER PTR [rdx])._r10, r10\r
  mov   (EFI_JUMP_BUFFER PTR [rdx])._r11, r11\r
  mov   (EFI_JUMP_BUFFER PTR [rdx])._r12, r12\r
  mov   (EFI_JUMP_BUFFER PTR [rdx])._r13, r13\r
  mov   (EFI_JUMP_BUFFER PTR [rdx])._r14, r14\r
  mov   (EFI_JUMP_BUFFER PTR [rdx])._r15, r15\r
  mov   rax, QWORD PTR [rsp+0]\r
  mov   (EFI_JUMP_BUFFER PTR [rdx])._rip, rax\r
  mov   rax, EFI_SUCCESS  \r
  ret\r
  \r
TransferControlSetJump      ENDP\r
\r
;\r
; EFI_STATUS\r
; EFIAPI\r
; TransferControlLongJump (\r
;   IN EFI_PEI_TRANSFER_CONTROL_PROTOCOL  *This,  // rcx\r
;   IN EFI_JUMP_BUFFER                    *Jump   // rdx\r
;   );\r
;\r
;\r
PUBLIC  TransferControlLongJump\r
TransferControlLongJump  PROC  \r
  ; set return from SetJump to EFI_WARN_RETURN_FROM_LONG_JUMP\r
  mov   rax, EFI_WARN_RETURN_FROM_LONG_JUMP          \r
  mov   rbx, (EFI_JUMP_BUFFER PTR [rdx])._rbx\r
  mov   rsp, (EFI_JUMP_BUFFER PTR [rdx])._rsp\r
  mov   rbp, (EFI_JUMP_BUFFER PTR [rdx])._rbp\r
  mov   rdi, (EFI_JUMP_BUFFER PTR [rdx])._rdi\r
  mov   rsi, (EFI_JUMP_BUFFER PTR [rdx])._rsi\r
  mov   r10, (EFI_JUMP_BUFFER PTR [rdx])._r10\r
  mov   r11, (EFI_JUMP_BUFFER PTR [rdx])._r11\r
  mov   r12, (EFI_JUMP_BUFFER PTR [rdx])._r12\r
  mov   r13, (EFI_JUMP_BUFFER PTR [rdx])._r13\r
  mov   r14, (EFI_JUMP_BUFFER PTR [rdx])._r14\r
  mov   r15, (EFI_JUMP_BUFFER PTR [rdx])._r15\r
  add   rsp, 8                                       ;pop the eip\r
  jmp   QWORD PTR (EFI_JUMP_BUFFER PTR [rdx])._rip\r
  ; set return from SetJump to EFI_WARN_RETURN_FROM_LONG_JUMP\r
  mov   rax, EFI_WARN_RETURN_FROM_LONG_JUMP\r
  ret\r
TransferControlLongJump  ENDP\r
\r
text  ENDS\r
END\r