Added generic EFIABI SEC to InOsEmuPkg. Add library to abstract FV cracking and remov...

[mirror_edk2.git] / InOsEmuPkg / Sec / X64 / SwitchRam.S

#------------------------------------------------------------------------------\r
#\r
# Copyright (c) 2006 - 2008, Intel Corporation. All rights reserved.<BR>\r
# Portitions copyright (c) 2011, Apple Inc. All rights reserved.\r
# This program and the accompanying materials\r
# are licensed and made available under the terms and conditions of the BSD License\r
# which accompanies this distribution.  The full text of the license may be found at\r
# http://opensource.org/licenses/bsd-license.php.\r
#\r
# THE PROGRAM IS DISTRIBUTED UNDER THE BSD LICENSE ON AN "AS IS" BASIS,\r
# WITHOUT WARRANTIES OR REPRESENTATIONS OF ANY KIND, EITHER EXPRESS OR IMPLIED.\r
#\r
#------------------------------------------------------------------------------\r
\r
\r
\r
//  EFI_STATUS\r
//  EFIAPI\r
//  SecTemporaryRamSupport (\r
//    IN CONST EFI_PEI_SERVICES   **PeiServices,         // %rcx\r
//    IN EFI_PHYSICAL_ADDRESS     TemporaryMemoryBase,   // %rdx\r
//    IN EFI_PHYSICAL_ADDRESS     PermanentMemoryBase,   // %r8 \r
//    IN UINTN                    CopySize               // %r9\r
//    )\r
//\r
ASM_GLOBAL ASM_PFX(SecTemporaryRamSupport)\r
ASM_PFX(SecTemporaryRamSupport):\r
  // Adjust callers %rbp to account for stack move\r
  subq    %rdx, %rbp     // Calc offset of %rbp in Temp Memory\r
  addq    %r8,  %rbp     // add in permanent base to offset\r
  \r
  pushq   %rbp           // stack frame is for the debugger\r
  movq    %rsp, %rbp\r
\r
  pushq   %rdx          // Save TemporaryMemoryBase\r
  pushq   %r8           // Save PermanentMemoryBase\r
  pushq   %r9           // Save CopySize\r
  \r
  //\r
  // Copy all of temp RAM to permanent memory, including stack\r
  //\r
  // CopyMem (PermanentMemoryBase, TemporaryMemoryBase, CopySize);\r
  //          %rcx,                %rdx,                %r8\r
  movq    %r8,  %rcx    // Shift arguments\r
  movq    %r9,  %r8\r
  call    ASM_PFX(CopyMem)\r
  // Temp mem stack now copied to permanent location. %esp still in temp memory\r
  \r
  popq    %r9           // CopySize (old stack)\r
  popq    %r8           // PermanentMemoryBase (old stack)\r
  popq    %rdx          // TemporaryMemoryBase (old stack)\r
    \r
  movq    %rsp, %rcx    // Move to new stack\r
  subq    %rdx, %rcx    // Calc offset of stack in Temp Memory\r
  addq    %r8,  %rcx    // Calc PermanentMemoryBase address\r
  movq    %rcx, %rsp    // Update stack \r
  // Stack now points to permanent memory\r
  \r
  // ZeroMem (TemporaryMemoryBase /* rcx */, CopySize /* rdx */);\r
  movq    %rdx, %rcx\r
  movq    %r9,  %rdx\r
  call    ASM_PFX(ZeroMem)\r
\r
  // This data comes off the NEW stack\r
  popq    %rbp\r
  ret\r
\r
\r