OvmfPkg LoadLinuxLib: Use kernel's EFI entry point where available

[mirror_edk2.git] / OvmfPkg / Library / LoadLinuxLib / X64 / JumpToKernel.S

#------------------------------------------------------------------------------\r
#\r
# Copyright (c) 2006 - 2013, Intel Corporation. All rights reserved.<BR>\r
#\r
# This program and the accompanying materials\r
# are licensed and made available under the terms and conditions of the BSD License\r
# which accompanies this distribution.  The full text of the license may be found at\r
# http://opensource.org/licenses/bsd-license.php.\r
#\r
# THE PROGRAM IS DISTRIBUTED UNDER THE BSD LICENSE ON AN "AS IS" BASIS,\r
# WITHOUT WARRANTIES OR REPRESENTATIONS OF ANY KIND, EITHER EXPRESS OR IMPLIED.\r
#\r
#------------------------------------------------------------------------------\r
\r
ASM_GLOBAL ASM_PFX(JumpToKernel)\r
ASM_GLOBAL ASM_PFX(JumpToUefiKernel)\r
\r
#------------------------------------------------------------------------------\r
# VOID\r
# EFIAPI\r
# JumpToKernel (\r
#   VOID *KernelStart,         // %rcx\r
#   VOID *KernelBootParams     // %rdx\r
#   );\r
#------------------------------------------------------------------------------\r
ASM_PFX(JumpToKernel):\r
\r
    // Set up for executing kernel. BP in %esi, entry point on the stack\r
    // (64-bit when the 'ret' will use it as 32-bit, but we're little-endian)\r
    movq    %rdx, %rsi\r
    pushq   %rcx\r
\r
    // Jump into the compatibility mode CS\r
    pushq   $0x10\r
    leaq    1f(%rip), %rax\r
    pushq   %rax\r
    .byte   0x48, 0xcb                      // retfq\r
\r
1:  // Now in compatibility mode\r
.code32\r
    movl    $0x18, %eax\r
    movl    %eax, %ds\r
    movl    %eax, %es\r
    movl    %eax, %fs\r
    movl    %eax, %gs\r
    movl    %eax, %ss\r
\r
    // Disable paging\r
    movl    %cr0, %eax\r
    btcl    $31, %eax\r
    movl    %eax, %cr0\r
\r
    // Disable long mode in EFER\r
    movl    $0x0c0000080, %ecx\r
    rdmsr\r
    btcl    $8, %eax\r
    wrmsr\r
\r
    // Disable PAE\r
    movl    %cr4, %eax\r
    btcl    $5, %eax\r
    movl    %eax, %cr4\r
\r
    // Zero registers and 'return' to kernel\r
    xorl    %ebp, %ebp\r
    xorl    %edi, %edi\r
    xorl    %ebx, %ebx\r
    ret\r
.code64\r
\r
#------------------------------------------------------------------------------\r
# VOID\r
# EFIAPI\r
# JumpToUefiKernel (\r
#   EFI_HANDLE ImageHandle,        // rcx\r
#   EFI_SYSTEM_TABLE *SystemTable, // rdx\r
#   VOID *KernelBootParams,        // r8\r
#   VOID *KernelStart              // r9\r
#   );\r
#------------------------------------------------------------------------------\r
ASM_PFX(JumpToUefiKernel):\r
    movq    %rcx, %rdi\r
    movq    %rdx, %rsi\r
    movq    %r8, %rdx\r
    xor     %rax, %rax\r
    movl    0x264(%r8), %eax\r
    addq    %rax, %r9\r
    addq    $0x200, %r9\r
    callq   %r9\r
    ret\r
\r