UefiCpuPkg: Move AsmRelocateApLoopStart from Mpfuncs.nasm to AmdSev.nasm

[mirror_edk2.git] / OvmfPkg / QemuVideoDxe / VbeShim.asm

;------------------------------------------------------------------------------\r
; @file\r
; A minimal Int10h stub that allows the Windows 2008 R2 SP1 UEFI guest's buggy,\r
; default VGA driver to switch to 1024x768x32, on the stdvga and QXL video\r
; cards of QEMU.\r
;\r
; Copyright (C) 2014, Red Hat, Inc.\r
; Copyright (c) 2013 - 2014, Intel Corporation. All rights reserved.<BR>\r
;\r
; SPDX-License-Identifier: BSD-2-Clause-Patent\r
;\r
;------------------------------------------------------------------------------\r
\r
; enable this macro for debug messages\r
;%define DEBUG\r
\r
%macro DebugLog 1\r
%ifdef DEBUG\r
  push       si\r
  mov        si, %1\r
  call       PrintStringSi\r
  pop        si\r
%endif\r
%endmacro\r
\r
\r
BITS 16\r
ORG 0\r
\r
VbeInfo:\r
TIMES 256 nop\r
\r
VbeModeInfo:\r
TIMES 256 nop\r
\r
\r
Handler:\r
  cmp        ax, 0x4f00\r
  je         GetInfo\r
  cmp        ax, 0x4f01\r
  je         GetModeInfo\r
  cmp        ax, 0x4f02\r
  je         SetMode\r
  cmp        ax, 0x4f03\r
  je         GetMode\r
  cmp        ax, 0x4f10\r
  je         GetPmCapabilities\r
  cmp        ax, 0x4f15\r
  je         ReadEdid\r
  cmp        ah, 0x00\r
  je         SetModeLegacy\r
  DebugLog   StrUnknownFunction\r
Hang:\r
  jmp        Hang\r
\r
\r
GetInfo:\r
  push       es\r
  push       di\r
  push       ds\r
  push       si\r
  push       cx\r
\r
  DebugLog   StrEnterGetInfo\r
\r
  ; target (es:di) set on input\r
  push       cs\r
  pop        ds\r
  mov        si, VbeInfo\r
  ; source (ds:si) set now\r
\r
  mov        cx, 256\r
  cld\r
  rep movsb\r
\r
  pop        cx\r
  pop        si\r
  pop        ds\r
  pop        di\r
  pop        es\r
  jmp        Success\r
\r
\r
GetModeInfo:\r
  push       es\r
  push       di\r
  push       ds\r
  push       si\r
  push       cx\r
\r
  DebugLog   StrEnterGetModeInfo\r
\r
  and        cx, ~0x4000 ; clear potentially set LFB bit in mode number\r
  cmp        cx, 0x00f1\r
  je         KnownMode1\r
  DebugLog   StrUnknownMode\r
  jmp        Hang\r
KnownMode1:\r
  ; target (es:di) set on input\r
  push       cs\r
  pop        ds\r
  mov        si, VbeModeInfo\r
  ; source (ds:si) set now\r
\r
  mov        cx, 256\r
  cld\r
  rep movsb\r
\r
  pop        cx\r
  pop        si\r
  pop        ds\r
  pop        di\r
  pop        es\r
  jmp        Success\r
\r
\r
%define ATT_ADDRESS_REGISTER   0x03c0\r
%define VBE_DISPI_IOPORT_INDEX 0x01ce\r
%define VBE_DISPI_IOPORT_DATA  0x01d0\r
\r
%define VBE_DISPI_INDEX_XRES        0x1\r
%define VBE_DISPI_INDEX_YRES        0x2\r
%define VBE_DISPI_INDEX_BPP         0x3\r
%define VBE_DISPI_INDEX_ENABLE      0x4\r
%define VBE_DISPI_INDEX_BANK        0x5\r
%define VBE_DISPI_INDEX_VIRT_WIDTH  0x6\r
%define VBE_DISPI_INDEX_VIRT_HEIGHT 0x7\r
%define VBE_DISPI_INDEX_X_OFFSET    0x8\r
%define VBE_DISPI_INDEX_Y_OFFSET    0x9\r
\r
%define VBE_DISPI_ENABLED     0x01\r
%define VBE_DISPI_LFB_ENABLED 0x40\r
\r
%macro BochsWrite 2\r
  push       dx\r
  push       ax\r
\r
  mov        dx, VBE_DISPI_IOPORT_INDEX\r
  mov        ax, %1\r
  out        dx, ax\r
