EmulatorPkg: Replace BSD License with BSD+Patent License

[mirror_edk2.git] / EmulatorPkg / Sec / X64 / SwitchRam.S

#------------------------------------------------------------------------------\r
#\r
# Copyright (c) 2006 - 2011, Intel Corporation. All rights reserved.<BR>\r
# Portitions copyright (c) 2011, Apple Inc. All rights reserved.\r
# SPDX-License-Identifier: BSD-2-Clause-Patent\r
#\r
#------------------------------------------------------------------------------\r
\r
\r
\r
//  EFI_STATUS\r
//  EFIAPI\r
//  SecTemporaryRamSupport (\r
//    IN CONST EFI_PEI_SERVICES   **PeiServices,         // %rcx\r
//    IN EFI_PHYSICAL_ADDRESS     TemporaryMemoryBase,   // %rdx\r
//    IN EFI_PHYSICAL_ADDRESS     PermanentMemoryBase,   // %r8\r
//    IN UINTN                    CopySize               // %r9\r
//    )\r
//\r
ASM_GLOBAL ASM_PFX(SecTemporaryRamSupport)\r
ASM_PFX(SecTemporaryRamSupport):\r
  // Adjust callers %rbp to account for stack move\r
  subq    %rdx, %rbp     // Calc offset of %rbp in Temp Memory\r
  addq    %r8,  %rbp     // add in permanent base to offset\r
\r
  pushq   %rbp           // stack frame is for the debugger\r
  movq    %rsp, %rbp\r
\r
  pushq   %rdx          // Save TemporaryMemoryBase\r
  pushq   %r8           // Save PermanentMemoryBase\r
  pushq   %r9           // Save CopySize\r
\r
  //\r
  // Copy all of temp RAM to permanent memory, including stack\r
  //\r
  // CopyMem (PermanentMemoryBase, TemporaryMemoryBase, CopySize);\r
  //          %rcx,                %rdx,                %r8\r
  movq    %r8,  %rcx    // Shift arguments\r
  movq    %r9,  %r8\r
  subq    $0x28, %rsp   // Allocate register spill area & 16-byte align stack\r
  call    ASM_PFX(CopyMem)\r
  // Temp mem stack now copied to permanent location. %esp still in temp memory\r
  addq    $0x28, %rsp\r
\r
  popq    %r9           // CopySize (old stack)\r
  popq    %r8           // PermanentMemoryBase (old stack)\r
  popq    %rdx          // TemporaryMemoryBase (old stack)\r
\r
  movq    %rsp, %rcx    // Move to new stack\r
  subq    %rdx, %rcx    // Calc offset of stack in Temp Memory\r
  addq    %r8,  %rcx    // Calc PermanentMemoryBase address\r
  movq    %rcx, %rsp    // Update stack\r
  // Stack now points to permanent memory\r
\r
  // ZeroMem (TemporaryMemoryBase /* rcx */, CopySize /* rdx */);\r
  movq    %rdx, %rcx\r
  movq    %r9,  %rdx\r
  subq    $0x28, %rsp   // Allocate register spill area & 16-byte align stack\r
  call    ASM_PFX(ZeroMem)\r
  addq    $0x28, %rsp\r
\r
  // This data comes off the NEW stack\r
  popq    %rbp\r
  ret\r
\r
\r