OvmfPkg X64 ResetVector: Move page tables from 512KB to 8MB

[mirror_edk2.git] / OvmfPkg / ResetVector / Ia32 / PageTables64.asm

;------------------------------------------------------------------------------\r
; @file\r
; Sets the CR3 register for 64-bit paging\r
;\r
; Copyright (c) 2008 - 2013, Intel Corporation. All rights reserved.<BR>\r
; This program and the accompanying materials\r
; are licensed and made available under the terms and conditions of the BSD License\r
; which accompanies this distribution.  The full text of the license may be found at\r
; http://opensource.org/licenses/bsd-license.php\r
;\r
; THE PROGRAM IS DISTRIBUTED UNDER THE BSD LICENSE ON AN "AS IS" BASIS,\r
; WITHOUT WARRANTIES OR REPRESENTATIONS OF ANY KIND, EITHER EXPRESS OR IMPLIED.\r
;\r
;------------------------------------------------------------------------------\r
\r
BITS    32\r
\r
%define PAGE_PRESENT            0x01\r
%define PAGE_READ_WRITE         0x02\r
%define PAGE_USER_SUPERVISOR    0x04\r
%define PAGE_WRITE_THROUGH      0x08\r
%define PAGE_CACHE_DISABLE     0x010\r
%define PAGE_ACCESSED          0x020\r
%define PAGE_DIRTY             0x040\r
%define PAGE_PAT               0x080\r
%define PAGE_GLOBAL           0x0100\r
%define PAGE_2M_MBO            0x080\r
%define PAGE_2M_PAT          0x01000\r
\r
%define PAGE_2M_PDE_ATTR (PAGE_2M_MBO + \\r
                          PAGE_ACCESSED + \\r
                          PAGE_DIRTY + \\r
                          PAGE_READ_WRITE + \\r
                          PAGE_PRESENT)\r
\r
%define PAGE_PDP_ATTR (PAGE_ACCESSED + \\r
                       PAGE_READ_WRITE + \\r
                       PAGE_PRESENT)\r
\r
\r
;\r
; Modified:  EAX, ECX\r
;\r
SetCr3ForPageTables64:\r
\r
    ;\r
    ; For OVMF, build some initial page tables at 0x800000-0x806000.\r
    ;\r
    ; This range should match with PcdOvmfSecPageTablesBase and\r
    ; PcdOvmfSecPageTablesSize which are declared in the FDF files.\r
    ;\r
    ; At the end of PEI, the pages tables will be rebuilt into a\r
    ; more permanent location by DxeIpl.\r
    ;\r
\r
    mov     ecx, 6 * 0x1000 / 4\r
    xor     eax, eax\r
clearPageTablesMemoryLoop:\r
    mov     dword[ecx * 4 + 0x800000 - 4], eax\r
    loop    clearPageTablesMemoryLoop\r
\r
    ;\r
    ; Top level Page Directory Pointers (1 * 512GB entry)\r
    ;\r
    mov     dword[0x800000], 0x801000 + PAGE_PDP_ATTR\r
\r
    ;\r
    ; Next level Page Directory Pointers (4 * 1GB entries => 4GB)\r
    ;\r
    mov     dword[0x801000], 0x802000 + PAGE_PDP_ATTR\r
    mov     dword[0x801008], 0x803000 + PAGE_PDP_ATTR\r
    mov     dword[0x801010], 0x804000 + PAGE_PDP_ATTR\r
    mov     dword[0x801018], 0x805000 + PAGE_PDP_ATTR\r
\r
    ;\r
    ; Page Table Entries (2048 * 2MB entries => 4GB)\r
    ;\r
    mov     ecx, 0x800\r
pageTableEntriesLoop:\r
    mov     eax, ecx\r
    dec     eax\r
    shl     eax, 21\r
    add     eax, PAGE_2M_PDE_ATTR\r
    mov     [ecx * 8 + 0x802000 - 8], eax\r
    loop    pageTableEntriesLoop\r
\r
    ;\r
    ; Set CR3 now that the paging structures are available\r
    ;\r
    mov     eax, 0x800000\r
    mov     cr3, eax\r
\r
    OneTimeCallRet SetCr3ForPageTables64\r