Update copyright for files modified in this year

[mirror_edk2.git] / MdePkg / Library / BaseMemoryLibSse2 / Ia32 / SetMem32.S

#------------------------------------------------------------------------------\r
#\r
# Copyright (c) 2006 - 2008, Intel Corporation\r
# All rights reserved. This program and the accompanying materials\r
# are licensed and made available under the terms and conditions of the BSD License\r
# which accompanies this distribution.  The full text of the license may be found at\r
# http://opensource.org/licenses/bsd-license.php\r
#\r
# THE PROGRAM IS DISTRIBUTED UNDER THE BSD LICENSE ON AN "AS IS" BASIS,\r
# WITHOUT WARRANTIES OR REPRESENTATIONS OF ANY KIND, EITHER EXPRESS OR IMPLIED.\r
#\r
# Module Name:\r
#\r
#   SetMem32.asm\r
#\r
# Abstract:\r
#\r
#   SetMem32 function\r
#\r
# Notes:\r
#\r
#------------------------------------------------------------------------------\r
\r
.globl _InternalMemSetMem32\r
\r
#------------------------------------------------------------------------------\r
#  VOID *\r
#  EFIAPI\r
#  InternalMemSetMem32 (\r
#    IN VOID   *Buffer,\r
#    IN UINTN  Count,\r
#    IN UINT32 Value\r
#    );\r
#------------------------------------------------------------------------------\r
_InternalMemSetMem32:\r
    push    %edi\r
    movl    12(%esp), %edx\r
    movl    8(%esp), %edi\r
    xorl    %ecx, %ecx\r
    subl    %edi, %ecx\r
    andl    $15, %ecx                   # ecx + edi aligns on 16-byte boundary\r
    movl    16(%esp), %eax\r
    jz      L0\r
    shrl    $2, %ecx\r
    cmpl    %edx, %ecx\r
    cmova   %edx, %ecx\r
    subl    %ecx, %edx\r
    rep\r
    stosl\r
L0:\r
    movl    %edx, %ecx\r
    andl    $3, %edx\r
    shrl    $2, %ecx\r
    jz      L_SetDwords\r
    movd    %eax, %xmm0\r
    pshufd  $0, %xmm0, %xmm0\r
L1:\r
    movntdq %xmm0, (%edi)\r
    addl    $16, %edi\r
    loop    L1\r
    mfence\r
L_SetDwords:\r
    movl    %edx, %ecx\r
    rep\r
    stosl\r
    movl    8(%esp), %eax\r
    pop     %edi\r
    ret\r