Remove assumption on EAX and R10 usage for IA32 compiler and X64 compiler.

[mirror_edk2.git] / MdeModulePkg / Universal / EbcDxe / X64 / EbcLowLevel.S

#/** @file\r
#  \r
#    This code provides low level routines that support the Virtual Machine\r
#   for option ROMs.\r
#  \r
#  Copyright (c) 2007 - 2011, Intel Corporation. All rights reserved.<BR>\r
#  This program and the accompanying materials\r
#  are licensed and made available under the terms and conditions of the BSD License\r
#  which accompanies this distribution.  The full text of the license may be found at\r
#  http://opensource.org/licenses/bsd-license.php\r
#  \r
#  THE PROGRAM IS DISTRIBUTED UNDER THE BSD LICENSE ON AN "AS IS" BASIS,\r
#  WITHOUT WARRANTIES OR REPRESENTATIONS OF ANY KIND, EITHER EXPRESS OR IMPLIED.\r
#  \r
#**/\r
\r
#---------------------------------------------------------------------------\r
# Equate files needed.\r
#---------------------------------------------------------------------------\r
\r
ASM_GLOBAL ASM_PFX(CopyMem);\r
ASM_GLOBAL ASM_PFX(EbcInterpret);\r
ASM_GLOBAL ASM_PFX(ExecuteEbcImageEntryPoint);\r
\r
#****************************************************************************\r
# EbcLLCALLEX\r
#\r
# This function is called to execute an EBC CALLEX instruction.\r
# This instruction requires that we thunk out to external native\r
# code. For x64, we switch stacks, copy the arguments to the stack\r
# and jump to the specified function.\r
# On return, we restore the stack pointer to its original location.\r
#\r
# Destroys no working registers.\r
#****************************************************************************\r
# VOID EbcLLCALLEXNative(UINTN FuncAddr, UINTN NewStackPointer, VOID *FramePtr)\r
ASM_GLOBAL ASM_PFX(EbcLLCALLEXNative);\r
ASM_PFX(EbcLLCALLEXNative):\r
      push   %rbp\r
      push   %rbx\r
      mov    %rsp, %rbp\r
      # Function prolog\r
\r
      # Copy FuncAddr to a preserved register.\r
      mov    %rcx, %rbx\r
\r
      # Set stack pointer to new value\r
      sub    %rdx, %r8  \r
      sub    %r8,  %rsp \r
      mov    %rsp, %rcx\r
      sub    $0x20, %rsp \r
      call   ASM_PFX(CopyMem)\r
      add    $0x20, %rsp\r
\r
      # Considering the worst case, load 4 potiential arguments\r
      # into registers.\r
      mov    (%rsp), %rcx\r
      mov    0x8(%rsp), %rdx\r
      mov    0x10(%rsp), %r8\r
      mov    0x18(%rsp), %r9\r
\r
      # Now call the external routine\r
      call  *%rbx\r
\r
      # Function epilog\r
      mov      %rbp, %rsp\r
      pop      %rbx\r
      pop      %rbp\r
      ret\r
\r
ASM_GLOBAL ASM_PFX(EbcLLEbcInterpret);\r
ASM_PFX(EbcLLEbcInterpret):\r
    # save old parameter to stack\r
    mov  %rcx, 0x8(%rsp)\r
    mov  %rdx, 0x10(%rsp)\r
    mov  %r8, 0x18(%rsp)\r
    mov  %r9, 0x20(%rsp)\r
\r
    # Construct new stack\r
    push %rbp\r
    mov  %rsp, %rbp\r
    push %rsi\r
    push %rdi\r
    push %rbx\r
    sub  $0x80, %rsp\r
    push %r10\r
    mov  %rbp, %rsi\r
    add  $0x10, %rsi\r
    mov  %rsp, %rdi\r
    add  $0x8, %rdi\r
    mov  $0x10, %rcx\r
    rep  movsq\r
    \r
    # build new paramater calling convention\r
    mov  0x18(%rsp), %r9\r
    mov  0x10(%rsp), %r8\r
    mov  0x8(%rsp), %rdx\r
    mov  %r10, %rcx\r
\r
    # call C-code\r
    call ASM_PFX(EbcInterpret)\r
    add  $0x88, %esp\r
    pop  %rbx\r
    pop  %rdi\r
    pop  %rsi\r
    pop  %rbp\r
    ret\r
\r
ASM_GLOBAL ASM_PFX(EbcLLExecuteEbcImageEntryPoint);\r
ASM_PFX(EbcLLExecuteEbcImageEntryPoint):\r
    # build new paramater calling convention\r
    mov  %rdx, %r8\r
    mov  %rcx, %rdx\r
    mov  %r10, %rcx\r
\r
    # call C-code\r
    sub  $0x28, %rsp\r
    call ASM_PFX(ExecuteEbcImageEntryPoint)\r
    add  $0x28, %rsp\r
    ret\r