\r
  mov        dx, VBE_DISPI_IOPORT_DATA\r
  mov        ax, %2\r
  out        dx, ax\r
\r
  pop        ax\r
  pop        dx\r
%endmacro\r
\r
SetMode:\r
  push       dx\r
  push       ax\r
\r
  DebugLog   StrEnterSetMode\r
\r
  cmp        bx, 0x40f1\r
  je         KnownMode2\r
  DebugLog   StrUnknownMode\r
  jmp        Hang\r
KnownMode2:\r
\r
  ; unblank\r
  mov        dx, ATT_ADDRESS_REGISTER\r
  mov        al, 0x20\r
  out        dx, al\r
\r
  BochsWrite VBE_DISPI_INDEX_ENABLE,        0\r
  BochsWrite VBE_DISPI_INDEX_BANK,          0\r
  BochsWrite VBE_DISPI_INDEX_X_OFFSET,      0\r
  BochsWrite VBE_DISPI_INDEX_Y_OFFSET,      0\r
  BochsWrite VBE_DISPI_INDEX_BPP,          32\r
  BochsWrite VBE_DISPI_INDEX_XRES,       1024\r
  BochsWrite VBE_DISPI_INDEX_VIRT_WIDTH, 1024\r
  BochsWrite VBE_DISPI_INDEX_YRES,        768\r
  BochsWrite VBE_DISPI_INDEX_VIRT_HEIGHT, 768\r
  BochsWrite VBE_DISPI_INDEX_ENABLE, VBE_DISPI_ENABLED | VBE_DISPI_LFB_ENABLED\r
\r
  pop        ax\r
  pop        dx\r
  jmp        Success\r
\r
\r
GetMode:\r
  DebugLog   StrEnterGetMode\r
  mov        bx, 0x40f1\r
  jmp        Success\r
\r
\r
GetPmCapabilities:\r
  DebugLog   StrGetPmCapabilities\r
  jmp        Unsupported\r
\r
\r
ReadEdid:\r
  DebugLog   StrReadEdid\r
  jmp        Unsupported\r
\r
\r
SetModeLegacy:\r
  DebugLog   StrEnterSetModeLegacy\r
\r
  cmp        al, 0x03\r
  je         KnownMode3\r
  cmp        al, 0x12\r
  je         KnownMode4\r
  DebugLog   StrUnknownMode\r
  jmp        Hang\r
KnownMode3:\r
  mov        al, 0x30\r
  jmp        SetModeLegacyDone\r
KnownMode4:\r
  mov        al, 0x20\r
SetModeLegacyDone:\r
  DebugLog   StrExitSuccess\r
  iret\r
\r
\r
Success:\r
  DebugLog   StrExitSuccess\r
  mov        ax, 0x004f\r
  iret\r
\r
\r
Unsupported:\r
  DebugLog   StrExitUnsupported\r
  mov        ax, 0x014f\r
  iret\r
\r
\r
%ifdef DEBUG\r
PrintStringSi:\r
  pusha\r
  push       ds ; save original\r
  push       cs\r
  pop        ds\r
  mov        dx, 0x0402\r
PrintStringSiLoop:\r
  lodsb\r
  cmp        al, 0\r
  je         PrintStringSiDone\r
  out        dx, al\r
  jmp        PrintStringSiLoop\r
PrintStringSiDone:\r
  pop        ds ; restore original\r
  popa\r
  ret\r
\r
\r
StrExitSuccess:\r
  db 'Exit', 0x0a, 0\r
\r
StrExitUnsupported:\r
  db 'Unsupported', 0x0a, 0\r
\r
StrUnknownFunction:\r
  db 'Unknown Function', 0x0a, 0\r
\r
StrEnterGetInfo:\r
  db 'GetInfo', 0x0a, 0\r
\r
StrEnterGetModeInfo:\r
  db 'GetModeInfo', 0x0a, 0\r
\r
StrEnterGetMode:\r
  db 'GetMode', 0x0a, 0\r
\r
StrEnterSetMode:\r
  db 'SetMode', 0x0a, 0\r
\r
StrEnterSetModeLegacy:\r
  db 'SetModeLegacy', 0x0a, 0\r
\r
StrUnknownMode:\r
  db 'Unknown Mode', 0x0a, 0\r
\r
StrGetPmCapabilities:\r
  db 'GetPmCapabilities', 0x0a, 0\r
\r
StrReadEdid:\r
  db 'ReadEdid', 0x0a, 0\r
%endif\r